lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.13';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12 use B            'svref_2object';
  13
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22 use Moose::Meta::Instance;
  23
  24 use Moose::Object;
  25 use Moose::Util::TypeConstraints;
  26
  27 {
  28     my $CALLER;
  29
  30     sub _init_meta {
  31         my $class = $CALLER;
  32
  33         # make a subtype for each Moose class
  34         subtype $class
  35             => as 'Object'
  36             => where { $_->isa($class) }
  37         unless find_type_constraint($class);
  38
  39         my $meta;
  40         if ($class->can('meta')) {
  41             # NOTE:
  42             # this is the case where the metaclass pragma
  43             # was used before the 'use Moose' statement to
  44             # override a specific class
  45             $meta = $class->meta();
  46             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  47                 || confess "You already have a &meta function, but it does not return a Moose::Meta::Class";
  48         }
  49         else {
  50             # NOTE:
  51             # this is broken currently, we actually need
  52             # to allow the possiblity of an inherited
  53             # meta, which will not be visible until the
  54             # user 'extends' first. This needs to have
  55             # more intelligence to it
  56             $meta = Moose::Meta::Class->initialize($class);
  57             $meta->add_method('meta' => sub {
  58                 # re-initialize so it inherits properly
  59                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  60             })
  61         }
  62
  63         # make sure they inherit from Moose::Object
  64         $meta->superclasses('Moose::Object')
  65            unless $meta->superclasses();
  66     }
  67
  68     my %exports = (
  69         extends => sub {
  70             my $class = $CALLER;
  71             return subname 'Moose::extends' => sub (@) {
  72                 confess "Must derive at least one class" unless @_;
  73                 _load_all_classes(@_);
  74                 # this checks the metaclass to make sure
  75                 # it is correct, sometimes it can get out
  76                 # of sync when the classes are being built
  77                 my $meta = $class->meta->_fix_metaclass_incompatability(@_);
  78                 $meta->superclasses(@_);
  79             };
  80         },
  81         with => sub {
  82             my $class = $CALLER;
  83             return subname 'Moose::with' => sub (@) {
  84                 my (@roles) = @_;
  85                 confess "Must specify at least one role" unless @roles;
  86                 _load_all_classes(@roles);
  87                 $class->meta->_apply_all_roles(@roles);
  88             };
  89         },
  90         has => sub {
  91             my $class = $CALLER;
  92             return subname 'Moose::has' => sub ($;%) {
  93                 my ($name, %options) = @_;
  94                 $class->meta->_process_attribute($name, %options);
  95             };
  96         },
  97         before => sub {
  98             my $class = $CALLER;
  99             return subname 'Moose::before' => sub (@&) {
 100                 my $code = pop @_;
 101                 my $meta = $class->meta;
 102                 $meta->add_before_method_modifier($_, $code) for @_;
 103             };
 104         },
 105         after => sub {
 106             my $class = $CALLER;
 107             return subname 'Moose::after' => sub (@&) {
 108                 my $code = pop @_;
 109                 my $meta = $class->meta;
 110                 $meta->add_after_method_modifier($_, $code) for @_;
 111             };
 112         },
 113         around => sub {
 114             my $class = $CALLER;
 115             return subname 'Moose::around' => sub (@&) {
 116                 my $code = pop @_;
 117                 my $meta = $class->meta;
 118                 $meta->add_around_method_modifier($_, $code) for @_;
 119             };
 120         },
 121         super => sub {
 122             return subname 'Moose::super' => sub {};
 123         },
 124         override => sub {
 125             my $class = $CALLER;
 126             return subname 'Moose::override' => sub ($&) {
 127                 my ($name, $method) = @_;
 128                 $class->meta->add_override_method_modifier($name => $method);
 129             };
 130         },
 131         inner => sub {
 132             return subname 'Moose::inner' => sub {};
 133         },
 134         augment => sub {
 135             my $class = $CALLER;
 136             return subname 'Moose::augment' => sub (@&) {
 137                 my ($name, $method) = @_;
 138                 $class->meta->add_augment_method_modifier($name => $method);
 139             };
 140         },
 141
 142         # NOTE:
 143         # this is experimental for now ...
 144         self => sub {
 145             return subname 'Moose::self' => sub {};
 146         },
 147         method => sub {
 148             my $class = $CALLER;
 149             return subname 'Moose::method' => sub {
 150                 my ($name, $method) = @_;
 151                 $class->meta->add_method($name, sub {
 152                     my $self = shift;
 153                     no strict   'refs';
 154                     no warnings 'redefine';
 155                     local *{$class->meta->name . '::self'} = sub { $self };
 156                     $method->(@_);
 157                 });
 158             };
 159         },
 160
 161         confess => sub {
 162             return \&Carp::confess;
 163         },
 164         blessed => sub {
 165             return \&Scalar::Util::blessed;
 166         },
 167     );
 168
 169     my $exporter = Sub::Exporter::build_exporter({
 170         exports => \%exports,
 171         groups  => {
 172             default => [':all']
 173         }
 174     });
 175
 176     sub import {
 177         $CALLER = caller();
 178
 179         strict->import;
 180         warnings->import;
 181
 182         # we should never export to main
 183         return if $CALLER eq 'main';
 184
 185         _init_meta();
 186
 187         goto $exporter;
 188     }
 189
 190     sub unimport {
 191         no strict 'refs';
 192         my $class = caller();
 193         # loop through the exports ...
 194         foreach my $name (keys %exports) {
 195             next if $name =~ /inner|super|self/;
 196
 197             # if we find one ...
 198             if (defined &{$class . '::' . $name}) {
 199                 my $keyword = \&{$class . '::' . $name};
 200
 201                 # make sure it is from Moose
 202                 my $pkg_name = eval { svref_2object($keyword)->GV->STASH->NAME };
 203                 next if $@;
 204                 next if $pkg_name ne 'Moose';
 205
 206                 # and if it is from Moose then undef the slot
 207                 delete ${$class . '::'}{$name};
 208             }
 209         }
 210     }
 211 }
 212
 213 ## Utility functions
 214
 215 sub _load_all_classes {
 216     foreach my $super (@_) {
 217         # see if this is already
 218         # loaded in the symbol table
 219         next if _is_class_already_loaded($super);
 220         # otherwise require it ...
 221         my $file = $class . '.pm';
 222         $file =~ s{::}{/}g;
 223         eval { CORE::require($file) };
 224         confess(
 225             "Could not load module '$super' because : $@"
 226             ) if $@;
 227     }
 228 }
 229
 230 sub _is_class_already_loaded {
 231         my $name = shift;
 232         no strict 'refs';
 233         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 234         foreach (keys %{"${name}::"}) {
 235                 next if substr($_, -2, 2) eq '::';
 236                 return 1 if defined &{"${name}::$_"};
 237         }
 238         return 0;
 239 }
 240
 241 1;
 242
 243 __END__
 244
 245 =pod
 246
 247 =head1 NAME
 248
 249 Moose - A complete modern object system for Perl 5
 250
 251 =head1 SYNOPSIS
 252
 253   package Point;
 254   use strict;
 255   use warnings;
 256   use Moose;
 257
 258   has 'x' => (is => 'rw', isa => 'Int');
 259   has 'y' => (is => 'rw', isa => 'Int');
 260
 261   sub clear {
 262       my $self = shift;
 263       $self->x(0);
 264       $self->y(0);
 265   }
 266
 267   package Point3D;
 268   use strict;
 269   use warnings;
 270   use Moose;
 271
 272   extends 'Point';
 273
 274   has 'z' => (is => 'rw', isa => 'Int');
 275
 276   after 'clear' => sub {
 277       my $self = shift;
 278       $self->z(0);
 279   };
 280
 281 =head1 CAVEAT
 282
 283 Moose is a rapidly maturing module, and is already being used by
 284 a number of people. It's test suite is growing larger by the day,
 285 and the docs should soon follow.
 286
 287 This said, Moose is not yet finished, and should still be considered
 288 to be evolving. Much of the outer API is stable, but the internals
 289 are still subject to change (although not without serious thought
 290 given to it).
 291
 292 For more details, please refer to the L<FUTURE PLANS> section of
 293 this document.
 294
 295 =head1 DESCRIPTION
 296
 297 Moose is an extension of the Perl 5 object system.
 298
 299 =head2 Another object system!?!?
 300
 301 Yes, I know there has been an explosion recently of new ways to
 302 build object's in Perl 5, most of them based on inside-out objects
 303 and other such things. Moose is different because it is not a new
 304 object system for Perl 5, but instead an extension of the existing
 305 object system.
 306
 307 Moose is built on top of L<Class::MOP>, which is a metaclass system
 308 for Perl 5. This means that Moose not only makes building normal
 309 Perl 5 objects better, but it also provides the power of metaclass
 310 programming.
 311
 312 =head2 Can I use this in production? Or is this just an experiment?
 313
 314 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 315 meta-model; however Moose is B<NOT> an experiment/prototype, it is
 316 for B<real>. I will be deploying Moose into production environments later
 317 this year, and I have every intentions of using it as my de facto class
 318 builder from now on.
 319
 320 =head2 Is Moose just Perl 6 in Perl 5?
 321
 322 No. While Moose is very much inspired by Perl 6, it is not itself Perl 6.
 323 Instead, it is an OO system for Perl 5. I built Moose because I was tired or
 324 writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 325 instead of switching to Ruby, I wrote Moose :)
 326
 327 =head1 BUILDING CLASSES WITH MOOSE
 328
 329 Moose makes every attempt to provide as much convenience as possible during
 330 class construction/definition, but still stay out of your way if you want it
 331 to. Here are a few items to note when building classes with Moose.
 332
 333 Unless specified with C<extends>, any class which uses Moose will
 334 inherit from L<Moose::Object>.
 335
 336 Moose will also manage all attributes (including inherited ones) that
 337 are defined with C<has>. And assuming that you call C<new>, which is
 338 inherited from L<Moose::Object>, then this includes properly initializing
 339 all instance slots, setting defaults where appropriate, and performing any
 340 type constraint checking or coercion.
 341
 342 =head1 EXPORTED FUNCTIONS
 343
 344 Moose will export a number of functions into the class's namespace which
 345 can then be used to set up the class. These functions all work directly
 346 on the current class.
 347
 348 =over 4
 349
 350 =item B<meta>
 351
 352 This is a method which provides access to the current class's metaclass.
 353
 354 =item B<extends (@superclasses)>
 355
 356 This function will set the superclass(es) for the current class.
 357
 358 This approach is recommended instead of C<use base>, because C<use base>
 359 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 360 replace it. This is important to ensure that classes which do not have
 361 superclasses still properly inherit from L<Moose::Object>.
 362
 363 =item B<with (@roles)>
 364
 365 This will apply a given set of C<@roles> to the local class. Role support
 366 is currently under heavy development; see L<Moose::Role> for more details.
 367
 368 =item B<has ($name, %options)>
 369
 370 This will install an attribute of a given C<$name> into the current class.
 371 The list of C<%options> are the same as those provided by
 372 L<Class::MOP::Attribute>, in addition to the list below which are provided
 373 by Moose (L<Moose::Meta::Attribute> to be more specific):
 374
 375 =over 4
 376
 377 =item I<is =E<gt> 'rw'|'ro'>
 378
 379 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 380 only). These will create either a read/write accessor or a read-only
 381 accessor respectively, using the same name as the C<$name> of the attribute.
 382
 383 If you need more control over how your accessors are named, you can use the
 384 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 385
 386 =item I<isa =E<gt> $type_name>
 387
 388 The I<isa> option uses Moose's type constraint facilities to set up runtime
 389 type checking for this attribute. Moose will perform the checks during class
 390 construction, and within any accessors. The C<$type_name> argument must be a
 391 string. The string can be either a class name or a type defined using
 392 Moose's type definition features.
 393
 394 =item I<coerce =E<gt> (1|0)>
 395
 396 This will attempt to use coercion with the supplied type constraint to change
 397 the value passed into any accessors or constructors. You B<must> have supplied
 398 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 399 for an example usage.
 400
 401 =item I<does =E<gt> $role_name>
 402
 403 This will accept the name of a role which the value stored in this attribute
 404 is expected to have consumed.
 405
 406 =item I<required =E<gt> (1|0)>
 407
 408 This marks the attribute as being required. This means a value must be supplied
 409 during class construction, and the attribute can never be set to C<undef> with
 410 an accessor.
 411
 412 =item I<weak_ref =E<gt> (1|0)>
 413
 414 This will tell the class to store the value of this attribute as a weakened
 415 reference. If an attribute is a weakened reference, it B<cannot> also be
 416 coerced.
 417
 418 =item I<lazy =E<gt> (1|0)>
 419
 420 This will tell the class to not create this slot until absolutely necessary.
 421 If an attribute is marked as lazy it B<must> have a default supplied.
 422
 423 =item I<auto_deref =E<gt> (1|0)>
 424
 425 This tells the accessor whether to automatically dereference the value returned.
 426 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 427
 428 =item I<trigger =E<gt> $code>
 429
 430 The trigger option is a CODE reference which will be called after the value of
 431 the attribute is set. The CODE ref will be passed the instance itself, the
 432 updated value and the attribute meta-object (this is for more advanced fiddling
 433 and can typically be ignored in most cases). You B<cannot> have a trigger on
 434 a read-only attribute.
 435
 436 =item I<handles =E<gt> [ @handles ]>
 437
 438 There is experimental support for attribute delegation using the C<handles>
 439 option. More docs to come later.
 440
 441 =back
 442
 443 =item B<before $name|@names =E<gt> sub { ... }>
 444
 445 =item B<after $name|@names =E<gt> sub { ... }>
 446
 447 =item B<around $name|@names =E<gt> sub { ... }>
 448
 449 This three items are syntactic sugar for the before, after, and around method
 450 modifier features that L<Class::MOP> provides. More information on these can
 451 be found in the L<Class::MOP> documentation for now.
 452
 453 =item B<super>
 454
 455 The keyword C<super> is a no-op when called outside of an C<override> method. In
 456 the context of an C<override> method, it will call the next most appropriate
 457 superclass method with the same arguments as the original method.
 458
 459 =item B<override ($name, &sub)>
 460
 461 An C<override> method is a way of explicitly saying "I am overriding this
 462 method from my superclass". You can call C<super> within this method, and
 463 it will work as expected. The same thing I<can> be accomplished with a normal
 464 method call and the C<SUPER::> pseudo-package; it is really your choice.
 465
 466 =item B<inner>
 467
 468 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 469 an C<augment> method. You can think of C<inner> as being the inverse of
 470 C<super>; the details of how C<inner> and C<augment> work is best described in
 471 the L<Moose::Cookbook>.
 472
 473 =item B<augment ($name, &sub)>
 474
 475 An C<augment> method, is a way of explicitly saying "I am augmenting this
 476 method from my superclass". Once again, the details of how C<inner> and
 477 C<augment> work is best described in the L<Moose::Cookbook>.
 478
 479 =item B<confess>
 480
 481 This is the C<Carp::confess> function, and exported here because I use it
 482 all the time. This feature may change in the future, so you have been warned.
 483
 484 =item B<blessed>
 485
 486 This is the C<Scalar::Uti::blessed> function, it is exported here because I
 487 use it all the time. It is highly recommended that this is used instead of
 488 C<ref> anywhere you need to test for an object's class name.
 489
 490 =back
 491
 492 =head1 UNEXPORTING FUNCTIONS
 493
 494 =head2 B<unimport>
 495
 496 Moose offers a way of removing the keywords it exports though the C<unimport>
 497 method. You simply have to say C<no Moose> at the bottom of your code for this
 498 to work. Here is an example:
 499
 500     package Person;
 501     use Moose;
 502
 503     has 'first_name' => (is => 'rw', isa => 'Str');
 504     has 'last_name'  => (is => 'rw', isa => 'Str');
 505
 506     sub full_name {
 507         my $self = shift;
 508         $self->first_name . ' ' . $self->last_name
 509     }
 510
 511     no Moose; # keywords are removed from the Person package
 512
 513 =head1 MISC.
 514
 515 =head2 What does Moose stand for??
 516
 517 Moose doesn't stand for one thing in particular, however, if you
 518 want, here are a few of my favorites; feel free to contribute
 519 more :)
 520
 521 =over 4
 522
 523 =item Make Other Object Systems Envious
 524
 525 =item Makes Object Orientation So Easy
 526
 527 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 528
 529 =item Most Other Object Systems Emasculate
 530
 531 =item Moose Often Ovulate Sorta Early
 532
 533 =item Moose Offers Often Super Extensions
 534
 535 =item Meta Object Orientation Syntax Extensions
 536
 537 =back
 538
 539 =head1 CAVEATS
 540
 541 =over 4
 542
 543 =item *
 544
 545 It should be noted that C<super> and C<inner> C<cannot> be used in the same
 546 method. However, they can be combined together with the same class hierarchy;
 547 see F<t/014_override_augment_inner_super.t> for an example.
 548
 549 The reason for this is that C<super> is only valid within a method
 550 with the C<override> modifier, and C<inner> will never be valid within an
 551 C<override> method. In fact, C<augment> will skip over any C<override> methods
 552 when searching for its appropriate C<inner>.
 553
 554 This might seem like a restriction, but I am of the opinion that keeping these
 555 two features separate (but interoperable) actually makes them easy to use, since
 556 their behavior is then easier to predict. Time will tell if I am right or not.
 557
 558 =back
 559
 560 =head1 ACKNOWLEDGEMENTS
 561
 562 =over 4
 563
 564 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 565
 566 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 567
 568 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 569 and it certainly wouldn't have this name ;P
 570
 571 =item The basis of the TypeContraints module was Rob Kinyon's idea
 572 originally, I just ran with it.
 573
 574 =item Thanks to mst & chansen and the whole #moose poose for all the
 575 ideas/feature-requests/encouragement
 576
 577 =item Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
 578
 579 =back
 580
 581 =head1 SEE ALSO
 582
 583 =over 4
 584
 585 =item L<Class::MOP> documentation
 586
 587 =item The #moose channel on irc.perl.org
 588
 589 =item The Moose mailing list - moose@perl.org
 590
 591 =item L<http://forum2.org/moose/>
 592
 593 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 594
 595 This paper (suggested by lbr on #moose) was what lead to the implementation
 596 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 597 want to understand this feature, I suggest you read this.
 598
 599 =back
 600
 601 =head1 BUGS
 602
 603 All complex software has bugs lurking in it, and this module is no
 604 exception. If you find a bug please either email me, or add the bug
 605 to cpan-RT.
 606
 607 =head1 AUTHOR
 608
 609 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 610
 611 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 612
 613 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 614
 615 =head1 COPYRIGHT AND LICENSE
 616
 617 Copyright 2006 by Infinity Interactive, Inc.
 618
 619 L<http://www.iinteractive.com>
 620
 621 This library is free software; you can redistribute it and/or modify
 622 it under the same terms as Perl itself.
 623
 624 =cut