lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.09_02';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22 use Moose::Meta::Instance;
  23
  24 use Moose::Object;
  25 use Moose::Util::TypeConstraints;
  26
  27 {
  28     my $CALLER;
  29
  30     sub _init_meta {
  31         my $class = $CALLER;
  32
  33         # make a subtype for each Moose class
  34         subtype $class
  35             => as 'Object'
  36             => where { $_->isa($class) }
  37         unless find_type_constraint($class);
  38
  39         my $meta;
  40         if ($class->can('meta')) {
  41             # NOTE:
  42             # this is the case where the metaclass pragma
  43             # was used before the 'use Moose' statement to
  44             # override a specific class
  45             $meta = $class->meta();
  46             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  47                 || confess "Whoops, not møøsey enough";
  48         }
  49         else {
  50             # NOTE:
  51             # this is broken currently, we actually need
  52             # to allow the possiblity of an inherited
  53             # meta, which will not be visible until the
  54             # user 'extends' first. This needs to have
  55             # more intelligence to it
  56             $meta = Moose::Meta::Class->initialize($class);
  57             $meta->add_method('meta' => sub {
  58                 # re-initialize so it inherits properly
  59                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  60             })
  61         }
  62
  63         # make sure they inherit from Moose::Object
  64         $meta->superclasses('Moose::Object')
  65            unless $meta->superclasses();
  66     }
  67
  68     my %exports = (
  69         extends => sub {
  70             my $class = $CALLER;
  71             return subname 'Moose::extends' => sub ($;@) {
  72                 _load_all_classes(@_);
  73                 my $meta = $class->meta;
  74                 foreach my $super (@_) {
  75                     # don't bother if it does not have a meta.
  76                     next unless $super->can('meta');
  77                     # if it's meta is a vanilla Moose,
  78                     # then we can safely ignore it.
  79                     next if blessed($super->meta) eq 'Moose::Meta::Class';
  80                     # but if we have anything else,
  81                     # we need to check it out ...
  82                     unless (# see if of our metaclass is incompatible
  83                             ($meta->isa(blessed($super->meta)) &&
  84                              # and see if our instance metaclass is incompatible
  85                              $meta->instance_metaclass->isa($super->meta->instance_metaclass)) &&
  86                             # ... and if we are just a vanilla Moose
  87                             $meta->isa('Moose::Meta::Class')) {
  88                         # re-initialize the meta ...
  89                         my $super_meta = $super->meta;
  90                         # NOTE:
  91                         # We might want to consider actually
  92                         # transfering any attributes from the
  93                         # original meta into this one, but in
  94                         # general you should not have any there
  95                         # at this point anyway, so it's very
  96                         # much an obscure edge case anyway
  97                         $meta = $super_meta->reinitialize($class => (
  98                             ':attribute_metaclass' => $super_meta->attribute_metaclass,
  99                             ':method_metaclass'    => $super_meta->method_metaclass,
 100                             ':instance_metaclass'  => $super_meta->instance_metaclass,
 101                         ));
 102                     }
 103                 }
 104                 $meta->superclasses(@_);
 105             };
 106         },
 107         with => sub {
 108             my $class = $CALLER;
 109             return subname 'Moose::with' => sub ($;@) {
 110                 my (@roles) = @_;
 111                 _load_all_classes(@roles);
 112                 ($_->can('meta') && $_->meta->isa('Moose::Meta::Role'))
 113                     || confess "You can only consume roles, $_ is not a Moose role"
 114                         foreach @roles;
 115                 if (scalar @roles == 1) {
 116                     $roles[0]->meta->apply($class->meta);
 117                 }
 118                 else {
 119                     Moose::Meta::Role->combine(
 120                         map { $_->meta } @roles
 121                     )->apply($class->meta);
 122                 }
 123             };
 124         },
 125         has => sub {
 126             my $class = $CALLER;
 127             return subname 'Moose::has' => sub ($;%) {
 128                 my ($name, %options) = @_;
 129                 my $meta = $class->meta;
 130                 if ($name =~ /^\+(.*)/) {
 131                     my $inherited_attr = $meta->find_attribute_by_name($1);
 132                     (defined $inherited_attr)
 133                         || confess "Could not find an attribute by the name of '$1' to inherit from";
 134                     my $new_attr;
 135                     if ($inherited_attr->isa('Moose::Meta::Attribute')) {
 136                         $new_attr = $inherited_attr->clone_and_inherit_options(%options);
 137                     }
 138                     else {
 139                         # NOTE:
 140                         # kind of a kludge to handle Class::MOP::Attributes
 141                         $new_attr = Moose::Meta::Attribute::clone_and_inherit_options(
 142                             $inherited_attr, %options
 143                         );
 144                     }
 145                     $meta->add_attribute($new_attr);
 146                 }
 147                 else {
 148                     if ($options{metaclass}) {
 149                         _load_all_classes($options{metaclass});
 150                         $meta->add_attribute($options{metaclass}->new($name, %options));
 151                     }
 152                     else {
 153                         $meta->add_attribute($name, %options);
 154                     }
 155                 }
 156             };
 157         },
 158         before => sub {
 159             my $class = $CALLER;
 160             return subname 'Moose::before' => sub (@&) {
 161                 my $code = pop @_;
 162                 my $meta = $class->meta;
 163                 $meta->add_before_method_modifier($_, $code) for @_;
 164             };
 165         },
 166         after => sub {
 167             my $class = $CALLER;
 168             return subname 'Moose::after' => sub (@&) {
 169                 my $code = pop @_;
 170                 my $meta = $class->meta;
 171                 $meta->add_after_method_modifier($_, $code) for @_;
 172             };
 173         },
 174         around => sub {
 175             my $class = $CALLER;
 176             return subname 'Moose::around' => sub (@&) {
 177                 my $code = pop @_;
 178                 my $meta = $class->meta;
 179                 $meta->add_around_method_modifier($_, $code) for @_;
 180             };
 181         },
 182         super => sub {
 183             return subname 'Moose::super' => sub {};
 184         },
 185         override => sub {
 186             my $class = $CALLER;
 187             return subname 'Moose::override' => sub ($&) {
 188                 my ($name, $method) = @_;
 189                 $class->meta->add_override_method_modifier($name => $method);
 190             };
 191         },
 192         inner => sub {
 193             return subname 'Moose::inner' => sub {};
 194         },
 195         augment => sub {
 196             my $class = $CALLER;
 197             return subname 'Moose::augment' => sub (@&) {
 198                 my ($name, $method) = @_;
 199                 $class->meta->add_augment_method_modifier($name => $method);
 200             };
 201         },
 202         confess => sub {
 203             return \&Carp::confess;
 204         },
 205         blessed => sub {
 206             return \&Scalar::Util::blessed;
 207         }
 208     );
 209
 210     my $exporter = Sub::Exporter::build_exporter({
 211         exports => \%exports,
 212         groups  => {
 213             default => [':all']
 214         }
 215     });
 216
 217     sub import {
 218         $CALLER = caller();
 219
 220         # we should never export to main
 221         return if $CALLER eq 'main';
 222
 223         _init_meta();
 224
 225         goto $exporter;
 226     }
 227 }
 228
 229 ## Utility functions
 230
 231 sub _load_all_classes {
 232     foreach my $super (@_) {
 233         # see if this is already
 234         # loaded in the symbol table
 235         next if _is_class_already_loaded($super);
 236         # otherwise require it ...
 237         ($super->require)
 238             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 239     }
 240 }
 241
 242 sub _is_class_already_loaded {
 243         my $name = shift;
 244         no strict 'refs';
 245         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 246         foreach (keys %{"${name}::"}) {
 247                 next if substr($_, -2, 2) eq '::';
 248                 return 1 if defined &{"${name}::$_"};
 249         }
 250     return 0;
 251 }
 252
 253 1;
 254
 255 __END__
 256
 257 =pod
 258
 259 =head1 NAME
 260
 261 Moose - Moose, it's the new Camel
 262
 263 =head1 SYNOPSIS
 264
 265   package Point;
 266   use strict;
 267   use warnings;
 268   use Moose;
 269
 270   has 'x' => (is => 'rw', isa => 'Int');
 271   has 'y' => (is => 'rw', isa => 'Int');
 272
 273   sub clear {
 274       my $self = shift;
 275       $self->x(0);
 276       $self->y(0);
 277   }
 278
 279   package Point3D;
 280   use strict;
 281   use warnings;
 282   use Moose;
 283
 284   extends 'Point';
 285
 286   has 'z' => (is => 'rw', isa => 'Int');
 287
 288   after 'clear' => sub {
 289       my $self = shift;
 290       $self->z(0);
 291   };
 292
 293 =head1 CAVEAT
 294
 295 Moose is a rapidly maturing module, and is already being used by
 296 a number of people. It's test suite is growing larger by the day,
 297 and the docs should soon follow.
 298
 299 This said, Moose is not yet finished, and should still be considered
 300 to be evolving. Much of the outer API is stable, but the internals
 301 are still subject to change (although not without serious thought
 302 given to it).
 303
 304 For more details, please refer to the L<FUTURE PLANS> section of
 305 this document.
 306
 307 =head1 DESCRIPTION
 308
 309 Moose is an extension of the Perl 5 object system.
 310
 311 =head2 Another object system!?!?
 312
 313 Yes, I know there has been an explosion recently of new ways to
 314 build object's in Perl 5, most of them based on inside-out objects,
 315 and other such things. Moose is different because it is not a new
 316 object system for Perl 5, but instead an extension of the existing
 317 object system.
 318
 319 Moose is built on top of L<Class::MOP>, which is a metaclass system
 320 for Perl 5. This means that Moose not only makes building normal
 321 Perl 5 objects better, but it also provides the power of metaclass
 322 programming.
 323
 324 =head2 Can I use this in production? Or is this just an experiment?
 325
 326 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 327 meta-model, however Moose is B<NOT> an experiment/prototype, it is
 328 for B<real>. I will be deploying Moose into production environments later
 329 this year, and I have all intentions of using it as my de-facto class
 330 builderfrom now on.
 331
 332 =head2 Is Moose just Perl 6 in Perl 5?
 333
 334 No. While Moose is very much inspired by Perl 6, it is not. Instead, it
 335 is an OO system for Perl 5. I built Moose because I was tired or writing
 336 the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 337 instead of switching to Ruby, I wrote Moose :)
 338
 339 =head1 BUILDING CLASSES WITH MOOSE
 340
 341 Moose makes every attempt to provide as much convience during class
 342 construction/definition, but still stay out of your way if you want
 343 it to. Here are a few items to note when building classes with Moose.
 344
 345 Unless specified with C<extends>, any class which uses Moose will
 346 inherit from L<Moose::Object>.
 347
 348 Moose will also manage all attributes (including inherited ones) that
 349 are defined with C<has>. And assuming that you call C<new> which is
 350 inherited from L<Moose::Object>, then this includes properly initializing
 351 all instance slots, setting defaults where approprtiate and performing any
 352 type constraint checking or coercion.
 353
 354 =head1 EXPORTED FUNCTIONS
 355
 356 Moose will export a number of functions into the class's namespace, which
 357 can then be used to set up the class. These functions all work directly
 358 on the current class.
 359
 360 =over 4
 361
 362 =item B<meta>
 363
 364 This is a method which provides access to the current class's metaclass.
 365
 366 =item B<extends (@superclasses)>
 367
 368 This function will set the superclass(es) for the current class.
 369
 370 This approach is recommended instead of C<use base>, because C<use base>
 371 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 372 replace it. This is important to ensure that classes which do not have
 373 superclasses properly inherit from L<Moose::Object>.
 374
 375 =item B<with (@roles)>
 376
 377 This will apply a given set of C<@roles> to the local class. Role support
 378 is currently under heavy development, see L<Moose::Role> for more details.
 379
 380 =item B<has ($name, %options)>
 381
 382 This will install an attribute of a given C<$name> into the current class.
 383 The list of C<%options> are the same as those provided by
 384 L<Class::MOP::Attribute>, in addition to the list below which are provided
 385 by Moose (L<Moose::Meta::Attribute> to be more specific):
 386
 387 =over 4
 388
 389 =item I<is =E<gt> 'rw'|'ro'>
 390
 391 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 392 only). These will create either a read/write accessor or a read-only
 393 accessor respectively, using the same name as the C<$name> of the attribute.
 394
 395 If you need more control over how your accessors are named, you can use the
 396 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 397
 398 =item I<isa =E<gt> $type_name>
 399
 400 The I<isa> option uses Moose's type constraint facilities to set up runtime
 401 type checking for this attribute. Moose will perform the checks during class
 402 construction, and within any accessors. The C<$type_name> argument must be a
 403 string. The string can be either a class name, or a type defined using
 404 Moose's type defintion features.
 405
 406 =item I<coerce =E<gt> (1|0)>
 407
 408 This will attempt to use coercion with the supplied type constraint to change
 409 the value passed into any accessors of constructors. You B<must> have supplied
 410 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 411 for an example usage.
 412
 413 =item I<does =E<gt> $role_name>
 414
 415 This will accept the name of a role which the value stored in this attribute
 416 is expected to have consumed.
 417
 418 =item I<required =E<gt> (1|0)>
 419
 420 This marks the attribute as being required. This means a value must be supplied
 421 during class construction, and the attribute can never be set to C<undef> with
 422 an accessor.
 423
 424 =item I<weak_ref =E<gt> (1|0)>
 425
 426 This will tell the class to strore the value of this attribute as a weakened
 427 reference. If an attribute is a weakened reference, it can B<not> also be coerced.
 428
 429 =item I<lazy =E<gt> (1|0)>
 430
 431 This will tell the class to not create this slot until absolutely nessecary.
 432 If an attribute is marked as lazy it B<must> have a default supplied.
 433
 434 =item I<auto_deref =E<gt> (1|0)>
 435
 436 This tells the accessor whether to automatically de-reference the value returned.
 437 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 438
 439 =item I<trigger =E<gt> $code>
 440
 441 The trigger option is a CODE reference which will be called after the value of
 442 the attribute is set. The CODE ref will be passed the instance itself, the
 443 updated value and the attribute meta-object (this is for more advanced fiddling
 444 and can typically be ignored in most cases). You can B<not> have a trigger on
 445 a read-only attribute.
 446
 447 =item I<handles =E<gt> [ @handles ]>
 448
 449 There is experimental support for attribute delegation using the C<handles>
 450 option. More docs to come later.
 451
 452 =back
 453
 454 =item B<before $name|@names =E<gt> sub { ... }>
 455
 456 =item B<after $name|@names =E<gt> sub { ... }>
 457
 458 =item B<around $name|@names =E<gt> sub { ... }>
 459
 460 This three items are syntactic sugar for the before, after and around method
 461 modifier features that L<Class::MOP> provides. More information on these can
 462 be found in the L<Class::MOP> documentation for now.
 463
 464 =item B<super>
 465
 466 The keyword C<super> is a noop when called outside of an C<override> method. In
 467 the context of an C<override> method, it will call the next most appropriate
 468 superclass method with the same arguments as the original method.
 469
 470 =item B<override ($name, &sub)>
 471
 472 An C<override> method, is a way of explictly saying "I am overriding this
 473 method from my superclass". You can call C<super> within this method, and
 474 it will work as expected. The same thing I<can> be accomplished with a normal
 475 method call and the C<SUPER::> pseudo-package, it is really your choice.
 476
 477 =item B<inner>
 478
 479 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 480 an C<augment> method. You can think of C<inner> as being the inverse of
 481 C<super>, the details of how C<inner> and C<augment> work is best described in
 482 the L<Moose::Cookbook>.
 483
 484 =item B<augment ($name, &sub)>
 485
 486 An C<augment> method, is a way of explictly saying "I am augmenting this
 487 method from my superclass". Once again, the details of how C<inner> and
 488 C<augment> work is best described in the L<Moose::Cookbook>.
 489
 490 =item B<confess>
 491
 492 This is the C<Carp::confess> function, and exported here beause I use it
 493 all the time. This feature may change in the future, so you have been warned.
 494
 495 =item B<blessed>
 496
 497 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 498 use it all the time. It is highly recommended that this is used instead of
 499 C<ref> anywhere you need to test for an object's class name.
 500
 501 =back
 502
 503 =head1 FUTURE PLANS
 504
 505 Here is just a sampling of the plans we have in store for Moose:
 506
 507 =over 4
 508
 509 =item *
 510
 511 Compiling Moose classes/roles into C<.pmc> files for faster loading and execution.
 512
 513 =item *
 514
 515 Supporting sealed and finalized classes in Moose. This will allow greater control
 516 of the extensions of frameworks and such.
 517
 518 =back
 519
 520 =head1 MISC.
 521
 522 =head2 What does Moose stand for??
 523
 524 Moose doesn't stand for one thing in particular, however, if you
 525 want, here are a few of my favorites, feel free to contribute
 526 more :)
 527
 528 =over 4
 529
 530 =item Make Other Object Systems Envious
 531
 532 =item Makes Object Orientation So Easy
 533
 534 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 535
 536 =item Most Other Object Systems Emasculate
 537
 538 =item Moose Often Ovulate Sorta Early
 539
 540 =item Moose Offers Often Super Extensions
 541
 542 =item Meta Object Orientation Syntax Extensions
 543
 544 =back
 545
 546 =head1 CAVEATS
 547
 548 =over 4
 549
 550 =item *
 551
 552 It should be noted that C<super> and C<inner> can B<not> be used in the same
 553 method. However, they can be combined together with the same class hierarchy,
 554 see F<t/014_override_augment_inner_super.t> for an example.
 555
 556 The reason that this is so is because C<super> is only valid within a method
 557 with the C<override> modifier, and C<inner> will never be valid within an
 558 C<override> method. In fact, C<augment> will skip over any C<override> methods
 559 when searching for it's appropriate C<inner>.
 560
 561 This might seem like a restriction, but I am of the opinion that keeping these
 562 two features seperate (but interoperable) actually makes them easy to use since
 563 their behavior is then easier to predict. Time will tell if I am right or not.
 564
 565 =back
 566
 567 =head1 ACKNOWLEDGEMENTS
 568
 569 =over 4
 570
 571 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 572
 573 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 574
 575 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 576 and it certainly wouldn't have this name ;P
 577
 578 =item The basis of the TypeContraints module was Rob Kinyon's idea
 579 originally, I just ran with it.
 580
 581 =item Thanks to mst & chansen and the whole #moose poose for all the
 582 ideas/feature-requests/encouragement
 583
 584 =back
 585
 586 =head1 SEE ALSO
 587
 588 =over 4
 589
 590 =item L<Class::MOP> documentation
 591
 592 =item The #moose channel on irc.perl.org
 593
 594 =item L<http://forum2.org/moose/>
 595
 596 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 597
 598 This paper (suggested by lbr on #moose) was what lead to the implementation
 599 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 600 want to understand this feature, I suggest you read this.
 601
 602 =back
 603
 604 =head1 BUGS
 605
 606 All complex software has bugs lurking in it, and this module is no
 607 exception. If you find a bug please either email me, or add the bug
 608 to cpan-RT.
 609
 610 =head1 AUTHOR
 611
 612 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 613
 614 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 615
 616 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 617
 618 =head1 COPYRIGHT AND LICENSE
 619
 620 Copyright 2006 by Infinity Interactive, Inc.
 621
 622 L<http://www.iinteractive.com>
 623
 624 This library is free software; you can redistribute it and/or modify
 625 it under the same terms as Perl itself.
 626
 627 =cut