lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.04';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14
  15 use Class::MOP;
  16
  17 use Moose::Meta::Class;
  18 use Moose::Meta::TypeConstraint;
  19 use Moose::Meta::TypeCoercion;
  20 use Moose::Meta::Attribute;
  21
  22 use Moose::Object;
  23 use Moose::Util::TypeConstraints;
  24
  25 sub import {
  26         shift;
  27         my $pkg = caller();
  28
  29         # we should never export to main
  30         return if $pkg eq 'main';
  31
  32         # make a subtype for each Moose class
  33     subtype $pkg
  34         => as 'Object'
  35         => where { $_->isa($pkg) };
  36
  37         my $meta;
  38         if ($pkg->can('meta')) {
  39                 $meta = $pkg->meta();
  40                 (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  41                         || confess "Whoops, not møøsey enough";
  42         }
  43         else {
  44                 $meta = Moose::Meta::Class->initialize($pkg => (
  45                         ':attribute_metaclass' => 'Moose::Meta::Attribute'
  46                 ));
  47                 $meta->add_method('meta' => sub {
  48                         # re-initialize so it inherits properly
  49                         Moose::Meta::Class->initialize($pkg => (
  50                                 ':attribute_metaclass' => 'Moose::Meta::Attribute'
  51                         ));
  52                 })
  53         }
  54
  55         # NOTE:
  56         # &alias_method will install the method, but it
  57         # will not name it with
  58
  59         # handle superclasses
  60         $meta->alias_method('extends' => subname 'Moose::extends' => sub {
  61         _load_all_classes(@_);
  62             $meta->superclasses(@_)
  63         });
  64
  65         # handle roles
  66         $meta->alias_method('with' => subname 'Moose::with' => sub {
  67             my ($role) = @_;
  68         _load_all_classes($role);
  69         $role->meta->apply($meta);
  70         });
  71
  72         # handle attributes
  73         $meta->alias_method('has' => subname 'Moose::has' => sub {
  74                 my ($name, %options) = @_;
  75                 $meta->add_attribute($name, %options)
  76         });
  77
  78         # handle method modifers
  79         $meta->alias_method('before' => subname 'Moose::before' => sub {
  80                 my $code = pop @_;
  81                 $meta->add_before_method_modifier($_, $code) for @_;
  82         });
  83         $meta->alias_method('after'  => subname 'Moose::after' => sub {
  84                 my $code = pop @_;
  85                 $meta->add_after_method_modifier($_, $code) for @_;
  86         });
  87         $meta->alias_method('around' => subname 'Moose::around' => sub {
  88                 my $code = pop @_;
  89                 $meta->add_around_method_modifier($_, $code) for @_;
  90         });
  91
  92         $meta->alias_method('super' => subname 'Moose::super' => sub {});
  93         $meta->alias_method('override' => subname 'Moose::override' => sub {
  94             my ($name, $method) = @_;
  95             $meta->add_override_method_modifier($name => $method);
  96         });
  97
  98         $meta->alias_method('inner' => subname 'Moose::inner' => sub {});
  99         $meta->alias_method('augment' => subname 'Moose::augment' => sub {
 100             my ($name, $method) = @_;
 101             $meta->add_augment_method_modifier($name => $method);
 102         });
 103
 104         # make sure they inherit from Moose::Object
 105         $meta->superclasses('Moose::Object')
 106        unless $meta->superclasses();
 107
 108         # we recommend using these things
 109         # so export them for them
 110         $meta->alias_method('confess' => \&Carp::confess);
 111         $meta->alias_method('blessed' => \&Scalar::Util::blessed);
 112 }
 113
 114 ## Utility functions
 115
 116 sub _load_all_classes {
 117     foreach my $super (@_) {
 118         # see if this is already
 119         # loaded in the symbol table
 120         next if _is_class_already_loaded($super);
 121         # otherwise require it ...
 122         ($super->require)
 123             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 124     }
 125 }
 126
 127 sub _is_class_already_loaded {
 128         my $name = shift;
 129         no strict 'refs';
 130         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 131         foreach (keys %{"${name}::"}) {
 132                 next if substr($_, -2, 2) eq '::';
 133                 return 1 if defined &{"${name}::$_"};
 134         }
 135     return 0;
 136 }
 137
 138 1;
 139
 140 __END__
 141
 142 =pod
 143
 144 =head1 NAME
 145
 146 Moose - Moose, it's the new Camel
 147
 148 =head1 SYNOPSIS
 149
 150   package Point;
 151   use Moose;
 152
 153   has 'x' => (isa => 'Int', is => 'rw');
 154   has 'y' => (isa => 'Int', is => 'rw');
 155
 156   sub clear {
 157       my $self = shift;
 158       $self->x(0);
 159       $self->y(0);
 160   }
 161
 162   package Point3D;
 163   use Moose;
 164
 165   extends 'Point';
 166
 167   has 'z' => (isa => 'Int');
 168
 169   after 'clear' => sub {
 170       my $self = shift;
 171       $self->{z} = 0;
 172   };
 173
 174 =head1 CAVEAT
 175
 176 This is an early release of this module, it still needs
 177 some fine tuning and B<lots> more documentation. I am adopting
 178 the I<release early and release often> approach with this module,
 179 so keep an eye on your favorite CPAN mirror!
 180
 181 =head1 DESCRIPTION
 182
 183 Moose is an extension of the Perl 5 object system.
 184
 185 =head2 Another object system!?!?
 186
 187 Yes, I know there has been an explosion recently of new ways to
 188 build object's in Perl 5, most of them based on inside-out objects,
 189 and other such things. Moose is different because it is not a new
 190 object system for Perl 5, but instead an extension of the existing
 191 object system.
 192
 193 Moose is built on top of L<Class::MOP>, which is a metaclass system
 194 for Perl 5. This means that Moose not only makes building normal
 195 Perl 5 objects better, but it also provides the power of metaclass
 196 programming.
 197
 198 =head2 What does Moose stand for??
 199
 200 Moose doesn't stand for one thing in particular, however, if you
 201 want, here are a few of my favorites, feel free to contribute
 202 more :)
 203
 204 =over 4
 205
 206 =item Make Other Object Systems Envious
 207
 208 =item Makes Object Orientation So Easy
 209
 210 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 211
 212 =item Most Other Object Systems Emasculate
 213
 214 =item My Overcraft Overfilled (with) Some Eels
 215
 216 =item Moose Often Ovulate Sorta Early
 217
 218 =item Many Overloaded Object Systems Exists
 219
 220 =item Moose Offers Often Super Extensions
 221
 222 =back
 223
 224 =head1 BUILDING CLASSES WITH MOOSE
 225
 226 Moose makes every attempt to provide as much convience during class
 227 construction/definition, but still stay out of your way if you want
 228 it to. Here are some of the features Moose provides:
 229
 230 Unless specified with C<extends>, any class which uses Moose will
 231 inherit from L<Moose::Object>.
 232
 233 Moose will also manage all attributes (including inherited ones) that
 234 are defined with C<has>. And assuming that you call C<new> which is
 235 inherited from L<Moose::Object>, then this includes properly initializing
 236 all instance slots, setting defaults where approprtiate and performing any
 237 type constraint checking or coercion.
 238
 239 For more details, see the ever expanding L<Moose::Cookbook>.
 240
 241 =head1 EXPORTED FUNCTIONS
 242
 243 Moose will export a number of functions into the class's namespace, which
 244 can then be used to set up the class. These functions all work directly
 245 on the current class.
 246
 247 =over 4
 248
 249 =item B<meta>
 250
 251 This is a method which provides access to the current class's metaclass.
 252
 253 =item B<extends (@superclasses)>
 254
 255 This function will set the superclass(es) for the current class.
 256
 257 This approach is recommended instead of C<use base>, because C<use base>
 258 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 259 replace it. This is important to ensure that classes which do not have
 260 superclasses properly inherit from L<Moose::Object>.
 261
 262 =item B<with ($role)>
 263
 264 This will apply a given C<$role> to the local class. Role support is
 265 currently very experimental, see L<Moose::Role> for more details.
 266
 267 =item B<has ($name, %options)>
 268
 269 This will install an attribute of a given C<$name> into the current class.
 270 The list of C<%options> are the same as those provided by both
 271 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 272 few convience ones provided by Moose which are listed below:
 273
 274 =over 4
 275
 276 =item I<is =E<gt> 'rw'|'ro'>
 277
 278 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 279 only). These will create either a read/write accessor or a read-only
 280 accessor respectively, using the same name as the C<$name> of the attribute.
 281
 282 If you need more control over how your accessors are named, you can use the
 283 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 284
 285 =item I<isa =E<gt> $type_name>
 286
 287 The I<isa> option uses Moose's type constraint facilities to set up runtime
 288 type checking for this attribute. Moose will perform the checks during class
 289 construction, and within any accessors. The C<$type_name> argument must be a
 290 string. The string can be either a class name, or a type defined using
 291 Moose's type defintion features.
 292
 293 =back
 294
 295 =item B<before $name|@names =E<gt> sub { ... }>
 296
 297 =item B<after $name|@names =E<gt> sub { ... }>
 298
 299 =item B<around $name|@names =E<gt> sub { ... }>
 300
 301 This three items are syntactic sugar for the before, after and around method
 302 modifier features that L<Class::MOP> provides. More information on these can
 303 be found in the L<Class::MOP> documentation for now.
 304
 305 =item B<super>
 306
 307 The keyword C<super> is a noop when called outside of an C<override> method. In
 308 the context of an C<override> method, it will call the next most appropriate
 309 superclass method with the same arguments as the original method.
 310
 311 =item B<override ($name, &sub)>
 312
 313 An C<override> method, is a way of explictly saying "I am overriding this
 314 method from my superclass". You can call C<super> within this method, and
 315 it will work as expected. The same thing I<can> be accomplished with a normal
 316 method call and the C<SUPER::> pseudo-package, it is really your choice.
 317
 318 =item B<inner>
 319
 320 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 321 an C<augment> method. You can think of C<inner> as being the inverse of
 322 C<super>, the details of how C<inner> and C<augment> work is best described in
 323 the L<Moose::Cookbook>.
 324
 325 =item B<augment ($name, &sub)>
 326
 327 An C<augment> method, is a way of explictly saying "I am augmenting this
 328 method from my superclass". Once again, the details of how C<inner> and
 329 C<augment> work is best described in the L<Moose::Cookbook>.
 330
 331 =item B<confess>
 332
 333 This is the C<Carp::confess> function, and exported here beause I use it
 334 all the time. This feature may change in the future, so you have been warned.
 335
 336 =item B<blessed>
 337
 338 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 339 use it all the time. It is highly recommended that this is used instead of
 340 C<ref> anywhere you need to test for an object's class name.
 341
 342 =back
 343
 344 =head1 CAVEATS
 345
 346 =over 4
 347
 348 =item *
 349
 350 It should be noted that C<super> and C<inner> can B<not> be used in the same
 351 method. However, they can be combined together with the same class hierarchy,
 352 see F<t/014_override_augment_inner_super.t> for an example.
 353
 354 The reason that this is so is because C<super> is only valid within a method
 355 with the C<override> modifier, and C<inner> will never be valid within an
 356 C<override> method. In fact, C<augment> will skip over any C<override> methods
 357 when searching for it's appropriate C<inner>.
 358
 359 This might seem like a restriction, but I am of the opinion that keeping these
 360 two features seperate (but interoperable) actually makes them easy to use since
 361 their behavior is then easier to predict. Time will tell if I am right or not.
 362
 363 =back
 364
 365 =head1 ACKNOWLEDGEMENTS
 366
 367 =over 4
 368
 369 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 370
 371 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 372
 373 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 374 and it certainly wouldn't have this name ;P
 375
 376 =item The basis of the TypeContraints module was Rob Kinyon's idea
 377 originally, I just ran with it.
 378
 379 =item Thanks to mst & chansen and the whole #moose poose for all the
 380 ideas/feature-requests/encouragement
 381
 382 =back
 383
 384 =head1 SEE ALSO
 385
 386 =over 4
 387
 388 =item L<Class::MOP> documentation
 389
 390 =item The #moose channel on irc.perl.org
 391
 392 =item L<http://forum2.org/moose/>
 393
 394 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 395
 396 This paper (suggested by lbr on #moose) was what lead to the implementation
 397 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 398 want to understand this feature, I suggest you read this.
 399
 400 =back
 401
 402 =head1 BUGS
 403
 404 All complex software has bugs lurking in it, and this module is no
 405 exception. If you find a bug please either email me, or add the bug
 406 to cpan-RT.
 407
 408 =head1 AUTHOR
 409
 410 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 411
 412 =head1 COPYRIGHT AND LICENSE
 413
 414 Copyright 2006 by Infinity Interactive, Inc.
 415
 416 L<http://www.iinteractive.com>
 417
 418 This library is free software; you can redistribute it and/or modify
 419 it under the same terms as Perl itself.
 420
 421 =cut