lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     $self->join_query_parts(' ', $self->format_keyword('update'), $target);
  31   };
  32   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  33   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  34   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  35   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  36     for @{$self->{clauses_of}{delete}};
  37   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  38   $self->{render_clause}{'delete.target'} = sub {
  39     my ($self, undef, $from) = @_;
  40     $self->join_query_parts(' ', $self->format_keyword('delete from'), $from);
  41   };
  42   $self->{clauses_of}{insert} = [
  43     'target', 'fields', 'from', 'returning'
  44   ];
  45   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  46   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  47   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  48   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  49   $self->{expand_clause}{'insert.fields'} = sub {
  50     return +{ -row => [
  51       $_[0]->_expand_maybe_list_expr($_[2], -ident)
  52     ] } if ref($_[2]) eq 'ARRAY';
  53     return $_[2]; # should maybe still expand somewhat?
  54   };
  55   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  56   $self->{expand_clause}{'insert.returning'} = sub {
  57     $_[0]->_expand_maybe_list_expr($_[2], -ident);
  58   };
  59   $self->{render_clause}{'insert.fields'} = sub {
  60     return $_[0]->render_aqt($_[2]);
  61   };
  62   $self->{render_clause}{'insert.target'} = sub {
  63     my ($self, undef, $from) = @_;
  64     $self->join_query_parts(' ', $self->format_keyword('insert into'), $from);
  65   };
  66   $self->{render_clause}{'insert.from'} = sub {
  67     return $_[0]->render_aqt($_[2], 1);
  68   };
  69   $self->{expand}{values} = '_expand_values';
  70   $self->{render}{values} = '_render_values';
  71   $self->{expand}{exists} = sub {
  72     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  73   };
  74   $self->{render}{convert_where} = sub {
  75     my $self = shift;
  76     local $self->{convert_where} = $self->{convert};
  77     $self->render_aqt($_[1]);
  78   };
  79   return $self;
  80 }
  81
  82 sub _expand_select_clause_select {
  83   my ($self, undef, $select) = @_;
  84   +(select => $self->_expand_maybe_list_expr($select, -ident));
  85 }
  86
  87 sub _expand_select_clause_from {
  88   my ($self, undef, $from) = @_;
  89   +(from => $self->_expand_maybe_list_expr($from, -ident));
  90 }
  91
  92 sub _expand_select_clause_where {
  93   my ($self, undef, $where) = @_;
  94   my $exp = $self->expand_expr($where);
  95   +(where => ($self->{convert} ? +{ -convert_where => $exp } : $exp));
  96 }
  97
  98 sub _expand_select_clause_order_by {
  99   my ($self, undef, $order_by) = @_;
 100   +(order_by => $self->_expand_order_by($order_by));
 101 }
 102
 103 sub _expand_update_clause_target {
 104   my ($self, undef, $target) = @_;
 105   +(target => $self->_expand_maybe_list_expr($target, -ident));
 106 }
 107
 108 sub _expand_update_clause_set {
 109   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 110   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 111 }
 112
 113 sub _expand_update_clause_where {
 114   +(where => $_[0]->expand_expr($_[2]));
 115 }
 116
 117 sub _expand_update_clause_returning {
 118   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 119 }
 120
 121 sub _expand_delete_clause_target {
 122   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 123 }
 124
 125 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 126
 127 sub _expand_delete_clause_returning {
 128   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 129 }
 130
 131 sub _expand_statement {
 132   my ($self, $type, $args) = @_;
 133   my $ec = $self->{expand_clause};
 134   if ($args->{_}) {
 135     $args = { %$args };
 136     $args->{$type} = delete $args->{_}
 137   }
 138   return +{ "-${type}" => +{
 139     map {
 140       my $val = $args->{$_};
 141       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 142         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 143           ($_ => $exp[0])
 144         } else {
 145           @exp
 146         }
 147       } else {
 148         ($_ => $self->expand_expr($val))
 149       }
 150     } sort keys %$args
 151   } };
 152 }
 153
 154 sub _render_statement {
 155   my ($self, $type, $args) = @_;
 156   my @parts;
 157   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 158     next unless my $clause_expr = $args->{$clause};
 159     my @part = do {
 160       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 161         $self->$rdr($clause, $clause_expr);
 162       } else {
 163         my ($clause_sql, @bind) = $self->render_aqt($clause_expr, 1);
 164         my $sql = join ' ',
 165           $self->_sqlcase(join ' ', split '_', $clause),
 166           $clause_sql;
 167         ($sql, @bind);
 168       }
 169     };
 170     push @parts, \@part;
 171   }
 172   my ($sql, @bind) = $self->join_query_parts(' ', @parts);
 173   return (
 174     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 175     @bind
 176   );
 177 }
 178
 179 sub render_aqt {
 180   my ($self, $aqt, $top_level) = @_;
 181   local our $Render_Top_Level = $top_level;
 182   return $self->next::method($aqt);
 183 }
 184
 185 sub render_statement {
 186   my ($self, $expr, $default_scalar_to) = @_;
 187   my ($sql, @bind) = $self->render_aqt(
 188     $self->expand_expr($expr, $default_scalar_to), 1
 189   );
 190   return (wantarray ? ($sql, @bind) : $sql);
 191 }
 192
 193 sub select {
 194   my ($self, @args) = @_;
 195
 196   return $self->render_statement({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 197
 198   my %clauses;
 199   @clauses{qw(from select where order_by)} = @args;
 200
 201   # This oddity is to literalify since historically SQLA doesn't quote
 202   # a single identifier argument, so we convert it into a literal
 203
 204   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 205     unless ref($clauses{select});
 206
 207   return $self->render_statement({ -select => \%clauses });
 208 }
 209
 210 sub update {
 211   my ($self, $table, $set, $where, $options) = @_;
 212
 213   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 214
 215   my %clauses;
 216   @clauses{qw(target set where)} = ($table, $set, $where);
 217   puke "Unsupported data type specified to \$sql->update"
 218     unless ref($clauses{set}) eq 'HASH';
 219   @clauses{keys %$options} = values %$options;
 220   return $self->render_statement({ -update => \%clauses });
 221 }
 222
 223 sub delete {
 224   my ($self, $table, $where, $options) = @_;
 225
 226   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 227
 228   my %clauses = (target => $table, where => $where, %{$options||{}});
 229   return $self->render_statement({ -delete => \%clauses });
 230 }
 231
 232 sub insert {
 233   my ($self, $table, $data, $options) = @_;
 234
 235   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 236
 237   my %clauses = (target => $table, values => $data, %{$options||{}});
 238   return $self->render_statement({ -insert => \%clauses });
 239 }
 240
 241 sub _expand_insert_clause_target {
 242   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 243 }
 244
 245 sub _expand_insert_clause_values {
 246   my ($self, undef, $data) = @_;
 247   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 248     return $self->expand_expr($data);
 249   }
 250   return $data if ref($data) eq 'HASH' and $data->{-row};
 251   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 252   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 253 }
 254
 255 sub _expand_values {
 256   my ($self, undef, $values) = @_;
 257   return { -values => [
 258     map +(
 259       ref($_) eq 'HASH'
 260         ? $self->expand_expr($_)
 261         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 262     ), ref($values) eq 'ARRAY' ? @$values : $values
 263   ] };
 264 }
 265
 266 sub _render_values {
 267   my ($self, undef, $values) = @_;
 268   my $inner = [
 269     $self->join_query_parts(' ',
 270       $self->format_keyword('values'),
 271       [ $self->join_query_parts(', ',
 272         ref($values) eq 'ARRAY' ? @$values : $values
 273       ) ],
 274     ),
 275   ];
 276   return $self->join_query_parts('',
 277     (our $Render_Top_Level ? $inner : ('(', $inner, ')'))
 278   );
 279 }
 280
 281 sub _ext_rw {
 282   my ($self, $name, $key, $value) = @_;
 283   return $self->{$name}{$key} unless @_ > 3;
 284   $self->{$name}{$key} = $value;
 285   return $self;
 286 }
 287
 288 BEGIN {
 289   foreach my $type (qw(
 290     expand op_expand render op_render clause_expand clause_render
 291   )) {
 292     my $name = join '_', reverse split '_', $type;
 293     my $singular = "${type}er";
 294     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 295       or die "Method builder failed for ${singular}: $@";
 296     eval qq{sub wrap_${singular} {
 297       my (\$self, \$key, \$builder) = \@_;
 298       my \$orig = \$self->_ext_rw('${name}', \$key);
 299       \$self->_ext_rw(
 300         '${name}', \$key,
 301         \$builder->(\$orig, '${name}', \$key)
 302       );
 303     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 304     eval qq{sub ${singular}s {
 305       my (\$self, \@args) = \@_;
 306       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 307         \$self->{${name}}{\$this_key} = \$this_value;
 308       }
 309       return \$self;
 310     }; 1 } or die "Method builder failed for ${singular}s: $@";
 311     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 312      or die "Method builder failed for ${singular}_list: $@";
 313   }
 314 }
 315
 316 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 317
 318 sub clauses_of {
 319   my ($self, $of, @clauses) = @_;
 320   unless (@clauses) {
 321     return @{$self->{clauses_of}{$of}||[]};
 322   }
 323   if (ref($clauses[0]) eq 'CODE') {
 324     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 325   }
 326   $self->{clauses_of}{$of} = \@clauses;
 327   return $self;
 328 }
 329
 330 sub clone {
 331   my ($self) = @_;
 332   bless(
 333     {
 334       (map +($_ => (
 335         ref($self->{$_}) eq 'HASH'
 336           ? { %{$self->{$_}} }
 337           : $self->{$_}
 338       )), keys %$self),
 339     },
 340     ref($self)
 341   );
 342 }
 343
 344 1;