lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.18_002';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12 use B            'svref_2object';
  13
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22 use Moose::Meta::Instance;
  23
  24 use Moose::Object;
  25 use Moose::Util::TypeConstraints;
  26
  27 {
  28     my $CALLER;
  29
  30     sub _init_meta {
  31         my $class = $CALLER;
  32
  33         # make a subtype for each Moose class
  34         subtype $class
  35             => as 'Object'
  36             => where { $_->isa($class) }
  37             => optimize_as { blessed($_[0]) && $_[0]->isa($class) }
  38         unless find_type_constraint($class);
  39
  40         my $meta;
  41         if ($class->can('meta')) {
  42             # NOTE:
  43             # this is the case where the metaclass pragma
  44             # was used before the 'use Moose' statement to
  45             # override a specific class
  46             $meta = $class->meta();
  47             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  48                 || confess "You already have a &meta function, but it does not return a Moose::Meta::Class";
  49         }
  50         else {
  51             # NOTE:
  52             # this is broken currently, we actually need
  53             # to allow the possiblity of an inherited
  54             # meta, which will not be visible until the
  55             # user 'extends' first. This needs to have
  56             # more intelligence to it
  57             $meta = Moose::Meta::Class->initialize($class);
  58             $meta->add_method('meta' => sub {
  59                 # re-initialize so it inherits properly
  60                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  61             })
  62         }
  63
  64         # make sure they inherit from Moose::Object
  65         $meta->superclasses('Moose::Object')
  66            unless $meta->superclasses();
  67     }
  68
  69     my %exports = (
  70         extends => sub {
  71             my $class = $CALLER;
  72             return subname 'Moose::extends' => sub (@) {
  73                 confess "Must derive at least one class" unless @_;
  74                 _load_all_classes(@_);
  75                 # this checks the metaclass to make sure
  76                 # it is correct, sometimes it can get out
  77                 # of sync when the classes are being built
  78                 my $meta = $class->meta->_fix_metaclass_incompatability(@_);
  79                 $meta->superclasses(@_);
  80             };
  81         },
  82         with => sub {
  83             my $class = $CALLER;
  84             return subname 'Moose::with' => sub (@) {
  85                 my (@roles) = @_;
  86                 confess "Must specify at least one role" unless @roles;
  87                 _load_all_classes(@roles);
  88                 $class->meta->_apply_all_roles(@roles);
  89             };
  90         },
  91         has => sub {
  92             my $class = $CALLER;
  93             return subname 'Moose::has' => sub ($;%) {
  94                 my ($name, %options) = @_;
  95                 $class->meta->_process_attribute($name, %options);
  96             };
  97         },
  98         before => sub {
  99             my $class = $CALLER;
 100             return subname 'Moose::before' => sub (@&) {
 101                 my $code = pop @_;
 102                 my $meta = $class->meta;
 103                 $meta->add_before_method_modifier($_, $code) for @_;
 104             };
 105         },
 106         after => sub {
 107             my $class = $CALLER;
 108             return subname 'Moose::after' => sub (@&) {
 109                 my $code = pop @_;
 110                 my $meta = $class->meta;
 111                 $meta->add_after_method_modifier($_, $code) for @_;
 112             };
 113         },
 114         around => sub {
 115             my $class = $CALLER;
 116             return subname 'Moose::around' => sub (@&) {
 117                 my $code = pop @_;
 118                 my $meta = $class->meta;
 119                 $meta->add_around_method_modifier($_, $code) for @_;
 120             };
 121         },
 122         super => sub {
 123             return subname 'Moose::super' => sub {};
 124         },
 125         override => sub {
 126             my $class = $CALLER;
 127             return subname 'Moose::override' => sub ($&) {
 128                 my ($name, $method) = @_;
 129                 $class->meta->add_override_method_modifier($name => $method);
 130             };
 131         },
 132         inner => sub {
 133             return subname 'Moose::inner' => sub {};
 134         },
 135         augment => sub {
 136             my $class = $CALLER;
 137             return subname 'Moose::augment' => sub (@&) {
 138                 my ($name, $method) = @_;
 139                 $class->meta->add_augment_method_modifier($name => $method);
 140             };
 141         },
 142
 143         # NOTE:
 144         # this is experimental, but I am not
 145         # happy with it. If you want to try
 146         # it, you will have to uncomment it
 147         # yourself.
 148         # There is a really good chance that
 149         # this will be deprecated, dont get
 150         # too attached
 151         # self => sub {
 152         #     return subname 'Moose::self' => sub {};
 153         # },
 154         # method => sub {
 155         #     my $class = $CALLER;
 156         #     return subname 'Moose::method' => sub {
 157         #         my ($name, $method) = @_;
 158         #         $class->meta->add_method($name, sub {
 159         #             my $self = shift;
 160         #             no strict   'refs';
 161         #             no warnings 'redefine';
 162         #             local *{$class->meta->name . '::self'} = sub { $self };
 163         #             $method->(@_);
 164         #         });
 165         #     };
 166         # },
 167
 168         confess => sub {
 169             return \&Carp::confess;
 170         },
 171         blessed => sub {
 172             return \&Scalar::Util::blessed;
 173         },
 174     );
 175
 176     my $exporter = Sub::Exporter::build_exporter({
 177         exports => \%exports,
 178         groups  => {
 179             default => [':all']
 180         }
 181     });
 182
 183     sub import {
 184         $CALLER = caller();
 185
 186         strict->import;
 187         warnings->import;
 188
 189         # we should never export to main
 190         return if $CALLER eq 'main';
 191
 192         _init_meta();
 193
 194         goto $exporter;
 195     }
 196
 197     sub unimport {
 198         no strict 'refs';
 199         my $class = caller();
 200         # loop through the exports ...
 201         foreach my $name (keys %exports) {
 202             next if $name =~ /inner|super|self/;
 203
 204             # if we find one ...
 205             if (defined &{$class . '::' . $name}) {
 206                 my $keyword = \&{$class . '::' . $name};
 207
 208                 # make sure it is from Moose
 209                 my $pkg_name = eval { svref_2object($keyword)->GV->STASH->NAME };
 210                 next if $@;
 211                 next if $pkg_name ne 'Moose';
 212
 213                 # and if it is from Moose then undef the slot
 214                 delete ${$class . '::'}{$name};
 215             }
 216         }
 217     }
 218
 219
 220 }
 221
 222 ## Utility functions
 223
 224 sub _load_all_classes {
 225     foreach my $class (@_) {
 226         # see if this is already
 227         # loaded in the symbol table
 228         next if _is_class_already_loaded($class);
 229         # otherwise require it ...
 230         my $file = $class . '.pm';
 231         $file =~ s{::}{/}g;
 232         eval { CORE::require($file) };
 233         confess(
 234             "Could not load module '$class' because : $@"
 235             ) if $@;
 236     }
 237 }
 238
 239 sub _is_class_already_loaded {
 240         my $name = shift;
 241         no strict 'refs';
 242         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 243         foreach (keys %{"${name}::"}) {
 244                 next if substr($_, -2, 2) eq '::';
 245                 return 1 if defined &{"${name}::$_"};
 246         }
 247         return 0;
 248 }
 249
 250 ## make 'em all immutable
 251
 252 $_->meta->make_immutable(
 253     inline_constructor => 0,
 254     inline_accessors   => 0,
 255 ) for (
 256     'Moose::Meta::Attribute',
 257     'Moose::Meta::Class',
 258     'Moose::Meta::Instance',
 259
 260     'Moose::Meta::TypeConstraint',
 261     'Moose::Meta::TypeConstraint::Union',
 262     'Moose::Meta::TypeCoercion',
 263
 264     'Moose::Meta::Method',
 265     'Moose::Meta::Method::Accessor',
 266     'Moose::Meta::Method::Constructor',
 267     'Moose::Meta::Method::Overriden',
 268 );
 269
 270 1;
 271
 272 __END__
 273
 274 =pod
 275
 276 =head1 NAME
 277
 278 Moose - A complete modern object system for Perl 5
 279
 280 =head1 SYNOPSIS
 281
 282   package Point;
 283   use strict;
 284   use warnings;
 285   use Moose;
 286
 287   has 'x' => (is => 'rw', isa => 'Int');
 288   has 'y' => (is => 'rw', isa => 'Int');
 289
 290   sub clear {
 291       my $self = shift;
 292       $self->x(0);
 293       $self->y(0);
 294   }
 295
 296   package Point3D;
 297   use strict;
 298   use warnings;
 299   use Moose;
 300
 301   extends 'Point';
 302
 303   has 'z' => (is => 'rw', isa => 'Int');
 304
 305   after 'clear' => sub {
 306       my $self = shift;
 307       $self->z(0);
 308   };
 309
 310 =head1 CAVEAT
 311
 312 Moose is a rapidly maturing module, and is already being used by
 313 a number of people. It's test suite is growing larger by the day,
 314 and the docs should soon follow.
 315
 316 This said, Moose is not yet finished, and should still be considered
 317 to be evolving. Much of the outer API is stable, but the internals
 318 are still subject to change (although not without serious thought
 319 given to it).
 320
 321 =head1 DESCRIPTION
 322
 323 Moose is an extension of the Perl 5 object system.
 324
 325 =head2 Another object system!?!?
 326
 327 Yes, I know there has been an explosion recently of new ways to
 328 build object's in Perl 5, most of them based on inside-out objects
 329 and other such things. Moose is different because it is not a new
 330 object system for Perl 5, but instead an extension of the existing
 331 object system.
 332
 333 Moose is built on top of L<Class::MOP>, which is a metaclass system
 334 for Perl 5. This means that Moose not only makes building normal
 335 Perl 5 objects better, but it also provides the power of metaclass
 336 programming.
 337
 338 =head2 Can I use this in production? Or is this just an experiment?
 339
 340 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 341 meta-model; however Moose is B<NOT> an experiment/prototype, it is
 342 for B<real>. I will be deploying Moose into production environments later
 343 this year, and I have every intentions of using it as my de facto class
 344 builder from now on.
 345
 346 =head2 Is Moose just Perl 6 in Perl 5?
 347
 348 No. While Moose is very much inspired by Perl 6, it is not itself Perl 6.
 349 Instead, it is an OO system for Perl 5. I built Moose because I was tired or
 350 writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 351 instead of switching to Ruby, I wrote Moose :)
 352
 353 =head1 BUILDING CLASSES WITH MOOSE
 354
 355 Moose makes every attempt to provide as much convenience as possible during
 356 class construction/definition, but still stay out of your way if you want it
 357 to. Here are a few items to note when building classes with Moose.
 358
 359 Unless specified with C<extends>, any class which uses Moose will
 360 inherit from L<Moose::Object>.
 361
 362 Moose will also manage all attributes (including inherited ones) that
 363 are defined with C<has>. And assuming that you call C<new>, which is
 364 inherited from L<Moose::Object>, then this includes properly initializing
 365 all instance slots, setting defaults where appropriate, and performing any
 366 type constraint checking or coercion.
 367
 368 =head1 EXPORTED FUNCTIONS
 369
 370 Moose will export a number of functions into the class's namespace which
 371 can then be used to set up the class. These functions all work directly
 372 on the current class.
 373
 374 =over 4
 375
 376 =item B<meta>
 377
 378 This is a method which provides access to the current class's metaclass.
 379
 380 =item B<extends (@superclasses)>
 381
 382 This function will set the superclass(es) for the current class.
 383
 384 This approach is recommended instead of C<use base>, because C<use base>
 385 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 386 replace it. This is important to ensure that classes which do not have
 387 superclasses still properly inherit from L<Moose::Object>.
 388
 389 =item B<with (@roles)>
 390
 391 This will apply a given set of C<@roles> to the local class. Role support
 392 is currently under heavy development; see L<Moose::Role> for more details.
 393
 394 =item B<has ($name, %options)>
 395
 396 This will install an attribute of a given C<$name> into the current class.
 397 The list of C<%options> are the same as those provided by
 398 L<Class::MOP::Attribute>, in addition to the list below which are provided
 399 by Moose (L<Moose::Meta::Attribute> to be more specific):
 400
 401 =over 4
 402
 403 =item I<is =E<gt> 'rw'|'ro'>
 404
 405 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 406 only). These will create either a read/write accessor or a read-only
 407 accessor respectively, using the same name as the C<$name> of the attribute.
 408
 409 If you need more control over how your accessors are named, you can use the
 410 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 411
 412 =item I<isa =E<gt> $type_name>
 413
 414 The I<isa> option uses Moose's type constraint facilities to set up runtime
 415 type checking for this attribute. Moose will perform the checks during class
 416 construction, and within any accessors. The C<$type_name> argument must be a
 417 string. The string can be either a class name or a type defined using
 418 Moose's type definition features.
 419
 420 =item I<coerce =E<gt> (1|0)>
 421
 422 This will attempt to use coercion with the supplied type constraint to change
 423 the value passed into any accessors or constructors. You B<must> have supplied
 424 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 425 for an example usage.
 426
 427 =item I<does =E<gt> $role_name>
 428
 429 This will accept the name of a role which the value stored in this attribute
 430 is expected to have consumed.
 431
 432 =item I<required =E<gt> (1|0)>
 433
 434 This marks the attribute as being required. This means a value must be supplied
 435 during class construction, and the attribute can never be set to C<undef> with
 436 an accessor.
 437
 438 =item I<weak_ref =E<gt> (1|0)>
 439
 440 This will tell the class to store the value of this attribute as a weakened
 441 reference. If an attribute is a weakened reference, it B<cannot> also be
 442 coerced.
 443
 444 =item I<lazy =E<gt> (1|0)>
 445
 446 This will tell the class to not create this slot until absolutely necessary.
 447 If an attribute is marked as lazy it B<must> have a default supplied.
 448
 449 =item I<auto_deref =E<gt> (1|0)>
 450
 451 This tells the accessor whether to automatically dereference the value returned.
 452 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 453
 454 =item I<trigger =E<gt> $code>
 455
 456 The trigger option is a CODE reference which will be called after the value of
 457 the attribute is set. The CODE ref will be passed the instance itself, the
 458 updated value and the attribute meta-object (this is for more advanced fiddling
 459 and can typically be ignored in most cases). You B<cannot> have a trigger on
 460 a read-only attribute.
 461
 462 =item I<handles =E<gt> [ @handles ]>
 463
 464 There is experimental support for attribute delegation using the C<handles>
 465 option. More docs to come later.
 466
 467 =back
 468
 469 =item B<before $name|@names =E<gt> sub { ... }>
 470
 471 =item B<after $name|@names =E<gt> sub { ... }>
 472
 473 =item B<around $name|@names =E<gt> sub { ... }>
 474
 475 This three items are syntactic sugar for the before, after, and around method
 476 modifier features that L<Class::MOP> provides. More information on these can
 477 be found in the L<Class::MOP> documentation for now.
 478
 479 =item B<super>
 480
 481 The keyword C<super> is a no-op when called outside of an C<override> method. In
 482 the context of an C<override> method, it will call the next most appropriate
 483 superclass method with the same arguments as the original method.
 484
 485 =item B<override ($name, &sub)>
 486
 487 An C<override> method is a way of explicitly saying "I am overriding this
 488 method from my superclass". You can call C<super> within this method, and
 489 it will work as expected. The same thing I<can> be accomplished with a normal
 490 method call and the C<SUPER::> pseudo-package; it is really your choice.
 491
 492 =item B<inner>
 493
 494 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 495 an C<augment> method. You can think of C<inner> as being the inverse of
 496 C<super>; the details of how C<inner> and C<augment> work is best described in
 497 the L<Moose::Cookbook>.
 498
 499 =item B<augment ($name, &sub)>
 500
 501 An C<augment> method, is a way of explicitly saying "I am augmenting this
 502 method from my superclass". Once again, the details of how C<inner> and
 503 C<augment> work is best described in the L<Moose::Cookbook>.
 504
 505 =item B<confess>
 506
 507 This is the C<Carp::confess> function, and exported here because I use it
 508 all the time. This feature may change in the future, so you have been warned.
 509
 510 =item B<blessed>
 511
 512 This is the C<Scalar::Uti::blessed> function, it is exported here because I
 513 use it all the time. It is highly recommended that this is used instead of
 514 C<ref> anywhere you need to test for an object's class name.
 515
 516 =back
 517
 518 =head1 UNEXPORTING FUNCTIONS
 519
 520 =head2 B<unimport>
 521
 522 Moose offers a way of removing the keywords it exports though the C<unimport>
 523 method. You simply have to say C<no Moose> at the bottom of your code for this
 524 to work. Here is an example:
 525
 526     package Person;
 527     use Moose;
 528
 529     has 'first_name' => (is => 'rw', isa => 'Str');
 530     has 'last_name'  => (is => 'rw', isa => 'Str');
 531
 532     sub full_name {
 533         my $self = shift;
 534         $self->first_name . ' ' . $self->last_name
 535     }
 536
 537     no Moose; # keywords are removed from the Person package
 538
 539 =head1 MISC.
 540
 541 =head2 What does Moose stand for??
 542
 543 Moose doesn't stand for one thing in particular, however, if you
 544 want, here are a few of my favorites; feel free to contribute
 545 more :)
 546
 547 =over 4
 548
 549 =item Make Other Object Systems Envious
 550
 551 =item Makes Object Orientation So Easy
 552
 553 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 554
 555 =item Most Other Object Systems Emasculate
 556
 557 =item Moose Often Ovulate Sorta Early
 558
 559 =item Moose Offers Often Super Extensions
 560
 561 =item Meta Object Orientation Syntax Extensions
 562
 563 =back
 564
 565 =head1 CAVEATS
 566
 567 =over 4
 568
 569 =item *
 570
 571 It should be noted that C<super> and C<inner> C<cannot> be used in the same
 572 method. However, they can be combined together with the same class hierarchy;
 573 see F<t/014_override_augment_inner_super.t> for an example.
 574
 575 The reason for this is that C<super> is only valid within a method
 576 with the C<override> modifier, and C<inner> will never be valid within an
 577 C<override> method. In fact, C<augment> will skip over any C<override> methods
 578 when searching for its appropriate C<inner>.
 579
 580 This might seem like a restriction, but I am of the opinion that keeping these
 581 two features separate (but interoperable) actually makes them easy to use, since
 582 their behavior is then easier to predict. Time will tell if I am right or not.
 583
 584 =back
 585
 586 =head1 ACKNOWLEDGEMENTS
 587
 588 =over 4
 589
 590 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 591
 592 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 593
 594 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 595 and it certainly wouldn't have this name ;P
 596
 597 =item The basis of the TypeContraints module was Rob Kinyon's idea
 598 originally, I just ran with it.
 599
 600 =item Thanks to mst & chansen and the whole #moose poose for all the
 601 ideas/feature-requests/encouragement
 602
 603 =item Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
 604
 605 =back
 606
 607 =head1 SEE ALSO
 608
 609 =over 4
 610
 611 =item L<Class::MOP> documentation
 612
 613 =item The #moose channel on irc.perl.org
 614
 615 =item The Moose mailing list - moose@perl.org
 616
 617 =item L<http://forum2.org/moose/>
 618
 619 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 620
 621 This paper (suggested by lbr on #moose) was what lead to the implementation
 622 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 623 want to understand this feature, I suggest you read this.
 624
 625 =back
 626
 627 =head1 BUGS
 628
 629 All complex software has bugs lurking in it, and this module is no
 630 exception. If you find a bug please either email me, or add the bug
 631 to cpan-RT.
 632
 633 =head1 AUTHOR
 634
 635 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 636
 637 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 638
 639 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 640
 641 =head1 COPYRIGHT AND LICENSE
 642
 643 Copyright 2006 by Infinity Interactive, Inc.
 644
 645 L<http://www.iinteractive.com>
 646
 647 This library is free software; you can redistribute it and/or modify
 648 it under the same terms as Perl itself.
 649
 650 =cut