lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use mro 'c3';
   6 use base 'SQL::Abstract';
   7
   8 BEGIN { *puke = \&SQL::Abstract::puke }
   9
  10 sub new {
  11   shift->next::method(@_)->register_defaults
  12 }
  13
  14 sub register_defaults {
  15   my ($self) = @_;
  16   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  17   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  18   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  19   $self->{expand_clause}{'select.select'} = sub {
  20     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  21   };
  22   $self->{expand_clause}{'select.from'} = sub {
  23     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  24   };
  25   $self->{expand_clause}{'select.where'} = 'expand_expr';
  26   $self->{expand_clause}{'select.order_by'} = '_expand_order_by';
  27   $self->{clauses_of}{update} = [ qw(update set where returning) ];
  28   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  29   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  30   $self->{expand_clause}{'update.update'} = sub {
  31     $_[0]->expand_expr($_[1], -ident)
  32   };
  33   $self->{expand_clause}{'update.set'} = '_expand_update_set_values';
  34   $self->{expand_clause}{'update.where'} = 'expand_expr';
  35   $self->{expand_clause}{'update.returning'} = sub {
  36     shift->_expand_maybe_list_expr(@_, -ident);
  37   };
  38   $self->{clauses_of}{delete} = [ qw(delete_from where returning) ];
  39   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  40   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  41   $self->{expand_clause}{'delete.delete_from'} = sub {
  42     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  43   };
  44   $self->{expand_clause}{'delete.where'} = 'expand_expr';
  45   $self->{expand_clause}{'delete.returning'} = sub {
  46     shift->_expand_maybe_list_expr(@_, -ident);
  47   };
  48   return $self;
  49 }
  50
  51 sub _expand_statement {
  52   my ($self, $type, $args) = @_;
  53   my $ec = $self->{expand_clause};
  54   return +{ "-${type}" => +{
  55     map +($_ => (do {
  56       my $val = $args->{$_};
  57       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
  58         $self->$exp($val);
  59       } else {
  60         $val;
  61       }
  62     })), sort keys %$args
  63   } };
  64 }
  65
  66 sub _render_statement {
  67   my ($self, $type, $args) = @_;
  68   my @parts;
  69   foreach my $clause (@{$self->{clauses_of}{$type}}) {
  70     next unless my $clause_expr = $args->{$clause};
  71     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
  72     my ($sql, @bind) = $self->render_aqt($clause_expr);
  73     next unless defined($sql) and length($sql);
  74     push @parts, [
  75       $self->_sqlcase(join ' ', split '_', $clause).' '.$sql,
  76       @bind
  77     ];
  78   }
  79   return $self->_join_parts(' ', @parts);
  80 }
  81
  82 sub select {
  83   my ($self, @args) = @_;
  84   my %clauses;
  85   @clauses{qw(from select where order_by)} = @args;
  86
  87   # This oddity is to literalify since historically SQLA doesn't quote
  88   # a single identifier argument, so we convert it into a literal
  89
  90   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
  91     unless ref($clauses{select});
  92
  93   my ($sql, @bind) = $self->render_expr({ -select => \%clauses });
  94   return wantarray ? ($sql, @bind) : $sql;
  95 }
  96
  97 sub update {
  98   my ($self, $table, $set, $where, $options) = @_;
  99   my %clauses;
 100   @clauses{qw(update set where)} = ($table, $set, $where);
 101   puke "Unsupported data type specified to \$sql->update"
 102     unless ref($clauses{set}) eq 'HASH';
 103   @clauses{keys %$options} = values %$options;
 104   my ($sql, @bind) = $self->render_expr({ -update => \%clauses });
 105   return wantarray ? ($sql, @bind) : $sql;
 106 }
 107
 108 sub delete {
 109   my ($self, $table, $where, $options) = @_;
 110   my %clauses = (delete_from => $table, where => $where, %{$options||{}});
 111   my ($sql, @bind) = $self->render_expr({ -delete => \%clauses });
 112   return wantarray ? ($sql, @bind) : $sql;
 113 }
 114
 115 1;