lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util   qw/first/;
  12 use Scalar::Util qw/blessed/;
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.55';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^(not )?in$/i,      handler => '_where_field_IN'},
  30 );
  31
  32 #======================================================================
  33 # DEBUGGING AND ERROR REPORTING
  34 #======================================================================
  35
  36 sub _debug {
  37   return unless $_[0]->{debug}; shift; # a little faster
  38   my $func = (caller(1))[3];
  39   warn "[$func] ", @_, "\n";
  40 }
  41
  42 sub belch (@) {
  43   my($func) = (caller(1))[3];
  44   carp "[$func] Warning: ", @_;
  45 }
  46
  47 sub puke (@) {
  48   my($func) = (caller(1))[3];
  49   croak "[$func] Fatal: ", @_;
  50 }
  51
  52
  53 #======================================================================
  54 # NEW
  55 #======================================================================
  56
  57 sub new {
  58   my $self = shift;
  59   my $class = ref($self) || $self;
  60   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  61
  62   # choose our case by keeping an option around
  63   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  64
  65   # default logic for interpreting arrayrefs
  66   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  67
  68   # how to return bind vars
  69   # LDNOTE: changed nwiger code : why this 'delete' ??
  70   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  71   $opt{bindtype} ||= 'normal';
  72
  73   # default comparison is "=", but can be overridden
  74   $opt{cmp} ||= '=';
  75
  76   # try to recognize which are the 'equality' and 'unequality' ops
  77   # (temporary quickfix, should go through a more seasoned API)
  78  $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  79  $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  80
  81   # SQL booleans
  82   $opt{sqltrue}  ||= '1=1';
  83   $opt{sqlfalse} ||= '0=1';
  84
  85   # special operators
  86   $opt{special_ops} ||= [];
  87   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  88
  89   return bless \%opt, $class;
  90 }
  91
  92
  93
  94 #======================================================================
  95 # INSERT methods
  96 #======================================================================
  97
  98 sub insert {
  99   my $self  = shift;
 100   my $table = $self->_table(shift);
 101   my $data  = shift || return;
 102
 103   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 104   my ($sql, @bind) = $self->$method($data);
 105   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 106   return wantarray ? ($sql, @bind) : $sql;
 107 }
 108
 109 sub _insert_HASHREF { # explicit list of fields and then values
 110   my ($self, $data) = @_;
 111
 112   my @fields = sort keys %$data;
 113
 114   my ($sql, @bind) = $self->_insert_values($data);
 115
 116   # assemble SQL
 117   $_ = $self->_quote($_) foreach @fields;
 118   $sql = "( ".join(", ", @fields).") ".$sql;
 119
 120   return ($sql, @bind);
 121 }
 122
 123 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 124   my ($self, $data) = @_;
 125
 126   # no names (arrayref) so can't generate bindtype
 127   $self->{bindtype} ne 'columns'
 128     or belch "can't do 'columns' bindtype when called with arrayref";
 129
 130   # fold the list of values into a hash of column name - value pairs
 131   # (where the column names are artificially generated, and their
 132   # lexicographical ordering keep the ordering of the original list)
 133   my $i = "a";  # incremented values will be in lexicographical order
 134   my $data_in_hash = { map { ($i++ => $_) } @$data };
 135
 136   return $self->_insert_values($data_in_hash);
 137 }
 138
 139 sub _insert_ARRAYREFREF { # literal SQL with bind
 140   my ($self, $data) = @_;
 141
 142   my ($sql, @bind) = @${$data};
 143   $self->_assert_bindval_matches_bindtype(@bind);
 144
 145   return ($sql, @bind);
 146 }
 147
 148
 149 sub _insert_SCALARREF { # literal SQL without bind
 150   my ($self, $data) = @_;
 151
 152   return ($$data);
 153 }
 154
 155 sub _insert_values {
 156   my ($self, $data) = @_;
 157
 158   my (@values, @all_bind);
 159   foreach my $column (sort keys %$data) {
 160     my $v = $data->{$column};
 161
 162     $self->_SWITCH_refkind($v, {
 163
 164       ARRAYREF => sub {
 165         if ($self->{array_datatypes}) { # if array datatype are activated
 166           push @values, '?';
 167           push @all_bind, $self->_bindtype($column, $v);
 168         }
 169         else {                          # else literal SQL with bind
 170           my ($sql, @bind) = @$v;
 171           $self->_assert_bindval_matches_bindtype(@bind);
 172           push @values, $sql;
 173           push @all_bind, @bind;
 174         }
 175       },
 176
 177       ARRAYREFREF => sub { # literal SQL with bind
 178         my ($sql, @bind) = @${$v};
 179         $self->_assert_bindval_matches_bindtype(@bind);
 180         push @values, $sql;
 181         push @all_bind, @bind;
 182       },
 183
 184       # THINK : anything useful to do with a HASHREF ?
 185       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 186         #TODO in SQLA >= 2.0 it will die instead
 187         belch "HASH ref as bind value in insert is not supported";
 188         push @values, '?';
 189         push @all_bind, $self->_bindtype($column, $v);
 190       },
 191
 192       SCALARREF => sub {  # literal SQL without bind
 193         push @values, $$v;
 194       },
 195
 196       SCALAR_or_UNDEF => sub {
 197         push @values, '?';
 198         push @all_bind, $self->_bindtype($column, $v);
 199       },
 200
 201      });
 202
 203   }
 204
 205   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 206   return ($sql, @all_bind);
 207 }
 208
 209
 210
 211 #======================================================================
 212 # UPDATE methods
 213 #======================================================================
 214
 215
 216 sub update {
 217   my $self  = shift;
 218   my $table = $self->_table(shift);
 219   my $data  = shift || return;
 220   my $where = shift;
 221
 222   # first build the 'SET' part of the sql statement
 223   my (@set, @all_bind);
 224   puke "Unsupported data type specified to \$sql->update"
 225     unless ref $data eq 'HASH';
 226
 227   for my $k (sort keys %$data) {
 228     my $v = $data->{$k};
 229     my $r = ref $v;
 230     my $label = $self->_quote($k);
 231
 232     $self->_SWITCH_refkind($v, {
 233       ARRAYREF => sub {
 234         if ($self->{array_datatypes}) { # array datatype
 235           push @set, "$label = ?";
 236           push @all_bind, $self->_bindtype($k, $v);
 237         }
 238         else {                          # literal SQL with bind
 239           my ($sql, @bind) = @$v;
 240           $self->_assert_bindval_matches_bindtype(@bind);
 241           push @set, "$label = $sql";
 242           push @all_bind, @bind;
 243         }
 244       },
 245       ARRAYREFREF => sub { # literal SQL with bind
 246         my ($sql, @bind) = @${$v};
 247         $self->_assert_bindval_matches_bindtype(@bind);
 248         push @set, "$label = $sql";
 249         push @all_bind, @bind;
 250       },
 251       SCALARREF => sub {  # literal SQL without bind
 252         push @set, "$label = $$v";
 253        },
 254       SCALAR_or_UNDEF => sub {
 255         push @set, "$label = ?";
 256         push @all_bind, $self->_bindtype($k, $v);
 257       },
 258     });
 259   }
 260
 261   # generate sql
 262   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 263           . join ', ', @set;
 264
 265   if ($where) {
 266     my($where_sql, @where_bind) = $self->where($where);
 267     $sql .= $where_sql;
 268     push @all_bind, @where_bind;
 269   }
 270
 271   return wantarray ? ($sql, @all_bind) : $sql;
 272 }
 273
 274
 275
 276
 277 #======================================================================
 278 # SELECT
 279 #======================================================================
 280
 281
 282 sub select {
 283   my $self   = shift;
 284   my $table  = $self->_table(shift);
 285   my $fields = shift || '*';
 286   my $where  = shift;
 287   my $order  = shift;
 288
 289   my($where_sql, @bind) = $self->where($where, $order);
 290
 291   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 292                                    : $fields;
 293   my $sql = join(' ', $self->_sqlcase('select'), $f,
 294                       $self->_sqlcase('from'),   $table)
 295           . $where_sql;
 296
 297   return wantarray ? ($sql, @bind) : $sql;
 298 }
 299
 300 #======================================================================
 301 # DELETE
 302 #======================================================================
 303
 304
 305 sub delete {
 306   my $self  = shift;
 307   my $table = $self->_table(shift);
 308   my $where = shift;
 309
 310
 311   my($where_sql, @bind) = $self->where($where);
 312   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 313
 314   return wantarray ? ($sql, @bind) : $sql;
 315 }
 316
 317
 318 #======================================================================
 319 # WHERE: entry point
 320 #======================================================================
 321
 322
 323
 324 # Finally, a separate routine just to handle WHERE clauses
 325 sub where {
 326   my ($self, $where, $order) = @_;
 327
 328   # where ?
 329   my ($sql, @bind) = $self->_recurse_where($where);
 330   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 331
 332   # order by?
 333   if ($order) {
 334     $sql .= $self->_order_by($order);
 335   }
 336
 337   return wantarray ? ($sql, @bind) : $sql;
 338 }
 339
 340
 341 sub _recurse_where {
 342   my ($self, $where, $logic) = @_;
 343
 344   # dispatch on appropriate method according to refkind of $where
 345   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 346
 347
 348   my ($sql, @bind) =  $self->$method($where, $logic);
 349
 350   # DBIx::Class directly calls _recurse_where in scalar context, so
 351   # we must implement it, even if not in the official API
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356
 357 #======================================================================
 358 # WHERE: top-level ARRAYREF
 359 #======================================================================
 360
 361
 362 sub _where_ARRAYREF {
 363   my ($self, $where, $logic) = @_;
 364
 365   $logic = uc($logic || $self->{logic});
 366   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 367
 368   my @clauses = @$where;
 369
 370   my (@sql_clauses, @all_bind);
 371   # need to use while() so can shift() for pairs
 372   while (my $el = shift @clauses) {
 373
 374     # switch according to kind of $el and get corresponding ($sql, @bind)
 375     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 376
 377       # skip empty elements, otherwise get invalid trailing AND stuff
 378       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 379
 380       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 381
 382       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 383            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 384            # side-effect: the first hashref within an array would change
 385            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 386            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 387            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 388
 389       SCALARREF => sub { ($$el);                                 },
 390
 391       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 392                         $self->_recurse_where({$el => shift(@clauses)})},
 393
 394       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 395     });
 396
 397     if ($sql) {
 398       push @sql_clauses, $sql;
 399       push @all_bind, @bind;
 400     }
 401   }
 402
 403   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 404 }
 405
 406 #======================================================================
 407 # WHERE: top-level ARRAYREFREF
 408 #======================================================================
 409
 410 sub _where_ARRAYREFREF {
 411     my ($self, $where) = @_;
 412     my ($sql, @bind) = @{${$where}};
 413
 414     return ($sql, @bind);
 415 }
 416
 417 #======================================================================
 418 # WHERE: top-level HASHREF
 419 #======================================================================
 420
 421 sub _where_HASHREF {
 422   my ($self, $where) = @_;
 423   my (@sql_clauses, @all_bind);
 424
 425   for my $k (sort keys %$where) {
 426     my $v = $where->{$k};
 427
 428     # ($k => $v) is either a special op or a regular hashpair
 429     my ($sql, @bind) = ($k =~ /^-(.+)/) ? $self->_where_op_in_hash($1, $v)
 430                                         : do {
 431          my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 432          $self->$method($k, $v);
 433        };
 434
 435     push @sql_clauses, $sql;
 436     push @all_bind, @bind;
 437   }
 438
 439   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 440 }
 441
 442
 443 sub _where_op_in_hash {
 444   my ($self, $op_str, $v) = @_;
 445
 446   $op_str =~ /^ (AND|OR|NEST) ( \_? \d* ) $/xi
 447     or puke "unknown operator: -$op_str";
 448
 449   my $op = uc($1); # uppercase, remove trailing digits
 450   if ($2) {
 451     belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 452           . "You probably wanted ...-and => [ $op_str => COND1, $op_str => COND2 ... ]";
 453   }
 454
 455   $self->_debug("OP(-$op) within hashref, recursing...");
 456
 457   $self->_SWITCH_refkind($v, {
 458
 459     ARRAYREF => sub {
 460       return $self->_where_ARRAYREF($v, $op eq 'NEST' ? '' : $op);
 461     },
 462
 463     HASHREF => sub {
 464       if ($op eq 'OR') {
 465         return $self->_where_ARRAYREF([ map { $_ => $v->{$_} } (sort keys %$v) ], 'OR');
 466       }
 467       else {                  # NEST | AND
 468         return $self->_where_HASHREF($v);
 469       }
 470     },
 471
 472     SCALARREF  => sub {         # literal SQL
 473       $op eq 'NEST'
 474         or puke "-$op => \\\$scalar not supported, use -nest => ...";
 475       return ($$v);
 476     },
 477
 478     ARRAYREFREF => sub {        # literal SQL
 479       $op eq 'NEST'
 480         or puke "-$op => \\[..] not supported, use -nest => ...";
 481       return @{${$v}};
 482     },
 483
 484     SCALAR => sub { # permissively interpreted as SQL
 485       $op eq 'NEST'
 486         or puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 487       belch "literal SQL should be -nest => \\'scalar' "
 488           . "instead of -nest => 'scalar' ";
 489       return ($v);
 490     },
 491
 492     UNDEF => sub {
 493       puke "-$op => undef not supported";
 494     },
 495    });
 496 }
 497
 498
 499 sub _where_hashpair_ARRAYREF {
 500   my ($self, $k, $v) = @_;
 501
 502   if( @$v ) {
 503     my @v = @$v; # need copy because of shift below
 504     $self->_debug("ARRAY($k) means distribute over elements");
 505
 506     # put apart first element if it is an operator (-and, -or)
 507     my $op = (
 508        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 509          ? shift @v
 510          : ''
 511     );
 512     my @distributed = map { {$k =>  $_} } @v;
 513
 514     if ($op) {
 515       $self->_debug("OP($op) reinjected into the distributed array");
 516       unshift @distributed, $op;
 517     }
 518
 519     my $logic = $op ? substr($op, 1) : '';
 520
 521     return $self->_recurse_where(\@distributed, $logic);
 522   }
 523   else {
 524     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 525     $self->_debug("empty ARRAY($k) means 0=1");
 526     return ($self->{sqlfalse});
 527   }
 528 }
 529
 530 sub _where_hashpair_HASHREF {
 531   my ($self, $k, $v, $logic) = @_;
 532   $logic ||= 'and';
 533
 534   my ($all_sql, @all_bind);
 535
 536   for my $op (sort keys %$v) {
 537     my $val = $v->{$op};
 538
 539     # put the operator in canonical form
 540     $op =~ s/^-//;       # remove initial dash
 541     $op =~ tr/_/ /;      # underscores become spaces
 542     $op =~ s/^\s+//;     # no initial space
 543     $op =~ s/\s+$//;     # no final space
 544     $op =~ s/\s+/ /;     # multiple spaces become one
 545
 546     my ($sql, @bind);
 547
 548     # CASE: special operators like -in or -between
 549     my $special_op = first {$op =~ $_->{regex}} @{$self->{special_ops}};
 550     if ($special_op) {
 551       my $handler = $special_op->{handler};
 552       if (! $handler) {
 553         puke "No handler supplied for special operator matching $special_op->{regex}";
 554       }
 555       elsif (not ref $handler) {
 556         ($sql, @bind) = $self->$handler ($k, $op, $val);
 557       }
 558       elsif (ref $handler eq 'CODE') {
 559         ($sql, @bind) = $handler->($self, $k, $op, $val);
 560       }
 561       else {
 562         puke "Illegal handler for special operator matching $special_op->{regex} - expecting a method name or a coderef";
 563       }
 564     }
 565     else {
 566       $self->_SWITCH_refkind($val, {
 567
 568         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 569           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 570         },
 571
 572         SCALARREF => sub {      # CASE: col => {op => \$scalar} (literal SQL without bind)
 573           $sql  = join ' ', $self->_convert($self->_quote($k)),
 574                             $self->_sqlcase($op),
 575                             $$val;
 576         },
 577
 578         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 579           my ($sub_sql, @sub_bind) = @$$val;
 580           $self->_assert_bindval_matches_bindtype(@sub_bind);
 581           $sql  = join ' ', $self->_convert($self->_quote($k)),
 582                             $self->_sqlcase($op),
 583                             $sub_sql;
 584           @bind = @sub_bind;
 585         },
 586
 587         HASHREF => sub {
 588           ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $op);
 589         },
 590
 591         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 592           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 593                    ($op =~ $self->{inequality_op}) ? 'is not' :
 594                puke "unexpected operator '$op' with undef operand";
 595           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 596         },
 597
 598         FALLBACK => sub {       # CASE: col => {op => $scalar}
 599           $sql  = join ' ', $self->_convert($self->_quote($k)),
 600                             $self->_sqlcase($op),
 601                             $self->_convert('?');
 602           @bind = $self->_bindtype($k, $val);
 603         },
 604       });
 605     }
 606
 607     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 608     push @all_bind, @bind;
 609   }
 610   return ($all_sql, @all_bind);
 611 }
 612
 613
 614
 615 sub _where_field_op_ARRAYREF {
 616   my ($self, $k, $op, $vals) = @_;
 617
 618   my @vals = @$vals;  #always work on a copy
 619
 620   if(@vals) {
 621     $self->_debug("ARRAY($vals) means multiple elements: [ @vals ]");
 622
 623     # see if the first element is an -and/-or op
 624     my $logic;
 625     if ($vals[0] =~ /^ - ( AND|OR ) $/ix) {
 626       $logic = uc $1;
 627       shift @vals;
 628     }
 629
 630     # distribute $op over each remaining member of @vals, append logic if exists
 631     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 632
 633     # LDNOTE : had planned to change the distribution logic when
 634     # $op =~ $self->{inequality_op}, because of Morgan laws :
 635     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 636     # WHERE field != 22 OR  field != 33 : the user probably means
 637     # WHERE field != 22 AND field != 33.
 638     # To do this, replace the above to roughly :
 639     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 640     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 641
 642   }
 643   else {
 644     # try to DWIM on equality operators
 645     # LDNOTE : not 100% sure this is the correct thing to do ...
 646     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 647     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 648
 649     # otherwise
 650     puke "operator '$op' applied on an empty array (field '$k')";
 651   }
 652 }
 653
 654
 655 sub _where_hashpair_SCALARREF {
 656   my ($self, $k, $v) = @_;
 657   $self->_debug("SCALAR($k) means literal SQL: $$v");
 658   my $sql = $self->_quote($k) . " " . $$v;
 659   return ($sql);
 660 }
 661
 662 # literal SQL with bind
 663 sub _where_hashpair_ARRAYREFREF {
 664   my ($self, $k, $v) = @_;
 665   $self->_debug("REF($k) means literal SQL: @${$v}");
 666   my ($sql, @bind) = @${$v};
 667   $self->_assert_bindval_matches_bindtype(@bind);
 668   $sql  = $self->_quote($k) . " " . $sql;
 669   return ($sql, @bind );
 670 }
 671
 672 # literal SQL without bind
 673 sub _where_hashpair_SCALAR {
 674   my ($self, $k, $v) = @_;
 675   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 676   my $sql = join ' ', $self->_convert($self->_quote($k)),
 677                       $self->_sqlcase($self->{cmp}),
 678                       $self->_convert('?');
 679   my @bind =  $self->_bindtype($k, $v);
 680   return ( $sql, @bind);
 681 }
 682
 683
 684 sub _where_hashpair_UNDEF {
 685   my ($self, $k, $v) = @_;
 686   $self->_debug("UNDEF($k) means IS NULL");
 687   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 688   return ($sql);
 689 }
 690
 691 #======================================================================
 692 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 693 #======================================================================
 694
 695
 696 sub _where_SCALARREF {
 697   my ($self, $where) = @_;
 698
 699   # literal sql
 700   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 701   return ($$where);
 702 }
 703
 704
 705 sub _where_SCALAR {
 706   my ($self, $where) = @_;
 707
 708   # literal sql
 709   $self->_debug("NOREF(*top) means literal SQL: $where");
 710   return ($where);
 711 }
 712
 713
 714 sub _where_UNDEF {
 715   my ($self) = @_;
 716   return ();
 717 }
 718
 719
 720 #======================================================================
 721 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 722 #======================================================================
 723
 724
 725 sub _where_field_BETWEEN {
 726   my ($self, $k, $op, $vals) = @_;
 727
 728   (ref $vals eq 'ARRAY' && @$vals == 2) or
 729   (ref $vals eq 'REF' && (@$$vals == 1 || @$$vals == 2 || @$$vals == 3))
 730     or puke "special op 'between' requires an arrayref of two values (or a scalarref or arrayrefref for literal SQL)";
 731
 732   my ($clause, @bind, $label, $and, $placeholder);
 733   $label       = $self->_convert($self->_quote($k));
 734   $and         = ' ' . $self->_sqlcase('and') . ' ';
 735   $placeholder = $self->_convert('?');
 736   $op               = $self->_sqlcase($op);
 737
 738   if (ref $vals eq 'REF') {
 739     ($clause, @bind) = @$$vals;
 740   }
 741   else {
 742     my (@all_sql, @all_bind);
 743
 744     foreach my $val (@$vals) {
 745       my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 746          SCALAR => sub {
 747            return ($placeholder, ($val));
 748          },
 749          SCALARREF => sub {
 750            return ($self->_convert($$val), ());
 751          },
 752       });
 753       push @all_sql, $sql;
 754       push @all_bind, @bind;
 755     }
 756
 757     $clause = (join $and, @all_sql);
 758     @bind = $self->_bindtype($k, @all_bind);
 759   }
 760   my $sql = "( $label $op $clause )";
 761   return ($sql, @bind)
 762 }
 763
 764
 765 sub _where_field_IN {
 766   my ($self, $k, $op, $vals) = @_;
 767
 768   # backwards compatibility : if scalar, force into an arrayref
 769   $vals = [$vals] if defined $vals && ! ref $vals;
 770
 771   my ($label)       = $self->_convert($self->_quote($k));
 772   my ($placeholder) = $self->_convert('?');
 773   $op               = $self->_sqlcase($op);
 774
 775   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 776     ARRAYREF => sub {     # list of choices
 777       if (@$vals) { # nonempty list
 778         my $placeholders  = join ", ", (($placeholder) x @$vals);
 779         my $sql           = "$label $op ( $placeholders )";
 780         my @bind = $self->_bindtype($k, @$vals);
 781
 782         return ($sql, @bind);
 783       }
 784       else { # empty list : some databases won't understand "IN ()", so DWIM
 785         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 786         return ($sql);
 787       }
 788     },
 789
 790     ARRAYREFREF => sub {  # literal SQL with bind
 791       my ($sql, @bind) = @$$vals;
 792       $self->_assert_bindval_matches_bindtype(@bind);
 793       return ("$label $op ( $sql )", @bind);
 794     },
 795
 796     FALLBACK => sub {
 797       puke "special op 'in' requires an arrayref (or arrayref-ref)";
 798     },
 799   });
 800
 801   return ($sql, @bind);
 802 }
 803
 804
 805
 806
 807
 808
 809 #======================================================================
 810 # ORDER BY
 811 #======================================================================
 812
 813 sub _order_by {
 814   my ($self, $arg) = @_;
 815
 816   my (@sql, @bind);
 817   for my $c ($self->_order_by_chunks ($arg) ) {
 818     $self->_SWITCH_refkind ($c, {
 819       SCALAR => sub { push @sql, $c },
 820       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
 821     });
 822   }
 823
 824   my $sql = @sql
 825     ? sprintf ('%s %s',
 826         $self->_sqlcase(' order by'),
 827         join (', ', @sql)
 828       )
 829     : ''
 830   ;
 831
 832   return wantarray ? ($sql, @bind) : $sql;
 833 }
 834
 835 sub _order_by_chunks {
 836   my ($self, $arg) = @_;
 837
 838   return $self->_SWITCH_refkind($arg, {
 839
 840     ARRAYREF => sub {
 841       map { $self->_order_by_chunks ($_ ) } @$arg;
 842     },
 843
 844     ARRAYREFREF => sub { [ @$$arg ] },
 845
 846     SCALAR    => sub {$self->_quote($arg)},
 847
 848     UNDEF     => sub {return () },
 849
 850     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 851
 852     HASHREF   => sub {
 853       # get first pair in hash
 854       my ($key, $val) = each %$arg;
 855
 856       return () unless $key;
 857
 858       if ( (keys %$arg) > 1 or not $key =~ /^-(desc|asc)/i ) {
 859         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
 860       }
 861
 862       my $direction = $1;
 863
 864       my (@sql, @bind);
 865       for my $c ($self->_order_by_chunks ($val)) {
 866
 867
 868
 869         $self->_SWITCH_refkind ($c, {
 870           SCALAR => sub {
 871             push @sql, $c
 872           },
 873           ARRAYREF => sub {
 874             my ($s, @b) = @$c;
 875             push @sql, $s;
 876             push @bind, @b;
 877           },
 878         });
 879       }
 880
 881       my $sql = join ', ', map { $_ . ' ' . $self->_sqlcase($direction) } @sql;
 882
 883       return [$sql, @bind];
 884     },
 885   });
 886 }
 887
 888
 889 #======================================================================
 890 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
 891 #======================================================================
 892
 893 sub _table  {
 894   my $self = shift;
 895   my $from = shift;
 896   $self->_SWITCH_refkind($from, {
 897     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
 898     SCALAR       => sub {$self->_quote($from)},
 899     SCALARREF    => sub {$$from},
 900     ARRAYREFREF  => sub {join ', ', @$from;},
 901   });
 902 }
 903
 904
 905 #======================================================================
 906 # UTILITY FUNCTIONS
 907 #======================================================================
 908
 909 sub _quote {
 910   my $self  = shift;
 911   my $label = shift;
 912
 913   $label or puke "can't quote an empty label";
 914
 915   # left and right quote characters
 916   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
 917     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
 918     ARRAYREF => sub {@{$self->{quote_char}}},
 919     UNDEF    => sub {()},
 920    });
 921   not @other
 922       or puke "quote_char must be an arrayref of 2 values";
 923
 924   # no quoting if no quoting chars
 925   $ql or return $label;
 926
 927   # no quoting for literal SQL
 928   return $$label if ref($label) eq 'SCALAR';
 929
 930   # separate table / column (if applicable)
 931   my $sep = $self->{name_sep} || '';
 932   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
 933
 934   # do the quoting, except for "*" or for `table`.*
 935   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
 936
 937   # reassemble and return.
 938   return join $sep, @quoted;
 939 }
 940
 941
 942 # Conversion, if applicable
 943 sub _convert ($) {
 944   my ($self, $arg) = @_;
 945
 946 # LDNOTE : modified the previous implementation below because
 947 # it was not consistent : the first "return" is always an array,
 948 # the second "return" is context-dependent. Anyway, _convert
 949 # seems always used with just a single argument, so make it a
 950 # scalar function.
 951 #     return @_ unless $self->{convert};
 952 #     my $conv = $self->_sqlcase($self->{convert});
 953 #     my @ret = map { $conv.'('.$_.')' } @_;
 954 #     return wantarray ? @ret : $ret[0];
 955   if ($self->{convert}) {
 956     my $conv = $self->_sqlcase($self->{convert});
 957     $arg = $conv.'('.$arg.')';
 958   }
 959   return $arg;
 960 }
 961
 962 # And bindtype
 963 sub _bindtype (@) {
 964   my $self = shift;
 965   my($col, @vals) = @_;
 966
 967   #LDNOTE : changed original implementation below because it did not make
 968   # sense when bindtype eq 'columns' and @vals > 1.
 969 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
 970
 971   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
 972 }
 973
 974 # Dies if any element of @bind is not in [colname => value] format
 975 # if bindtype is 'columns'.
 976 sub _assert_bindval_matches_bindtype {
 977   my ($self, @bind) = @_;
 978
 979   if ($self->{bindtype} eq 'columns') {
 980     foreach my $val (@bind) {
 981       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
 982         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
 983       }
 984     }
 985   }
 986 }
 987
 988 sub _join_sql_clauses {
 989   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
 990
 991   if (@$clauses_aref > 1) {
 992     my $join  = " " . $self->_sqlcase($logic) . " ";
 993     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
 994     return ($sql, @$bind_aref);
 995   }
 996   elsif (@$clauses_aref) {
 997     return ($clauses_aref->[0], @$bind_aref); # no parentheses
 998   }
 999   else {
1000     return (); # if no SQL, ignore @$bind_aref
1001   }
1002 }
1003
1004
1005 # Fix SQL case, if so requested
1006 sub _sqlcase {
1007   my $self = shift;
1008
1009   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1010   # don't touch the argument ... crooked logic, but let's not change it!
1011   return $self->{case} ? $_[0] : uc($_[0]);
1012 }
1013
1014
1015 #======================================================================
1016 # DISPATCHING FROM REFKIND
1017 #======================================================================
1018
1019 sub _refkind {
1020   my ($self, $data) = @_;
1021   my $suffix = '';
1022   my $ref;
1023   my $n_steps = 0;
1024
1025   while (1) {
1026     # blessed objects are treated like scalars
1027     $ref = (blessed $data) ? '' : ref $data;
1028     $n_steps += 1 if $ref;
1029     last          if $ref ne 'REF';
1030     $data = $$data;
1031   }
1032
1033   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
1034
1035   return $base . ('REF' x $n_steps);
1036 }
1037
1038
1039
1040 sub _try_refkind {
1041   my ($self, $data) = @_;
1042   my @try = ($self->_refkind($data));
1043   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1044   push @try, 'FALLBACK';
1045   return @try;
1046 }
1047
1048 sub _METHOD_FOR_refkind {
1049   my ($self, $meth_prefix, $data) = @_;
1050   my $method = first {$_} map {$self->can($meth_prefix."_".$_)}
1051                               $self->_try_refkind($data)
1052     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1053   return $method;
1054 }
1055
1056
1057 sub _SWITCH_refkind {
1058   my ($self, $data, $dispatch_table) = @_;
1059
1060   my $coderef = first {$_} map {$dispatch_table->{$_}}
1061                                $self->_try_refkind($data)
1062     or puke "no dispatch entry for ".$self->_refkind($data);
1063   $coderef->();
1064 }
1065
1066
1067
1068
1069 #======================================================================
1070 # VALUES, GENERATE, AUTOLOAD
1071 #======================================================================
1072
1073 # LDNOTE: original code from nwiger, didn't touch code in that section
1074 # I feel the AUTOLOAD stuff should not be the default, it should
1075 # only be activated on explicit demand by user.
1076
1077 sub values {
1078     my $self = shift;
1079     my $data = shift || return;
1080     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1081         unless ref $data eq 'HASH';
1082
1083     my @all_bind;
1084     foreach my $k ( sort keys %$data ) {
1085         my $v = $data->{$k};
1086         $self->_SWITCH_refkind($v, {
1087           ARRAYREF => sub {
1088             if ($self->{array_datatypes}) { # array datatype
1089               push @all_bind, $self->_bindtype($k, $v);
1090             }
1091             else {                          # literal SQL with bind
1092               my ($sql, @bind) = @$v;
1093               $self->_assert_bindval_matches_bindtype(@bind);
1094               push @all_bind, @bind;
1095             }
1096           },
1097           ARRAYREFREF => sub { # literal SQL with bind
1098             my ($sql, @bind) = @${$v};
1099             $self->_assert_bindval_matches_bindtype(@bind);
1100             push @all_bind, @bind;
1101           },
1102           SCALARREF => sub {  # literal SQL without bind
1103           },
1104           SCALAR_or_UNDEF => sub {
1105             push @all_bind, $self->_bindtype($k, $v);
1106           },
1107         });
1108     }
1109
1110     return @all_bind;
1111 }
1112
1113 sub generate {
1114     my $self  = shift;
1115
1116     my(@sql, @sqlq, @sqlv);
1117
1118     for (@_) {
1119         my $ref = ref $_;
1120         if ($ref eq 'HASH') {
1121             for my $k (sort keys %$_) {
1122                 my $v = $_->{$k};
1123                 my $r = ref $v;
1124                 my $label = $self->_quote($k);
1125                 if ($r eq 'ARRAY') {
1126                     # literal SQL with bind
1127                     my ($sql, @bind) = @$v;
1128                     $self->_assert_bindval_matches_bindtype(@bind);
1129                     push @sqlq, "$label = $sql";
1130                     push @sqlv, @bind;
1131                 } elsif ($r eq 'SCALAR') {
1132                     # literal SQL without bind
1133                     push @sqlq, "$label = $$v";
1134                 } else {
1135                     push @sqlq, "$label = ?";
1136                     push @sqlv, $self->_bindtype($k, $v);
1137                 }
1138             }
1139             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1140         } elsif ($ref eq 'ARRAY') {
1141             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1142             for my $v (@$_) {
1143                 my $r = ref $v;
1144                 if ($r eq 'ARRAY') {   # literal SQL with bind
1145                     my ($sql, @bind) = @$v;
1146                     $self->_assert_bindval_matches_bindtype(@bind);
1147                     push @sqlq, $sql;
1148                     push @sqlv, @bind;
1149                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1150                     # embedded literal SQL
1151                     push @sqlq, $$v;
1152                 } else {
1153                     push @sqlq, '?';
1154                     push @sqlv, $v;
1155                 }
1156             }
1157             push @sql, '(' . join(', ', @sqlq) . ')';
1158         } elsif ($ref eq 'SCALAR') {
1159             # literal SQL
1160             push @sql, $$_;
1161         } else {
1162             # strings get case twiddled
1163             push @sql, $self->_sqlcase($_);
1164         }
1165     }
1166
1167     my $sql = join ' ', @sql;
1168
1169     # this is pretty tricky
1170     # if ask for an array, return ($stmt, @bind)
1171     # otherwise, s/?/shift @sqlv/ to put it inline
1172     if (wantarray) {
1173         return ($sql, @sqlv);
1174     } else {
1175         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1176                              ref $d ? $d->[1] : $d/e;
1177         return $sql;
1178     }
1179 }
1180
1181
1182 sub DESTROY { 1 }
1183
1184 sub AUTOLOAD {
1185     # This allows us to check for a local, then _form, attr
1186     my $self = shift;
1187     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1188     return $self->generate($name, @_);
1189 }
1190
1191 1;
1192
1193
1194
1195 __END__
1196
1197 =head1 NAME
1198
1199 SQL::Abstract - Generate SQL from Perl data structures
1200
1201 =head1 SYNOPSIS
1202
1203     use SQL::Abstract;
1204
1205     my $sql = SQL::Abstract->new;
1206
1207     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1208
1209     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1210
1211     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1212
1213     my($stmt, @bind) = $sql->delete($table, \%where);
1214
1215     # Then, use these in your DBI statements
1216     my $sth = $dbh->prepare($stmt);
1217     $sth->execute(@bind);
1218
1219     # Just generate the WHERE clause
1220     my($stmt, @bind) = $sql->where(\%where, \@order);
1221
1222     # Return values in the same order, for hashed queries
1223     # See PERFORMANCE section for more details
1224     my @bind = $sql->values(\%fieldvals);
1225
1226 =head1 DESCRIPTION
1227
1228 This module was inspired by the excellent L<DBIx::Abstract>.
1229 However, in using that module I found that what I really wanted
1230 to do was generate SQL, but still retain complete control over my
1231 statement handles and use the DBI interface. So, I set out to
1232 create an abstract SQL generation module.
1233
1234 While based on the concepts used by L<DBIx::Abstract>, there are
1235 several important differences, especially when it comes to WHERE
1236 clauses. I have modified the concepts used to make the SQL easier
1237 to generate from Perl data structures and, IMO, more intuitive.
1238 The underlying idea is for this module to do what you mean, based
1239 on the data structures you provide it. The big advantage is that
1240 you don't have to modify your code every time your data changes,
1241 as this module figures it out.
1242
1243 To begin with, an SQL INSERT is as easy as just specifying a hash
1244 of C<key=value> pairs:
1245
1246     my %data = (
1247         name => 'Jimbo Bobson',
1248         phone => '123-456-7890',
1249         address => '42 Sister Lane',
1250         city => 'St. Louis',
1251         state => 'Louisiana',
1252     );
1253
1254 The SQL can then be generated with this:
1255
1256     my($stmt, @bind) = $sql->insert('people', \%data);
1257
1258 Which would give you something like this:
1259
1260     $stmt = "INSERT INTO people
1261                     (address, city, name, phone, state)
1262                     VALUES (?, ?, ?, ?, ?)";
1263     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1264              '123-456-7890', 'Louisiana');
1265
1266 These are then used directly in your DBI code:
1267
1268     my $sth = $dbh->prepare($stmt);
1269     $sth->execute(@bind);
1270
1271 =head2 Inserting and Updating Arrays
1272
1273 If your database has array types (like for example Postgres),
1274 activate the special option C<< array_datatypes => 1 >>
1275 when creating the C<SQL::Abstract> object.
1276 Then you may use an arrayref to insert and update database array types:
1277
1278     my $sql = SQL::Abstract->new(array_datatypes => 1);
1279     my %data = (
1280         planets => [qw/Mercury Venus Earth Mars/]
1281     );
1282
1283     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1284
1285 This results in:
1286
1287     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1288
1289     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1290
1291
1292 =head2 Inserting and Updating SQL
1293
1294 In order to apply SQL functions to elements of your C<%data> you may
1295 specify a reference to an arrayref for the given hash value. For example,
1296 if you need to execute the Oracle C<to_date> function on a value, you can
1297 say something like this:
1298
1299     my %data = (
1300         name => 'Bill',
1301         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1302     );
1303
1304 The first value in the array is the actual SQL. Any other values are
1305 optional and would be included in the bind values array. This gives
1306 you:
1307
1308     my($stmt, @bind) = $sql->insert('people', \%data);
1309
1310     $stmt = "INSERT INTO people (name, date_entered)
1311                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1312     @bind = ('Bill', '03/02/2003');
1313
1314 An UPDATE is just as easy, all you change is the name of the function:
1315
1316     my($stmt, @bind) = $sql->update('people', \%data);
1317
1318 Notice that your C<%data> isn't touched; the module will generate
1319 the appropriately quirky SQL for you automatically. Usually you'll
1320 want to specify a WHERE clause for your UPDATE, though, which is
1321 where handling C<%where> hashes comes in handy...
1322
1323 =head2 Complex where statements
1324
1325 This module can generate pretty complicated WHERE statements
1326 easily. For example, simple C<key=value> pairs are taken to mean
1327 equality, and if you want to see if a field is within a set
1328 of values, you can use an arrayref. Let's say we wanted to
1329 SELECT some data based on this criteria:
1330
1331     my %where = (
1332        requestor => 'inna',
1333        worker => ['nwiger', 'rcwe', 'sfz'],
1334        status => { '!=', 'completed' }
1335     );
1336
1337     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1338
1339 The above would give you something like this:
1340
1341     $stmt = "SELECT * FROM tickets WHERE
1342                 ( requestor = ? ) AND ( status != ? )
1343                 AND ( worker = ? OR worker = ? OR worker = ? )";
1344     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1345
1346 Which you could then use in DBI code like so:
1347
1348     my $sth = $dbh->prepare($stmt);
1349     $sth->execute(@bind);
1350
1351 Easy, eh?
1352
1353 =head1 FUNCTIONS
1354
1355 The functions are simple. There's one for each major SQL operation,
1356 and a constructor you use first. The arguments are specified in a
1357 similar order to each function (table, then fields, then a where
1358 clause) to try and simplify things.
1359
1360
1361
1362
1363 =head2 new(option => 'value')
1364
1365 The C<new()> function takes a list of options and values, and returns
1366 a new B<SQL::Abstract> object which can then be used to generate SQL
1367 through the methods below. The options accepted are:
1368
1369 =over
1370
1371 =item case
1372
1373 If set to 'lower', then SQL will be generated in all lowercase. By
1374 default SQL is generated in "textbook" case meaning something like:
1375
1376     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1377
1378 Any setting other than 'lower' is ignored.
1379
1380 =item cmp
1381
1382 This determines what the default comparison operator is. By default
1383 it is C<=>, meaning that a hash like this:
1384
1385     %where = (name => 'nwiger', email => 'nate@wiger.org');
1386
1387 Will generate SQL like this:
1388
1389     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1390
1391 However, you may want loose comparisons by default, so if you set
1392 C<cmp> to C<like> you would get SQL such as:
1393
1394     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1395
1396 You can also override the comparsion on an individual basis - see
1397 the huge section on L</"WHERE CLAUSES"> at the bottom.
1398
1399 =item sqltrue, sqlfalse
1400
1401 Expressions for inserting boolean values within SQL statements.
1402 By default these are C<1=1> and C<1=0>. They are used
1403 by the special operators C<-in> and C<-not_in> for generating
1404 correct SQL even when the argument is an empty array (see below).
1405
1406 =item logic
1407
1408 This determines the default logical operator for multiple WHERE
1409 statements in arrays or hashes. If absent, the default logic is "or"
1410 for arrays, and "and" for hashes. This means that a WHERE
1411 array of the form:
1412
1413     @where = (
1414         event_date => {'>=', '2/13/99'},
1415         event_date => {'<=', '4/24/03'},
1416     );
1417
1418 will generate SQL like this:
1419
1420     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1421
1422 This is probably not what you want given this query, though (look
1423 at the dates). To change the "OR" to an "AND", simply specify:
1424
1425     my $sql = SQL::Abstract->new(logic => 'and');
1426
1427 Which will change the above C<WHERE> to:
1428
1429     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1430
1431 The logic can also be changed locally by inserting
1432 a modifier in front of an arrayref :
1433
1434     @where = (-and => [event_date => {'>=', '2/13/99'},
1435                        event_date => {'<=', '4/24/03'} ]);
1436
1437 See the L</"WHERE CLAUSES"> section for explanations.
1438
1439 =item convert
1440
1441 This will automatically convert comparisons using the specified SQL
1442 function for both column and value. This is mostly used with an argument
1443 of C<upper> or C<lower>, so that the SQL will have the effect of
1444 case-insensitive "searches". For example, this:
1445
1446     $sql = SQL::Abstract->new(convert => 'upper');
1447     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1448
1449 Will turn out the following SQL:
1450
1451     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1452
1453 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1454 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1455 not validate this option; it will just pass through what you specify verbatim).
1456
1457 =item bindtype
1458
1459 This is a kludge because many databases suck. For example, you can't
1460 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1461 Instead, you have to use C<bind_param()>:
1462
1463     $sth->bind_param(1, 'reg data');
1464     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1465
1466 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1467 which loses track of which field each slot refers to. Fear not.
1468
1469 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1470 Currently, you can specify either C<normal> (default) or C<columns>. If you
1471 specify C<columns>, you will get an array that looks like this:
1472
1473     my $sql = SQL::Abstract->new(bindtype => 'columns');
1474     my($stmt, @bind) = $sql->insert(...);
1475
1476     @bind = (
1477         [ 'column1', 'value1' ],
1478         [ 'column2', 'value2' ],
1479         [ 'column3', 'value3' ],
1480     );
1481
1482 You can then iterate through this manually, using DBI's C<bind_param()>.
1483
1484     $sth->prepare($stmt);
1485     my $i = 1;
1486     for (@bind) {
1487         my($col, $data) = @$_;
1488         if ($col eq 'details' || $col eq 'comments') {
1489             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1490         } elsif ($col eq 'image') {
1491             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1492         } else {
1493             $sth->bind_param($i, $data);
1494         }
1495         $i++;
1496     }
1497     $sth->execute;      # execute without @bind now
1498
1499 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1500 Basically, the advantage is still that you don't have to care which fields
1501 are or are not included. You could wrap that above C<for> loop in a simple
1502 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1503 get a layer of abstraction over manual SQL specification.
1504
1505 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1506 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1507 will expect the bind values in this format.
1508
1509 =item quote_char
1510
1511 This is the character that a table or column name will be quoted
1512 with.  By default this is an empty string, but you could set it to
1513 the character C<`>, to generate SQL like this:
1514
1515   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1516
1517 Alternatively, you can supply an array ref of two items, the first being the left
1518 hand quote character, and the second the right hand quote character. For
1519 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1520 that generates SQL like this:
1521
1522   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1523
1524 Quoting is useful if you have tables or columns names that are reserved
1525 words in your database's SQL dialect.
1526
1527 =item name_sep
1528
1529 This is the character that separates a table and column name.  It is
1530 necessary to specify this when the C<quote_char> option is selected,
1531 so that tables and column names can be individually quoted like this:
1532
1533   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1534
1535 =item array_datatypes
1536
1537 When this option is true, arrayrefs in INSERT or UPDATE are
1538 interpreted as array datatypes and are passed directly
1539 to the DBI layer.
1540 When this option is false, arrayrefs are interpreted
1541 as literal SQL, just like refs to arrayrefs
1542 (but this behavior is for backwards compatibility; when writing
1543 new queries, use the "reference to arrayref" syntax
1544 for literal SQL).
1545
1546
1547 =item special_ops
1548
1549 Takes a reference to a list of "special operators"
1550 to extend the syntax understood by L<SQL::Abstract>.
1551 See section L</"SPECIAL OPERATORS"> for details.
1552
1553
1554
1555 =back
1556
1557 =head2 insert($table, \@values || \%fieldvals)
1558
1559 This is the simplest function. You simply give it a table name
1560 and either an arrayref of values or hashref of field/value pairs.
1561 It returns an SQL INSERT statement and a list of bind values.
1562 See the sections on L</"Inserting and Updating Arrays"> and
1563 L</"Inserting and Updating SQL"> for information on how to insert
1564 with those data types.
1565
1566 =head2 update($table, \%fieldvals, \%where)
1567
1568 This takes a table, hashref of field/value pairs, and an optional
1569 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1570 of bind values.
1571 See the sections on L</"Inserting and Updating Arrays"> and
1572 L</"Inserting and Updating SQL"> for information on how to insert
1573 with those data types.
1574
1575 =head2 select($source, $fields, $where, $order)
1576
1577 This returns a SQL SELECT statement and associated list of bind values, as
1578 specified by the arguments  :
1579
1580 =over
1581
1582 =item $source
1583
1584 Specification of the 'FROM' part of the statement.
1585 The argument can be either a plain scalar (interpreted as a table
1586 name, will be quoted), or an arrayref (interpreted as a list
1587 of table names, joined by commas, quoted), or a scalarref
1588 (literal table name, not quoted), or a ref to an arrayref
1589 (list of literal table names, joined by commas, not quoted).
1590
1591 =item $fields
1592
1593 Specification of the list of fields to retrieve from
1594 the source.
1595 The argument can be either an arrayref (interpreted as a list
1596 of field names, will be joined by commas and quoted), or a
1597 plain scalar (literal SQL, not quoted).
1598 Please observe that this API is not as flexible as for
1599 the first argument C<$table>, for backwards compatibility reasons.
1600
1601 =item $where
1602
1603 Optional argument to specify the WHERE part of the query.
1604 The argument is most often a hashref, but can also be
1605 an arrayref or plain scalar --
1606 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1607
1608 =item $order
1609
1610 Optional argument to specify the ORDER BY part of the query.
1611 The argument can be a scalar, a hashref or an arrayref
1612 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1613 for details.
1614
1615 =back
1616
1617
1618 =head2 delete($table, \%where)
1619
1620 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1621 It returns an SQL DELETE statement and list of bind values.
1622
1623 =head2 where(\%where, \@order)
1624
1625 This is used to generate just the WHERE clause. For example,
1626 if you have an arbitrary data structure and know what the
1627 rest of your SQL is going to look like, but want an easy way
1628 to produce a WHERE clause, use this. It returns an SQL WHERE
1629 clause and list of bind values.
1630
1631
1632 =head2 values(\%data)
1633
1634 This just returns the values from the hash C<%data>, in the same
1635 order that would be returned from any of the other above queries.
1636 Using this allows you to markedly speed up your queries if you
1637 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1638
1639 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1640
1641 Warning: This is an experimental method and subject to change.
1642
1643 This returns arbitrarily generated SQL. It's a really basic shortcut.
1644 It will return two different things, depending on return context:
1645
1646     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1647     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1648
1649 These would return the following:
1650
1651     # First calling form
1652     $stmt = "CREATE TABLE test (?, ?)";
1653     @bind = (field1, field2);
1654
1655     # Second calling form
1656     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1657
1658 Depending on what you're trying to do, it's up to you to choose the correct
1659 format. In this example, the second form is what you would want.
1660
1661 By the same token:
1662
1663     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1664
1665 Might give you:
1666
1667     ALTER SESSION SET nls_date_format = 'MM/YY'
1668
1669 You get the idea. Strings get their case twiddled, but everything
1670 else remains verbatim.
1671
1672
1673
1674
1675 =head1 WHERE CLAUSES
1676
1677 =head2 Introduction
1678
1679 This module uses a variation on the idea from L<DBIx::Abstract>. It
1680 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1681 module is that things in arrays are OR'ed, and things in hashes
1682 are AND'ed.>
1683
1684 The easiest way to explain is to show lots of examples. After
1685 each C<%where> hash shown, it is assumed you used:
1686
1687     my($stmt, @bind) = $sql->where(\%where);
1688
1689 However, note that the C<%where> hash can be used directly in any
1690 of the other functions as well, as described above.
1691
1692 =head2 Key-value pairs
1693
1694 So, let's get started. To begin, a simple hash:
1695
1696     my %where  = (
1697         user   => 'nwiger',
1698         status => 'completed'
1699     );
1700
1701 Is converted to SQL C<key = val> statements:
1702
1703     $stmt = "WHERE user = ? AND status = ?";
1704     @bind = ('nwiger', 'completed');
1705
1706 One common thing I end up doing is having a list of values that
1707 a field can be in. To do this, simply specify a list inside of
1708 an arrayref:
1709
1710     my %where  = (
1711         user   => 'nwiger',
1712         status => ['assigned', 'in-progress', 'pending'];
1713     );
1714
1715 This simple code will create the following:
1716
1717     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1718     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1719
1720 A field associated to an empty arrayref will be considered a
1721 logical false and will generate 0=1.
1722
1723 =head2 Specific comparison operators
1724
1725 If you want to specify a different type of operator for your comparison,
1726 you can use a hashref for a given column:
1727
1728     my %where  = (
1729         user   => 'nwiger',
1730         status => { '!=', 'completed' }
1731     );
1732
1733 Which would generate:
1734
1735     $stmt = "WHERE user = ? AND status != ?";
1736     @bind = ('nwiger', 'completed');
1737
1738 To test against multiple values, just enclose the values in an arrayref:
1739
1740     status => { '=', ['assigned', 'in-progress', 'pending'] };
1741
1742 Which would give you:
1743
1744     "WHERE status = ? OR status = ? OR status = ?"
1745
1746
1747 The hashref can also contain multiple pairs, in which case it is expanded
1748 into an C<AND> of its elements:
1749
1750     my %where  = (
1751         user   => 'nwiger',
1752         status => { '!=', 'completed', -not_like => 'pending%' }
1753     );
1754
1755     # Or more dynamically, like from a form
1756     $where{user} = 'nwiger';
1757     $where{status}{'!='} = 'completed';
1758     $where{status}{'-not_like'} = 'pending%';
1759
1760     # Both generate this
1761     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1762     @bind = ('nwiger', 'completed', 'pending%');
1763
1764
1765 To get an OR instead, you can combine it with the arrayref idea:
1766
1767     my %where => (
1768          user => 'nwiger',
1769          priority => [ {'=', 2}, {'!=', 1} ]
1770     );
1771
1772 Which would generate:
1773
1774     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1775     @bind = ('nwiger', '2', '1');
1776
1777 If you want to include literal SQL (with or without bind values), just use a
1778 scalar reference or array reference as the value:
1779
1780     my %where  = (
1781         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1782         date_expires => { '<' => \"now()" }
1783     );
1784
1785 Which would generate:
1786
1787     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1788     @bind = ('11/26/2008');
1789
1790
1791 =head2 Logic and nesting operators
1792
1793 In the example above,
1794 there is a subtle trap if you want to say something like
1795 this (notice the C<AND>):
1796
1797     WHERE priority != ? AND priority != ?
1798
1799 Because, in Perl you I<can't> do this:
1800
1801     priority => { '!=', 2, '!=', 1 }
1802
1803 As the second C<!=> key will obliterate the first. The solution
1804 is to use the special C<-modifier> form inside an arrayref:
1805
1806     priority => [ -and => {'!=', 2},
1807                           {'!=', 1} ]
1808
1809
1810 Normally, these would be joined by C<OR>, but the modifier tells it
1811 to use C<AND> instead. (Hint: You can use this in conjunction with the
1812 C<logic> option to C<new()> in order to change the way your queries
1813 work by default.) B<Important:> Note that the C<-modifier> goes
1814 B<INSIDE> the arrayref, as an extra first element. This will
1815 B<NOT> do what you think it might:
1816
1817     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1818
1819 Here is a quick list of equivalencies, since there is some overlap:
1820
1821     # Same
1822     status => {'!=', 'completed', 'not like', 'pending%' }
1823     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1824
1825     # Same
1826     status => {'=', ['assigned', 'in-progress']}
1827     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1828     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1829
1830
1831
1832 =head2 Special operators : IN, BETWEEN, etc.
1833
1834 You can also use the hashref format to compare a list of fields using the
1835 C<IN> comparison operator, by specifying the list as an arrayref:
1836
1837     my %where  = (
1838         status   => 'completed',
1839         reportid => { -in => [567, 2335, 2] }
1840     );
1841
1842 Which would generate:
1843
1844     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
1845     @bind = ('completed', '567', '2335', '2');
1846
1847 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
1848 the same way.
1849
1850 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
1851 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
1852 'sqltrue' (by default : C<1=1>).
1853
1854
1855
1856 Another pair of operators is C<-between> and C<-not_between>,
1857 used with an arrayref of two values:
1858
1859     my %where  = (
1860         user   => 'nwiger',
1861         completion_date => {
1862            -not_between => ['2002-10-01', '2003-02-06']
1863         }
1864     );
1865
1866 Would give you:
1867
1868     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
1869
1870 These are the two builtin "special operators"; but the
1871 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
1872
1873 =head2 Nested conditions, -and/-or prefixes
1874
1875 So far, we've seen how multiple conditions are joined with a top-level
1876 C<AND>.  We can change this by putting the different conditions we want in
1877 hashes and then putting those hashes in an array. For example:
1878
1879     my @where = (
1880         {
1881             user   => 'nwiger',
1882             status => { -like => ['pending%', 'dispatched'] },
1883         },
1884         {
1885             user   => 'robot',
1886             status => 'unassigned',
1887         }
1888     );
1889
1890 This data structure would create the following:
1891
1892     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
1893                 OR ( user = ? AND status = ? ) )";
1894     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
1895
1896
1897 There is also a special C<-nest>
1898 operator which adds an additional set of parens, to create a subquery.
1899 For example, to get something like this:
1900
1901     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
1902     @bind = ('nwiger', '20', 'ASIA');
1903
1904 You would do:
1905
1906     my %where = (
1907          user => 'nwiger',
1908         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
1909     );
1910
1911
1912 Finally, clauses in hashrefs or arrayrefs can be
1913 prefixed with an C<-and> or C<-or> to change the logic
1914 inside :
1915
1916     my @where = (
1917          -and => [
1918             user => 'nwiger',
1919             -nest => [
1920                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
1921                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
1922             ],
1923         ],
1924     );
1925
1926 That would yield:
1927
1928     WHERE ( user = ? AND
1929           ( ( workhrs > ? AND geo = ? )
1930          OR ( workhrs < ? AND geo = ? ) ) )
1931
1932
1933 =head2 Algebraic inconsistency, for historical reasons
1934
1935 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
1936 operator goes C<outside> of the nested structure; whereas when connecting
1937 several constraints on one column, the C<-and> operator goes
1938 C<inside> the arrayref. Here is an example combining both features :
1939
1940    my @where = (
1941      -and => [a => 1, b => 2],
1942      -or  => [c => 3, d => 4],
1943       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
1944    )
1945
1946 yielding
1947
1948   WHERE ( (    ( a = ? AND b = ? )
1949             OR ( c = ? OR d = ? )
1950             OR ( e LIKE ? AND e LIKE ? ) ) )
1951
1952 This difference in syntax is unfortunate but must be preserved for
1953 historical reasons. So be careful : the two examples below would
1954 seem algebraically equivalent, but they are not
1955
1956   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
1957   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
1958
1959   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
1960   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
1961
1962
1963 =head2 Literal SQL
1964
1965 Finally, sometimes only literal SQL will do. If you want to include
1966 literal SQL verbatim, you can specify it as a scalar reference, namely:
1967
1968     my $inn = 'is Not Null';
1969     my %where = (
1970         priority => { '<', 2 },
1971         requestor => \$inn
1972     );
1973
1974 This would create:
1975
1976     $stmt = "WHERE priority < ? AND requestor is Not Null";
1977     @bind = ('2');
1978
1979 Note that in this example, you only get one bind parameter back, since
1980 the verbatim SQL is passed as part of the statement.
1981
1982 Of course, just to prove a point, the above can also be accomplished
1983 with this:
1984
1985     my %where = (
1986         priority  => { '<', 2 },
1987         requestor => { '!=', undef },
1988     );
1989
1990
1991 TMTOWTDI.
1992
1993 Conditions on boolean columns can be expressed in the
1994 same way, passing a reference to an empty string :
1995
1996     my %where = (
1997         priority  => { '<', 2 },
1998         is_ready  => \"";
1999     );
2000
2001 which yields
2002
2003     $stmt = "WHERE priority < ? AND is_ready";
2004     @bind = ('2');
2005
2006
2007 =head2 Literal SQL with placeholders and bind values (subqueries)
2008
2009 If the literal SQL to be inserted has placeholders and bind values,
2010 use a reference to an arrayref (yes this is a double reference --
2011 not so common, but perfectly legal Perl). For example, to find a date
2012 in Postgres you can use something like this:
2013
2014     my %where = (
2015        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2016     )
2017
2018 This would create:
2019
2020     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2021     @bind = ('10');
2022
2023 Note that you must pass the bind values in the same format as they are returned
2024 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2025 provide the bind values in the C<< [ column_meta => value ] >> format, where
2026 C<column_meta> is an opaque scalar value; most commonly the column name, but
2027 you can use any scalar value (including references and blessed references),
2028 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2029 to C<columns> the above example will look like:
2030
2031     my %where = (
2032        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2033     )
2034
2035 Literal SQL is especially useful for nesting parenthesized clauses in the
2036 main SQL query. Here is a first example :
2037
2038   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2039                                100, "foo%");
2040   my %where = (
2041     foo => 1234,
2042     bar => \["IN ($sub_stmt)" => @sub_bind],
2043   );
2044
2045 This yields :
2046
2047   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2048                                              WHERE c2 < ? AND c3 LIKE ?))";
2049   @bind = (1234, 100, "foo%");
2050
2051 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2052 are expressed in the same way. Of course the C<$sub_stmt> and
2053 its associated bind values can be generated through a former call
2054 to C<select()> :
2055
2056   my ($sub_stmt, @sub_bind)
2057      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2058                                  c3 => {-like => "foo%"}});
2059   my %where = (
2060     foo => 1234,
2061     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2062   );
2063
2064 In the examples above, the subquery was used as an operator on a column;
2065 but the same principle also applies for a clause within the main C<%where>
2066 hash, like an EXISTS subquery :
2067
2068   my ($sub_stmt, @sub_bind)
2069      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2070   my %where = (
2071     foo   => 1234,
2072     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
2073   );
2074
2075 which yields
2076
2077   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2078                                         WHERE c1 = ? AND c2 > t0.c0))";
2079   @bind = (1234, 1);
2080
2081
2082 Observe that the condition on C<c2> in the subquery refers to
2083 column C<t0.c0> of the main query : this is I<not> a bind
2084 value, so we have to express it through a scalar ref.
2085 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2086 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2087 what we wanted here.
2088
2089 Another use of the subquery technique is when some SQL clauses need
2090 parentheses, as it often occurs with some proprietary SQL extensions
2091 like for example fulltext expressions, geospatial expressions,
2092 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2093
2094   my %where = (
2095     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2096   );
2097
2098 Finally, here is an example where a subquery is used
2099 for expressing unary negation:
2100
2101   my ($sub_stmt, @sub_bind)
2102      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2103   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2104   my %where = (
2105         lname  => {like => '%son%'},
2106         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2107     );
2108
2109 This yields
2110
2111   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2112   @bind = ('%son%', 10, 20)
2113
2114
2115
2116 =head2 Conclusion
2117
2118 These pages could go on for a while, since the nesting of the data
2119 structures this module can handle are pretty much unlimited (the
2120 module implements the C<WHERE> expansion as a recursive function
2121 internally). Your best bet is to "play around" with the module a
2122 little to see how the data structures behave, and choose the best
2123 format for your data based on that.
2124
2125 And of course, all the values above will probably be replaced with
2126 variables gotten from forms or the command line. After all, if you
2127 knew everything ahead of time, you wouldn't have to worry about
2128 dynamically-generating SQL and could just hardwire it into your
2129 script.
2130
2131
2132
2133
2134 =head1 ORDER BY CLAUSES
2135
2136 Some functions take an order by clause. This can either be a scalar (just a
2137 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2138 or an array of either of the two previous forms. Examples:
2139
2140                Given            |         Will Generate
2141     ----------------------------------------------------------
2142                                 |
2143     \'colA DESC'                | ORDER BY colA DESC
2144                                 |
2145     'colA'                      | ORDER BY colA
2146                                 |
2147     [qw/colA colB/]             | ORDER BY colA, colB
2148                                 |
2149     {-asc  => 'colA'}           | ORDER BY colA ASC
2150                                 |
2151     {-desc => 'colB'}           | ORDER BY colB DESC
2152                                 |
2153     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2154                                 |
2155     { -asc => [qw/colA colB] }  | ORDER BY colA ASC, colB ASC
2156                                 |
2157     [                           |
2158       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2159       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2160       { -asc => [qw/colC colD/],|
2161     ]                           |
2162     ===========================================================
2163
2164
2165
2166 =head1 SPECIAL OPERATORS
2167
2168   my $sqlmaker = SQL::Abstract->new(special_ops => [
2169      {
2170       regex => qr/.../,
2171       handler => sub {
2172         my ($self, $field, $op, $arg) = @_;
2173         ...
2174       },
2175      },
2176      {
2177       regex => qr/.../,
2178       handler => 'method_name',
2179      },
2180    ]);
2181
2182 A "special operator" is a SQL syntactic clause that can be
2183 applied to a field, instead of a usual binary operator.
2184 For example :
2185
2186    WHERE field IN (?, ?, ?)
2187    WHERE field BETWEEN ? AND ?
2188    WHERE MATCH(field) AGAINST (?, ?)
2189
2190 Special operators IN and BETWEEN are fairly standard and therefore
2191 are builtin within C<SQL::Abstract> (as the overridable methods
2192 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2193 like the MATCH .. AGAINST example above which is specific to MySQL,
2194 you can write your own operator handlers - supply a C<special_ops>
2195 argument to the C<new> method. That argument takes an arrayref of
2196 operator definitions; each operator definition is a hashref with two
2197 entries:
2198
2199 =over
2200
2201 =item regex
2202
2203 the regular expression to match the operator
2204
2205 =item handler
2206
2207 Either a coderef or a plain scalar method name. In both cases
2208 the expected return is C<< ($sql, @bind) >>.
2209
2210 When supplied with a method name, it is simply called on the
2211 L<SQL::Abstract/> object as:
2212
2213  $self->$method_name ($field, $op, $arg)
2214
2215  Where:
2216
2217   $op is the part that matched the handler regex
2218   $field is the LHS of the operator
2219   $arg is the RHS
2220
2221 When supplied with a coderef, it is called as:
2222
2223  $coderef->($self, $field, $op, $arg)
2224
2225
2226 =back
2227
2228 For example, here is an implementation
2229 of the MATCH .. AGAINST syntax for MySQL
2230
2231   my $sqlmaker = SQL::Abstract->new(special_ops => [
2232
2233     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2234     {regex => qr/^match$/i,
2235      handler => sub {
2236        my ($self, $field, $op, $arg) = @_;
2237        $arg = [$arg] if not ref $arg;
2238        my $label         = $self->_quote($field);
2239        my ($placeholder) = $self->_convert('?');
2240        my $placeholders  = join ", ", (($placeholder) x @$arg);
2241        my $sql           = $self->_sqlcase('match') . " ($label) "
2242                          . $self->_sqlcase('against') . " ($placeholders) ";
2243        my @bind = $self->_bindtype($field, @$arg);
2244        return ($sql, @bind);
2245        }
2246      },
2247
2248   ]);
2249
2250
2251 =head1 PERFORMANCE
2252
2253 Thanks to some benchmarking by Mark Stosberg, it turns out that
2254 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2255 I must admit this wasn't an intentional design issue, but it's a
2256 byproduct of the fact that you get to control your C<DBI> handles
2257 yourself.
2258
2259 To maximize performance, use a code snippet like the following:
2260
2261     # prepare a statement handle using the first row
2262     # and then reuse it for the rest of the rows
2263     my($sth, $stmt);
2264     for my $href (@array_of_hashrefs) {
2265         $stmt ||= $sql->insert('table', $href);
2266         $sth  ||= $dbh->prepare($stmt);
2267         $sth->execute($sql->values($href));
2268     }
2269
2270 The reason this works is because the keys in your C<$href> are sorted
2271 internally by B<SQL::Abstract>. Thus, as long as your data retains
2272 the same structure, you only have to generate the SQL the first time
2273 around. On subsequent queries, simply use the C<values> function provided
2274 by this module to return your values in the correct order.
2275
2276
2277 =head1 FORMBUILDER
2278
2279 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2280 really like this part (I do, at least). Building up a complex query
2281 can be as simple as the following:
2282
2283     #!/usr/bin/perl
2284
2285     use CGI::FormBuilder;
2286     use SQL::Abstract;
2287
2288     my $form = CGI::FormBuilder->new(...);
2289     my $sql  = SQL::Abstract->new;
2290
2291     if ($form->submitted) {
2292         my $field = $form->field;
2293         my $id = delete $field->{id};
2294         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2295     }
2296
2297 Of course, you would still have to connect using C<DBI> to run the
2298 query, but the point is that if you make your form look like your
2299 table, the actual query script can be extremely simplistic.
2300
2301 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2302 a fast interface to returning and formatting data. I frequently
2303 use these three modules together to write complex database query
2304 apps in under 50 lines.
2305
2306
2307 =head1 CHANGES
2308
2309 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2310 Great care has been taken to preserve the I<published> behavior
2311 documented in previous versions in the 1.* family; however,
2312 some features that were previously undocumented, or behaved
2313 differently from the documentation, had to be changed in order
2314 to clarify the semantics. Hence, client code that was relying
2315 on some dark areas of C<SQL::Abstract> v1.*
2316 B<might behave differently> in v1.50.
2317
2318 The main changes are :
2319
2320 =over
2321
2322 =item *
2323
2324 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2325
2326 =item *
2327
2328 support for the { operator => \"..." } construct (to embed literal SQL)
2329
2330 =item *
2331
2332 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2333
2334 =item *
2335
2336 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2337
2338 =item *
2339
2340 defensive programming : check arguments
2341
2342 =item *
2343
2344 fixed bug with global logic, which was previously implemented
2345 through global variables yielding side-effects. Prior versions would
2346 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2347 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2348 Now this is interpreted
2349 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2350
2351
2352 =item *
2353
2354 fixed semantics of  _bindtype on array args
2355
2356 =item *
2357
2358 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2359 we just avoid shifting arrays within that tree.
2360
2361 =item *
2362
2363 dropped the C<_modlogic> function
2364
2365 =back
2366
2367
2368
2369 =head1 ACKNOWLEDGEMENTS
2370
2371 There are a number of individuals that have really helped out with
2372 this module. Unfortunately, most of them submitted bugs via CPAN
2373 so I have no idea who they are! But the people I do know are:
2374
2375     Ash Berlin (order_by hash term support)
2376     Matt Trout (DBIx::Class support)
2377     Mark Stosberg (benchmarking)
2378     Chas Owens (initial "IN" operator support)
2379     Philip Collins (per-field SQL functions)
2380     Eric Kolve (hashref "AND" support)
2381     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2382     Dan Kubb (support for "quote_char" and "name_sep")
2383     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2384     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2385     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2386     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2387
2388 Thanks!
2389
2390 =head1 SEE ALSO
2391
2392 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2393
2394 =head1 AUTHOR
2395
2396 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2397
2398 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2399
2400 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2401 While not an official support venue, C<DBIx::Class> makes heavy use of
2402 C<SQL::Abstract>, and as such list members there are very familiar with
2403 how to create queries.
2404
2405 =head1 LICENSE
2406
2407 This module is free software; you may copy this under the terms of
2408 the GNU General Public License, or the Artistic License, copies of
2409 which should have accompanied your Perl kit.
2410
2411 =cut
2412