lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use mro 'c3';
   6 use base 'SQL::Abstract';
   7
   8 BEGIN { *puke = \&SQL::Abstract::puke }
   9
  10 sub new {
  11   shift->next::method(@_)->register_defaults
  12 }
  13
  14 sub register_defaults {
  15   my ($self) = @_;
  16   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  17   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  18   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  19   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  20     for @{$self->{clauses_of}{select}};
  21   $self->{clauses_of}{update} = [ qw(update set where returning) ];
  22   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  23   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  24   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  25     for @{$self->{clauses_of}{update}};
  26   $self->{clauses_of}{delete} = [ qw(delete_from where returning) ];
  27   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  28   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  29   $self->{expand_clause}{'delete.delete_from'} = sub {
  30     $_[0]->_expand_maybe_list_expr($_[1], -ident)
  31   };
  32   $self->{expand_clause}{'delete.where'} = 'expand_expr';
  33   $self->{expand_clause}{'delete.returning'} = sub {
  34     shift->_expand_maybe_list_expr(@_, -ident);
  35   };
  36   $self->{clauses_of}{insert} = [
  37     'insert_into', 'fields', 'values', 'returning'
  38   ];
  39   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  40   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  41   $self->{expand_clause}{'insert.insert_into'} = sub {
  42     shift->expand_expr(@_, -ident);
  43   };
  44   $self->{expand_clause}{'insert.returning'} = sub {
  45     shift->_expand_maybe_list_expr(@_, -ident);
  46   };
  47   $self->{render_clause}{'insert.fields'} = sub {
  48     return $_[0]->render_aqt({ -row => [ $_[1] ] });
  49   };
  50   return $self;
  51 }
  52
  53 sub _expand_select_clause_select {
  54   my ($self, $select) = @_;
  55   +(select => $self->_expand_maybe_list_expr($select, -ident));
  56 }
  57
  58 sub _expand_select_clause_from {
  59   my ($self, $from) = @_;
  60   +(from => $self->_expand_maybe_list_expr($from, -ident));
  61 }
  62
  63 sub _expand_select_clause_where {
  64   my ($self, $where) = @_;
  65   +(where => $self->expand_expr($where));
  66 }
  67
  68 sub _expand_select_clause_order_by {
  69   my ($self, $order_by) = @_;
  70   +(order_by => $self->_expand_order_by($order_by));
  71 }
  72
  73 sub _expand_update_clause_update {
  74   my ($self, $target) = @_;
  75   +(update => $self->expand_expr($target, -ident));
  76 }
  77
  78 sub _expand_update_clause_set {
  79   +(set => shift->_expand_update_set_values(@_));
  80 }
  81
  82 sub _expand_update_clause_where {
  83   +(where => shift->expand_expr(@_));
  84 }
  85
  86 sub _expand_update_clause_returning {
  87   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
  88 }
  89
  90 sub _expand_statement {
  91   my ($self, $type, $args) = @_;
  92   my $ec = $self->{expand_clause};
  93   return +{ "-${type}" => +{
  94     map {
  95       my $val = $args->{$_};
  96       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
  97         if ((my (@exp) = $self->$exp($val)) == 1) {
  98           ($_ => $exp[0])
  99         } else {
 100           @exp
 101         }
 102       } else {
 103         ($_ => $val)
 104       }
 105     } sort keys %$args
 106   } };
 107 }
 108
 109 sub _render_statement {
 110   my ($self, $type, $args) = @_;
 111   my @parts;
 112   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 113     next unless my $clause_expr = $args->{$clause};
 114     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 115     my ($sql) = my @part = do {
 116       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 117         $self->$rdr($clause_expr);
 118       } else {
 119         my ($clause_sql, @bind) = $self->render_aqt($clause_expr);
 120         my $sql = join ' ',
 121           $self->_sqlcase(join ' ', split '_', $clause),
 122           $clause_sql;
 123         ($sql, @bind);
 124       }
 125     };
 126     next unless defined($sql) and length($sql);
 127     push @parts, \@part;
 128   }
 129   return $self->_join_parts(' ', @parts);
 130 }
 131
 132 sub select {
 133   my ($self, @args) = @_;
 134   my %clauses;
 135   @clauses{qw(from select where order_by)} = @args;
 136
 137   # This oddity is to literalify since historically SQLA doesn't quote
 138   # a single identifier argument, so we convert it into a literal
 139
 140   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 141     unless ref($clauses{select});
 142
 143   my ($sql, @bind) = $self->render_expr({ -select => \%clauses });
 144   return wantarray ? ($sql, @bind) : $sql;
 145 }
 146
 147 sub update {
 148   my ($self, $table, $set, $where, $options) = @_;
 149   my %clauses;
 150   @clauses{qw(update set where)} = ($table, $set, $where);
 151   puke "Unsupported data type specified to \$sql->update"
 152     unless ref($clauses{set}) eq 'HASH';
 153   @clauses{keys %$options} = values %$options;
 154   my ($sql, @bind) = $self->render_expr({ -update => \%clauses });
 155   return wantarray ? ($sql, @bind) : $sql;
 156 }
 157
 158 sub delete {
 159   my ($self, $table, $where, $options) = @_;
 160   my %clauses = (delete_from => $table, where => $where, %{$options||{}});
 161   my ($sql, @bind) = $self->render_expr({ -delete => \%clauses });
 162   return wantarray ? ($sql, @bind) : $sql;
 163 }
 164
 165 sub insert {
 166   my ($self, $table, $data, $options) = @_;
 167   my %clauses = (insert_into => $table, %{$options||{}});
 168   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 169   $clauses{fields} = $f_aqt if $f_aqt;
 170   $clauses{values} = $v_aqt;
 171   my ($sql, @bind) = $self->render_expr({ -insert => \%clauses });
 172   return wantarray ? ($sql, @bind) : $sql;
 173 }
 174
 175 1;