lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use mro 'c3';
   6 use base 'SQL::Abstract';
   7
   8 BEGIN { *puke = \&SQL::Abstract::puke }
   9
  10 sub new {
  11   shift->next::method(@_)->register_defaults
  12 }
  13
  14 sub register_defaults {
  15   my ($self) = @_;
  16   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  17   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  18   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  19   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  20     for @{$self->{clauses_of}{select}};
  21   $self->{clauses_of}{update} = [ qw(update set where returning) ];
  22   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  23   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  24   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  25     for @{$self->{clauses_of}{update}};
  26   $self->{clauses_of}{delete} = [ qw(delete_from where returning) ];
  27   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  28   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  29   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  30     for @{$self->{clauses_of}{delete}};
  31   $self->{clauses_of}{insert} = [
  32     'insert_into', 'fields', 'values', 'returning'
  33   ];
  34   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  36   $self->{expand_clause}{'insert.insert_into'} = sub {
  37     shift->expand_expr(@_, -ident);
  38   };
  39   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  40   $self->{expand_clause}{'insert.returning'} = sub {
  41     shift->_expand_maybe_list_expr(@_, -ident);
  42   };
  43   $self->{render_clause}{'insert.fields'} = sub {
  44     return $_[0]->render_aqt({ -row => [ $_[1] ] });
  45   };
  46   return $self;
  47 }
  48
  49 sub _expand_select_clause_select {
  50   my ($self, $select) = @_;
  51   +(select => $self->_expand_maybe_list_expr($select, -ident));
  52 }
  53
  54 sub _expand_select_clause_from {
  55   my ($self, $from) = @_;
  56   +(from => $self->_expand_maybe_list_expr($from, -ident));
  57 }
  58
  59 sub _expand_select_clause_where {
  60   my ($self, $where) = @_;
  61   +(where => $self->expand_expr($where));
  62 }
  63
  64 sub _expand_select_clause_order_by {
  65   my ($self, $order_by) = @_;
  66   +(order_by => $self->_expand_order_by($order_by));
  67 }
  68
  69 sub _expand_update_clause_update {
  70   my ($self, $target) = @_;
  71   +(update => $self->expand_expr($target, -ident));
  72 }
  73
  74 sub _expand_update_clause_set {
  75   +(set => shift->_expand_update_set_values(@_));
  76 }
  77
  78 sub _expand_update_clause_where {
  79   +(where => shift->expand_expr(@_));
  80 }
  81
  82 sub _expand_update_clause_returning {
  83   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
  84 }
  85
  86 sub _expand_delete_clause_delete_from {
  87   +(delete_from => shift->_expand_maybe_list_expr(@_, -ident));
  88 }
  89
  90 sub _expand_delete_clause_where { +(where => shift->expand_expr(@_)); }
  91
  92 sub _expand_delete_clause_returning {
  93   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
  94 }
  95
  96 sub _expand_statement {
  97   my ($self, $type, $args) = @_;
  98   my $ec = $self->{expand_clause};
  99   return +{ "-${type}" => +{
 100     map {
 101       my $val = $args->{$_};
 102       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 103         if ((my (@exp) = $self->$exp($val)) == 1) {
 104           ($_ => $exp[0])
 105         } else {
 106           @exp
 107         }
 108       } else {
 109         ($_ => $val)
 110       }
 111     } sort keys %$args
 112   } };
 113 }
 114
 115 sub _render_statement {
 116   my ($self, $type, $args) = @_;
 117   my @parts;
 118   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 119     next unless my $clause_expr = $args->{$clause};
 120     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 121     my ($sql) = my @part = do {
 122       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 123         $self->$rdr($clause_expr);
 124       } else {
 125         my ($clause_sql, @bind) = $self->render_aqt($clause_expr);
 126         my $sql = join ' ',
 127           $self->_sqlcase(join ' ', split '_', $clause),
 128           $clause_sql;
 129         ($sql, @bind);
 130       }
 131     };
 132     next unless defined($sql) and length($sql);
 133     push @parts, \@part;
 134   }
 135   return $self->_join_parts(' ', @parts);
 136 }
 137
 138 sub select {
 139   my ($self, @args) = @_;
 140   my %clauses;
 141   @clauses{qw(from select where order_by)} = @args;
 142
 143   # This oddity is to literalify since historically SQLA doesn't quote
 144   # a single identifier argument, so we convert it into a literal
 145
 146   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 147     unless ref($clauses{select});
 148
 149   my ($sql, @bind) = $self->render_expr({ -select => \%clauses });
 150   return wantarray ? ($sql, @bind) : $sql;
 151 }
 152
 153 sub update {
 154   my ($self, $table, $set, $where, $options) = @_;
 155   my %clauses;
 156   @clauses{qw(update set where)} = ($table, $set, $where);
 157   puke "Unsupported data type specified to \$sql->update"
 158     unless ref($clauses{set}) eq 'HASH';
 159   @clauses{keys %$options} = values %$options;
 160   my ($sql, @bind) = $self->render_expr({ -update => \%clauses });
 161   return wantarray ? ($sql, @bind) : $sql;
 162 }
 163
 164 sub delete {
 165   my ($self, $table, $where, $options) = @_;
 166   my %clauses = (delete_from => $table, where => $where, %{$options||{}});
 167   my ($sql, @bind) = $self->render_expr({ -delete => \%clauses });
 168   return wantarray ? ($sql, @bind) : $sql;
 169 }
 170
 171 sub insert {
 172   my ($self, $table, $data, $options) = @_;
 173   my %clauses = (insert_into => $table, values => $data, %{$options||{}});
 174   my ($sql, @bind) = $self->render_expr({ -insert => \%clauses });
 175   return wantarray ? ($sql, @bind) : $sql;
 176 }
 177
 178 sub _expand_insert_clause_values {
 179   my ($self, $data) = @_;
 180   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 181   return (values => $v_aqt, ($f_aqt ? (fields => $f_aqt) : ()));
 182 }
 183
 184 1;