lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use mro 'c3';
   6 use base 'SQL::Abstract';
   7
   8 BEGIN { *puke = \&SQL::Abstract::puke }
   9
  10 sub new {
  11   shift->next::method(@_)->register_defaults
  12 }
  13
  14 sub register_defaults {
  15   my ($self) = @_;
  16   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  17   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  18   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  19   $self->{expand_clause}{'select.select'} = sub {
  20     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  21   };
  22   $self->{expand_clause}{'select.from'} = sub {
  23     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  24   };
  25   $self->{expand_clause}{'select.where'} = 'expand_expr';
  26   $self->{expand_clause}{'select.order_by'} = '_expand_order_by';
  27   $self->{clauses_of}{update} = [ qw(update set where returning) ];
  28   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  29   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  30   $self->{expand_clause}{'update.update'} = sub {
  31     $_[0]->expand_expr($_[1], -ident)
  32   };
  33   $self->{expand_clause}{'update.set'} = '_expand_update_set_values';
  34   $self->{expand_clause}{'update.where'} = 'expand_expr';
  35   $self->{expand_clause}{'update.returning'} = sub {
  36     shift->_expand_maybe_list_expr(@_, -ident);
  37   };
  38   $self->{clauses_of}{delete} = [ qw(delete_from where returning) ];
  39   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  40   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  41   $self->{expand_clause}{'delete.delete_from'} = sub {
  42     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  43   };
  44   $self->{expand_clause}{'delete.where'} = 'expand_expr';
  45   $self->{expand_clause}{'delete.returning'} = sub {
  46     shift->_expand_maybe_list_expr(@_, -ident);
  47   };
  48   $self->{clauses_of}{insert} = [
  49     'insert_into', 'fields', 'values', 'returning'
  50   ];
  51   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  52   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  53   $self->{expand_clause}{'insert.insert_into'} = sub {
  54     shift->expand_expr(@_, -ident);
  55   };
  56   $self->{expand_clause}{'insert.returning'} = sub {
  57     shift->_expand_maybe_list_expr(@_, -ident);
  58   };
  59   $self->{render_clause}{'insert.fields'} = sub {
  60     return $_[0]->render_aqt({ -row => [ $_[1] ] });
  61   };
  62   return $self;
  63 }
  64
  65 sub _expand_statement {
  66   my ($self, $type, $args) = @_;
  67   my $ec = $self->{expand_clause};
  68   return +{ "-${type}" => +{
  69     map {
  70       my $val = $args->{$_};
  71       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
  72         if ((my (@exp) = $self->$exp($val)) == 1) {
  73           ($_ => $exp[0])
  74         } else {
  75           @exp
  76         }
  77       } else {
  78         ($_ => $val)
  79       }
  80     } sort keys %$args
  81   } };
  82 }
  83
  84 sub _render_statement {
  85   my ($self, $type, $args) = @_;
  86   my @parts;
  87   foreach my $clause (@{$self->{clauses_of}{$type}}) {
  88     next unless my $clause_expr = $args->{$clause};
  89     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
  90     my ($sql) = my @part = do {
  91       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
  92         $self->$rdr($clause_expr);
  93       } else {
  94         my ($clause_sql, @bind) = $self->render_aqt($clause_expr);
  95         my $sql = join ' ',
  96           $self->_sqlcase(join ' ', split '_', $clause),
  97           $clause_sql;
  98         ($sql, @bind);
  99       }
 100     };
 101     next unless defined($sql) and length($sql);
 102     push @parts, \@part;
 103   }
 104   return $self->_join_parts(' ', @parts);
 105 }
 106
 107 sub select {
 108   my ($self, @args) = @_;
 109   my %clauses;
 110   @clauses{qw(from select where order_by)} = @args;
 111
 112   # This oddity is to literalify since historically SQLA doesn't quote
 113   # a single identifier argument, so we convert it into a literal
 114
 115   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 116     unless ref($clauses{select});
 117
 118   my ($sql, @bind) = $self->render_expr({ -select => \%clauses });
 119   return wantarray ? ($sql, @bind) : $sql;
 120 }
 121
 122 sub update {
 123   my ($self, $table, $set, $where, $options) = @_;
 124   my %clauses;
 125   @clauses{qw(update set where)} = ($table, $set, $where);
 126   puke "Unsupported data type specified to \$sql->update"
 127     unless ref($clauses{set}) eq 'HASH';
 128   @clauses{keys %$options} = values %$options;
 129   my ($sql, @bind) = $self->render_expr({ -update => \%clauses });
 130   return wantarray ? ($sql, @bind) : $sql;
 131 }
 132
 133 sub delete {
 134   my ($self, $table, $where, $options) = @_;
 135   my %clauses = (delete_from => $table, where => $where, %{$options||{}});
 136   my ($sql, @bind) = $self->render_expr({ -delete => \%clauses });
 137   return wantarray ? ($sql, @bind) : $sql;
 138 }
 139
 140 sub insert {
 141   my ($self, $table, $data, $options) = @_;
 142   my %clauses = (insert_into => $table, %{$options||{}});
 143   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 144   $clauses{fields} = $f_aqt if $f_aqt;
 145   $clauses{values} = $v_aqt;
 146   my ($sql, @bind) = $self->render_expr({ -insert => \%clauses });
 147   return wantarray ? ($sql, @bind) : $sql;
 148 }
 149
 150 1;