lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     my ($sql, @bind) = $self->render_aqt($target);
  31     ($self->_sqlcase('update ').$sql, @bind);
  32   };
  33   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  34   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  36   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  37     for @{$self->{clauses_of}{delete}};
  38   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  39   $self->{render_clause}{'delete.target'} = sub {
  40     my ($self, undef, $from) = @_;
  41     my ($sql, @bind) = $self->render_aqt($from);
  42     ($self->_sqlcase('delete from ').$sql, @bind);
  43   };
  44   $self->{clauses_of}{insert} = [
  45     'target', 'fields', 'from', 'returning'
  46   ];
  47   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  48   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  51   $self->{expand_clause}{'insert.fields'} = sub {
  52     return +{ -row => [
  53       shift->_expand_maybe_list_expr($_[2], -ident)
  54     ] } if ref($_[2]) eq 'ARRAY';
  55     return $_[2]; # should maybe still expand somewhat?
  56   };
  57   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  58   $self->{expand_clause}{'insert.returning'} = sub {
  59     shift->_expand_maybe_list_expr(@_, -ident);
  60   };
  61   $self->{render_clause}{'insert.fields'} = sub {
  62     return $_[0]->render_aqt($_[2]);
  63   };
  64   $self->{render_clause}{'insert.target'} = sub {
  65     my ($self, undef, $from) = @_;
  66     my ($sql, @bind) = $self->render_aqt($from);
  67     ($self->_sqlcase('insert into ').$sql, @bind);
  68   };
  69   $self->{render_clause}{'insert.from'} = sub {
  70     return $_[0]->render_aqt($_[2], 1);
  71   };
  72   $self->{expand}{values} = '_expand_values';
  73   $self->{render}{values} = '_render_values';
  74   $self->{expand}{exists} = sub {
  75     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  76   };
  77   return $self;
  78 }
  79
  80 sub _expand_select_clause_select {
  81   my ($self, undef, $select) = @_;
  82   +(select => $self->_expand_maybe_list_expr($select, -ident));
  83 }
  84
  85 sub _expand_select_clause_from {
  86   my ($self, undef, $from) = @_;
  87   +(from => $self->_expand_maybe_list_expr($from, -ident));
  88 }
  89
  90 sub _expand_select_clause_where {
  91   my ($self, undef, $where) = @_;
  92   +(where => $self->expand_expr($where));
  93 }
  94
  95 sub _expand_select_clause_order_by {
  96   my ($self, undef, $order_by) = @_;
  97   +(order_by => $self->_expand_order_by($order_by));
  98 }
  99
 100 sub _expand_update_clause_target {
 101   my ($self, undef, $target) = @_;
 102   +(target => $self->_expand_maybe_list_expr($target, -ident));
 103 }
 104
 105 sub _expand_update_clause_set {
 106   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 107   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 108 }
 109
 110 sub _expand_update_clause_where {
 111   +(where => $_[0]->expand_expr($_[2]));
 112 }
 113
 114 sub _expand_update_clause_returning {
 115   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 116 }
 117
 118 sub _expand_delete_clause_target {
 119   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 120 }
 121
 122 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 123
 124 sub _expand_delete_clause_returning {
 125   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 126 }
 127
 128 sub _expand_statement {
 129   my ($self, $type, $args) = @_;
 130   my $ec = $self->{expand_clause};
 131   if ($args->{_}) {
 132     $args = { %$args };
 133     $args->{$type} = delete $args->{_}
 134   }
 135   return +{ "-${type}" => +{
 136     map {
 137       my $val = $args->{$_};
 138       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 139         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 140           ($_ => $exp[0])
 141         } else {
 142           @exp
 143         }
 144       } else {
 145         ($_ => $self->expand_expr($val))
 146       }
 147     } sort keys %$args
 148   } };
 149 }
 150
 151 sub _render_statement {
 152   my ($self, $type, $args) = @_;
 153   my @parts;
 154   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 155     next unless my $clause_expr = $args->{$clause};
 156     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 157     my @part = do {
 158       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 159         $self->$rdr($clause, $clause_expr);
 160       } else {
 161         my ($clause_sql, @bind) = $self->render_aqt($clause_expr, 1);
 162         my $sql = join ' ',
 163           $self->_sqlcase(join ' ', split '_', $clause),
 164           $clause_sql;
 165         ($sql, @bind);
 166       }
 167     };
 168     push @parts, \@part;
 169   }
 170   my ($sql, @bind) = $self->join_query_parts(' ', @parts);
 171   return (
 172     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 173     @bind
 174   );
 175 }
 176
 177 sub render_aqt {
 178   my ($self, $aqt, $top_level) = @_;
 179   local our $Render_Top_Level = $top_level;
 180   return $self->next::method($aqt);
 181 }
 182
 183 sub render_statement {
 184   my ($self, $expr, $default_scalar_to) = @_;
 185   my ($sql, @bind) = $self->render_aqt(
 186     $self->expand_expr($expr, $default_scalar_to), 1
 187   );
 188   return (wantarray ? ($sql, @bind) : $sql);
 189 }
 190
 191 sub select {
 192   my ($self, @args) = @_;
 193
 194   return $self->render_statement({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 195
 196   my %clauses;
 197   @clauses{qw(from select where order_by)} = @args;
 198
 199   # This oddity is to literalify since historically SQLA doesn't quote
 200   # a single identifier argument, so we convert it into a literal
 201
 202   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 203     unless ref($clauses{select});
 204
 205   return $self->render_statement({ -select => \%clauses });
 206 }
 207
 208 sub update {
 209   my ($self, $table, $set, $where, $options) = @_;
 210
 211   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 212
 213   my %clauses;
 214   @clauses{qw(target set where)} = ($table, $set, $where);
 215   puke "Unsupported data type specified to \$sql->update"
 216     unless ref($clauses{set}) eq 'HASH';
 217   @clauses{keys %$options} = values %$options;
 218   return $self->render_statement({ -update => \%clauses });
 219 }
 220
 221 sub delete {
 222   my ($self, $table, $where, $options) = @_;
 223
 224   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 225
 226   my %clauses = (target => $table, where => $where, %{$options||{}});
 227   return $self->render_statement({ -delete => \%clauses });
 228 }
 229
 230 sub insert {
 231   my ($self, $table, $data, $options) = @_;
 232
 233   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 234
 235   my %clauses = (target => $table, values => $data, %{$options||{}});
 236   return $self->render_statement({ -insert => \%clauses });
 237 }
 238
 239 sub _expand_insert_clause_target {
 240   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 241 }
 242
 243 sub _expand_insert_clause_values {
 244   my ($self, undef, $data) = @_;
 245   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 246     return $self->expand_expr($data);
 247   }
 248   return $data if ref($data) eq 'HASH' and $data->{-row};
 249   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 250   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 251 }
 252
 253 sub _expand_values {
 254   my ($self, undef, $values) = @_;
 255   return { -values => [
 256     map +(
 257       ref($_) eq 'HASH'
 258         ? $self->expand_expr($_)
 259         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 260     ), ref($values) eq 'ARRAY' ? @$values : $values
 261   ] };
 262 }
 263
 264 sub _render_values {
 265   my ($self, undef, $values) = @_;
 266   my ($v_sql, @bind) = $self->join_query_parts(
 267     ', ',
 268     map [ $self->render_aqt($_) ],
 269       ref($values) eq 'ARRAY' ? @$values : $values
 270   );
 271   my $sql = $self->_sqlcase('values').' '.$v_sql;
 272   return (
 273     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 274     @bind
 275   );
 276 }
 277
 278 sub _ext_rw {
 279   my ($self, $name, $key, $value) = @_;
 280   return $self->{$name}{$key} unless @_ > 3;
 281   $self->{$name}{$key} = $value;
 282   return $self;
 283 }
 284
 285 BEGIN {
 286   foreach my $type (qw(
 287     expand op_expand render op_render clause_expand clause_render
 288   )) {
 289     my $name = join '_', reverse split '_', $type;
 290     my $singular = "${type}er";
 291     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 292       or die "Method builder failed for ${singular}: $@";
 293     eval qq{sub wrap_${singular} {
 294       my (\$self, \$key, \$builder) = \@_;
 295       my \$orig = \$self->_ext_rw('${name}', \$key);
 296       \$self->_ext_rw(
 297         '${name}', \$key,
 298         \$builder->(\$orig, '${name}', \$key)
 299       );
 300     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 301     eval qq{sub ${singular}s {
 302       my (\$self, \@args) = \@_;
 303       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 304         \$self->{${name}}{\$this_key} = \$this_value;
 305       }
 306       return \$self;
 307     }; 1 } or die "Method builder failed for ${singular}s: $@";
 308     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 309      or die "Method builder failed for ${singular}_list: $@";
 310   }
 311 }
 312
 313 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 314
 315 sub clauses_of {
 316   my ($self, $of, @clauses) = @_;
 317   unless (@clauses) {
 318     return @{$self->{clauses_of}{$of}||[]};
 319   }
 320   if (ref($clauses[0]) eq 'CODE') {
 321     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 322   }
 323   $self->{clauses_of}{$of} = \@clauses;
 324   return $self;
 325 }
 326
 327 sub clone {
 328   my ($self) = @_;
 329   bless(
 330     {
 331       (map +($_ => (
 332         ref($self->{$_}) eq 'HASH'
 333           ? { %{$self->{$_}} }
 334           : $self->{$_}
 335       )), keys %$self),
 336     },
 337     ref($self)
 338   );
 339 }
 340
 341 1;