lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.05';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22
  23 use Moose::Object;
  24 use Moose::Util::TypeConstraints;
  25
  26 {
  27     my ( $CALLER, %METAS );
  28
  29     sub _find_meta {
  30         my $class = $CALLER;
  31
  32         return $METAS{$class} if exists $METAS{$class};
  33
  34         # make a subtype for each Moose class
  35         subtype $class
  36             => as 'Object'
  37             => where { $_->isa($class) }
  38         unless find_type_constraint($class);
  39
  40         my $meta;
  41         if ($class->can('meta')) {
  42             $meta = $class->meta();
  43             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  44                 || confess "Whoops, not møøsey enough";
  45         }
  46         else {
  47             $meta = Moose::Meta::Class->initialize($class);
  48             $meta->add_method('meta' => sub {
  49                 # re-initialize so it inherits properly
  50                 Moose::Meta::Class->initialize($class);
  51             })
  52         }
  53
  54         # make sure they inherit from Moose::Object
  55         $meta->superclasses('Moose::Object')
  56            unless $meta->superclasses();
  57
  58         return $METAS{$class} = $meta;
  59     }
  60
  61     my %exports = (
  62         extends => sub {
  63             my $meta = _find_meta();
  64             return subname 'Moose::extends' => sub {
  65                 _load_all_classes(@_);
  66                 $meta->superclasses(@_)
  67             };
  68         },
  69         with => sub {
  70             my $meta = _find_meta();
  71             return subname 'Moose::with' => sub {
  72                 my ($role) = @_;
  73                 _load_all_classes($role);
  74                 $role->meta->apply($meta);
  75             };
  76         },
  77         has => sub {
  78             my $meta = _find_meta();
  79             return subname 'Moose::has' => sub {
  80                 my ($name, %options) = @_;
  81                 if ($options{metaclass}) {
  82                     _load_all_classes($options{metaclass});
  83                     $meta->add_attribute($options{metaclass}->new($name, %options));
  84                 }
  85                 else {
  86                     $meta->add_attribute($name, %options);
  87                 }
  88             };
  89         },
  90         before => sub {
  91             my $meta = _find_meta();
  92             return subname 'Moose::before' => sub {
  93                 my $code = pop @_;
  94                 $meta->add_before_method_modifier($_, $code) for @_;
  95             };
  96         },
  97         after => sub {
  98             my $meta = _find_meta();
  99             return subname 'Moose::after' => sub {
 100                 my $code = pop @_;
 101                 $meta->add_after_method_modifier($_, $code) for @_;
 102             };
 103         },
 104         around => sub {
 105             my $meta = _find_meta();
 106             return subname 'Moose::around' => sub {
 107                 my $code = pop @_;
 108                 $meta->add_around_method_modifier($_, $code) for @_;
 109             };
 110         },
 111         super => sub {
 112             my $meta = _find_meta();
 113             return subname 'Moose::super' => sub {};
 114         },
 115         override => sub {
 116             my $meta = _find_meta();
 117             return subname 'Moose::override' => sub {
 118                 my ($name, $method) = @_;
 119                 $meta->add_override_method_modifier($name => $method);
 120             };
 121         },
 122         inner => sub {
 123             my $meta = _find_meta();
 124             return subname 'Moose::inner' => sub {};
 125         },
 126         augment => sub {
 127             my $meta = _find_meta();
 128             return subname 'Moose::augment' => sub {
 129                 my ($name, $method) = @_;
 130                 $meta->add_augment_method_modifier($name => $method);
 131             };
 132         },
 133         confess => sub {
 134             return \&Carp::confess;
 135         },
 136         blessed => sub {
 137             return \&Scalar::Util::blessed;
 138         }
 139     );
 140
 141     my $exporter = Sub::Exporter::build_exporter({
 142         exports => \%exports,
 143         groups  => {
 144             default => [':all']
 145         }
 146     });
 147
 148     sub import {
 149         $CALLER = caller();
 150
 151         # we should never export to main
 152         return if $CALLER eq 'main';
 153
 154         goto $exporter;
 155     };
 156 }
 157
 158 ## Utility functions
 159
 160 sub _load_all_classes {
 161     foreach my $super (@_) {
 162         # see if this is already
 163         # loaded in the symbol table
 164         next if _is_class_already_loaded($super);
 165         # otherwise require it ...
 166         ($super->require)
 167             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 168     }
 169 }
 170
 171 sub _is_class_already_loaded {
 172         my $name = shift;
 173         no strict 'refs';
 174         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 175         foreach (keys %{"${name}::"}) {
 176                 next if substr($_, -2, 2) eq '::';
 177                 return 1 if defined &{"${name}::$_"};
 178         }
 179     return 0;
 180 }
 181
 182 1;
 183
 184 __END__
 185
 186 =pod
 187
 188 =head1 NAME
 189
 190 Moose - Moose, it's the new Camel
 191
 192 =head1 SYNOPSIS
 193
 194   package Point;
 195   use Moose;
 196
 197   has 'x' => (isa => 'Int', is => 'rw');
 198   has 'y' => (isa => 'Int', is => 'rw');
 199
 200   sub clear {
 201       my $self = shift;
 202       $self->x(0);
 203       $self->y(0);
 204   }
 205
 206   package Point3D;
 207   use Moose;
 208
 209   extends 'Point';
 210
 211   has 'z' => (isa => 'Int');
 212
 213   after 'clear' => sub {
 214       my $self = shift;
 215       $self->{z} = 0;
 216   };
 217
 218 =head1 CAVEAT
 219
 220 This is an early release of this module, it still needs
 221 some fine tuning and B<lots> more documentation. I am adopting
 222 the I<release early and release often> approach with this module,
 223 so keep an eye on your favorite CPAN mirror!
 224
 225 =head1 DESCRIPTION
 226
 227 Moose is an extension of the Perl 5 object system.
 228
 229 =head2 Another object system!?!?
 230
 231 Yes, I know there has been an explosion recently of new ways to
 232 build object's in Perl 5, most of them based on inside-out objects,
 233 and other such things. Moose is different because it is not a new
 234 object system for Perl 5, but instead an extension of the existing
 235 object system.
 236
 237 Moose is built on top of L<Class::MOP>, which is a metaclass system
 238 for Perl 5. This means that Moose not only makes building normal
 239 Perl 5 objects better, but it also provides the power of metaclass
 240 programming.
 241
 242 =head2 What does Moose stand for??
 243
 244 Moose doesn't stand for one thing in particular, however, if you
 245 want, here are a few of my favorites, feel free to contribute
 246 more :)
 247
 248 =over 4
 249
 250 =item Make Other Object Systems Envious
 251
 252 =item Makes Object Orientation So Easy
 253
 254 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 255
 256 =item Most Other Object Systems Emasculate
 257
 258 =item My Overcraft Overfilled (with) Some Eels
 259
 260 =item Moose Often Ovulate Sorta Early
 261
 262 =item Many Overloaded Object Systems Exists
 263
 264 =item Moose Offers Often Super Extensions
 265
 266 =item Meta Object Orientation Syntax Extensions
 267
 268 =back
 269
 270 =head1 BUILDING CLASSES WITH MOOSE
 271
 272 Moose makes every attempt to provide as much convience during class
 273 construction/definition, but still stay out of your way if you want
 274 it to. Here are some of the features Moose provides:
 275
 276 Unless specified with C<extends>, any class which uses Moose will
 277 inherit from L<Moose::Object>.
 278
 279 Moose will also manage all attributes (including inherited ones) that
 280 are defined with C<has>. And assuming that you call C<new> which is
 281 inherited from L<Moose::Object>, then this includes properly initializing
 282 all instance slots, setting defaults where approprtiate and performing any
 283 type constraint checking or coercion.
 284
 285 For more details, see the ever expanding L<Moose::Cookbook>.
 286
 287 =head1 EXPORTED FUNCTIONS
 288
 289 Moose will export a number of functions into the class's namespace, which
 290 can then be used to set up the class. These functions all work directly
 291 on the current class.
 292
 293 =over 4
 294
 295 =item B<meta>
 296
 297 This is a method which provides access to the current class's metaclass.
 298
 299 =item B<extends (@superclasses)>
 300
 301 This function will set the superclass(es) for the current class.
 302
 303 This approach is recommended instead of C<use base>, because C<use base>
 304 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 305 replace it. This is important to ensure that classes which do not have
 306 superclasses properly inherit from L<Moose::Object>.
 307
 308 =item B<with ($role)>
 309
 310 This will apply a given C<$role> to the local class. Role support is
 311 currently very experimental, see L<Moose::Role> for more details.
 312
 313 =item B<has ($name, %options)>
 314
 315 This will install an attribute of a given C<$name> into the current class.
 316 The list of C<%options> are the same as those provided by both
 317 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 318 few convience ones provided by Moose which are listed below:
 319
 320 =over 4
 321
 322 =item I<is =E<gt> 'rw'|'ro'>
 323
 324 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 325 only). These will create either a read/write accessor or a read-only
 326 accessor respectively, using the same name as the C<$name> of the attribute.
 327
 328 If you need more control over how your accessors are named, you can use the
 329 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 330
 331 =item I<isa =E<gt> $type_name>
 332
 333 The I<isa> option uses Moose's type constraint facilities to set up runtime
 334 type checking for this attribute. Moose will perform the checks during class
 335 construction, and within any accessors. The C<$type_name> argument must be a
 336 string. The string can be either a class name, or a type defined using
 337 Moose's type defintion features.
 338
 339 =back
 340
 341 =item B<before $name|@names =E<gt> sub { ... }>
 342
 343 =item B<after $name|@names =E<gt> sub { ... }>
 344
 345 =item B<around $name|@names =E<gt> sub { ... }>
 346
 347 This three items are syntactic sugar for the before, after and around method
 348 modifier features that L<Class::MOP> provides. More information on these can
 349 be found in the L<Class::MOP> documentation for now.
 350
 351 =item B<super>
 352
 353 The keyword C<super> is a noop when called outside of an C<override> method. In
 354 the context of an C<override> method, it will call the next most appropriate
 355 superclass method with the same arguments as the original method.
 356
 357 =item B<override ($name, &sub)>
 358
 359 An C<override> method, is a way of explictly saying "I am overriding this
 360 method from my superclass". You can call C<super> within this method, and
 361 it will work as expected. The same thing I<can> be accomplished with a normal
 362 method call and the C<SUPER::> pseudo-package, it is really your choice.
 363
 364 =item B<inner>
 365
 366 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 367 an C<augment> method. You can think of C<inner> as being the inverse of
 368 C<super>, the details of how C<inner> and C<augment> work is best described in
 369 the L<Moose::Cookbook>.
 370
 371 =item B<augment ($name, &sub)>
 372
 373 An C<augment> method, is a way of explictly saying "I am augmenting this
 374 method from my superclass". Once again, the details of how C<inner> and
 375 C<augment> work is best described in the L<Moose::Cookbook>.
 376
 377 =item B<confess>
 378
 379 This is the C<Carp::confess> function, and exported here beause I use it
 380 all the time. This feature may change in the future, so you have been warned.
 381
 382 =item B<blessed>
 383
 384 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 385 use it all the time. It is highly recommended that this is used instead of
 386 C<ref> anywhere you need to test for an object's class name.
 387
 388 =back
 389
 390 =head1 CAVEATS
 391
 392 =over 4
 393
 394 =item *
 395
 396 It should be noted that C<super> and C<inner> can B<not> be used in the same
 397 method. However, they can be combined together with the same class hierarchy,
 398 see F<t/014_override_augment_inner_super.t> for an example.
 399
 400 The reason that this is so is because C<super> is only valid within a method
 401 with the C<override> modifier, and C<inner> will never be valid within an
 402 C<override> method. In fact, C<augment> will skip over any C<override> methods
 403 when searching for it's appropriate C<inner>.
 404
 405 This might seem like a restriction, but I am of the opinion that keeping these
 406 two features seperate (but interoperable) actually makes them easy to use since
 407 their behavior is then easier to predict. Time will tell if I am right or not.
 408
 409 =back
 410
 411 =head1 ACKNOWLEDGEMENTS
 412
 413 =over 4
 414
 415 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 416
 417 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 418
 419 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 420 and it certainly wouldn't have this name ;P
 421
 422 =item The basis of the TypeContraints module was Rob Kinyon's idea
 423 originally, I just ran with it.
 424
 425 =item Thanks to mst & chansen and the whole #moose poose for all the
 426 ideas/feature-requests/encouragement
 427
 428 =back
 429
 430 =head1 SEE ALSO
 431
 432 =over 4
 433
 434 =item L<Class::MOP> documentation
 435
 436 =item The #moose channel on irc.perl.org
 437
 438 =item L<http://forum2.org/moose/>
 439
 440 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 441
 442 This paper (suggested by lbr on #moose) was what lead to the implementation
 443 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 444 want to understand this feature, I suggest you read this.
 445
 446 =back
 447
 448 =head1 BUGS
 449
 450 All complex software has bugs lurking in it, and this module is no
 451 exception. If you find a bug please either email me, or add the bug
 452 to cpan-RT.
 453
 454 =head1 AUTHOR
 455
 456 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 457
 458 =head1 COPYRIGHT AND LICENSE
 459
 460 Copyright 2006 by Infinity Interactive, Inc.
 461
 462 L<http://www.iinteractive.com>
 463
 464 This library is free software; you can redistribute it and/or modify
 465 it under the same terms as Perl itself.
 466
 467 =cut