lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60
  61             next if not defined $meta;
  62
  63             if(Mouse::Util::is_a_metarole($meta)){
  64                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  65             }
  66
  67             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  68
  69             $self->_reconcile_with_superclass_meta($meta);
  70         }
  71         @{ $self->{superclasses} } = @_;
  72     }
  73
  74     return @{ $self->{superclasses} };
  75 }
  76 my @MetaClassTypes = (
  77     'attribute',   # Mouse::Meta::Attribute
  78     'method',      # Mouse::Meta::Method
  79     'constructor', # Mouse::Meta::Method::Constructor
  80     'destructor',  # Mouse::Meta::Method::Destructor
  81 );
  82
  83 sub _reconcile_with_superclass_meta {
  84     my($self, $other) = @_;
  85
  86     # find incompatible traits
  87     my %metaroles;
  88     foreach my $metaclass_type(@MetaClassTypes){
  89         my $accessor = $self->can($metaclass_type . '_metaclass')
  90             || $self->can($metaclass_type . '_class');
  91
  92         my $other_c = $other->$accessor();
  93         my $self_c  = $self->$accessor();
  94
  95         if(!$self_c->isa($other_c)){
  96             $metaroles{$metaclass_type}
  97                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
  98         }
  99     }
 100
 101     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 102
 103     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 104
 105     require Mouse::Util::MetaRole;
 106     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 107         for             => $self,
 108         class_metaroles => \%metaroles,
 109     );
 110     return;
 111 }
 112
 113 sub _collect_roles {
 114     my ($self, $other) = @_;
 115
 116     # find common ancestor
 117     my @self_lin_isa  = $self->linearized_isa;
 118     my @other_lin_isa = $other->linearized_isa;
 119
 120     my(@self_anon_supers, @other_anon_supers);
 121     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 122     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 123
 124     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 125
 126     if(!$common_ancestor){
 127         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 128             $self->name, $other->name);
 129     }
 130
 131     my %seen;
 132     return sort grep { !$seen{$_}++ } ## no critic
 133         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 134         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 135     ;
 136 }
 137
 138
 139 sub find_method_by_name{
 140     my($self, $method_name) = @_;
 141     defined($method_name)
 142         or $self->throw_error('You must define a method name to find');
 143
 144     foreach my $class( $self->linearized_isa ){
 145         my $method = $self->initialize($class)->get_method($method_name);
 146         return $method if defined $method;
 147     }
 148     return undef;
 149 }
 150
 151 sub get_all_methods {
 152     my($self) = @_;
 153     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 154 }
 155
 156 sub get_all_method_names {
 157     my $self = shift;
 158     my %uniq;
 159     return grep { $uniq{$_}++ == 0 }
 160             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 161             $self->linearized_isa;
 162 }
 163
 164 sub find_attribute_by_name{
 165     my($self, $name) = @_;
 166     my $attr;
 167     foreach my $class($self->linearized_isa){
 168         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 169         $attr = $meta->get_attribute($name) and last;
 170     }
 171     return $attr;
 172 }
 173
 174 sub add_attribute {
 175     my $self = shift;
 176
 177     my($attr, $name);
 178
 179     if(blessed $_[0]){
 180         $attr = $_[0];
 181
 182         $attr->isa('Mouse::Meta::Attribute')
 183             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 184
 185         $name = $attr->name;
 186     }
 187     else{
 188         # _process_attribute
 189         $name = shift;
 190
 191         my %args = (@_ == 1) ? %{$_[0]} : @_;
 192
 193         defined($name)
 194             or $self->throw_error('You must provide a name for the attribute');
 195
 196         if ($name =~ s/^\+//) { # inherited attributes
 197             my $inherited_attr = $self->find_attribute_by_name($name)
 198                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 199
 200             $attr = $inherited_attr->clone_and_inherit_options(%args);
 201         }
 202         else{
 203             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 204             $args{traits} = \@traits if @traits;
 205
 206             $attr = $attribute_class->new($name, %args);
 207         }
 208     }
 209
 210     weaken( $attr->{associated_class} = $self );
 211
 212     $self->{attributes}{$attr->name} = $attr;
 213     $attr->install_accessors();
 214
 215     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 216         Carp::carp(qq{Attribute ($name) of class }.$self->name
 217             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 218     }
 219     return $attr;
 220 }
 221
 222 sub compute_all_applicable_attributes { # DEPRECATED
 223     Carp::cluck('compute_all_applicable_attributes() has been deprecated. Use get_all_attributes() instead');
 224
 225     return shift->get_all_attributes(@_)
 226 }
 227
 228 sub linearized_isa;
 229
 230 sub new_object;
 231 sub clone_object;
 232
 233
 234 sub clone_instance { # DEPRECATED
 235     my ($class, $instance, %params) = @_;
 236
 237     Carp::cluck('clone_instance() has been deprecated. Use clone_object() instead');
 238
 239     return $class->clone_object($instance, %params);
 240 }
 241
 242
 243 sub immutable_options {
 244     my ( $self, @args ) = @_;
 245
 246     return (
 247         inline_constructor => 1,
 248         inline_destructor  => 1,
 249         constructor_name   => 'new',
 250         @args,
 251     );
 252 }
 253
 254
 255 sub make_immutable {
 256     my $self = shift;
 257     my %args = $self->immutable_options(@_);
 258
 259     $self->{is_immutable}++;
 260
 261     $self->{strict_constructor} = $args{strict_constructor};
 262
 263     if ($args{inline_constructor}) {
 264         $self->add_method($args{constructor_name} =>
 265             Mouse::Util::load_class($self->constructor_class)
 266                 ->_generate_constructor($self, \%args));
 267     }
 268
 269     if ($args{inline_destructor}) {
 270         $self->add_method(DESTROY =>
 271             Mouse::Util::load_class($self->destructor_class)
 272                 ->_generate_destructor($self, \%args));
 273     }
 274
 275     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 276     # at the end of a source file.
 277     return 1;
 278 }
 279
 280 sub make_mutable {
 281     my($self) = @_;
 282     $self->{is_immutable} = 0;
 283     return;
 284 }
 285
 286 sub is_immutable;
 287 sub is_mutable   { !$_[0]->is_immutable }
 288
 289 sub _install_modifier_pp{
 290     my( $self, $type, $name, $code ) = @_;
 291     my $into = $self->name;
 292
 293     my $original = $into->can($name)
 294         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 295
 296     my $modifier_table = $self->{modifiers}{$name};
 297
 298     if(!$modifier_table){
 299         my(@before, @after, @around, $cache, $modified);
 300
 301         $cache = $original;
 302
 303         $modified = sub {
 304             for my $c (@before) { $c->(@_) }
 305
 306             if(wantarray){ # list context
 307                 my @rval = $cache->(@_);
 308
 309                 for my $c(@after){ $c->(@_) }
 310                 return @rval;
 311             }
 312             elsif(defined wantarray){ # scalar context
 313                 my $rval = $cache->(@_);
 314
 315                 for my $c(@after){ $c->(@_) }
 316                 return $rval;
 317             }
 318             else{ # void context
 319                 $cache->(@_);
 320
 321                 for my $c(@after){ $c->(@_) }
 322                 return;
 323             }
 324         };
 325
 326         $self->{modifiers}{$name} = $modifier_table = {
 327             original => $original,
 328
 329             before   => \@before,
 330             after    => \@after,
 331             around   => \@around,
 332
 333             cache    => \$cache, # cache for around modifiers
 334         };
 335
 336         $self->add_method($name => $modified);
 337     }
 338
 339     if($type eq 'before'){
 340         unshift @{$modifier_table->{before}}, $code;
 341     }
 342     elsif($type eq 'after'){
 343         push @{$modifier_table->{after}}, $code;
 344     }
 345     else{ # around
 346         push @{$modifier_table->{around}}, $code;
 347
 348         my $next = ${ $modifier_table->{cache} };
 349         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 350     }
 351
 352     return;
 353 }
 354
 355 sub _install_modifier {
 356     my ( $self, $type, $name, $code ) = @_;
 357
 358     # load Data::Util first
 359     my $no_cmm_fast = do{
 360         local $@;
 361         eval q{ use Data::Util 0.55 () };
 362         $@;
 363     };
 364
 365     my $impl;
 366     if($no_cmm_fast){
 367         $impl = \&_install_modifier_pp;
 368     }
 369     else{
 370         $impl = sub {
 371             my ( $self, $type, $name, $code ) = @_;
 372             my $into = $self->name;
 373
 374             my $method = Mouse::Util::get_code_ref( $into, $name );
 375
 376             if ( !$method || !Data::Util::subroutine_modifier($method) ) {
 377                 unless ($method) {
 378                     $method = $into->can($name)
 379                         or Carp::confess("The method '$name' is not found in the inheritance hierarchy for class $into");
 380                 }
 381                 $method = Data::Util::modify_subroutine( $method,
 382                     $type => [$code] );
 383
 384                 $self->add_method($name => $method);
 385             }
 386             else {
 387                 Data::Util::subroutine_modifier( $method, $type => $code );
 388                 $self->add_method($name => Mouse::Util::get_code_ref($into, $name));
 389             }
 390
 391             return;
 392         };
 393     }
 394
 395     # replace this method itself :)
 396     {
 397         no warnings 'redefine';
 398         *_install_modifier = $impl;
 399     }
 400
 401     $self->$impl( $type, $name, $code );
 402 }
 403
 404 sub add_before_method_modifier {
 405     my ( $self, $name, $code ) = @_;
 406     $self->_install_modifier( 'before', $name, $code );
 407 }
 408
 409 sub add_around_method_modifier {
 410     my ( $self, $name, $code ) = @_;
 411     $self->_install_modifier( 'around', $name, $code );
 412 }
 413
 414 sub add_after_method_modifier {
 415     my ( $self, $name, $code ) = @_;
 416     $self->_install_modifier( 'after', $name, $code );
 417 }
 418
 419 sub add_override_method_modifier {
 420     my ($self, $name, $code) = @_;
 421
 422     if($self->has_method($name)){
 423         $self->throw_error("Cannot add an override method if a local method is already present");
 424     }
 425
 426     my $package = $self->name;
 427
 428     my $super_body = $package->can($name)
 429         or $self->throw_error("You cannot override '$name' because it has no super method");
 430
 431     $self->add_method($name => sub {
 432         local $Mouse::SUPER_PACKAGE = $package;
 433         local $Mouse::SUPER_BODY    = $super_body;
 434         local @Mouse::SUPER_ARGS    = @_;
 435
 436         $code->(@_);
 437     });
 438     return;
 439 }
 440
 441 sub add_augment_method_modifier {
 442     my ($self, $name, $code) = @_;
 443     if($self->has_method($name)){
 444         $self->throw_error("Cannot add an augment method if a local method is already present");
 445     }
 446
 447     my $super = $self->find_method_by_name($name)
 448         or $self->throw_error("You cannot augment '$name' because it has no super method");
 449
 450     my $super_package = $super->package_name;
 451     my $super_body    = $super->body;
 452
 453     $self->add_method($name => sub{
 454         local $Mouse::INNER_BODY{$super_package} = $code;
 455         local $Mouse::INNER_ARGS{$super_package} = [@_];
 456         $super_body->(@_);
 457     });
 458     return;
 459 }
 460
 461 sub does_role {
 462     my ($self, $role_name) = @_;
 463
 464     (defined $role_name)
 465         || $self->throw_error("You must supply a role name to look for");
 466
 467     $role_name = $role_name->name if ref $role_name;
 468
 469     for my $class ($self->linearized_isa) {
 470         my $meta = Mouse::Util::get_metaclass_by_name($class)
 471             or next;
 472
 473         for my $role (@{ $meta->roles }) {
 474
 475             return 1 if $role->does_role($role_name);
 476         }
 477     }
 478
 479     return 0;
 480 }
 481
 482 1;
 483 __END__
 484
 485 =head1 NAME
 486
 487 Mouse::Meta::Class - The Mouse class metaclass
 488
 489 =head1 VERSION
 490
 491 This document describes Mouse version 0.60
 492
 493 =head1 METHODS
 494
 495 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 496
 497 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 498 one instance should exist for a given class.
 499
 500 =head2 C<< name -> ClassName >>
 501
 502 Returns the name of the owner class.
 503
 504 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 505
 506 Gets (or sets) the list of superclasses of the owner class.
 507
 508 =head2 C<< add_method(name => CodeRef) >>
 509
 510 Adds a method to the owner class.
 511
 512 =head2 C<< has_method(name) -> Bool >>
 513
 514 Returns whether we have a method with the given name.
 515
 516 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 517
 518 Returns a L<Mouse::Meta::Method> with the given name.
 519
 520 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 521
 522 =head2 C<< get_method_list -> Names >>
 523
 524 Returns a list of method names which are defined in the local class.
 525 If you want a list of all applicable methods for a class, use the
 526 C<get_all_methods> method.
 527
 528 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 529
 530 Return the list of all L<Mouse::Meta::Method> instances associated with
 531 the class and its superclasses.
 532
 533 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 534
 535 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 536 class.
 537
 538 =head2 C<< has_attribute(Name) -> Bool >>
 539
 540 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 541
 542 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 543
 544 Returns the L<Mouse::Meta::Attribute> with the given name.
 545
 546 =head2 C<< get_attribute_list -> Names >>
 547
 548 Returns a list of attribute names which are defined in the local
 549 class. If you want a list of all applicable attributes for a class,
 550 use the C<get_all_attributes> method.
 551
 552 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 553
 554 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 555 this class and its superclasses.
 556
 557 =head2 C<< linearized_isa -> [ClassNames] >>
 558
 559 Returns the list of classes in method dispatch order, with duplicates removed.
 560
 561 =head2 C<< new_object(Parameters) -> Instance >>
 562
 563 Creates a new instance.
 564
 565 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 566
 567 Clones the given instance which must be an instance governed by this
 568 metaclass.
 569
 570 =head2 C<< throw_error(Message, Parameters) >>
 571
 572 Throws an error with the given message.
 573
 574 =head1 SEE ALSO
 575
 576 L<Mouse::Meta::Module>
 577
 578 L<Moose::Meta::Class>
 579
 580 L<Class::MOP::Class>
 581
 582 =cut
 583