lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util   qw/first/;
  12 use Scalar::Util qw/blessed/;
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.53';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => \&_where_field_BETWEEN},
  29   {regex => qr/^(not )?in$/i,      handler => \&_where_field_IN},
  30 );
  31
  32 #======================================================================
  33 # DEBUGGING AND ERROR REPORTING
  34 #======================================================================
  35
  36 sub _debug {
  37   return unless $_[0]->{debug}; shift; # a little faster
  38   my $func = (caller(1))[3];
  39   warn "[$func] ", @_, "\n";
  40 }
  41
  42 sub belch (@) {
  43   my($func) = (caller(1))[3];
  44   carp "[$func] Warning: ", @_;
  45 }
  46
  47 sub puke (@) {
  48   my($func) = (caller(1))[3];
  49   croak "[$func] Fatal: ", @_;
  50 }
  51
  52
  53 #======================================================================
  54 # NEW
  55 #======================================================================
  56
  57 sub new {
  58   my $self = shift;
  59   my $class = ref($self) || $self;
  60   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  61
  62   # choose our case by keeping an option around
  63   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  64
  65   # default logic for interpreting arrayrefs
  66   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  67
  68   # how to return bind vars
  69   # LDNOTE: changed nwiger code : why this 'delete' ??
  70   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  71   $opt{bindtype} ||= 'normal';
  72
  73   # default comparison is "=", but can be overridden
  74   $opt{cmp} ||= '=';
  75
  76   # try to recognize which are the 'equality' and 'unequality' ops
  77   # (temporary quickfix, should go through a more seasoned API)
  78  $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  79  $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  80
  81   # SQL booleans
  82   $opt{sqltrue}  ||= '1=1';
  83   $opt{sqlfalse} ||= '0=1';
  84
  85   # special operators
  86   $opt{special_ops} ||= [];
  87   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  88
  89   return bless \%opt, $class;
  90 }
  91
  92
  93
  94 #======================================================================
  95 # INSERT methods
  96 #======================================================================
  97
  98 sub insert {
  99   my $self  = shift;
 100   my $table = $self->_table(shift);
 101   my $data  = shift || return;
 102
 103   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 104   my ($sql, @bind) = $self->$method($data);
 105   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 106   return wantarray ? ($sql, @bind) : $sql;
 107 }
 108
 109 sub _insert_HASHREF { # explicit list of fields and then values
 110   my ($self, $data) = @_;
 111
 112   my @fields = sort keys %$data;
 113
 114   my ($sql, @bind) = $self->_insert_values($data);
 115
 116   # assemble SQL
 117   $_ = $self->_quote($_) foreach @fields;
 118   $sql = "( ".join(", ", @fields).") ".$sql;
 119
 120   return ($sql, @bind);
 121 }
 122
 123 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 124   my ($self, $data) = @_;
 125
 126   # no names (arrayref) so can't generate bindtype
 127   $self->{bindtype} ne 'columns'
 128     or belch "can't do 'columns' bindtype when called with arrayref";
 129
 130   # fold the list of values into a hash of column name - value pairs
 131   # (where the column names are artificially generated, and their
 132   # lexicographical ordering keep the ordering of the original list)
 133   my $i = "a";  # incremented values will be in lexicographical order
 134   my $data_in_hash = { map { ($i++ => $_) } @$data };
 135
 136   return $self->_insert_values($data_in_hash);
 137 }
 138
 139 sub _insert_ARRAYREFREF { # literal SQL with bind
 140   my ($self, $data) = @_;
 141
 142   my ($sql, @bind) = @${$data};
 143   $self->_assert_bindval_matches_bindtype(@bind);
 144
 145   return ($sql, @bind);
 146 }
 147
 148
 149 sub _insert_SCALARREF { # literal SQL without bind
 150   my ($self, $data) = @_;
 151
 152   return ($$data);
 153 }
 154
 155 sub _insert_values {
 156   my ($self, $data) = @_;
 157
 158   my (@values, @all_bind);
 159   foreach my $column (sort keys %$data) {
 160     my $v = $data->{$column};
 161
 162     $self->_SWITCH_refkind($v, {
 163
 164       ARRAYREF => sub {
 165         if ($self->{array_datatypes}) { # if array datatype are activated
 166           push @values, '?';
 167           push @all_bind, $self->_bindtype($column, $v);
 168         }
 169         else {                          # else literal SQL with bind
 170           my ($sql, @bind) = @$v;
 171           $self->_assert_bindval_matches_bindtype(@bind);
 172           push @values, $sql;
 173           push @all_bind, @bind;
 174         }
 175       },
 176
 177       ARRAYREFREF => sub { # literal SQL with bind
 178         my ($sql, @bind) = @${$v};
 179         $self->_assert_bindval_matches_bindtype(@bind);
 180         push @values, $sql;
 181         push @all_bind, @bind;
 182       },
 183
 184       # THINK : anything useful to do with a HASHREF ?
 185       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 186         #TODO in SQLA >= 2.0 it will die instead
 187         belch "HASH ref as bind value in insert is not supported";
 188         push @values, '?';
 189         push @all_bind, $self->_bindtype($column, $v);
 190       },
 191
 192       SCALARREF => sub {  # literal SQL without bind
 193         push @values, $$v;
 194       },
 195
 196       SCALAR_or_UNDEF => sub {
 197         push @values, '?';
 198         push @all_bind, $self->_bindtype($column, $v);
 199       },
 200
 201      });
 202
 203   }
 204
 205   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 206   return ($sql, @all_bind);
 207 }
 208
 209
 210
 211 #======================================================================
 212 # UPDATE methods
 213 #======================================================================
 214
 215
 216 sub update {
 217   my $self  = shift;
 218   my $table = $self->_table(shift);
 219   my $data  = shift || return;
 220   my $where = shift;
 221
 222   # first build the 'SET' part of the sql statement
 223   my (@set, @all_bind);
 224   puke "Unsupported data type specified to \$sql->update"
 225     unless ref $data eq 'HASH';
 226
 227   for my $k (sort keys %$data) {
 228     my $v = $data->{$k};
 229     my $r = ref $v;
 230     my $label = $self->_quote($k);
 231
 232     $self->_SWITCH_refkind($v, {
 233       ARRAYREF => sub {
 234         if ($self->{array_datatypes}) { # array datatype
 235           push @set, "$label = ?";
 236           push @all_bind, $self->_bindtype($k, $v);
 237         }
 238         else {                          # literal SQL with bind
 239           my ($sql, @bind) = @$v;
 240           $self->_assert_bindval_matches_bindtype(@bind);
 241           push @set, "$label = $sql";
 242           push @all_bind, @bind;
 243         }
 244       },
 245       ARRAYREFREF => sub { # literal SQL with bind
 246         my ($sql, @bind) = @${$v};
 247         $self->_assert_bindval_matches_bindtype(@bind);
 248         push @set, "$label = $sql";
 249         push @all_bind, @bind;
 250       },
 251       SCALARREF => sub {  # literal SQL without bind
 252         push @set, "$label = $$v";
 253        },
 254       SCALAR_or_UNDEF => sub {
 255         push @set, "$label = ?";
 256         push @all_bind, $self->_bindtype($k, $v);
 257       },
 258     });
 259   }
 260
 261   # generate sql
 262   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 263           . join ', ', @set;
 264
 265   if ($where) {
 266     my($where_sql, @where_bind) = $self->where($where);
 267     $sql .= $where_sql;
 268     push @all_bind, @where_bind;
 269   }
 270
 271   return wantarray ? ($sql, @all_bind) : $sql;
 272 }
 273
 274
 275
 276
 277 #======================================================================
 278 # SELECT
 279 #======================================================================
 280
 281
 282 sub select {
 283   my $self   = shift;
 284   my $table  = $self->_table(shift);
 285   my $fields = shift || '*';
 286   my $where  = shift;
 287   my $order  = shift;
 288
 289   my($where_sql, @bind) = $self->where($where, $order);
 290
 291   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 292                                    : $fields;
 293   my $sql = join(' ', $self->_sqlcase('select'), $f,
 294                       $self->_sqlcase('from'),   $table)
 295           . $where_sql;
 296
 297   return wantarray ? ($sql, @bind) : $sql;
 298 }
 299
 300 #======================================================================
 301 # DELETE
 302 #======================================================================
 303
 304
 305 sub delete {
 306   my $self  = shift;
 307   my $table = $self->_table(shift);
 308   my $where = shift;
 309
 310
 311   my($where_sql, @bind) = $self->where($where);
 312   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 313
 314   return wantarray ? ($sql, @bind) : $sql;
 315 }
 316
 317
 318 #======================================================================
 319 # WHERE: entry point
 320 #======================================================================
 321
 322
 323
 324 # Finally, a separate routine just to handle WHERE clauses
 325 sub where {
 326   my ($self, $where, $order) = @_;
 327
 328   # where ?
 329   my ($sql, @bind) = $self->_recurse_where($where);
 330   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 331
 332   # order by?
 333   if ($order) {
 334     $sql .= $self->_order_by($order);
 335   }
 336
 337   return wantarray ? ($sql, @bind) : $sql;
 338 }
 339
 340
 341 sub _recurse_where {
 342   my ($self, $where, $logic) = @_;
 343
 344   # dispatch on appropriate method according to refkind of $where
 345   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 346
 347
 348   my ($sql, @bind) =  $self->$method($where, $logic);
 349
 350   # DBIx::Class directly calls _recurse_where in scalar context, so
 351   # we must implement it, even if not in the official API
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356
 357 #======================================================================
 358 # WHERE: top-level ARRAYREF
 359 #======================================================================
 360
 361
 362 sub _where_ARRAYREF {
 363   my ($self, $where, $logic) = @_;
 364
 365   $logic = uc($logic || $self->{logic});
 366   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 367
 368   my @clauses = @$where;
 369
 370   my (@sql_clauses, @all_bind);
 371   # need to use while() so can shift() for pairs
 372   while (my $el = shift @clauses) {
 373
 374     # switch according to kind of $el and get corresponding ($sql, @bind)
 375     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 376
 377       # skip empty elements, otherwise get invalid trailing AND stuff
 378       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 379
 380       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 381
 382       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 383            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 384            # side-effect: the first hashref within an array would change
 385            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 386            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 387            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 388
 389       SCALARREF => sub { ($$el);                                 },
 390
 391       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 392                         $self->_recurse_where({$el => shift(@clauses)})},
 393
 394       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 395     });
 396
 397     if ($sql) {
 398       push @sql_clauses, $sql;
 399       push @all_bind, @bind;
 400     }
 401   }
 402
 403   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 404 }
 405
 406 #======================================================================
 407 # WHERE: top-level ARRAYREFREF
 408 #======================================================================
 409
 410 sub _where_ARRAYREFREF {
 411     my ($self, $where) = @_;
 412     my ($sql, @bind) = @{${$where}};
 413
 414     return ($sql, @bind);
 415 }
 416
 417 #======================================================================
 418 # WHERE: top-level HASHREF
 419 #======================================================================
 420
 421 sub _where_HASHREF {
 422   my ($self, $where) = @_;
 423   my (@sql_clauses, @all_bind);
 424
 425   for my $k (sort keys %$where) {
 426     my $v = $where->{$k};
 427
 428     # ($k => $v) is either a special op or a regular hashpair
 429     my ($sql, @bind) = ($k =~ /^-(.+)/) ? $self->_where_op_in_hash($1, $v)
 430                                         : do {
 431          my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 432          $self->$method($k, $v);
 433        };
 434
 435     push @sql_clauses, $sql;
 436     push @all_bind, @bind;
 437   }
 438
 439   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 440 }
 441
 442
 443 sub _where_op_in_hash {
 444   my ($self, $op_str, $v) = @_;
 445
 446   $op_str =~ /^ (AND|OR|PAREN|NEST) ( \_? \d* ) $/xi
 447     or puke "unknown operator: -$op_str";
 448
 449   my $op = uc($1); # uppercase, remove trailing digits
 450   if ($2) {
 451     belch 'Use of op_N modifiers is deprecated and will be removed in SQLA v2.0. '
 452           . "You probably wanted ...-and => [ $op_str => COND1, $op_str => COND2 ... ]";
 453   }
 454
 455   if ($op eq 'NEST') {
 456     belch 'The -nest modifier is deprecated in favor of -paren and will be removed in SQLA v2.0';
 457     $op = 'PAREN';
 458   }
 459
 460   $self->_debug("OP(-$op) within hashref, recursing...");
 461
 462   $self->_SWITCH_refkind($v, {
 463
 464     ARRAYREF => sub {
 465       return $self->_where_ARRAYREF($v, $op eq 'PAREN' ? '' : $op);
 466     },
 467
 468     HASHREF => sub {
 469       if ($op eq 'OR') {
 470         return $self->_where_ARRAYREF([ map { $_ => $v->{$_} } (sort keys %$v) ], 'OR');
 471       }
 472       else {                  # PAREN | AND
 473         return $self->_where_HASHREF($v);
 474       }
 475     },
 476
 477     SCALARREF  => sub {         # literal SQL
 478       $op eq 'PAREN'
 479         or puke "-$op => \\\$scalar not supported, use -paren => ...";
 480       return ($$v);
 481     },
 482
 483     ARRAYREFREF => sub {        # literal SQL
 484       $op eq 'PAREN'
 485         or puke "-$op => \\[..] not supported, use -paren => ...";
 486       return @{${$v}};
 487     },
 488
 489     SCALAR => sub { # permissively interpreted as SQL
 490       $op eq 'PAREN'
 491         or puke "-$op => 'scalar' not supported, use -paren => \\'scalar'";
 492       belch "literal SQL should be -paren => \\'scalar' "
 493           . "instead of -paren => 'scalar' ";
 494       return ($v);
 495     },
 496
 497     UNDEF => sub {
 498       puke "-$op => undef not supported";
 499     },
 500    });
 501 }
 502
 503
 504 sub _where_hashpair_ARRAYREF {
 505   my ($self, $k, $v) = @_;
 506
 507   if( @$v ) {
 508     my @v = @$v; # need copy because of shift below
 509     $self->_debug("ARRAY($k) means distribute over elements");
 510
 511     # put apart first element if it is an operator (-and, -or)
 512     my $op = (
 513        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 514          ? shift @v
 515          : ''
 516     );
 517     my @distributed = map { {$k =>  $_} } @v;
 518
 519     if ($op) {
 520       $self->_debug("OP($op) reinjected into the distributed array");
 521       unshift @distributed, $op;
 522     }
 523
 524     my $logic = $op ? substr($op, 1) : '';
 525
 526     return $self->_recurse_where(\@distributed, $logic);
 527   }
 528   else {
 529     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 530     $self->_debug("empty ARRAY($k) means 0=1");
 531     return ($self->{sqlfalse});
 532   }
 533 }
 534
 535 sub _where_hashpair_HASHREF {
 536   my ($self, $k, $v, $logic) = @_;
 537   $logic ||= 'and';
 538
 539   my ($all_sql, @all_bind);
 540
 541   for my $op (sort keys %$v) {
 542     my $val = $v->{$op};
 543
 544     # put the operator in canonical form
 545     $op =~ s/^-//;       # remove initial dash
 546     $op =~ tr/_/ /;      # underscores become spaces
 547     $op =~ s/^\s+//;     # no initial space
 548     $op =~ s/\s+$//;     # no final space
 549     $op =~ s/\s+/ /;     # multiple spaces become one
 550
 551     my ($sql, @bind);
 552
 553     # CASE: special operators like -in or -between
 554     my $special_op = first {$op =~ $_->{regex}} @{$self->{special_ops}};
 555     if ($special_op) {
 556       ($sql, @bind) = $special_op->{handler}->($self, $k, $op, $val);
 557     }
 558     else {
 559       $self->_SWITCH_refkind($val, {
 560
 561         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 562           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 563         },
 564
 565         SCALARREF => sub {      # CASE: col => {op => \$scalar} (literal SQL without bind)
 566           $sql  = join ' ', $self->_convert($self->_quote($k)),
 567                             $self->_sqlcase($op),
 568                             $$val;
 569         },
 570
 571         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 572           my ($sub_sql, @sub_bind) = @$$val;
 573           $self->_assert_bindval_matches_bindtype(@sub_bind);
 574           $sql  = join ' ', $self->_convert($self->_quote($k)),
 575                             $self->_sqlcase($op),
 576                             $sub_sql;
 577           @bind = @sub_bind;
 578         },
 579
 580         HASHREF => sub {
 581           ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $op);
 582         },
 583
 584         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 585           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 586                    ($op =~ $self->{inequality_op}) ? 'is not' :
 587                puke "unexpected operator '$op' with undef operand";
 588           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 589         },
 590
 591         FALLBACK => sub {       # CASE: col => {op => $scalar}
 592           $sql  = join ' ', $self->_convert($self->_quote($k)),
 593                             $self->_sqlcase($op),
 594                             $self->_convert('?');
 595           @bind = $self->_bindtype($k, $val);
 596         },
 597       });
 598     }
 599
 600     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 601     push @all_bind, @bind;
 602   }
 603   return ($all_sql, @all_bind);
 604 }
 605
 606
 607
 608 sub _where_field_op_ARRAYREF {
 609   my ($self, $k, $op, $vals) = @_;
 610
 611   if(@$vals) {
 612     $self->_debug("ARRAY($vals) means multiple elements: [ @$vals ]");
 613
 614     # see if the first element is an -and/-or op
 615     my $logic;
 616     if ($vals->[0] =~ /^ - ( AND|OR ) $/ix) {
 617       $logic = uc $1;
 618       shift @$vals;
 619     }
 620
 621     # distribute $op over each remaining member of @$vals, append logic if exists
 622     return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals], $logic);
 623
 624     # LDNOTE : had planned to change the distribution logic when
 625     # $op =~ $self->{inequality_op}, because of Morgan laws :
 626     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 627     # WHERE field != 22 OR  field != 33 : the user probably means
 628     # WHERE field != 22 AND field != 33.
 629     # To do this, replace the above to roughly :
 630     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 631     # return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals], $logic);
 632
 633   }
 634   else {
 635     # try to DWIM on equality operators
 636     # LDNOTE : not 100% sure this is the correct thing to do ...
 637     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 638     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 639
 640     # otherwise
 641     puke "operator '$op' applied on an empty array (field '$k')";
 642   }
 643 }
 644
 645
 646 sub _where_hashpair_SCALARREF {
 647   my ($self, $k, $v) = @_;
 648   $self->_debug("SCALAR($k) means literal SQL: $$v");
 649   my $sql = $self->_quote($k) . " " . $$v;
 650   return ($sql);
 651 }
 652
 653 # literal SQL with bind
 654 sub _where_hashpair_ARRAYREFREF {
 655   my ($self, $k, $v) = @_;
 656   $self->_debug("REF($k) means literal SQL: @${$v}");
 657   my ($sql, @bind) = @${$v};
 658   $self->_assert_bindval_matches_bindtype(@bind);
 659   $sql  = $self->_quote($k) . " " . $sql;
 660   return ($sql, @bind );
 661 }
 662
 663 # literal SQL without bind
 664 sub _where_hashpair_SCALAR {
 665   my ($self, $k, $v) = @_;
 666   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 667   my $sql = join ' ', $self->_convert($self->_quote($k)),
 668                       $self->_sqlcase($self->{cmp}),
 669                       $self->_convert('?');
 670   my @bind =  $self->_bindtype($k, $v);
 671   return ( $sql, @bind);
 672 }
 673
 674
 675 sub _where_hashpair_UNDEF {
 676   my ($self, $k, $v) = @_;
 677   $self->_debug("UNDEF($k) means IS NULL");
 678   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 679   return ($sql);
 680 }
 681
 682 #======================================================================
 683 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 684 #======================================================================
 685
 686
 687 sub _where_SCALARREF {
 688   my ($self, $where) = @_;
 689
 690   # literal sql
 691   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 692   return ($$where);
 693 }
 694
 695
 696 sub _where_SCALAR {
 697   my ($self, $where) = @_;
 698
 699   # literal sql
 700   $self->_debug("NOREF(*top) means literal SQL: $where");
 701   return ($where);
 702 }
 703
 704
 705 sub _where_UNDEF {
 706   my ($self) = @_;
 707   return ();
 708 }
 709
 710
 711 #======================================================================
 712 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 713 #======================================================================
 714
 715
 716 sub _where_field_BETWEEN {
 717   my ($self, $k, $op, $vals) = @_;
 718
 719   (ref $vals eq 'ARRAY' && @$vals == 2) or
 720   (ref $vals eq 'REF' && (@$$vals == 1 || @$$vals == 2 || @$$vals == 3))
 721     or puke "special op 'between' requires an arrayref of two values (or a scalarref or arrayrefref for literal SQL)";
 722
 723   my ($clause, @bind, $label, $and, $placeholder);
 724   $label       = $self->_convert($self->_quote($k));
 725   $and         = ' ' . $self->_sqlcase('and') . ' ';
 726   $placeholder = $self->_convert('?');
 727   $op               = $self->_sqlcase($op);
 728
 729   if (ref $vals eq 'REF') {
 730     ($clause, @bind) = @$$vals;
 731   }
 732   else {
 733     my (@all_sql, @all_bind);
 734
 735     foreach my $val (@$vals) {
 736       my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 737          SCALAR => sub {
 738            return ($placeholder, ($val));
 739          },
 740          SCALARREF => sub {
 741            return ($self->_convert($$val), ());
 742          },
 743       });
 744       push @all_sql, $sql;
 745       push @all_bind, @bind;
 746     }
 747
 748     $clause = (join $and, @all_sql);
 749     @bind = $self->_bindtype($k, @all_bind);
 750   }
 751   my $sql = "( $label $op $clause )";
 752   return ($sql, @bind)
 753 }
 754
 755
 756 sub _where_field_IN {
 757   my ($self, $k, $op, $vals) = @_;
 758
 759   # backwards compatibility : if scalar, force into an arrayref
 760   $vals = [$vals] if defined $vals && ! ref $vals;
 761
 762   my ($label)       = $self->_convert($self->_quote($k));
 763   my ($placeholder) = $self->_convert('?');
 764   $op               = $self->_sqlcase($op);
 765
 766   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 767     ARRAYREF => sub {     # list of choices
 768       if (@$vals) { # nonempty list
 769         my $placeholders  = join ", ", (($placeholder) x @$vals);
 770         my $sql           = "$label $op ( $placeholders )";
 771         my @bind = $self->_bindtype($k, @$vals);
 772
 773         return ($sql, @bind);
 774       }
 775       else { # empty list : some databases won't understand "IN ()", so DWIM
 776         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 777         return ($sql);
 778       }
 779     },
 780
 781     ARRAYREFREF => sub {  # literal SQL with bind
 782       my ($sql, @bind) = @$$vals;
 783       $self->_assert_bindval_matches_bindtype(@bind);
 784       return ("$label $op ( $sql )", @bind);
 785     },
 786
 787     FALLBACK => sub {
 788       puke "special op 'in' requires an arrayref (or arrayref-ref)";
 789     },
 790   });
 791
 792   return ($sql, @bind);
 793 }
 794
 795
 796
 797
 798
 799
 800 #======================================================================
 801 # ORDER BY
 802 #======================================================================
 803
 804 sub _order_by {
 805   my ($self, $arg) = @_;
 806
 807   # construct list of ordering instructions
 808   my @order = $self->_SWITCH_refkind($arg, {
 809
 810     ARRAYREF => sub {
 811       map {$self->_SWITCH_refkind($_, {
 812               SCALAR    => sub {$self->_quote($_)},
 813               UNDEF     => sub {},
 814               SCALARREF => sub {$$_}, # literal SQL, no quoting
 815               HASHREF   => sub {$self->_order_by_hash($_)}
 816              }) } @$arg;
 817     },
 818
 819     SCALAR    => sub {$self->_quote($arg)},
 820     UNDEF     => sub {},
 821     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 822     HASHREF   => sub {$self->_order_by_hash($arg)},
 823
 824   });
 825
 826   # build SQL
 827   my $order = join ', ', @order;
 828   return $order ? $self->_sqlcase(' order by')." $order" : '';
 829 }
 830
 831
 832 sub _order_by_hash {
 833   my ($self, $hash) = @_;
 834
 835   # get first pair in hash
 836   my ($key, $val) = each %$hash;
 837
 838   # check if one pair was found and no other pair in hash
 839   $key && !(each %$hash)
 840     or puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
 841
 842   my ($order) = ($key =~ /^-(desc|asc)/i)
 843     or puke "invalid key in _order_by hash : $key";
 844
 845   $val = ref $val eq 'ARRAY' ? $val : [$val];
 846   return join ', ', map { $self->_quote($_) . ' ' . $self->_sqlcase($order) } @$val;
 847 }
 848
 849
 850
 851 #======================================================================
 852 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
 853 #======================================================================
 854
 855 sub _table  {
 856   my $self = shift;
 857   my $from = shift;
 858   $self->_SWITCH_refkind($from, {
 859     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
 860     SCALAR       => sub {$self->_quote($from)},
 861     SCALARREF    => sub {$$from},
 862     ARRAYREFREF  => sub {join ', ', @$from;},
 863   });
 864 }
 865
 866
 867 #======================================================================
 868 # UTILITY FUNCTIONS
 869 #======================================================================
 870
 871 sub _quote {
 872   my $self  = shift;
 873   my $label = shift;
 874
 875   $label or puke "can't quote an empty label";
 876
 877   # left and right quote characters
 878   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
 879     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
 880     ARRAYREF => sub {@{$self->{quote_char}}},
 881     UNDEF    => sub {()},
 882    });
 883   not @other
 884       or puke "quote_char must be an arrayref of 2 values";
 885
 886   # no quoting if no quoting chars
 887   $ql or return $label;
 888
 889   # no quoting for literal SQL
 890   return $$label if ref($label) eq 'SCALAR';
 891
 892   # separate table / column (if applicable)
 893   my $sep = $self->{name_sep} || '';
 894   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
 895
 896   # do the quoting, except for "*" or for `table`.*
 897   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
 898
 899   # reassemble and return.
 900   return join $sep, @quoted;
 901 }
 902
 903
 904 # Conversion, if applicable
 905 sub _convert ($) {
 906   my ($self, $arg) = @_;
 907
 908 # LDNOTE : modified the previous implementation below because
 909 # it was not consistent : the first "return" is always an array,
 910 # the second "return" is context-dependent. Anyway, _convert
 911 # seems always used with just a single argument, so make it a
 912 # scalar function.
 913 #     return @_ unless $self->{convert};
 914 #     my $conv = $self->_sqlcase($self->{convert});
 915 #     my @ret = map { $conv.'('.$_.')' } @_;
 916 #     return wantarray ? @ret : $ret[0];
 917   if ($self->{convert}) {
 918     my $conv = $self->_sqlcase($self->{convert});
 919     $arg = $conv.'('.$arg.')';
 920   }
 921   return $arg;
 922 }
 923
 924 # And bindtype
 925 sub _bindtype (@) {
 926   my $self = shift;
 927   my($col, @vals) = @_;
 928
 929   #LDNOTE : changed original implementation below because it did not make
 930   # sense when bindtype eq 'columns' and @vals > 1.
 931 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
 932
 933   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
 934 }
 935
 936 # Dies if any element of @bind is not in [colname => value] format
 937 # if bindtype is 'columns'.
 938 sub _assert_bindval_matches_bindtype {
 939   my ($self, @bind) = @_;
 940
 941   if ($self->{bindtype} eq 'columns') {
 942     foreach my $val (@bind) {
 943       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
 944         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
 945       }
 946     }
 947   }
 948 }
 949
 950 sub _join_sql_clauses {
 951   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
 952
 953   if (@$clauses_aref > 1) {
 954     my $join  = " " . $self->_sqlcase($logic) . " ";
 955     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
 956     return ($sql, @$bind_aref);
 957   }
 958   elsif (@$clauses_aref) {
 959     return ($clauses_aref->[0], @$bind_aref); # no parentheses
 960   }
 961   else {
 962     return (); # if no SQL, ignore @$bind_aref
 963   }
 964 }
 965
 966
 967 # Fix SQL case, if so requested
 968 sub _sqlcase {
 969   my $self = shift;
 970
 971   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
 972   # don't touch the argument ... crooked logic, but let's not change it!
 973   return $self->{case} ? $_[0] : uc($_[0]);
 974 }
 975
 976
 977 #======================================================================
 978 # DISPATCHING FROM REFKIND
 979 #======================================================================
 980
 981 sub _refkind {
 982   my ($self, $data) = @_;
 983   my $suffix = '';
 984   my $ref;
 985   my $n_steps = 0;
 986
 987   while (1) {
 988     # blessed objects are treated like scalars
 989     $ref = (blessed $data) ? '' : ref $data;
 990     $n_steps += 1 if $ref;
 991     last          if $ref ne 'REF';
 992     $data = $$data;
 993   }
 994
 995   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
 996
 997   return $base . ('REF' x $n_steps);
 998 }
 999
1000
1001
1002 sub _try_refkind {
1003   my ($self, $data) = @_;
1004   my @try = ($self->_refkind($data));
1005   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1006   push @try, 'FALLBACK';
1007   return @try;
1008 }
1009
1010 sub _METHOD_FOR_refkind {
1011   my ($self, $meth_prefix, $data) = @_;
1012   my $method = first {$_} map {$self->can($meth_prefix."_".$_)}
1013                               $self->_try_refkind($data)
1014     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1015   return $method;
1016 }
1017
1018
1019 sub _SWITCH_refkind {
1020   my ($self, $data, $dispatch_table) = @_;
1021
1022   my $coderef = first {$_} map {$dispatch_table->{$_}}
1023                                $self->_try_refkind($data)
1024     or puke "no dispatch entry for ".$self->_refkind($data);
1025   $coderef->();
1026 }
1027
1028
1029
1030
1031 #======================================================================
1032 # VALUES, GENERATE, AUTOLOAD
1033 #======================================================================
1034
1035 # LDNOTE: original code from nwiger, didn't touch code in that section
1036 # I feel the AUTOLOAD stuff should not be the default, it should
1037 # only be activated on explicit demand by user.
1038
1039 sub values {
1040     my $self = shift;
1041     my $data = shift || return;
1042     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1043         unless ref $data eq 'HASH';
1044
1045     my @all_bind;
1046     foreach my $k ( sort keys %$data ) {
1047         my $v = $data->{$k};
1048         $self->_SWITCH_refkind($v, {
1049           ARRAYREF => sub {
1050             if ($self->{array_datatypes}) { # array datatype
1051               push @all_bind, $self->_bindtype($k, $v);
1052             }
1053             else {                          # literal SQL with bind
1054               my ($sql, @bind) = @$v;
1055               $self->_assert_bindval_matches_bindtype(@bind);
1056               push @all_bind, @bind;
1057             }
1058           },
1059           ARRAYREFREF => sub { # literal SQL with bind
1060             my ($sql, @bind) = @${$v};
1061             $self->_assert_bindval_matches_bindtype(@bind);
1062             push @all_bind, @bind;
1063           },
1064           SCALARREF => sub {  # literal SQL without bind
1065           },
1066           SCALAR_or_UNDEF => sub {
1067             push @all_bind, $self->_bindtype($k, $v);
1068           },
1069         });
1070     }
1071
1072     return @all_bind;
1073 }
1074
1075 sub generate {
1076     my $self  = shift;
1077
1078     my(@sql, @sqlq, @sqlv);
1079
1080     for (@_) {
1081         my $ref = ref $_;
1082         if ($ref eq 'HASH') {
1083             for my $k (sort keys %$_) {
1084                 my $v = $_->{$k};
1085                 my $r = ref $v;
1086                 my $label = $self->_quote($k);
1087                 if ($r eq 'ARRAY') {
1088                     # literal SQL with bind
1089                     my ($sql, @bind) = @$v;
1090                     $self->_assert_bindval_matches_bindtype(@bind);
1091                     push @sqlq, "$label = $sql";
1092                     push @sqlv, @bind;
1093                 } elsif ($r eq 'SCALAR') {
1094                     # literal SQL without bind
1095                     push @sqlq, "$label = $$v";
1096                 } else {
1097                     push @sqlq, "$label = ?";
1098                     push @sqlv, $self->_bindtype($k, $v);
1099                 }
1100             }
1101             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1102         } elsif ($ref eq 'ARRAY') {
1103             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1104             for my $v (@$_) {
1105                 my $r = ref $v;
1106                 if ($r eq 'ARRAY') {   # literal SQL with bind
1107                     my ($sql, @bind) = @$v;
1108                     $self->_assert_bindval_matches_bindtype(@bind);
1109                     push @sqlq, $sql;
1110                     push @sqlv, @bind;
1111                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1112                     # embedded literal SQL
1113                     push @sqlq, $$v;
1114                 } else {
1115                     push @sqlq, '?';
1116                     push @sqlv, $v;
1117                 }
1118             }
1119             push @sql, '(' . join(', ', @sqlq) . ')';
1120         } elsif ($ref eq 'SCALAR') {
1121             # literal SQL
1122             push @sql, $$_;
1123         } else {
1124             # strings get case twiddled
1125             push @sql, $self->_sqlcase($_);
1126         }
1127     }
1128
1129     my $sql = join ' ', @sql;
1130
1131     # this is pretty tricky
1132     # if ask for an array, return ($stmt, @bind)
1133     # otherwise, s/?/shift @sqlv/ to put it inline
1134     if (wantarray) {
1135         return ($sql, @sqlv);
1136     } else {
1137         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1138                              ref $d ? $d->[1] : $d/e;
1139         return $sql;
1140     }
1141 }
1142
1143
1144 sub DESTROY { 1 }
1145
1146 sub AUTOLOAD {
1147     # This allows us to check for a local, then _form, attr
1148     my $self = shift;
1149     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1150     return $self->generate($name, @_);
1151 }
1152
1153 1;
1154
1155
1156
1157 __END__
1158
1159 =head1 NAME
1160
1161 SQL::Abstract - Generate SQL from Perl data structures
1162
1163 =head1 SYNOPSIS
1164
1165     use SQL::Abstract;
1166
1167     my $sql = SQL::Abstract->new;
1168
1169     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1170
1171     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1172
1173     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1174
1175     my($stmt, @bind) = $sql->delete($table, \%where);
1176
1177     # Then, use these in your DBI statements
1178     my $sth = $dbh->prepare($stmt);
1179     $sth->execute(@bind);
1180
1181     # Just generate the WHERE clause
1182     my($stmt, @bind) = $sql->where(\%where, \@order);
1183
1184     # Return values in the same order, for hashed queries
1185     # See PERFORMANCE section for more details
1186     my @bind = $sql->values(\%fieldvals);
1187
1188 =head1 DESCRIPTION
1189
1190 This module was inspired by the excellent L<DBIx::Abstract>.
1191 However, in using that module I found that what I really wanted
1192 to do was generate SQL, but still retain complete control over my
1193 statement handles and use the DBI interface. So, I set out to
1194 create an abstract SQL generation module.
1195
1196 While based on the concepts used by L<DBIx::Abstract>, there are
1197 several important differences, especially when it comes to WHERE
1198 clauses. I have modified the concepts used to make the SQL easier
1199 to generate from Perl data structures and, IMO, more intuitive.
1200 The underlying idea is for this module to do what you mean, based
1201 on the data structures you provide it. The big advantage is that
1202 you don't have to modify your code every time your data changes,
1203 as this module figures it out.
1204
1205 To begin with, an SQL INSERT is as easy as just specifying a hash
1206 of C<key=value> pairs:
1207
1208     my %data = (
1209         name => 'Jimbo Bobson',
1210         phone => '123-456-7890',
1211         address => '42 Sister Lane',
1212         city => 'St. Louis',
1213         state => 'Louisiana',
1214     );
1215
1216 The SQL can then be generated with this:
1217
1218     my($stmt, @bind) = $sql->insert('people', \%data);
1219
1220 Which would give you something like this:
1221
1222     $stmt = "INSERT INTO people
1223                     (address, city, name, phone, state)
1224                     VALUES (?, ?, ?, ?, ?)";
1225     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1226              '123-456-7890', 'Louisiana');
1227
1228 These are then used directly in your DBI code:
1229
1230     my $sth = $dbh->prepare($stmt);
1231     $sth->execute(@bind);
1232
1233 =head2 Inserting and Updating Arrays
1234
1235 If your database has array types (like for example Postgres),
1236 activate the special option C<< array_datatypes => 1 >>
1237 when creating the C<SQL::Abstract> object.
1238 Then you may use an arrayref to insert and update database array types:
1239
1240     my $sql = SQL::Abstract->new(array_datatypes => 1);
1241     my %data = (
1242         planets => [qw/Mercury Venus Earth Mars/]
1243     );
1244
1245     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1246
1247 This results in:
1248
1249     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1250
1251     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1252
1253
1254 =head2 Inserting and Updating SQL
1255
1256 In order to apply SQL functions to elements of your C<%data> you may
1257 specify a reference to an arrayref for the given hash value. For example,
1258 if you need to execute the Oracle C<to_date> function on a value, you can
1259 say something like this:
1260
1261     my %data = (
1262         name => 'Bill',
1263         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1264     );
1265
1266 The first value in the array is the actual SQL. Any other values are
1267 optional and would be included in the bind values array. This gives
1268 you:
1269
1270     my($stmt, @bind) = $sql->insert('people', \%data);
1271
1272     $stmt = "INSERT INTO people (name, date_entered)
1273                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1274     @bind = ('Bill', '03/02/2003');
1275
1276 An UPDATE is just as easy, all you change is the name of the function:
1277
1278     my($stmt, @bind) = $sql->update('people', \%data);
1279
1280 Notice that your C<%data> isn't touched; the module will generate
1281 the appropriately quirky SQL for you automatically. Usually you'll
1282 want to specify a WHERE clause for your UPDATE, though, which is
1283 where handling C<%where> hashes comes in handy...
1284
1285 =head2 Complex where statements
1286
1287 This module can generate pretty complicated WHERE statements
1288 easily. For example, simple C<key=value> pairs are taken to mean
1289 equality, and if you want to see if a field is within a set
1290 of values, you can use an arrayref. Let's say we wanted to
1291 SELECT some data based on this criteria:
1292
1293     my %where = (
1294        requestor => 'inna',
1295        worker => ['nwiger', 'rcwe', 'sfz'],
1296        status => { '!=', 'completed' }
1297     );
1298
1299     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1300
1301 The above would give you something like this:
1302
1303     $stmt = "SELECT * FROM tickets WHERE
1304                 ( requestor = ? ) AND ( status != ? )
1305                 AND ( worker = ? OR worker = ? OR worker = ? )";
1306     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1307
1308 Which you could then use in DBI code like so:
1309
1310     my $sth = $dbh->prepare($stmt);
1311     $sth->execute(@bind);
1312
1313 Easy, eh?
1314
1315 =head1 FUNCTIONS
1316
1317 The functions are simple. There's one for each major SQL operation,
1318 and a constructor you use first. The arguments are specified in a
1319 similar order to each function (table, then fields, then a where
1320 clause) to try and simplify things.
1321
1322
1323
1324
1325 =head2 new(option => 'value')
1326
1327 The C<new()> function takes a list of options and values, and returns
1328 a new B<SQL::Abstract> object which can then be used to generate SQL
1329 through the methods below. The options accepted are:
1330
1331 =over
1332
1333 =item case
1334
1335 If set to 'lower', then SQL will be generated in all lowercase. By
1336 default SQL is generated in "textbook" case meaning something like:
1337
1338     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1339
1340 Any setting other than 'lower' is ignored.
1341
1342 =item cmp
1343
1344 This determines what the default comparison operator is. By default
1345 it is C<=>, meaning that a hash like this:
1346
1347     %where = (name => 'nwiger', email => 'nate@wiger.org');
1348
1349 Will generate SQL like this:
1350
1351     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1352
1353 However, you may want loose comparisons by default, so if you set
1354 C<cmp> to C<like> you would get SQL such as:
1355
1356     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1357
1358 You can also override the comparsion on an individual basis - see
1359 the huge section on L</"WHERE CLAUSES"> at the bottom.
1360
1361 =item sqltrue, sqlfalse
1362
1363 Expressions for inserting boolean values within SQL statements.
1364 By default these are C<1=1> and C<1=0>. They are used
1365 by the special operators C<-in> and C<-not_in> for generating
1366 correct SQL even when the argument is an empty array (see below).
1367
1368 =item logic
1369
1370 This determines the default logical operator for multiple WHERE
1371 statements in arrays or hashes. If absent, the default logic is "or"
1372 for arrays, and "and" for hashes. This means that a WHERE
1373 array of the form:
1374
1375     @where = (
1376         event_date => {'>=', '2/13/99'},
1377         event_date => {'<=', '4/24/03'},
1378     );
1379
1380 will generate SQL like this:
1381
1382     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1383
1384 This is probably not what you want given this query, though (look
1385 at the dates). To change the "OR" to an "AND", simply specify:
1386
1387     my $sql = SQL::Abstract->new(logic => 'and');
1388
1389 Which will change the above C<WHERE> to:
1390
1391     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1392
1393 The logic can also be changed locally by inserting
1394 a modifier in front of an arrayref :
1395
1396     @where = (-and => [event_date => {'>=', '2/13/99'},
1397                        event_date => {'<=', '4/24/03'} ]);
1398
1399 See the L</"WHERE CLAUSES"> section for explanations.
1400
1401 =item convert
1402
1403 This will automatically convert comparisons using the specified SQL
1404 function for both column and value. This is mostly used with an argument
1405 of C<upper> or C<lower>, so that the SQL will have the effect of
1406 case-insensitive "searches". For example, this:
1407
1408     $sql = SQL::Abstract->new(convert => 'upper');
1409     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1410
1411 Will turn out the following SQL:
1412
1413     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1414
1415 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1416 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1417 not validate this option; it will just pass through what you specify verbatim).
1418
1419 =item bindtype
1420
1421 This is a kludge because many databases suck. For example, you can't
1422 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1423 Instead, you have to use C<bind_param()>:
1424
1425     $sth->bind_param(1, 'reg data');
1426     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1427
1428 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1429 which loses track of which field each slot refers to. Fear not.
1430
1431 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1432 Currently, you can specify either C<normal> (default) or C<columns>. If you
1433 specify C<columns>, you will get an array that looks like this:
1434
1435     my $sql = SQL::Abstract->new(bindtype => 'columns');
1436     my($stmt, @bind) = $sql->insert(...);
1437
1438     @bind = (
1439         [ 'column1', 'value1' ],
1440         [ 'column2', 'value2' ],
1441         [ 'column3', 'value3' ],
1442     );
1443
1444 You can then iterate through this manually, using DBI's C<bind_param()>.
1445
1446     $sth->prepare($stmt);
1447     my $i = 1;
1448     for (@bind) {
1449         my($col, $data) = @$_;
1450         if ($col eq 'details' || $col eq 'comments') {
1451             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1452         } elsif ($col eq 'image') {
1453             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1454         } else {
1455             $sth->bind_param($i, $data);
1456         }
1457         $i++;
1458     }
1459     $sth->execute;      # execute without @bind now
1460
1461 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1462 Basically, the advantage is still that you don't have to care which fields
1463 are or are not included. You could wrap that above C<for> loop in a simple
1464 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1465 get a layer of abstraction over manual SQL specification.
1466
1467 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1468 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1469 will expect the bind values in this format.
1470
1471 =item quote_char
1472
1473 This is the character that a table or column name will be quoted
1474 with.  By default this is an empty string, but you could set it to
1475 the character C<`>, to generate SQL like this:
1476
1477   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1478
1479 Alternatively, you can supply an array ref of two items, the first being the left
1480 hand quote character, and the second the right hand quote character. For
1481 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1482 that generates SQL like this:
1483
1484   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1485
1486 Quoting is useful if you have tables or columns names that are reserved
1487 words in your database's SQL dialect.
1488
1489 =item name_sep
1490
1491 This is the character that separates a table and column name.  It is
1492 necessary to specify this when the C<quote_char> option is selected,
1493 so that tables and column names can be individually quoted like this:
1494
1495   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1496
1497 =item array_datatypes
1498
1499 When this option is true, arrayrefs in INSERT or UPDATE are
1500 interpreted as array datatypes and are passed directly
1501 to the DBI layer.
1502 When this option is false, arrayrefs are interpreted
1503 as literal SQL, just like refs to arrayrefs
1504 (but this behavior is for backwards compatibility; when writing
1505 new queries, use the "reference to arrayref" syntax
1506 for literal SQL).
1507
1508
1509 =item special_ops
1510
1511 Takes a reference to a list of "special operators"
1512 to extend the syntax understood by L<SQL::Abstract>.
1513 See section L</"SPECIAL OPERATORS"> for details.
1514
1515
1516
1517 =back
1518
1519 =head2 insert($table, \@values || \%fieldvals)
1520
1521 This is the simplest function. You simply give it a table name
1522 and either an arrayref of values or hashref of field/value pairs.
1523 It returns an SQL INSERT statement and a list of bind values.
1524 See the sections on L</"Inserting and Updating Arrays"> and
1525 L</"Inserting and Updating SQL"> for information on how to insert
1526 with those data types.
1527
1528 =head2 update($table, \%fieldvals, \%where)
1529
1530 This takes a table, hashref of field/value pairs, and an optional
1531 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1532 of bind values.
1533 See the sections on L</"Inserting and Updating Arrays"> and
1534 L</"Inserting and Updating SQL"> for information on how to insert
1535 with those data types.
1536
1537 =head2 select($source, $fields, $where, $order)
1538
1539 This returns a SQL SELECT statement and associated list of bind values, as
1540 specified by the arguments  :
1541
1542 =over
1543
1544 =item $source
1545
1546 Specification of the 'FROM' part of the statement.
1547 The argument can be either a plain scalar (interpreted as a table
1548 name, will be quoted), or an arrayref (interpreted as a list
1549 of table names, joined by commas, quoted), or a scalarref
1550 (literal table name, not quoted), or a ref to an arrayref
1551 (list of literal table names, joined by commas, not quoted).
1552
1553 =item $fields
1554
1555 Specification of the list of fields to retrieve from
1556 the source.
1557 The argument can be either an arrayref (interpreted as a list
1558 of field names, will be joined by commas and quoted), or a
1559 plain scalar (literal SQL, not quoted).
1560 Please observe that this API is not as flexible as for
1561 the first argument C<$table>, for backwards compatibility reasons.
1562
1563 =item $where
1564
1565 Optional argument to specify the WHERE part of the query.
1566 The argument is most often a hashref, but can also be
1567 an arrayref or plain scalar --
1568 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1569
1570 =item $order
1571
1572 Optional argument to specify the ORDER BY part of the query.
1573 The argument can be a scalar, a hashref or an arrayref
1574 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1575 for details.
1576
1577 =back
1578
1579
1580 =head2 delete($table, \%where)
1581
1582 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1583 It returns an SQL DELETE statement and list of bind values.
1584
1585 =head2 where(\%where, \@order)
1586
1587 This is used to generate just the WHERE clause. For example,
1588 if you have an arbitrary data structure and know what the
1589 rest of your SQL is going to look like, but want an easy way
1590 to produce a WHERE clause, use this. It returns an SQL WHERE
1591 clause and list of bind values.
1592
1593
1594 =head2 values(\%data)
1595
1596 This just returns the values from the hash C<%data>, in the same
1597 order that would be returned from any of the other above queries.
1598 Using this allows you to markedly speed up your queries if you
1599 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1600
1601 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1602
1603 Warning: This is an experimental method and subject to change.
1604
1605 This returns arbitrarily generated SQL. It's a really basic shortcut.
1606 It will return two different things, depending on return context:
1607
1608     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1609     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1610
1611 These would return the following:
1612
1613     # First calling form
1614     $stmt = "CREATE TABLE test (?, ?)";
1615     @bind = (field1, field2);
1616
1617     # Second calling form
1618     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1619
1620 Depending on what you're trying to do, it's up to you to choose the correct
1621 format. In this example, the second form is what you would want.
1622
1623 By the same token:
1624
1625     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1626
1627 Might give you:
1628
1629     ALTER SESSION SET nls_date_format = 'MM/YY'
1630
1631 You get the idea. Strings get their case twiddled, but everything
1632 else remains verbatim.
1633
1634
1635
1636
1637 =head1 WHERE CLAUSES
1638
1639 =head2 Introduction
1640
1641 This module uses a variation on the idea from L<DBIx::Abstract>. It
1642 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1643 module is that things in arrays are OR'ed, and things in hashes
1644 are AND'ed.>
1645
1646 The easiest way to explain is to show lots of examples. After
1647 each C<%where> hash shown, it is assumed you used:
1648
1649     my($stmt, @bind) = $sql->where(\%where);
1650
1651 However, note that the C<%where> hash can be used directly in any
1652 of the other functions as well, as described above.
1653
1654 =head2 Key-value pairs
1655
1656 So, let's get started. To begin, a simple hash:
1657
1658     my %where  = (
1659         user   => 'nwiger',
1660         status => 'completed'
1661     );
1662
1663 Is converted to SQL C<key = val> statements:
1664
1665     $stmt = "WHERE user = ? AND status = ?";
1666     @bind = ('nwiger', 'completed');
1667
1668 One common thing I end up doing is having a list of values that
1669 a field can be in. To do this, simply specify a list inside of
1670 an arrayref:
1671
1672     my %where  = (
1673         user   => 'nwiger',
1674         status => ['assigned', 'in-progress', 'pending'];
1675     );
1676
1677 This simple code will create the following:
1678
1679     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1680     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1681
1682 A field associated to an empty arrayref will be considered a
1683 logical false and will generate 0=1.
1684
1685 =head2 Specific comparison operators
1686
1687 If you want to specify a different type of operator for your comparison,
1688 you can use a hashref for a given column:
1689
1690     my %where  = (
1691         user   => 'nwiger',
1692         status => { '!=', 'completed' }
1693     );
1694
1695 Which would generate:
1696
1697     $stmt = "WHERE user = ? AND status != ?";
1698     @bind = ('nwiger', 'completed');
1699
1700 To test against multiple values, just enclose the values in an arrayref:
1701
1702     status => { '=', ['assigned', 'in-progress', 'pending'] };
1703
1704 Which would give you:
1705
1706     "WHERE status = ? OR status = ? OR status = ?"
1707
1708
1709 The hashref can also contain multiple pairs, in which case it is expanded
1710 into an C<AND> of its elements:
1711
1712     my %where  = (
1713         user   => 'nwiger',
1714         status => { '!=', 'completed', -not_like => 'pending%' }
1715     );
1716
1717     # Or more dynamically, like from a form
1718     $where{user} = 'nwiger';
1719     $where{status}{'!='} = 'completed';
1720     $where{status}{'-not_like'} = 'pending%';
1721
1722     # Both generate this
1723     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1724     @bind = ('nwiger', 'completed', 'pending%');
1725
1726
1727 To get an OR instead, you can combine it with the arrayref idea:
1728
1729     my %where => (
1730          user => 'nwiger',
1731          priority => [ {'=', 2}, {'!=', 1} ]
1732     );
1733
1734 Which would generate:
1735
1736     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1737     @bind = ('nwiger', '2', '1');
1738
1739 If you want to include literal SQL (with or without bind values), just use a
1740 scalar reference or array reference as the value:
1741
1742     my %where  = (
1743         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1744         date_expires => { '<' => \"now()" }
1745     );
1746
1747 Which would generate:
1748
1749     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1750     @bind = ('11/26/2008');
1751
1752
1753 =head2 Logic and nesting operators
1754
1755 In the example above,
1756 there is a subtle trap if you want to say something like
1757 this (notice the C<AND>):
1758
1759     WHERE priority != ? AND priority != ?
1760
1761 Because, in Perl you I<can't> do this:
1762
1763     priority => { '!=', 2, '!=', 1 }
1764
1765 As the second C<!=> key will obliterate the first. The solution
1766 is to use the special C<-modifier> form inside an arrayref:
1767
1768     priority => [ -and => {'!=', 2},
1769                           {'!=', 1} ]
1770
1771
1772 Normally, these would be joined by C<OR>, but the modifier tells it
1773 to use C<AND> instead. (Hint: You can use this in conjunction with the
1774 C<logic> option to C<new()> in order to change the way your queries
1775 work by default.) B<Important:> Note that the C<-modifier> goes
1776 B<INSIDE> the arrayref, as an extra first element. This will
1777 B<NOT> do what you think it might:
1778
1779     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1780
1781 Here is a quick list of equivalencies, since there is some overlap:
1782
1783     # Same
1784     status => {'!=', 'completed', 'not like', 'pending%' }
1785     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1786
1787     # Same
1788     status => {'=', ['assigned', 'in-progress']}
1789     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1790     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1791
1792
1793
1794 =head2 Special operators : IN, BETWEEN, etc.
1795
1796 You can also use the hashref format to compare a list of fields using the
1797 C<IN> comparison operator, by specifying the list as an arrayref:
1798
1799     my %where  = (
1800         status   => 'completed',
1801         reportid => { -in => [567, 2335, 2] }
1802     );
1803
1804 Which would generate:
1805
1806     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
1807     @bind = ('completed', '567', '2335', '2');
1808
1809 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
1810 the same way.
1811
1812 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
1813 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
1814 'sqltrue' (by default : C<1=1>).
1815
1816
1817
1818 Another pair of operators is C<-between> and C<-not_between>,
1819 used with an arrayref of two values:
1820
1821     my %where  = (
1822         user   => 'nwiger',
1823         completion_date => {
1824            -not_between => ['2002-10-01', '2003-02-06']
1825         }
1826     );
1827
1828 Would give you:
1829
1830     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
1831
1832 These are the two builtin "special operators"; but the
1833 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
1834
1835 =head2 Nested conditions, -and/-or prefixes
1836
1837 So far, we've seen how multiple conditions are joined with a top-level
1838 C<AND>.  We can change this by putting the different conditions we want in
1839 hashes and then putting those hashes in an array. For example:
1840
1841     my @where = (
1842         {
1843             user   => 'nwiger',
1844             status => { -like => ['pending%', 'dispatched'] },
1845         },
1846         {
1847             user   => 'robot',
1848             status => 'unassigned',
1849         }
1850     );
1851
1852 This data structure would create the following:
1853
1854     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
1855                 OR ( user = ? AND status = ? ) )";
1856     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
1857
1858
1859 There is also a special C<-paren>
1860 operator which adds an additional set of parens, to create a subquery.
1861 For example, to get something like this:
1862
1863     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
1864     @bind = ('nwiger', '20', 'ASIA');
1865
1866 You would do:
1867
1868     my %where = (
1869          user => 'nwiger',
1870         -paren => [ workhrs => {'>', 20}, geo => 'ASIA' ],
1871     );
1872
1873
1874 Finally, clauses in hashrefs or arrayrefs can be
1875 prefixed with an C<-and> or C<-or> to change the logic
1876 inside :
1877
1878     my @where = (
1879          -and => [
1880             user => 'nwiger',
1881             -paren => [
1882                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
1883                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
1884             ],
1885         ],
1886     );
1887
1888 That would yield:
1889
1890     WHERE ( user = ? AND
1891           ( ( workhrs > ? AND geo = ? )
1892          OR ( workhrs < ? AND geo = ? ) ) )
1893
1894
1895 =head2 Algebraic inconsistency, for historical reasons
1896
1897 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
1898 operator goes C<outside> of the nested structure; whereas when connecting
1899 several constraints on one column, the C<-and> operator goes
1900 C<inside> the arrayref. Here is an example combining both features :
1901
1902    my @where = (
1903      -and => [a => 1, b => 2],
1904      -or  => [c => 3, d => 4],
1905       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
1906    )
1907
1908 yielding
1909
1910   WHERE ( (    ( a = ? AND b = ? )
1911             OR ( c = ? OR d = ? )
1912             OR ( e LIKE ? AND e LIKE ? ) ) )
1913
1914 This difference in syntax is unfortunate but must be preserved for
1915 historical reasons. So be careful : the two examples below would
1916 seem algebraically equivalent, but they are not
1917
1918   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
1919   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
1920
1921   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
1922   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
1923
1924
1925 =head2 Literal SQL
1926
1927 Finally, sometimes only literal SQL will do. If you want to include
1928 literal SQL verbatim, you can specify it as a scalar reference, namely:
1929
1930     my $inn = 'is Not Null';
1931     my %where = (
1932         priority => { '<', 2 },
1933         requestor => \$inn
1934     );
1935
1936 This would create:
1937
1938     $stmt = "WHERE priority < ? AND requestor is Not Null";
1939     @bind = ('2');
1940
1941 Note that in this example, you only get one bind parameter back, since
1942 the verbatim SQL is passed as part of the statement.
1943
1944 Of course, just to prove a point, the above can also be accomplished
1945 with this:
1946
1947     my %where = (
1948         priority  => { '<', 2 },
1949         requestor => { '!=', undef },
1950     );
1951
1952
1953 TMTOWTDI.
1954
1955 Conditions on boolean columns can be expressed in the
1956 same way, passing a reference to an empty string :
1957
1958     my %where = (
1959         priority  => { '<', 2 },
1960         is_ready  => \"";
1961     );
1962
1963 which yields
1964
1965     $stmt = "WHERE priority < ? AND is_ready";
1966     @bind = ('2');
1967
1968
1969 =head2 Literal SQL with placeholders and bind values (subqueries)
1970
1971 If the literal SQL to be inserted has placeholders and bind values,
1972 use a reference to an arrayref (yes this is a double reference --
1973 not so common, but perfectly legal Perl). For example, to find a date
1974 in Postgres you can use something like this:
1975
1976     my %where = (
1977        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
1978     )
1979
1980 This would create:
1981
1982     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
1983     @bind = ('10');
1984
1985 Note that you must pass the bind values in the same format as they are returned
1986 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
1987 provide the bind values in the C<< [ column_meta => value ] >> format, where
1988 C<column_meta> is an opaque scalar value; most commonly the column name, but
1989 you can use any scalar value (including references and blessed references),
1990 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
1991 to C<columns> the above example will look like:
1992
1993     my %where = (
1994        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
1995     )
1996
1997 Literal SQL is especially useful for nesting parenthesized clauses in the
1998 main SQL query. Here is a first example :
1999
2000   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2001                                100, "foo%");
2002   my %where = (
2003     foo => 1234,
2004     bar => \["IN ($sub_stmt)" => @sub_bind],
2005   );
2006
2007 This yields :
2008
2009   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2010                                              WHERE c2 < ? AND c3 LIKE ?))";
2011   @bind = (1234, 100, "foo%");
2012
2013 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2014 are expressed in the same way. Of course the C<$sub_stmt> and
2015 its associated bind values can be generated through a former call
2016 to C<select()> :
2017
2018   my ($sub_stmt, @sub_bind)
2019      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2020                                  c3 => {-like => "foo%"}});
2021   my %where = (
2022     foo => 1234,
2023     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2024   );
2025
2026 In the examples above, the subquery was used as an operator on a column;
2027 but the same principle also applies for a clause within the main C<%where>
2028 hash, like an EXISTS subquery :
2029
2030   my ($sub_stmt, @sub_bind)
2031      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2032   my %where = (
2033     foo   => 1234,
2034     -paren => \["EXISTS ($sub_stmt)" => @sub_bind],
2035   );
2036
2037 which yields
2038
2039   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2040                                         WHERE c1 = ? AND c2 > t0.c0))";
2041   @bind = (1234, 1);
2042
2043
2044 Observe that the condition on C<c2> in the subquery refers to
2045 column C<t0.c0> of the main query : this is I<not> a bind
2046 value, so we have to express it through a scalar ref.
2047 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2048 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2049 what we wanted here.
2050
2051 Another use of the subquery technique is when some SQL clauses need
2052 parentheses, as it often occurs with some proprietary SQL extensions
2053 like for example fulltext expressions, geospatial expressions,
2054 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2055
2056   my %where = (
2057     -paren => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2058   );
2059
2060 Finally, here is an example where a subquery is used
2061 for expressing unary negation:
2062
2063   my ($sub_stmt, @sub_bind)
2064      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2065   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2066   my %where = (
2067         lname  => {like => '%son%'},
2068         -paren  => \["NOT ($sub_stmt)" => @sub_bind],
2069     );
2070
2071 This yields
2072
2073   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2074   @bind = ('%son%', 10, 20)
2075
2076
2077
2078 =head2 Conclusion
2079
2080 These pages could go on for a while, since the nesting of the data
2081 structures this module can handle are pretty much unlimited (the
2082 module implements the C<WHERE> expansion as a recursive function
2083 internally). Your best bet is to "play around" with the module a
2084 little to see how the data structures behave, and choose the best
2085 format for your data based on that.
2086
2087 And of course, all the values above will probably be replaced with
2088 variables gotten from forms or the command line. After all, if you
2089 knew everything ahead of time, you wouldn't have to worry about
2090 dynamically-generating SQL and could just hardwire it into your
2091 script.
2092
2093
2094
2095
2096 =head1 ORDER BY CLAUSES
2097
2098 Some functions take an order by clause. This can either be a scalar (just a
2099 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2100 or an array of either of the two previous forms. Examples:
2101
2102                Given            |         Will Generate
2103     ----------------------------------------------------------
2104                                 |
2105     \'colA DESC'                | ORDER BY colA DESC
2106                                 |
2107     'colA'                      | ORDER BY colA
2108                                 |
2109     [qw/colA colB/]             | ORDER BY colA, colB
2110                                 |
2111     {-asc  => 'colA'}           | ORDER BY colA ASC
2112                                 |
2113     {-desc => 'colB'}           | ORDER BY colB DESC
2114                                 |
2115     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2116                                 |
2117     { -asc => [qw/colA colB] }  | ORDER BY colA ASC, colB ASC
2118                                 |
2119     [                           |
2120       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2121       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2122       { -asc => [qw/colC colD/],|
2123     ]                           |
2124     ===========================================================
2125
2126
2127
2128 =head1 SPECIAL OPERATORS
2129
2130   my $sqlmaker = SQL::Abstract->new(special_ops => [
2131      {regex => qr/.../,
2132       handler => sub {
2133         my ($self, $field, $op, $arg) = @_;
2134         ...
2135         },
2136      },
2137    ]);
2138
2139 A "special operator" is a SQL syntactic clause that can be
2140 applied to a field, instead of a usual binary operator.
2141 For example :
2142
2143    WHERE field IN (?, ?, ?)
2144    WHERE field BETWEEN ? AND ?
2145    WHERE MATCH(field) AGAINST (?, ?)
2146
2147 Special operators IN and BETWEEN are fairly standard and therefore
2148 are builtin within C<SQL::Abstract>. For other operators,
2149 like the MATCH .. AGAINST example above which is
2150 specific to MySQL, you can write your own operator handlers :
2151 supply a C<special_ops> argument to the C<new> method.
2152 That argument takes an arrayref of operator definitions;
2153 each operator definition is a hashref with two entries
2154
2155 =over
2156
2157 =item regex
2158
2159 the regular expression to match the operator
2160
2161 =item handler
2162
2163 coderef that will be called when meeting that operator
2164 in the input tree. The coderef will be called with
2165 arguments  C<< ($self, $field, $op, $arg) >>, and
2166 should return a C<< ($sql, @bind) >> structure.
2167
2168 =back
2169
2170 For example, here is an implementation
2171 of the MATCH .. AGAINST syntax for MySQL
2172
2173   my $sqlmaker = SQL::Abstract->new(special_ops => [
2174
2175     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2176     {regex => qr/^match$/i,
2177      handler => sub {
2178        my ($self, $field, $op, $arg) = @_;
2179        $arg = [$arg] if not ref $arg;
2180        my $label         = $self->_quote($field);
2181        my ($placeholder) = $self->_convert('?');
2182        my $placeholders  = join ", ", (($placeholder) x @$arg);
2183        my $sql           = $self->_sqlcase('match') . " ($label) "
2184                          . $self->_sqlcase('against') . " ($placeholders) ";
2185        my @bind = $self->_bindtype($field, @$arg);
2186        return ($sql, @bind);
2187        }
2188      },
2189
2190   ]);
2191
2192
2193 =head1 PERFORMANCE
2194
2195 Thanks to some benchmarking by Mark Stosberg, it turns out that
2196 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2197 I must admit this wasn't an intentional design issue, but it's a
2198 byproduct of the fact that you get to control your C<DBI> handles
2199 yourself.
2200
2201 To maximize performance, use a code snippet like the following:
2202
2203     # prepare a statement handle using the first row
2204     # and then reuse it for the rest of the rows
2205     my($sth, $stmt);
2206     for my $href (@array_of_hashrefs) {
2207         $stmt ||= $sql->insert('table', $href);
2208         $sth  ||= $dbh->prepare($stmt);
2209         $sth->execute($sql->values($href));
2210     }
2211
2212 The reason this works is because the keys in your C<$href> are sorted
2213 internally by B<SQL::Abstract>. Thus, as long as your data retains
2214 the same structure, you only have to generate the SQL the first time
2215 around. On subsequent queries, simply use the C<values> function provided
2216 by this module to return your values in the correct order.
2217
2218
2219 =head1 FORMBUILDER
2220
2221 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2222 really like this part (I do, at least). Building up a complex query
2223 can be as simple as the following:
2224
2225     #!/usr/bin/perl
2226
2227     use CGI::FormBuilder;
2228     use SQL::Abstract;
2229
2230     my $form = CGI::FormBuilder->new(...);
2231     my $sql  = SQL::Abstract->new;
2232
2233     if ($form->submitted) {
2234         my $field = $form->field;
2235         my $id = delete $field->{id};
2236         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2237     }
2238
2239 Of course, you would still have to connect using C<DBI> to run the
2240 query, but the point is that if you make your form look like your
2241 table, the actual query script can be extremely simplistic.
2242
2243 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2244 a fast interface to returning and formatting data. I frequently
2245 use these three modules together to write complex database query
2246 apps in under 50 lines.
2247
2248
2249 =head1 CHANGES
2250
2251 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2252 Great care has been taken to preserve the I<published> behavior
2253 documented in previous versions in the 1.* family; however,
2254 some features that were previously undocumented, or behaved
2255 differently from the documentation, had to be changed in order
2256 to clarify the semantics. Hence, client code that was relying
2257 on some dark areas of C<SQL::Abstract> v1.*
2258 B<might behave differently> in v1.50.
2259
2260 The main changes are :
2261
2262 =over
2263
2264 =item *
2265
2266 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2267
2268 =item *
2269
2270 support for the { operator => \"..." } construct (to embed literal SQL)
2271
2272 =item *
2273
2274 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2275
2276 =item *
2277
2278 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2279
2280 =item *
2281
2282 defensive programming : check arguments
2283
2284 =item *
2285
2286 fixed bug with global logic, which was previously implemented
2287 through global variables yielding side-effects. Prior versions would
2288 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2289 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2290 Now this is interpreted
2291 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2292
2293
2294 =item *
2295
2296 fixed semantics of  _bindtype on array args
2297
2298 =item *
2299
2300 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2301 we just avoid shifting arrays within that tree.
2302
2303 =item *
2304
2305 dropped the C<_modlogic> function
2306
2307 =back
2308
2309
2310
2311 =head1 ACKNOWLEDGEMENTS
2312
2313 There are a number of individuals that have really helped out with
2314 this module. Unfortunately, most of them submitted bugs via CPAN
2315 so I have no idea who they are! But the people I do know are:
2316
2317     Ash Berlin (order_by hash term support)
2318     Matt Trout (DBIx::Class support)
2319     Mark Stosberg (benchmarking)
2320     Chas Owens (initial "IN" operator support)
2321     Philip Collins (per-field SQL functions)
2322     Eric Kolve (hashref "AND" support)
2323     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2324     Dan Kubb (support for "quote_char" and "name_sep")
2325     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2326     Laurent Dami (internal refactoring, multiple -paren, extensible list of special operators, literal SQL)
2327     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2328     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2329
2330 Thanks!
2331
2332 =head1 SEE ALSO
2333
2334 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2335
2336 =head1 AUTHOR
2337
2338 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2339
2340 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2341
2342 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2343 While not an official support venue, C<DBIx::Class> makes heavy use of
2344 C<SQL::Abstract>, and as such list members there are very familiar with
2345 how to create queries.
2346
2347 =head1 LICENSE
2348
2349 This module is free software; you may copy this under the terms of
2350 the GNU General Public License, or the Artistic License, copies of
2351 which should have accompanied your Perl kit.
2352
2353 =cut
2354