lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION   = '0.19';
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use Scalar::Util 'blessed', 'reftype';
  11 use Carp         'confess';
  12 use Sub::Name    'subname';
  13 use B            'svref_2object';
  14
  15 use Sub::Exporter;
  16
  17 use Class::MOP;
  18
  19 use Moose::Meta::Class;
  20 use Moose::Meta::TypeConstraint;
  21 use Moose::Meta::TypeCoercion;
  22 use Moose::Meta::Attribute;
  23 use Moose::Meta::Instance;
  24
  25 use Moose::Object;
  26 use Moose::Util::TypeConstraints;
  27
  28 {
  29     my $CALLER;
  30
  31     sub _init_meta {
  32         my $class = $CALLER;
  33
  34         # make a subtype for each Moose class
  35         subtype $class
  36             => as 'Object'
  37             => where { $_->isa($class) }
  38             => optimize_as { blessed($_[0]) && $_[0]->isa($class) }
  39         unless find_type_constraint($class);
  40
  41         my $meta;
  42         if ($class->can('meta')) {
  43             # NOTE:
  44             # this is the case where the metaclass pragma
  45             # was used before the 'use Moose' statement to
  46             # override a specific class
  47             $meta = $class->meta();
  48             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  49                 || confess "You already have a &meta function, but it does not return a Moose::Meta::Class";
  50         }
  51         else {
  52             # NOTE:
  53             # this is broken currently, we actually need
  54             # to allow the possiblity of an inherited
  55             # meta, which will not be visible until the
  56             # user 'extends' first. This needs to have
  57             # more intelligence to it
  58             $meta = Moose::Meta::Class->initialize($class);
  59             $meta->add_method('meta' => sub {
  60                 # re-initialize so it inherits properly
  61                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  62             })
  63         }
  64
  65         # make sure they inherit from Moose::Object
  66         $meta->superclasses('Moose::Object')
  67            unless $meta->superclasses();
  68     }
  69
  70     my %exports = (
  71         extends => sub {
  72             my $class = $CALLER;
  73             return subname 'Moose::extends' => sub (@) {
  74                 confess "Must derive at least one class" unless @_;
  75                 Class::MOP::load_class($_) for @_;
  76                 # this checks the metaclass to make sure
  77                 # it is correct, sometimes it can get out
  78                 # of sync when the classes are being built
  79                 my $meta = $class->meta->_fix_metaclass_incompatability(@_);
  80                 $meta->superclasses(@_);
  81             };
  82         },
  83         with => sub {
  84             my $class = $CALLER;
  85             return subname 'Moose::with' => sub (@) {
  86                 my (@roles) = @_;
  87                 confess "Must specify at least one role" unless @roles;
  88                 Class::MOP::load_class($_) for @roles;
  89                 $class->meta->_apply_all_roles(@roles);
  90             };
  91         },
  92         has => sub {
  93             my $class = $CALLER;
  94             return subname 'Moose::has' => sub ($;%) {
  95                 my ($name, %options) = @_;
  96                 $class->meta->_process_attribute($name, %options);
  97             };
  98         },
  99         before => sub {
 100             my $class = $CALLER;
 101             return subname 'Moose::before' => sub (@&) {
 102                 my $code = pop @_;
 103                 my $meta = $class->meta;
 104                 $meta->add_before_method_modifier($_, $code) for @_;
 105             };
 106         },
 107         after => sub {
 108             my $class = $CALLER;
 109             return subname 'Moose::after' => sub (@&) {
 110                 my $code = pop @_;
 111                 my $meta = $class->meta;
 112                 $meta->add_after_method_modifier($_, $code) for @_;
 113             };
 114         },
 115         around => sub {
 116             my $class = $CALLER;
 117             return subname 'Moose::around' => sub (@&) {
 118                 my $code = pop @_;
 119                 my $meta = $class->meta;
 120                 $meta->add_around_method_modifier($_, $code) for @_;
 121             };
 122         },
 123         super => sub {
 124             return subname 'Moose::super' => sub {};
 125         },
 126         override => sub {
 127             my $class = $CALLER;
 128             return subname 'Moose::override' => sub ($&) {
 129                 my ($name, $method) = @_;
 130                 $class->meta->add_override_method_modifier($name => $method);
 131             };
 132         },
 133         inner => sub {
 134             return subname 'Moose::inner' => sub {};
 135         },
 136         augment => sub {
 137             my $class = $CALLER;
 138             return subname 'Moose::augment' => sub (@&) {
 139                 my ($name, $method) = @_;
 140                 $class->meta->add_augment_method_modifier($name => $method);
 141             };
 142         },
 143
 144         # NOTE:
 145         # this is experimental, but I am not
 146         # happy with it. If you want to try
 147         # it, you will have to uncomment it
 148         # yourself.
 149         # There is a really good chance that
 150         # this will be deprecated, dont get
 151         # too attached
 152         # self => sub {
 153         #     return subname 'Moose::self' => sub {};
 154         # },
 155         # method => sub {
 156         #     my $class = $CALLER;
 157         #     return subname 'Moose::method' => sub {
 158         #         my ($name, $method) = @_;
 159         #         $class->meta->add_method($name, sub {
 160         #             my $self = shift;
 161         #             no strict   'refs';
 162         #             no warnings 'redefine';
 163         #             local *{$class->meta->name . '::self'} = sub { $self };
 164         #             $method->(@_);
 165         #         });
 166         #     };
 167         # },
 168
 169         confess => sub {
 170             return \&Carp::confess;
 171         },
 172         blessed => sub {
 173             return \&Scalar::Util::blessed;
 174         },
 175     );
 176
 177     my $exporter = Sub::Exporter::build_exporter({
 178         exports => \%exports,
 179         groups  => {
 180             default => [':all']
 181         }
 182     });
 183
 184     sub import {
 185         $CALLER = caller();
 186
 187         strict->import;
 188         warnings->import;
 189
 190         # we should never export to main
 191         return if $CALLER eq 'main';
 192
 193         _init_meta();
 194
 195         goto $exporter;
 196     }
 197
 198     sub unimport {
 199         no strict 'refs';
 200         my $class = caller();
 201         # loop through the exports ...
 202         foreach my $name (keys %exports) {
 203             next if $name =~ /inner|super|self/;
 204
 205             # if we find one ...
 206             if (defined &{$class . '::' . $name}) {
 207                 my $keyword = \&{$class . '::' . $name};
 208
 209                 # make sure it is from Moose
 210                 my $pkg_name = eval { svref_2object($keyword)->GV->STASH->NAME };
 211                 next if $@;
 212                 next if $pkg_name ne 'Moose';
 213
 214                 # and if it is from Moose then undef the slot
 215                 delete ${$class . '::'}{$name};
 216             }
 217         }
 218     }
 219
 220
 221 }
 222
 223 ## make 'em all immutable
 224
 225 $_->meta->make_immutable(
 226     inline_constructor => 0,
 227     inline_accessors   => 0,
 228 ) for (
 229     'Moose::Meta::Attribute',
 230     'Moose::Meta::Class',
 231     'Moose::Meta::Instance',
 232
 233     'Moose::Meta::TypeConstraint',
 234     'Moose::Meta::TypeConstraint::Union',
 235     'Moose::Meta::TypeCoercion',
 236
 237     'Moose::Meta::Method',
 238     'Moose::Meta::Method::Accessor',
 239     'Moose::Meta::Method::Constructor',
 240     'Moose::Meta::Method::Overriden',
 241 );
 242
 243 1;
 244
 245 __END__
 246
 247 =pod
 248
 249 =head1 NAME
 250
 251 Moose - A complete modern object system for Perl 5
 252
 253 =head1 SYNOPSIS
 254
 255   package Point;
 256   use strict;
 257   use warnings;
 258   use Moose;
 259
 260   has 'x' => (is => 'rw', isa => 'Int');
 261   has 'y' => (is => 'rw', isa => 'Int');
 262
 263   sub clear {
 264       my $self = shift;
 265       $self->x(0);
 266       $self->y(0);
 267   }
 268
 269   package Point3D;
 270   use strict;
 271   use warnings;
 272   use Moose;
 273
 274   extends 'Point';
 275
 276   has 'z' => (is => 'rw', isa => 'Int');
 277
 278   after 'clear' => sub {
 279       my $self = shift;
 280       $self->z(0);
 281   };
 282
 283 =head1 DESCRIPTION
 284
 285 Moose is an extension of the Perl 5 object system.
 286
 287 =head2 Another object system!?!?
 288
 289 Yes, I know there has been an explosion recently of new ways to
 290 build object's in Perl 5, most of them based on inside-out objects
 291 and other such things. Moose is different because it is not a new
 292 object system for Perl 5, but instead an extension of the existing
 293 object system.
 294
 295 Moose is built on top of L<Class::MOP>, which is a metaclass system
 296 for Perl 5. This means that Moose not only makes building normal
 297 Perl 5 objects better, but it also provides the power of metaclass
 298 programming.
 299
 300 =head2 Is this for real? Or is this just an experiment?
 301
 302 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 303 meta-model; however Moose is B<NOT> an experiment/prototype, it is
 304 for B<real>.
 305
 306 =head2 Is this ready for use in production?
 307
 308 Yes, I believe that it is.
 309
 310 I have two medium-to-large-ish web applications which use Moose heavily
 311 and have been in production (without issue) for several months now. At
 312 $work, we are re-writing our core offering in it. And several people on
 313 #moose have been using it (in production) for several months now as well.
 314
 315 Of course, in the end, you need to make this call yourself. If you have
 316 any questions or concerns, please feel free to email me, or even the list
 317 or just stop by #moose and ask away.
 318
 319 =head2 Is Moose just Perl 6 in Perl 5?
 320
 321 No. While Moose is very much inspired by Perl 6, it is not itself Perl 6.
 322 Instead, it is an OO system for Perl 5. I built Moose because I was tired or
 323 writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 324 instead of switching to Ruby, I wrote Moose :)
 325
 326 =head1 BUILDING CLASSES WITH MOOSE
 327
 328 Moose makes every attempt to provide as much convenience as possible during
 329 class construction/definition, but still stay out of your way if you want it
 330 to. Here are a few items to note when building classes with Moose.
 331
 332 Unless specified with C<extends>, any class which uses Moose will
 333 inherit from L<Moose::Object>.
 334
 335 Moose will also manage all attributes (including inherited ones) that
 336 are defined with C<has>. And assuming that you call C<new>, which is
 337 inherited from L<Moose::Object>, then this includes properly initializing
 338 all instance slots, setting defaults where appropriate, and performing any
 339 type constraint checking or coercion.
 340
 341 =head1 EXPORTED FUNCTIONS
 342
 343 Moose will export a number of functions into the class's namespace which
 344 can then be used to set up the class. These functions all work directly
 345 on the current class.
 346
 347 =over 4
 348
 349 =item B<meta>
 350
 351 This is a method which provides access to the current class's metaclass.
 352
 353 =item B<extends (@superclasses)>
 354
 355 This function will set the superclass(es) for the current class.
 356
 357 This approach is recommended instead of C<use base>, because C<use base>
 358 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 359 replace it. This is important to ensure that classes which do not have
 360 superclasses still properly inherit from L<Moose::Object>.
 361
 362 =item B<with (@roles)>
 363
 364 This will apply a given set of C<@roles> to the local class. Role support
 365 is currently under heavy development; see L<Moose::Role> for more details.
 366
 367 =item B<has ($name, %options)>
 368
 369 This will install an attribute of a given C<$name> into the current class.
 370 The list of C<%options> are the same as those provided by
 371 L<Class::MOP::Attribute>, in addition to the list below which are provided
 372 by Moose (L<Moose::Meta::Attribute> to be more specific):
 373
 374 =over 4
 375
 376 =item I<is =E<gt> 'rw'|'ro'>
 377
 378 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 379 only). These will create either a read/write accessor or a read-only
 380 accessor respectively, using the same name as the C<$name> of the attribute.
 381
 382 If you need more control over how your accessors are named, you can use the
 383 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 384
 385 =item I<isa =E<gt> $type_name>
 386
 387 The I<isa> option uses Moose's type constraint facilities to set up runtime
 388 type checking for this attribute. Moose will perform the checks during class
 389 construction, and within any accessors. The C<$type_name> argument must be a
 390 string. The string can be either a class name or a type defined using
 391 Moose's type definition features.
 392
 393 =item I<coerce =E<gt> (1|0)>
 394
 395 This will attempt to use coercion with the supplied type constraint to change
 396 the value passed into any accessors or constructors. You B<must> have supplied
 397 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 398 for an example usage.
 399
 400 =item I<does =E<gt> $role_name>
 401
 402 This will accept the name of a role which the value stored in this attribute
 403 is expected to have consumed.
 404
 405 =item I<required =E<gt> (1|0)>
 406
 407 This marks the attribute as being required. This means a value must be supplied
 408 during class construction, and the attribute can never be set to C<undef> with
 409 an accessor.
 410
 411 =item I<weak_ref =E<gt> (1|0)>
 412
 413 This will tell the class to store the value of this attribute as a weakened
 414 reference. If an attribute is a weakened reference, it B<cannot> also be
 415 coerced.
 416
 417 =item I<lazy =E<gt> (1|0)>
 418
 419 This will tell the class to not create this slot until absolutely necessary.
 420 If an attribute is marked as lazy it B<must> have a default supplied.
 421
 422 =item I<auto_deref =E<gt> (1|0)>
 423
 424 This tells the accessor whether to automatically dereference the value returned.
 425 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 426
 427 =item I<trigger =E<gt> $code>
 428
 429 The trigger option is a CODE reference which will be called after the value of
 430 the attribute is set. The CODE ref will be passed the instance itself, the
 431 updated value and the attribute meta-object (this is for more advanced fiddling
 432 and can typically be ignored in most cases). You B<cannot> have a trigger on
 433 a read-only attribute.
 434
 435 =item I<handles =E<gt> [ @handles ]>
 436
 437 There is experimental support for attribute delegation using the C<handles>
 438 option. More docs to come later.
 439
 440 =back
 441
 442 =item B<before $name|@names =E<gt> sub { ... }>
 443
 444 =item B<after $name|@names =E<gt> sub { ... }>
 445
 446 =item B<around $name|@names =E<gt> sub { ... }>
 447
 448 This three items are syntactic sugar for the before, after, and around method
 449 modifier features that L<Class::MOP> provides. More information on these can
 450 be found in the L<Class::MOP> documentation for now.
 451
 452 =item B<super>
 453
 454 The keyword C<super> is a no-op when called outside of an C<override> method. In
 455 the context of an C<override> method, it will call the next most appropriate
 456 superclass method with the same arguments as the original method.
 457
 458 =item B<override ($name, &sub)>
 459
 460 An C<override> method is a way of explicitly saying "I am overriding this
 461 method from my superclass". You can call C<super> within this method, and
 462 it will work as expected. The same thing I<can> be accomplished with a normal
 463 method call and the C<SUPER::> pseudo-package; it is really your choice.
 464
 465 =item B<inner>
 466
 467 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 468 an C<augment> method. You can think of C<inner> as being the inverse of
 469 C<super>; the details of how C<inner> and C<augment> work is best described in
 470 the L<Moose::Cookbook>.
 471
 472 =item B<augment ($name, &sub)>
 473
 474 An C<augment> method, is a way of explicitly saying "I am augmenting this
 475 method from my superclass". Once again, the details of how C<inner> and
 476 C<augment> work is best described in the L<Moose::Cookbook>.
 477
 478 =item B<confess>
 479
 480 This is the C<Carp::confess> function, and exported here because I use it
 481 all the time. This feature may change in the future, so you have been warned.
 482
 483 =item B<blessed>
 484
 485 This is the C<Scalar::Uti::blessed> function, it is exported here because I
 486 use it all the time. It is highly recommended that this is used instead of
 487 C<ref> anywhere you need to test for an object's class name.
 488
 489 =back
 490
 491 =head1 UNEXPORTING FUNCTIONS
 492
 493 =head2 B<unimport>
 494
 495 Moose offers a way of removing the keywords it exports though the C<unimport>
 496 method. You simply have to say C<no Moose> at the bottom of your code for this
 497 to work. Here is an example:
 498
 499     package Person;
 500     use Moose;
 501
 502     has 'first_name' => (is => 'rw', isa => 'Str');
 503     has 'last_name'  => (is => 'rw', isa => 'Str');
 504
 505     sub full_name {
 506         my $self = shift;
 507         $self->first_name . ' ' . $self->last_name
 508     }
 509
 510     no Moose; # keywords are removed from the Person package
 511
 512 =head1 MISC.
 513
 514 =head2 What does Moose stand for??
 515
 516 Moose doesn't stand for one thing in particular, however, if you
 517 want, here are a few of my favorites; feel free to contribute
 518 more :)
 519
 520 =over 4
 521
 522 =item Make Other Object Systems Envious
 523
 524 =item Makes Object Orientation So Easy
 525
 526 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 527
 528 =item Most Other Object Systems Emasculate
 529
 530 =item Moose Often Ovulate Sorta Early
 531
 532 =item Moose Offers Often Super Extensions
 533
 534 =item Meta Object Orientation Syntax Extensions
 535
 536 =back
 537
 538 =head1 CAVEATS
 539
 540 =over 4
 541
 542 =item *
 543
 544 It should be noted that C<super> and C<inner> C<cannot> be used in the same
 545 method. However, they can be combined together with the same class hierarchy;
 546 see F<t/014_override_augment_inner_super.t> for an example.
 547
 548 The reason for this is that C<super> is only valid within a method
 549 with the C<override> modifier, and C<inner> will never be valid within an
 550 C<override> method. In fact, C<augment> will skip over any C<override> methods
 551 when searching for its appropriate C<inner>.
 552
 553 This might seem like a restriction, but I am of the opinion that keeping these
 554 two features separate (but interoperable) actually makes them easy to use, since
 555 their behavior is then easier to predict. Time will tell if I am right or not.
 556
 557 =back
 558
 559 =head1 ACKNOWLEDGEMENTS
 560
 561 =over 4
 562
 563 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 564
 565 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 566
 567 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 568 and it certainly wouldn't have this name ;P
 569
 570 =item The basis of the TypeContraints module was Rob Kinyon's idea
 571 originally, I just ran with it.
 572
 573 =item Thanks to mst & chansen and the whole #moose poose for all the
 574 ideas/feature-requests/encouragement
 575
 576 =item Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
 577
 578 =back
 579
 580 =head1 SEE ALSO
 581
 582 =over 4
 583
 584 =item L<Class::MOP> documentation
 585
 586 =item The #moose channel on irc.perl.org
 587
 588 =item The Moose mailing list - moose@perl.org
 589
 590 =item L<http://forum2.org/moose/>
 591
 592 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 593
 594 This paper (suggested by lbr on #moose) was what lead to the implementation
 595 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 596 want to understand this feature, I suggest you read this.
 597
 598 =back
 599
 600 =head1 BUGS
 601
 602 All complex software has bugs lurking in it, and this module is no
 603 exception. If you find a bug please either email me, or add the bug
 604 to cpan-RT.
 605
 606 =head1 AUTHOR
 607
 608 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 609
 610 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 611
 612 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 613
 614 =head1 COPYRIGHT AND LICENSE
 615
 616 Copyright 2006, 2007 by Infinity Interactive, Inc.
 617
 618 L<http://www.iinteractive.com>
 619
 620 This library is free software; you can redistribute it and/or modify
 621 it under the same terms as Perl itself.
 622
 623 =cut