lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.05';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22
  23 use Moose::Object;
  24 use Moose::Util::TypeConstraints;
  25
  26 {
  27     my ( $CALLER, %METAS );
  28
  29     sub _find_meta {
  30         my $class = $CALLER;
  31
  32         return $METAS{$class} if exists $METAS{$class};
  33
  34         # make a subtype for each Moose class
  35         subtype $class
  36             => as 'Object'
  37             => where { $_->isa($class) }
  38         unless find_type_constraint($class);
  39
  40         my $meta;
  41         if ($class->can('meta')) {
  42             $meta = $class->meta();
  43             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  44                 || confess "Whoops, not møøsey enough";
  45         }
  46         else {
  47             $meta = Moose::Meta::Class->initialize($class => (
  48                 ':attribute_metaclass' => 'Moose::Meta::Attribute'
  49             ));
  50             $meta->add_method('meta' => sub {
  51                 # re-initialize so it inherits properly
  52                 Moose::Meta::Class->initialize($class => (
  53                     ':attribute_metaclass' => 'Moose::Meta::Attribute'
  54                 ));
  55             })
  56         }
  57
  58         # make sure they inherit from Moose::Object
  59         $meta->superclasses('Moose::Object')
  60            unless $meta->superclasses();
  61
  62         return $METAS{$class} = $meta;
  63     }
  64
  65     my %exports = (
  66         extends => sub {
  67             my $meta = _find_meta();
  68             return subname 'Moose::extends' => sub {
  69                 _load_all_classes(@_);
  70                 $meta->superclasses(@_)
  71             };
  72         },
  73         with => sub {
  74             my $meta = _find_meta();
  75             return subname 'Moose::with' => sub {
  76                 my ($role) = @_;
  77                 _load_all_classes($role);
  78                 $role->meta->apply($meta);
  79             };
  80         },
  81         has => sub {
  82             my $meta = _find_meta();
  83             return subname 'Moose::has' => sub {
  84                 my ($name, %options) = @_;
  85                 if ($options{metaclass}) {
  86                     $meta->add_attribute($options{metaclass}->new($name, %options));
  87                 }
  88                 else {
  89                     $meta->add_attribute($name, %options);
  90                 }
  91             };
  92         },
  93         before => sub {
  94             my $meta = _find_meta();
  95             return subname 'Moose::before' => sub {
  96                 my $code = pop @_;
  97                 $meta->add_before_method_modifier($_, $code) for @_;
  98             };
  99         },
 100         after => sub {
 101             my $meta = _find_meta();
 102             return subname 'Moose::after' => sub {
 103                 my $code = pop @_;
 104                 $meta->add_after_method_modifier($_, $code) for @_;
 105             };
 106         },
 107         around => sub {
 108             my $meta = _find_meta();
 109             return subname 'Moose::around' => sub {
 110                 my $code = pop @_;
 111                 $meta->add_around_method_modifier($_, $code) for @_;
 112             };
 113         },
 114         super => sub {
 115             my $meta = _find_meta();
 116             return subname 'Moose::super' => sub {};
 117         },
 118         override => sub {
 119             my $meta = _find_meta();
 120             return subname 'Moose::override' => sub {
 121                 my ($name, $method) = @_;
 122                 $meta->add_override_method_modifier($name => $method);
 123             };
 124         },
 125         inner => sub {
 126             my $meta = _find_meta();
 127             return subname 'Moose::inner' => sub {};
 128         },
 129         augment => sub {
 130             my $meta = _find_meta();
 131             return subname 'Moose::augment' => sub {
 132                 my ($name, $method) = @_;
 133                 $meta->add_augment_method_modifier($name => $method);
 134             };
 135         },
 136         confess => sub {
 137             return \&Carp::confess;
 138         },
 139         blessed => sub {
 140             return \&Scalar::Util::blessed;
 141         }
 142     );
 143
 144     my $exporter = Sub::Exporter::build_exporter({
 145         exports => \%exports,
 146         groups  => {
 147             default => [':all']
 148         }
 149     });
 150
 151     sub import {
 152         $CALLER = caller();
 153
 154         # we should never export to main
 155         return if $CALLER eq 'main';
 156
 157         goto $exporter;
 158     };
 159 }
 160
 161 ## Utility functions
 162
 163 sub _load_all_classes {
 164     foreach my $super (@_) {
 165         # see if this is already
 166         # loaded in the symbol table
 167         next if _is_class_already_loaded($super);
 168         # otherwise require it ...
 169         ($super->require)
 170             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 171     }
 172 }
 173
 174 sub _is_class_already_loaded {
 175         my $name = shift;
 176         no strict 'refs';
 177         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 178         foreach (keys %{"${name}::"}) {
 179                 next if substr($_, -2, 2) eq '::';
 180                 return 1 if defined &{"${name}::$_"};
 181         }
 182     return 0;
 183 }
 184
 185 1;
 186
 187 __END__
 188
 189 =pod
 190
 191 =head1 NAME
 192
 193 Moose - Moose, it's the new Camel
 194
 195 =head1 SYNOPSIS
 196
 197   package Point;
 198   use Moose;
 199
 200   has 'x' => (isa => 'Int', is => 'rw');
 201   has 'y' => (isa => 'Int', is => 'rw');
 202
 203   sub clear {
 204       my $self = shift;
 205       $self->x(0);
 206       $self->y(0);
 207   }
 208
 209   package Point3D;
 210   use Moose;
 211
 212   extends 'Point';
 213
 214   has 'z' => (isa => 'Int');
 215
 216   after 'clear' => sub {
 217       my $self = shift;
 218       $self->{z} = 0;
 219   };
 220
 221 =head1 CAVEAT
 222
 223 This is an early release of this module, it still needs
 224 some fine tuning and B<lots> more documentation. I am adopting
 225 the I<release early and release often> approach with this module,
 226 so keep an eye on your favorite CPAN mirror!
 227
 228 =head1 DESCRIPTION
 229
 230 Moose is an extension of the Perl 5 object system.
 231
 232 =head2 Another object system!?!?
 233
 234 Yes, I know there has been an explosion recently of new ways to
 235 build object's in Perl 5, most of them based on inside-out objects,
 236 and other such things. Moose is different because it is not a new
 237 object system for Perl 5, but instead an extension of the existing
 238 object system.
 239
 240 Moose is built on top of L<Class::MOP>, which is a metaclass system
 241 for Perl 5. This means that Moose not only makes building normal
 242 Perl 5 objects better, but it also provides the power of metaclass
 243 programming.
 244
 245 =head2 What does Moose stand for??
 246
 247 Moose doesn't stand for one thing in particular, however, if you
 248 want, here are a few of my favorites, feel free to contribute
 249 more :)
 250
 251 =over 4
 252
 253 =item Make Other Object Systems Envious
 254
 255 =item Makes Object Orientation So Easy
 256
 257 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 258
 259 =item Most Other Object Systems Emasculate
 260
 261 =item My Overcraft Overfilled (with) Some Eels
 262
 263 =item Moose Often Ovulate Sorta Early
 264
 265 =item Many Overloaded Object Systems Exists
 266
 267 =item Moose Offers Often Super Extensions
 268
 269 =item Meta Object Orientation Syntax Extensions
 270
 271 =back
 272
 273 =head1 BUILDING CLASSES WITH MOOSE
 274
 275 Moose makes every attempt to provide as much convience during class
 276 construction/definition, but still stay out of your way if you want
 277 it to. Here are some of the features Moose provides:
 278
 279 Unless specified with C<extends>, any class which uses Moose will
 280 inherit from L<Moose::Object>.
 281
 282 Moose will also manage all attributes (including inherited ones) that
 283 are defined with C<has>. And assuming that you call C<new> which is
 284 inherited from L<Moose::Object>, then this includes properly initializing
 285 all instance slots, setting defaults where approprtiate and performing any
 286 type constraint checking or coercion.
 287
 288 For more details, see the ever expanding L<Moose::Cookbook>.
 289
 290 =head1 EXPORTED FUNCTIONS
 291
 292 Moose will export a number of functions into the class's namespace, which
 293 can then be used to set up the class. These functions all work directly
 294 on the current class.
 295
 296 =over 4
 297
 298 =item B<meta>
 299
 300 This is a method which provides access to the current class's metaclass.
 301
 302 =item B<extends (@superclasses)>
 303
 304 This function will set the superclass(es) for the current class.
 305
 306 This approach is recommended instead of C<use base>, because C<use base>
 307 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 308 replace it. This is important to ensure that classes which do not have
 309 superclasses properly inherit from L<Moose::Object>.
 310
 311 =item B<with ($role)>
 312
 313 This will apply a given C<$role> to the local class. Role support is
 314 currently very experimental, see L<Moose::Role> for more details.
 315
 316 =item B<has ($name, %options)>
 317
 318 This will install an attribute of a given C<$name> into the current class.
 319 The list of C<%options> are the same as those provided by both
 320 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 321 few convience ones provided by Moose which are listed below:
 322
 323 =over 4
 324
 325 =item I<is =E<gt> 'rw'|'ro'>
 326
 327 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 328 only). These will create either a read/write accessor or a read-only
 329 accessor respectively, using the same name as the C<$name> of the attribute.
 330
 331 If you need more control over how your accessors are named, you can use the
 332 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 333
 334 =item I<isa =E<gt> $type_name>
 335
 336 The I<isa> option uses Moose's type constraint facilities to set up runtime
 337 type checking for this attribute. Moose will perform the checks during class
 338 construction, and within any accessors. The C<$type_name> argument must be a
 339 string. The string can be either a class name, or a type defined using
 340 Moose's type defintion features.
 341
 342 =back
 343
 344 =item B<before $name|@names =E<gt> sub { ... }>
 345
 346 =item B<after $name|@names =E<gt> sub { ... }>
 347
 348 =item B<around $name|@names =E<gt> sub { ... }>
 349
 350 This three items are syntactic sugar for the before, after and around method
 351 modifier features that L<Class::MOP> provides. More information on these can
 352 be found in the L<Class::MOP> documentation for now.
 353
 354 =item B<super>
 355
 356 The keyword C<super> is a noop when called outside of an C<override> method. In
 357 the context of an C<override> method, it will call the next most appropriate
 358 superclass method with the same arguments as the original method.
 359
 360 =item B<override ($name, &sub)>
 361
 362 An C<override> method, is a way of explictly saying "I am overriding this
 363 method from my superclass". You can call C<super> within this method, and
 364 it will work as expected. The same thing I<can> be accomplished with a normal
 365 method call and the C<SUPER::> pseudo-package, it is really your choice.
 366
 367 =item B<inner>
 368
 369 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 370 an C<augment> method. You can think of C<inner> as being the inverse of
 371 C<super>, the details of how C<inner> and C<augment> work is best described in
 372 the L<Moose::Cookbook>.
 373
 374 =item B<augment ($name, &sub)>
 375
 376 An C<augment> method, is a way of explictly saying "I am augmenting this
 377 method from my superclass". Once again, the details of how C<inner> and
 378 C<augment> work is best described in the L<Moose::Cookbook>.
 379
 380 =item B<confess>
 381
 382 This is the C<Carp::confess> function, and exported here beause I use it
 383 all the time. This feature may change in the future, so you have been warned.
 384
 385 =item B<blessed>
 386
 387 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 388 use it all the time. It is highly recommended that this is used instead of
 389 C<ref> anywhere you need to test for an object's class name.
 390
 391 =back
 392
 393 =head1 CAVEATS
 394
 395 =over 4
 396
 397 =item *
 398
 399 It should be noted that C<super> and C<inner> can B<not> be used in the same
 400 method. However, they can be combined together with the same class hierarchy,
 401 see F<t/014_override_augment_inner_super.t> for an example.
 402
 403 The reason that this is so is because C<super> is only valid within a method
 404 with the C<override> modifier, and C<inner> will never be valid within an
 405 C<override> method. In fact, C<augment> will skip over any C<override> methods
 406 when searching for it's appropriate C<inner>.
 407
 408 This might seem like a restriction, but I am of the opinion that keeping these
 409 two features seperate (but interoperable) actually makes them easy to use since
 410 their behavior is then easier to predict. Time will tell if I am right or not.
 411
 412 =back
 413
 414 =head1 ACKNOWLEDGEMENTS
 415
 416 =over 4
 417
 418 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 419
 420 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 421
 422 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 423 and it certainly wouldn't have this name ;P
 424
 425 =item The basis of the TypeContraints module was Rob Kinyon's idea
 426 originally, I just ran with it.
 427
 428 =item Thanks to mst & chansen and the whole #moose poose for all the
 429 ideas/feature-requests/encouragement
 430
 431 =back
 432
 433 =head1 SEE ALSO
 434
 435 =over 4
 436
 437 =item L<Class::MOP> documentation
 438
 439 =item The #moose channel on irc.perl.org
 440
 441 =item L<http://forum2.org/moose/>
 442
 443 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 444
 445 This paper (suggested by lbr on #moose) was what lead to the implementation
 446 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 447 want to understand this feature, I suggest you read this.
 448
 449 =back
 450
 451 =head1 BUGS
 452
 453 All complex software has bugs lurking in it, and this module is no
 454 exception. If you find a bug please either email me, or add the bug
 455 to cpan-RT.
 456
 457 =head1 AUTHOR
 458
 459 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 460
 461 =head1 COPYRIGHT AND LICENSE
 462
 463 Copyright 2006 by Infinity Interactive, Inc.
 464
 465 L<http://www.iinteractive.com>
 466
 467 This library is free software; you can redistribute it and/or modify
 468 it under the same terms as Perl itself.
 469
 470 =cut