lib/Moose.pm

   1
   2 use lib '/Users/stevan/Projects/Moose/Moose/Class-MOP/branches/Class-MOP-tranformations/lib';
   3
   4 package Moose;
   5
   6 use strict;
   7 use warnings;
   8
   9 our $VERSION = '0.15';
  10
  11 use Scalar::Util 'blessed', 'reftype';
  12 use Carp         'confess';
  13 use Sub::Name    'subname';
  14 use B            'svref_2object';
  15
  16 use Sub::Exporter;
  17
  18 use Class::MOP;
  19
  20 use Moose::Meta::Class;
  21 use Moose::Meta::TypeConstraint;
  22 use Moose::Meta::TypeCoercion;
  23 use Moose::Meta::Attribute;
  24 use Moose::Meta::Instance;
  25
  26 use Moose::Object;
  27 use Moose::Util::TypeConstraints;
  28
  29 {
  30     my $CALLER;
  31
  32     sub _init_meta {
  33         my $class = $CALLER;
  34
  35         # make a subtype for each Moose class
  36         subtype $class
  37             => as 'Object'
  38             => where { $_->isa($class) }
  39         unless find_type_constraint($class);
  40
  41         my $meta;
  42         if ($class->can('meta')) {
  43             # NOTE:
  44             # this is the case where the metaclass pragma
  45             # was used before the 'use Moose' statement to
  46             # override a specific class
  47             $meta = $class->meta();
  48             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  49                 || confess "You already have a &meta function, but it does not return a Moose::Meta::Class";
  50         }
  51         else {
  52             # NOTE:
  53             # this is broken currently, we actually need
  54             # to allow the possiblity of an inherited
  55             # meta, which will not be visible until the
  56             # user 'extends' first. This needs to have
  57             # more intelligence to it
  58             $meta = Moose::Meta::Class->initialize($class);
  59             $meta->add_method('meta' => sub {
  60                 # re-initialize so it inherits properly
  61                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  62             })
  63         }
  64
  65         # make sure they inherit from Moose::Object
  66         $meta->superclasses('Moose::Object')
  67            unless $meta->superclasses();
  68     }
  69
  70     my %exports = (
  71         extends => sub {
  72             my $class = $CALLER;
  73             return subname 'Moose::extends' => sub (@) {
  74                 confess "Must derive at least one class" unless @_;
  75                 _load_all_classes(@_);
  76                 # this checks the metaclass to make sure
  77                 # it is correct, sometimes it can get out
  78                 # of sync when the classes are being built
  79                 my $meta = $class->meta->_fix_metaclass_incompatability(@_);
  80                 $meta->superclasses(@_);
  81             };
  82         },
  83         with => sub {
  84             my $class = $CALLER;
  85             return subname 'Moose::with' => sub (@) {
  86                 my (@roles) = @_;
  87                 confess "Must specify at least one role" unless @roles;
  88                 _load_all_classes(@roles);
  89                 $class->meta->_apply_all_roles(@roles);
  90             };
  91         },
  92         has => sub {
  93             my $class = $CALLER;
  94             return subname 'Moose::has' => sub ($;%) {
  95                 my ($name, %options) = @_;
  96                 $class->meta->_process_attribute($name, %options);
  97             };
  98         },
  99         before => sub {
 100             my $class = $CALLER;
 101             return subname 'Moose::before' => sub (@&) {
 102                 my $code = pop @_;
 103                 my $meta = $class->meta;
 104                 $meta->add_before_method_modifier($_, $code) for @_;
 105             };
 106         },
 107         after => sub {
 108             my $class = $CALLER;
 109             return subname 'Moose::after' => sub (@&) {
 110                 my $code = pop @_;
 111                 my $meta = $class->meta;
 112                 $meta->add_after_method_modifier($_, $code) for @_;
 113             };
 114         },
 115         around => sub {
 116             my $class = $CALLER;
 117             return subname 'Moose::around' => sub (@&) {
 118                 my $code = pop @_;
 119                 my $meta = $class->meta;
 120                 $meta->add_around_method_modifier($_, $code) for @_;
 121             };
 122         },
 123         super => sub {
 124             return subname 'Moose::super' => sub {};
 125         },
 126         override => sub {
 127             my $class = $CALLER;
 128             return subname 'Moose::override' => sub ($&) {
 129                 my ($name, $method) = @_;
 130                 $class->meta->add_override_method_modifier($name => $method);
 131             };
 132         },
 133         inner => sub {
 134             return subname 'Moose::inner' => sub {};
 135         },
 136         augment => sub {
 137             my $class = $CALLER;
 138             return subname 'Moose::augment' => sub (@&) {
 139                 my ($name, $method) = @_;
 140                 $class->meta->add_augment_method_modifier($name => $method);
 141             };
 142         },
 143
 144         # NOTE:
 145         # this is experimental, but I am not
 146         # happy with it. If you want to try
 147         # it, you will have to uncomment it
 148         # yourself.
 149         # There is a really good chance that
 150         # this will be deprecated, dont get
 151         # too attached
 152         # self => sub {
 153         #     return subname 'Moose::self' => sub {};
 154         # },
 155         # method => sub {
 156         #     my $class = $CALLER;
 157         #     return subname 'Moose::method' => sub {
 158         #         my ($name, $method) = @_;
 159         #         $class->meta->add_method($name, sub {
 160         #             my $self = shift;
 161         #             no strict   'refs';
 162         #             no warnings 'redefine';
 163         #             local *{$class->meta->name . '::self'} = sub { $self };
 164         #             $method->(@_);
 165         #         });
 166         #     };
 167         # },
 168
 169         confess => sub {
 170             return \&Carp::confess;
 171         },
 172         blessed => sub {
 173             return \&Scalar::Util::blessed;
 174         },
 175     );
 176
 177     my $exporter = Sub::Exporter::build_exporter({
 178         exports => \%exports,
 179         groups  => {
 180             default => [':all']
 181         }
 182     });
 183
 184     sub import {
 185         $CALLER = caller();
 186
 187         strict->import;
 188         warnings->import;
 189
 190         # we should never export to main
 191         return if $CALLER eq 'main';
 192
 193         _init_meta();
 194
 195         goto $exporter;
 196     }
 197
 198     sub unimport {
 199         no strict 'refs';
 200         my $class = caller();
 201         # loop through the exports ...
 202         foreach my $name (keys %exports) {
 203             next if $name =~ /inner|super|self/;
 204
 205             # if we find one ...
 206             if (defined &{$class . '::' . $name}) {
 207                 my $keyword = \&{$class . '::' . $name};
 208
 209                 # make sure it is from Moose
 210                 my $pkg_name = eval { svref_2object($keyword)->GV->STASH->NAME };
 211                 next if $@;
 212                 next if $pkg_name ne 'Moose';
 213
 214                 # and if it is from Moose then undef the slot
 215                 delete ${$class . '::'}{$name};
 216             }
 217         }
 218     }
 219
 220
 221 }
 222
 223 ## Utility functions
 224
 225 sub _load_all_classes {
 226     foreach my $class (@_) {
 227         # see if this is already
 228         # loaded in the symbol table
 229         next if _is_class_already_loaded($class);
 230         # otherwise require it ...
 231         my $file = $class . '.pm';
 232         $file =~ s{::}{/}g;
 233         eval { CORE::require($file) };
 234         confess(
 235             "Could not load module '$class' because : $@"
 236             ) if $@;
 237     }
 238 }
 239
 240 sub _is_class_already_loaded {
 241         my $name = shift;
 242         no strict 'refs';
 243         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 244         foreach (keys %{"${name}::"}) {
 245                 next if substr($_, -2, 2) eq '::';
 246                 return 1 if defined &{"${name}::$_"};
 247         }
 248         return 0;
 249 }
 250
 251 1;
 252
 253 __END__
 254
 255 =pod
 256
 257 =head1 NAME
 258
 259 Moose - A complete modern object system for Perl 5
 260
 261 =head1 SYNOPSIS
 262
 263   package Point;
 264   use strict;
 265   use warnings;
 266   use Moose;
 267
 268   has 'x' => (is => 'rw', isa => 'Int');
 269   has 'y' => (is => 'rw', isa => 'Int');
 270
 271   sub clear {
 272       my $self = shift;
 273       $self->x(0);
 274       $self->y(0);
 275   }
 276
 277   package Point3D;
 278   use strict;
 279   use warnings;
 280   use Moose;
 281
 282   extends 'Point';
 283
 284   has 'z' => (is => 'rw', isa => 'Int');
 285
 286   after 'clear' => sub {
 287       my $self = shift;
 288       $self->z(0);
 289   };
 290
 291 =head1 CAVEAT
 292
 293 Moose is a rapidly maturing module, and is already being used by
 294 a number of people. It's test suite is growing larger by the day,
 295 and the docs should soon follow.
 296
 297 This said, Moose is not yet finished, and should still be considered
 298 to be evolving. Much of the outer API is stable, but the internals
 299 are still subject to change (although not without serious thought
 300 given to it).
 301
 302 =head1 DESCRIPTION
 303
 304 Moose is an extension of the Perl 5 object system.
 305
 306 =head2 Another object system!?!?
 307
 308 Yes, I know there has been an explosion recently of new ways to
 309 build object's in Perl 5, most of them based on inside-out objects
 310 and other such things. Moose is different because it is not a new
 311 object system for Perl 5, but instead an extension of the existing
 312 object system.
 313
 314 Moose is built on top of L<Class::MOP>, which is a metaclass system
 315 for Perl 5. This means that Moose not only makes building normal
 316 Perl 5 objects better, but it also provides the power of metaclass
 317 programming.
 318
 319 =head2 Can I use this in production? Or is this just an experiment?
 320
 321 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 322 meta-model; however Moose is B<NOT> an experiment/prototype, it is
 323 for B<real>. I will be deploying Moose into production environments later
 324 this year, and I have every intentions of using it as my de facto class
 325 builder from now on.
 326
 327 =head2 Is Moose just Perl 6 in Perl 5?
 328
 329 No. While Moose is very much inspired by Perl 6, it is not itself Perl 6.
 330 Instead, it is an OO system for Perl 5. I built Moose because I was tired or
 331 writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 332 instead of switching to Ruby, I wrote Moose :)
 333
 334 =head1 BUILDING CLASSES WITH MOOSE
 335
 336 Moose makes every attempt to provide as much convenience as possible during
 337 class construction/definition, but still stay out of your way if you want it
 338 to. Here are a few items to note when building classes with Moose.
 339
 340 Unless specified with C<extends>, any class which uses Moose will
 341 inherit from L<Moose::Object>.
 342
 343 Moose will also manage all attributes (including inherited ones) that
 344 are defined with C<has>. And assuming that you call C<new>, which is
 345 inherited from L<Moose::Object>, then this includes properly initializing
 346 all instance slots, setting defaults where appropriate, and performing any
 347 type constraint checking or coercion.
 348
 349 =head1 EXPORTED FUNCTIONS
 350
 351 Moose will export a number of functions into the class's namespace which
 352 can then be used to set up the class. These functions all work directly
 353 on the current class.
 354
 355 =over 4
 356
 357 =item B<meta>
 358
 359 This is a method which provides access to the current class's metaclass.
 360
 361 =item B<extends (@superclasses)>
 362
 363 This function will set the superclass(es) for the current class.
 364
 365 This approach is recommended instead of C<use base>, because C<use base>
 366 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 367 replace it. This is important to ensure that classes which do not have
 368 superclasses still properly inherit from L<Moose::Object>.
 369
 370 =item B<with (@roles)>
 371
 372 This will apply a given set of C<@roles> to the local class. Role support
 373 is currently under heavy development; see L<Moose::Role> for more details.
 374
 375 =item B<has ($name, %options)>
 376
 377 This will install an attribute of a given C<$name> into the current class.
 378 The list of C<%options> are the same as those provided by
 379 L<Class::MOP::Attribute>, in addition to the list below which are provided
 380 by Moose (L<Moose::Meta::Attribute> to be more specific):
 381
 382 =over 4
 383
 384 =item I<is =E<gt> 'rw'|'ro'>
 385
 386 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 387 only). These will create either a read/write accessor or a read-only
 388 accessor respectively, using the same name as the C<$name> of the attribute.
 389
 390 If you need more control over how your accessors are named, you can use the
 391 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 392
 393 =item I<isa =E<gt> $type_name>
 394
 395 The I<isa> option uses Moose's type constraint facilities to set up runtime
 396 type checking for this attribute. Moose will perform the checks during class
 397 construction, and within any accessors. The C<$type_name> argument must be a
 398 string. The string can be either a class name or a type defined using
 399 Moose's type definition features.
 400
 401 =item I<coerce =E<gt> (1|0)>
 402
 403 This will attempt to use coercion with the supplied type constraint to change
 404 the value passed into any accessors or constructors. You B<must> have supplied
 405 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 406 for an example usage.
 407
 408 =item I<does =E<gt> $role_name>
 409
 410 This will accept the name of a role which the value stored in this attribute
 411 is expected to have consumed.
 412
 413 =item I<required =E<gt> (1|0)>
 414
 415 This marks the attribute as being required. This means a value must be supplied
 416 during class construction, and the attribute can never be set to C<undef> with
 417 an accessor.
 418
 419 =item I<weak_ref =E<gt> (1|0)>
 420
 421 This will tell the class to store the value of this attribute as a weakened
 422 reference. If an attribute is a weakened reference, it B<cannot> also be
 423 coerced.
 424
 425 =item I<lazy =E<gt> (1|0)>
 426
 427 This will tell the class to not create this slot until absolutely necessary.
 428 If an attribute is marked as lazy it B<must> have a default supplied.
 429
 430 =item I<auto_deref =E<gt> (1|0)>
 431
 432 This tells the accessor whether to automatically dereference the value returned.
 433 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 434
 435 =item I<trigger =E<gt> $code>
 436
 437 The trigger option is a CODE reference which will be called after the value of
 438 the attribute is set. The CODE ref will be passed the instance itself, the
 439 updated value and the attribute meta-object (this is for more advanced fiddling
 440 and can typically be ignored in most cases). You B<cannot> have a trigger on
 441 a read-only attribute.
 442
 443 =item I<handles =E<gt> [ @handles ]>
 444
 445 There is experimental support for attribute delegation using the C<handles>
 446 option. More docs to come later.
 447
 448 =back
 449
 450 =item B<before $name|@names =E<gt> sub { ... }>
 451
 452 =item B<after $name|@names =E<gt> sub { ... }>
 453
 454 =item B<around $name|@names =E<gt> sub { ... }>
 455
 456 This three items are syntactic sugar for the before, after, and around method
 457 modifier features that L<Class::MOP> provides. More information on these can
 458 be found in the L<Class::MOP> documentation for now.
 459
 460 =item B<super>
 461
 462 The keyword C<super> is a no-op when called outside of an C<override> method. In
 463 the context of an C<override> method, it will call the next most appropriate
 464 superclass method with the same arguments as the original method.
 465
 466 =item B<override ($name, &sub)>
 467
 468 An C<override> method is a way of explicitly saying "I am overriding this
 469 method from my superclass". You can call C<super> within this method, and
 470 it will work as expected. The same thing I<can> be accomplished with a normal
 471 method call and the C<SUPER::> pseudo-package; it is really your choice.
 472
 473 =item B<inner>
 474
 475 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 476 an C<augment> method. You can think of C<inner> as being the inverse of
 477 C<super>; the details of how C<inner> and C<augment> work is best described in
 478 the L<Moose::Cookbook>.
 479
 480 =item B<augment ($name, &sub)>
 481
 482 An C<augment> method, is a way of explicitly saying "I am augmenting this
 483 method from my superclass". Once again, the details of how C<inner> and
 484 C<augment> work is best described in the L<Moose::Cookbook>.
 485
 486 =item B<confess>
 487
 488 This is the C<Carp::confess> function, and exported here because I use it
 489 all the time. This feature may change in the future, so you have been warned.
 490
 491 =item B<blessed>
 492
 493 This is the C<Scalar::Uti::blessed> function, it is exported here because I
 494 use it all the time. It is highly recommended that this is used instead of
 495 C<ref> anywhere you need to test for an object's class name.
 496
 497 =back
 498
 499 =head1 UNEXPORTING FUNCTIONS
 500
 501 =head2 B<unimport>
 502
 503 Moose offers a way of removing the keywords it exports though the C<unimport>
 504 method. You simply have to say C<no Moose> at the bottom of your code for this
 505 to work. Here is an example:
 506
 507     package Person;
 508     use Moose;
 509
 510     has 'first_name' => (is => 'rw', isa => 'Str');
 511     has 'last_name'  => (is => 'rw', isa => 'Str');
 512
 513     sub full_name {
 514         my $self = shift;
 515         $self->first_name . ' ' . $self->last_name
 516     }
 517
 518     no Moose; # keywords are removed from the Person package
 519
 520 =head1 MISC.
 521
 522 =head2 What does Moose stand for??
 523
 524 Moose doesn't stand for one thing in particular, however, if you
 525 want, here are a few of my favorites; feel free to contribute
 526 more :)
 527
 528 =over 4
 529
 530 =item Make Other Object Systems Envious
 531
 532 =item Makes Object Orientation So Easy
 533
 534 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 535
 536 =item Most Other Object Systems Emasculate
 537
 538 =item Moose Often Ovulate Sorta Early
 539
 540 =item Moose Offers Often Super Extensions
 541
 542 =item Meta Object Orientation Syntax Extensions
 543
 544 =back
 545
 546 =head1 CAVEATS
 547
 548 =over 4
 549
 550 =item *
 551
 552 It should be noted that C<super> and C<inner> C<cannot> be used in the same
 553 method. However, they can be combined together with the same class hierarchy;
 554 see F<t/014_override_augment_inner_super.t> for an example.
 555
 556 The reason for this is that C<super> is only valid within a method
 557 with the C<override> modifier, and C<inner> will never be valid within an
 558 C<override> method. In fact, C<augment> will skip over any C<override> methods
 559 when searching for its appropriate C<inner>.
 560
 561 This might seem like a restriction, but I am of the opinion that keeping these
 562 two features separate (but interoperable) actually makes them easy to use, since
 563 their behavior is then easier to predict. Time will tell if I am right or not.
 564
 565 =back
 566
 567 =head1 ACKNOWLEDGEMENTS
 568
 569 =over 4
 570
 571 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 572
 573 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 574
 575 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 576 and it certainly wouldn't have this name ;P
 577
 578 =item The basis of the TypeContraints module was Rob Kinyon's idea
 579 originally, I just ran with it.
 580
 581 =item Thanks to mst & chansen and the whole #moose poose for all the
 582 ideas/feature-requests/encouragement
 583
 584 =item Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
 585
 586 =back
 587
 588 =head1 SEE ALSO
 589
 590 =over 4
 591
 592 =item L<Class::MOP> documentation
 593
 594 =item The #moose channel on irc.perl.org
 595
 596 =item The Moose mailing list - moose@perl.org
 597
 598 =item L<http://forum2.org/moose/>
 599
 600 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 601
 602 This paper (suggested by lbr on #moose) was what lead to the implementation
 603 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 604 want to understand this feature, I suggest you read this.
 605
 606 =back
 607
 608 =head1 BUGS
 609
 610 All complex software has bugs lurking in it, and this module is no
 611 exception. If you find a bug please either email me, or add the bug
 612 to cpan-RT.
 613
 614 =head1 AUTHOR
 615
 616 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 617
 618 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 619
 620 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 621
 622 =head1 COPYRIGHT AND LICENSE
 623
 624 Copyright 2006 by Infinity Interactive, Inc.
 625
 626 L<http://www.iinteractive.com>
 627
 628 This library is free software; you can redistribute it and/or modify
 629 it under the same terms as Perl itself.
 630
 631 =cut