Fix the super recursion bug perigrin found
[gitmo/Moose.git] / lib / Moose.pm
1
2 package Moose;
3
4 use strict;
5 use warnings;
6
7 use 5.008;
8
9 our $VERSION   = '0.64';
10 $VERSION = eval $VERSION;
11 our $AUTHORITY = 'cpan:STEVAN';
12
13 use Scalar::Util 'blessed';
14 use Carp         'confess', 'croak', 'cluck';
15
16 use Moose::Exporter;
17
18 use Class::MOP 0.75;
19
20 use Moose::Meta::Class;
21 use Moose::Meta::TypeConstraint;
22 use Moose::Meta::TypeCoercion;
23 use Moose::Meta::Attribute;
24 use Moose::Meta::Instance;
25
26 use Moose::Object;
27
28 use Moose::Meta::Role;
29 use Moose::Meta::Role::Composite;
30 use Moose::Meta::Role::Application;
31 use Moose::Meta::Role::Application::RoleSummation;
32 use Moose::Meta::Role::Application::ToClass;
33 use Moose::Meta::Role::Application::ToRole;
34 use Moose::Meta::Role::Application::ToInstance;
35
36 use Moose::Util::TypeConstraints;
37 use Moose::Util ();
38
39 sub throw_error {
40     # FIXME This 
41     shift;
42     goto \&confess
43 }
44
45 sub extends {
46     my $class = shift;
47
48     croak "Must derive at least one class" unless @_;
49
50     my @supers = @_;
51     foreach my $super (@supers) {
52         Class::MOP::load_class($super);
53         croak "You cannot inherit from a Moose Role ($super)"
54             if $super->can('meta')  && 
55                blessed $super->meta &&
56                $super->meta->isa('Moose::Meta::Role')
57     }
58
59
60
61     # this checks the metaclass to make sure
62     # it is correct, sometimes it can get out
63     # of sync when the classes are being built
64     my $meta = Moose::Meta::Class->initialize($class);
65     $meta->superclasses(@supers);
66 }
67
68 sub with {
69     my $class = shift;
70     Moose::Util::apply_all_roles(Class::MOP::Class->initialize($class), @_);
71 }
72
73 sub has {
74     my $class = shift;
75     my $name  = shift;
76     croak 'Usage: has \'name\' => ( key => value, ... )' if @_ == 1;
77     my %options = @_;
78     my $attrs = ( ref($name) eq 'ARRAY' ) ? $name : [ ($name) ];
79     Class::MOP::Class->initialize($class)->add_attribute( $_, %options ) for @$attrs;
80 }
81
82 sub before {
83     my $class = shift;
84     Moose::Util::add_method_modifier($class, 'before', \@_);
85 }
86
87 sub after {
88     my $class = shift;
89     Moose::Util::add_method_modifier($class, 'after', \@_);
90 }
91
92 sub around {
93     my $class = shift;
94     Moose::Util::add_method_modifier($class, 'around', \@_);
95 }
96
97 our $SUPER_PACKAGE;
98 our $SUPER_BODY;
99 our @SUPER_ARGS;
100
101 sub super {
102     # This check avoids a recursion loop - see
103     # t/100_bugs/020_super_recursion.t
104     return if defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
105     return unless $SUPER_BODY; $SUPER_BODY->(@SUPER_ARGS);
106 }
107
108 sub override {
109     my $class = shift;
110     my ( $name, $method ) = @_;
111     Class::MOP::Class->initialize($class)->add_override_method_modifier( $name => $method );
112 }
113
114 sub inner {
115     my $pkg = caller();
116     our ( %INNER_BODY, %INNER_ARGS );
117
118     if ( my $body = $INNER_BODY{$pkg} ) {
119         my @args = @{ $INNER_ARGS{$pkg} };
120         local $INNER_ARGS{$pkg};
121         local $INNER_BODY{$pkg};
122         return $body->(@args);
123     } else {
124         return;
125     }
126 }
127
128 sub augment {
129     my $class = shift;
130     my ( $name, $method ) = @_;
131     Class::MOP::Class->initialize($class)->add_augment_method_modifier( $name => $method );
132 }
133
134 Moose::Exporter->setup_import_methods(
135     with_caller => [
136         qw( extends with has before after around override augment)
137     ],
138     as_is => [
139         qw( super inner ),
140         \&Carp::confess,
141         \&Scalar::Util::blessed,
142     ],
143 );
144
145 sub init_meta {
146     # This used to be called as a function. This hack preserves
147     # backwards compatibility.
148     if ( $_[0] ne __PACKAGE__ ) {
149         return __PACKAGE__->init_meta(
150             for_class  => $_[0],
151             base_class => $_[1],
152             metaclass  => $_[2],
153         );
154     }
155
156     shift;
157     my %args = @_;
158
159     my $class = $args{for_class}
160         or Moose->throw_error("Cannot call init_meta without specifying a for_class");
161     my $base_class = $args{base_class} || 'Moose::Object';
162     my $metaclass  = $args{metaclass}  || 'Moose::Meta::Class';
163
164     Moose->throw_error("The Metaclass $metaclass must be a subclass of Moose::Meta::Class.")
165         unless $metaclass->isa('Moose::Meta::Class');
166
167     # make a subtype for each Moose class
168     class_type($class)
169         unless find_type_constraint($class);
170
171     my $meta;
172
173     if ( $meta = Class::MOP::get_metaclass_by_name($class) ) {
174         unless ( $meta->isa("Moose::Meta::Class") ) {
175             Moose->throw_error("$class already has a metaclass, but it does not inherit $metaclass ($meta)");
176         }
177     } else {
178         # no metaclass, no 'meta' method
179
180         # now we check whether our ancestors have metaclass, and if so borrow that
181         my ( undef, @isa ) = @{ $class->mro::get_linear_isa };
182
183         foreach my $ancestor ( @isa ) {
184             my $ancestor_meta = Class::MOP::get_metaclass_by_name($ancestor) || next;
185
186             my $ancestor_meta_class = ($ancestor_meta->is_immutable
187                 ? $ancestor_meta->get_mutable_metaclass_name
188                 : ref($ancestor_meta));
189
190             # if we have an ancestor metaclass that inherits $metaclass, we use
191             # that. This is like _fix_metaclass_incompatibility, but we can do it now.
192
193             # the case of having an ancestry is not very common, but arises in
194             # e.g. Reaction
195             unless ( $metaclass->isa( $ancestor_meta_class ) ) {
196                 if ( $ancestor_meta_class->isa($metaclass) ) {
197                     $metaclass = $ancestor_meta_class;
198                 }
199             }
200         }
201
202         $meta = $metaclass->initialize($class);
203     }
204
205     if ( $class->can('meta') ) {
206         # check 'meta' method
207
208         # it may be inherited
209
210         # NOTE:
211         # this is the case where the metaclass pragma
212         # was used before the 'use Moose' statement to
213         # override a specific class
214         my $method_meta = $class->meta;
215
216         ( blessed($method_meta) && $method_meta->isa('Moose::Meta::Class') )
217             || Moose->throw_error("$class already has a &meta function, but it does not return a Moose::Meta::Class ($meta)");
218
219         $meta = $method_meta;
220     }
221
222     unless ( $meta->has_method("meta") ) { # don't overwrite
223         # also check for inherited non moose 'meta' method?
224         # FIXME also skip this if the user requested by passing an option
225         $meta->add_method(
226             'meta' => sub {
227                 # re-initialize so it inherits properly
228                 $metaclass->initialize( ref($_[0]) || $_[0] );
229             }
230         );
231     }
232
233     # make sure they inherit from Moose::Object
234     $meta->superclasses($base_class)
235       unless $meta->superclasses();
236
237     return $meta;
238 }
239
240 # This may be used in some older MooseX extensions.
241 sub _get_caller {
242     goto &Moose::Exporter::_get_caller;
243 }
244
245 ## make 'em all immutable
246
247 $_->make_immutable(
248     inline_constructor => 1,
249     constructor_name   => "_new",
250     # these are Class::MOP accessors, so they need inlining
251     inline_accessors => 1
252     ) for grep { $_->is_mutable }
253     map { $_->meta }
254     qw(
255     Moose::Meta::Attribute
256     Moose::Meta::Class
257     Moose::Meta::Instance
258
259     Moose::Meta::TypeCoercion
260     Moose::Meta::TypeCoercion::Union
261
262     Moose::Meta::Method
263     Moose::Meta::Method::Accessor
264     Moose::Meta::Method::Constructor
265     Moose::Meta::Method::Destructor
266     Moose::Meta::Method::Overriden
267     Moose::Meta::Method::Augmented
268
269     Moose::Meta::Role
270     Moose::Meta::Role::Method
271     Moose::Meta::Role::Method::Required
272
273     Moose::Meta::Role::Composite
274
275     Moose::Meta::Role::Application
276     Moose::Meta::Role::Application::RoleSummation
277     Moose::Meta::Role::Application::ToClass
278     Moose::Meta::Role::Application::ToRole
279     Moose::Meta::Role::Application::ToInstance
280 );
281
282 1;
283
284 __END__
285
286 =pod
287
288 =head1 NAME
289
290 Moose - A postmodern object system for Perl 5
291
292 =head1 SYNOPSIS
293
294   package Point;
295   use Moose; # automatically turns on strict and warnings
296
297   has 'x' => (is => 'rw', isa => 'Int');
298   has 'y' => (is => 'rw', isa => 'Int');
299
300   sub clear {
301       my $self = shift;
302       $self->x(0);
303       $self->y(0);
304   }
305
306   package Point3D;
307   use Moose;
308
309   extends 'Point';
310
311   has 'z' => (is => 'rw', isa => 'Int');
312
313   after 'clear' => sub {
314       my $self = shift;
315       $self->z(0);
316   };
317
318 =head1 DESCRIPTION
319
320 Moose is an extension of the Perl 5 object system.
321
322 The main goal of Moose is to make Perl 5 Object Oriented programming
323 easier, more consistent and less tedious. With Moose you can to think
324 more about what you want to do and less about the mechanics of OOP.
325
326 Additionally, Moose is built on top of L<Class::MOP>, which is a
327 metaclass system for Perl 5. This means that Moose not only makes
328 building normal Perl 5 objects better, but it provides the power of
329 metaclass programming as well.
330
331 =head2 New to Moose?
332
333 If you're new to Moose, the best place to start is the L<Moose::Intro>
334 docs, followed by the L<Moose::Cookbook>. The intro will show you what
335 Moose is, and how it makes Perl 5 OO better.
336
337 The cookbook recipes on Moose basics will get you up to speed with
338 many of Moose's features quickly. Once you have an idea of what Moose
339 can do, you can use the API documentation to get more detail on
340 features which interest you.
341
342 =head2 Moose Extensions
343
344 The C<MooseX::> namespace is the official place to find Moose extensions.
345 These extensions can be found on the CPAN.  The easiest way to find them
346 is to search for them (L<http://search.cpan.org/search?query=MooseX::>),
347 or to examine L<Task::Moose> which aims to keep an up-to-date, easily
348 installable list of Moose extensions.
349
350 =head1 BUILDING CLASSES WITH MOOSE
351
352 Moose makes every attempt to provide as much convenience as possible during
353 class construction/definition, but still stay out of your way if you want it
354 to. Here are a few items to note when building classes with Moose.
355
356 Unless specified with C<extends>, any class which uses Moose will
357 inherit from L<Moose::Object>.
358
359 Moose will also manage all attributes (including inherited ones) that are
360 defined with C<has>. And (assuming you call C<new>, which is inherited from
361 L<Moose::Object>) this includes properly initializing all instance slots,
362 setting defaults where appropriate, and performing any type constraint checking
363 or coercion.
364
365 =head1 PROVIDED METHODS
366
367 Moose provides a number of methods to all your classes, mostly through the 
368 inheritance of L<Moose::Object>. There is however, one exception.
369
370 =over 4
371
372 =item B<meta>
373
374 This is a method which provides access to the current class's metaclass.
375
376 =back
377
378 =head1 EXPORTED FUNCTIONS
379
380 Moose will export a number of functions into the class's namespace which
381 may then be used to set up the class. These functions all work directly
382 on the current class.
383
384 =over 4
385
386 =item B<extends (@superclasses)>
387
388 This function will set the superclass(es) for the current class.
389
390 This approach is recommended instead of C<use base>, because C<use base>
391 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
392 replace it. This is important to ensure that classes which do not have
393 superclasses still properly inherit from L<Moose::Object>.
394
395 =item B<with (@roles)>
396
397 This will apply a given set of C<@roles> to the local class. 
398
399 =item B<has $name|@$names =E<gt> %options>
400
401 This will install an attribute of a given C<$name> into the current class. If
402 the first parameter is an array reference, it will create an attribute for
403 every C<$name> in the list. The C<%options> are the same as those provided by
404 L<Class::MOP::Attribute>, in addition to the list below which are provided by
405 Moose (L<Moose::Meta::Attribute> to be more specific):
406
407 =over 4
408
409 =item I<is =E<gt> 'rw'|'ro'>
410
411 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
412 only). These will create either a read/write accessor or a read-only
413 accessor respectively, using the same name as the C<$name> of the attribute.
414
415 If you need more control over how your accessors are named, you can
416 use the L<reader|Class::MOP::Attribute/reader>,
417 L<writer|Class::MOP::Attribute/writer> and
418 L<accessor|Class::MOP::Attribute/accessor> options inherited from
419 L<Class::MOP::Attribute>, however if you use those, you won't need the
420 I<is> option.
421
422 =item I<isa =E<gt> $type_name>
423
424 The I<isa> option uses Moose's type constraint facilities to set up runtime
425 type checking for this attribute. Moose will perform the checks during class
426 construction, and within any accessors. The C<$type_name> argument must be a
427 string. The string may be either a class name or a type defined using
428 Moose's type definition features. (Refer to L<Moose::Util::TypeConstraints>
429 for information on how to define a new type, and how to retrieve type meta-data).
430
431 =item I<coerce =E<gt> (1|0)>
432
433 This will attempt to use coercion with the supplied type constraint to change
434 the value passed into any accessors or constructors. You B<must> have supplied
435 a type constraint in order for this to work. See L<Moose::Cookbook::Basics::Recipe5>
436 for an example.
437
438 =item I<does =E<gt> $role_name>
439
440 This will accept the name of a role which the value stored in this attribute
441 is expected to have consumed.
442
443 =item I<required =E<gt> (1|0)>
444
445 This marks the attribute as being required. This means a I<defined> value must be
446 supplied during class construction, and the attribute may never be set to
447 C<undef> with an accessor.
448
449 =item I<weak_ref =E<gt> (1|0)>
450
451 This will tell the class to store the value of this attribute as a weakened
452 reference. If an attribute is a weakened reference, it B<cannot> also be
453 coerced.
454
455 =item I<lazy =E<gt> (1|0)>
456
457 This will tell the class to not create this slot until absolutely necessary.
458 If an attribute is marked as lazy it B<must> have a default supplied.
459
460 =item I<auto_deref =E<gt> (1|0)>
461
462 This tells the accessor whether to automatically dereference the value returned.
463 This is only legal if your C<isa> option is either C<ArrayRef> or C<HashRef>.
464
465 =item I<trigger =E<gt> $code>
466
467 The I<trigger> option is a CODE reference which will be called after the value of
468 the attribute is set. The CODE ref will be passed the instance itself, the
469 updated value and the attribute meta-object (this is for more advanced fiddling
470 and can typically be ignored). You B<cannot> have a trigger on a read-only
471 attribute. 
472
473 B<NOTE:> Triggers will only fire when you B<assign> to the attribute,
474 either in the constructor, or using the writer. Default and built values will
475 B<not> cause the trigger to be fired.
476
477 =item I<handles =E<gt> ARRAY | HASH | REGEXP | ROLE | CODE>
478
479 The I<handles> option provides Moose classes with automated delegation features.
480 This is a pretty complex and powerful option. It accepts many different option
481 formats, each with its own benefits and drawbacks.
482
483 B<NOTE:> The class being delegated to does not need to be a Moose based class,
484 which is why this feature is especially useful when wrapping non-Moose classes.
485
486 All I<handles> option formats share the following traits:
487
488 You cannot override a locally defined method with a delegated method; an
489 exception will be thrown if you try. That is to say, if you define C<foo> in
490 your class, you cannot override it with a delegated C<foo>. This is almost never
491 something you would want to do, and if it is, you should do it by hand and not
492 use Moose.
493
494 You cannot override any of the methods found in Moose::Object, or the C<BUILD>
495 and C<DEMOLISH> methods. These will not throw an exception, but will silently
496 move on to the next method in the list. My reasoning for this is that you would
497 almost never want to do this, since it usually breaks your class. As with
498 overriding locally defined methods, if you do want to do this, you should do it
499 manually, not with Moose.
500
501 You do not I<need> to have a reader (or accessor) for the attribute in order 
502 to delegate to it. Moose will create a means of accessing the value for you, 
503 however this will be several times B<less> efficient then if you had given 
504 the attribute a reader (or accessor) to use.
505
506 Below is the documentation for each option format:
507
508 =over 4
509
510 =item C<ARRAY>
511
512 This is the most common usage for I<handles>. You basically pass a list of
513 method names to be delegated, and Moose will install a delegation method
514 for each one.
515
516 =item C<HASH>
517
518 This is the second most common usage for I<handles>. Instead of a list of
519 method names, you pass a HASH ref where each key is the method name you
520 want installed locally, and its value is the name of the original method
521 in the class being delegated to.
522
523 This can be very useful for recursive classes like trees. Here is a
524 quick example (soon to be expanded into a Moose::Cookbook recipe):
525
526   package Tree;
527   use Moose;
528
529   has 'node' => (is => 'rw', isa => 'Any');
530
531   has 'children' => (
532       is      => 'ro',
533       isa     => 'ArrayRef',
534       default => sub { [] }
535   );
536
537   has 'parent' => (
538       is          => 'rw',
539       isa         => 'Tree',
540       weak_ref => 1,
541       handles     => {
542           parent_node => 'node',
543           siblings    => 'children',
544       }
545   );
546
547 In this example, the Tree package gets C<parent_node> and C<siblings> methods,
548 which delegate to the C<node> and C<children> methods (respectively) of the Tree
549 instance stored in the C<parent> slot.
550
551 =item C<REGEXP>
552
553 The regexp option works very similar to the ARRAY option, except that it builds
554 the list of methods for you. It starts by collecting all possible methods of the
555 class being delegated to, then filters that list using the regexp supplied here.
556
557 B<NOTE:> An I<isa> option is required when using the regexp option format. This
558 is so that we can determine (at compile time) the method list from the class.
559 Without an I<isa> this is just not possible.
560
561 =item C<ROLE>
562
563 With the role option, you specify the name of a role whose "interface" then
564 becomes the list of methods to handle. The "interface" can be defined as; the
565 methods of the role and any required methods of the role. It should be noted
566 that this does B<not> include any method modifiers or generated attribute
567 methods (which is consistent with role composition).
568
569 =item C<CODE>
570
571 This is the option to use when you really want to do something funky. You should
572 only use it if you really know what you are doing, as it involves manual
573 metaclass twiddling.
574
575 This takes a code reference, which should expect two arguments. The first is the
576 attribute meta-object this I<handles> is attached to. The second is the
577 metaclass of the class being delegated to. It expects you to return a hash (not
578 a HASH ref) of the methods you want mapped.
579
580 =back
581
582 =item I<metaclass =E<gt> $metaclass_name>
583
584 This tells the class to use a custom attribute metaclass for this particular
585 attribute. Custom attribute metaclasses are useful for extending the
586 capabilities of the I<has> keyword: they are the simplest way to extend the MOP,
587 but they are still a fairly advanced topic and too much to cover here, see 
588 L<Moose::Cookbook::Meta::Recipe1> for more information.
589
590 The default behavior here is to just load C<$metaclass_name>; however, we also
591 have a way to alias to a shorter name. This will first look to see if
592 B<Moose::Meta::Attribute::Custom::$metaclass_name> exists. If it does, Moose
593 will then check to see if that has the method C<register_implementation>, which
594 should return the actual name of the custom attribute metaclass. If there is no
595 C<register_implementation> method, it will fall back to using
596 B<Moose::Meta::Attribute::Custom::$metaclass_name> as the metaclass name.
597
598 =item I<traits =E<gt> [ @role_names ]>
599
600 This tells Moose to take the list of C<@role_names> and apply them to the 
601 attribute meta-object. This is very similar to the I<metaclass> option, but 
602 allows you to use more than one extension at a time.
603
604 See L<TRAIT NAME RESOLUTION> for details on how a trait name is
605 resolved to a class name.
606
607 Also see L<Moose::Cookbook::Meta::Recipe3> for a metaclass trait
608 example.
609
610 =item I<builder> => Str
611
612 The value of this key is the name of the method that will be called to
613 obtain the value used to initialize the attribute. See the L<builder
614 option docs in Class::MOP::Attribute|Class::MOP::Attribute/builder>
615 for more information.
616
617 =item I<default> => SCALAR | CODE
618
619 The value of this key is the default value which will initialize the attribute.
620
621 NOTE: If the value is a simple scalar (string or number), then it can
622 be just passed as is.  However, if you wish to initialize it with a
623 HASH or ARRAY ref, then you need to wrap that inside a CODE reference.
624 See the L<default option docs in
625 Class::MOP::Attribute|Class::MOP::Attribute/default> for more
626 information.
627
628 =item I<initializer> => Str
629
630 This may be a method name (referring to a method on the class with
631 this attribute) or a CODE ref.  The initializer is used to set the
632 attribute value on an instance when the attribute is set during
633 instance initialization (but not when the value is being assigned
634 to). See the L<initializer option docs in
635 Class::MOP::Attribute|Class::MOP::Attribute/initializer> for more
636 information.
637
638 =item I<clearer> => Str
639
640 Allows you to clear the value, see the L<clearer option docs in
641 Class::MOP::Attribute|Class::MOP::Attribute/clearer> for more
642 information.
643
644 =item I<predicate> => Str
645
646 Basic test to see if a value has been set in the attribute, see the
647 L<predicate option docs in
648 Class::MOP::Attribute|Class::MOP::Attribute/predicate> for more
649 information.
650
651 =item I<lazy_build> => (0|1)
652
653 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
654 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
655
656
657 =back
658
659 =item B<has +$name =E<gt> %options>
660
661 This is variation on the normal attribute creator C<has> which allows you to
662 clone and extend an attribute from a superclass or from a role. Here is an 
663 example of the superclass usage:
664
665   package Foo;
666   use Moose;
667
668   has 'message' => (
669       is      => 'rw',
670       isa     => 'Str',
671       default => 'Hello, I am a Foo'
672   );
673
674   package My::Foo;
675   use Moose;
676
677   extends 'Foo';
678
679   has '+message' => (default => 'Hello I am My::Foo');
680
681 What is happening here is that B<My::Foo> is cloning the C<message> attribute
682 from its parent class B<Foo>, retaining the C<is =E<gt> 'rw'> and C<isa =E<gt>
683 'Str'> characteristics, but changing the value in C<default>.
684
685 Here is another example, but within the context of a role:
686
687   package Foo::Role;
688   use Moose::Role;
689
690   has 'message' => (
691       is      => 'rw',
692       isa     => 'Str',
693       default => 'Hello, I am a Foo'
694   );
695
696   package My::Foo;
697   use Moose;
698
699   with 'Foo::Role';
700
701   has '+message' => (default => 'Hello I am My::Foo');
702
703 In this case, we are basically taking the attribute which the role supplied 
704 and altering it within the bounds of this feature. 
705
706 Aside from where the attributes come from (one from superclass, the other 
707 from a role), this feature works exactly the same. This feature is restricted 
708 somewhat, so as to try and force at least I<some> sanity into it. You are only 
709 allowed to change the following attributes:
710
711 =over 4
712
713 =item I<default>
714
715 Change the default value of an attribute.
716
717 =item I<coerce>
718
719 Change whether the attribute attempts to coerce a value passed to it.
720
721 =item I<required>
722
723 Change if the attribute is required to have a value.
724
725 =item I<documentation>
726
727 Change the documentation string associated with the attribute.
728
729 =item I<lazy>
730
731 Change if the attribute lazily initializes the slot.
732
733 =item I<isa>
734
735 You I<are> allowed to change the type without restriction. 
736
737 It is recommended that you use this freedom with caution. We used to 
738 only allow for extension only if the type was a subtype of the parent's 
739 type, but we felt that was too restrictive and is better left as a 
740 policy decision. 
741
742 =item I<handles>
743
744 You are allowed to B<add> a new C<handles> definition, but you are B<not>
745 allowed to I<change> one.
746
747 =item I<builder>
748
749 You are allowed to B<add> a new C<builder> definition, but you are B<not>
750 allowed to I<change> one.
751
752 =item I<metaclass>
753
754 You are allowed to B<add> a new C<metaclass> definition, but you are
755 B<not> allowed to I<change> one.
756
757 =item I<traits>
758
759 You are allowed to B<add> additional traits to the C<traits> definition.
760 These traits will be composed into the attribute, but pre-existing traits
761 B<are not> overridden, or removed.
762
763 =back
764
765 =item B<before $name|@names =E<gt> sub { ... }>
766
767 =item B<after $name|@names =E<gt> sub { ... }>
768
769 =item B<around $name|@names =E<gt> sub { ... }>
770
771 This three items are syntactic sugar for the before, after, and around method
772 modifier features that L<Class::MOP> provides. More information on these may be
773 found in the L<Class::MOP::Class documentation|Class::MOP::Class/"Method
774 Modifiers"> for now.
775
776 =item B<super>
777
778 The keyword C<super> is a no-op when called outside of an C<override> method. In
779 the context of an C<override> method, it will call the next most appropriate
780 superclass method with the same arguments as the original method.
781
782 =item B<override ($name, &sub)>
783
784 An C<override> method is a way of explicitly saying "I am overriding this
785 method from my superclass". You can call C<super> within this method, and
786 it will work as expected. The same thing I<can> be accomplished with a normal
787 method call and the C<SUPER::> pseudo-package; it is really your choice.
788
789 =item B<inner>
790
791 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
792 an C<augment> method. You can think of C<inner> as being the inverse of
793 C<super>; the details of how C<inner> and C<augment> work is best described in
794 the L<Moose::Cookbook::Basics::Recipe6>.
795
796 =item B<augment ($name, &sub)>
797
798 An C<augment> method, is a way of explicitly saying "I am augmenting this
799 method from my superclass". Once again, the details of how C<inner> and
800 C<augment> work is best described in the L<Moose::Cookbook::Basics::Recipe6>.
801
802 =item B<confess>
803
804 This is the C<Carp::confess> function, and exported here because I use it
805 all the time. 
806
807 =item B<blessed>
808
809 This is the C<Scalar::Util::blessed> function, it is exported here because I
810 use it all the time. It is highly recommended that this is used instead of
811 C<ref> anywhere you need to test for an object's class name.
812
813 =back
814
815 =head1 METACLASS TRAITS
816
817 When you use Moose, you can also specify traits which will be applied
818 to your metaclass:
819
820     use Moose -traits => 'My::Trait';
821
822 This is very similar to the attribute traits feature. When you do
823 this, your class's C<meta> object will have the specified traits
824 applied to it. See L<TRAIT NAME RESOLUTION> for more details.
825
826 =head1 TRAIT NAME RESOLUTION
827
828 By default, when given a trait name, Moose simply tries to load a
829 class of the same name. If such a class does not exist, it then looks
830 for for a class matching
831 B<Moose::Meta::$type::Custom::Trait::$trait_name>. The C<$type>
832 variable here will be one of B<Attribute> or B<Class>, depending on
833 what the trait is being applied to.
834
835 If a class with this long name exists, Moose checks to see if it has
836 the method C<register_implementation>. This method is expected to
837 return the I<real> class name of the trait. If there is no
838 C<register_implementation> method, it will fall back to using
839 B<Moose::Meta::$type::Custom::Trait::$trait> as the trait name.
840
841 If all this is confusing, take a look at
842 L<Moose::Cookbook::Meta::Recipe3>, which demonstrates how to create an
843 attribute trait.
844
845 =head1 UNIMPORTING FUNCTIONS
846
847 =head2 B<unimport>
848
849 Moose offers a way to remove the keywords it exports, through the C<unimport>
850 method. You simply have to say C<no Moose> at the bottom of your code for this
851 to work. Here is an example:
852
853     package Person;
854     use Moose;
855
856     has 'first_name' => (is => 'rw', isa => 'Str');
857     has 'last_name'  => (is => 'rw', isa => 'Str');
858
859     sub full_name {
860         my $self = shift;
861         $self->first_name . ' ' . $self->last_name
862     }
863
864     no Moose; # keywords are removed from the Person package
865
866 =head1 EXTENDING AND EMBEDDING MOOSE
867
868 To learn more about extending Moose, we recommend checking out the
869 "Extending" recipes in the L<Moose::Cookbook>, starting with
870 L<Moose::Cookbook::Extending::Recipe1>, which provides an overview of
871 all the different ways you might extend Moose.
872
873 =head2 B<< Moose->init_meta(for_class => $class, base_class => $baseclass, metaclass => $metaclass) >>
874
875 The C<init_meta> method sets up the metaclass object for the class
876 specified by C<for_class>. This method injects a a C<meta> accessor
877 into the class so you can get at this object. It also sets the class's
878 superclass to C<base_class>, with L<Moose::Object> as the default.
879
880 You can specify an alternate metaclass with the C<metaclass> parameter.
881
882 For more detail on this topic, see L<Moose::Cookbook::Extending::Recipe2>.
883
884 This method used to be documented as a function which accepted
885 positional parameters. This calling style will still work for
886 backwards compatibility, but is deprecated.
887
888 =head2 B<import>
889
890 Moose's C<import> method supports the L<Sub::Exporter> form of C<{into =E<gt> $pkg}>
891 and C<{into_level =E<gt> 1}>.
892
893 B<NOTE>: Doing this is more or less deprecated. Use L<Moose::Exporter>
894 instead, which lets you stack multiple C<Moose.pm>-alike modules
895 sanely. It handles getting the exported functions into the right place
896 for you.
897
898 =head2 B<throw_error>
899
900 An alias for C<confess>, used by internally by Moose.
901
902 =head1 METACLASS COMPATIBILITY AND MOOSE
903
904 Metaclass compatibility is a thorny subject. You should start by
905 reading the "About Metaclass compatibility" section in the
906 C<Class::MOP> docs.
907
908 Moose will attempt to resolve a few cases of metaclass incompatibility
909 when you set the superclasses for a class, unlike C<Class::MOP>, which
910 simply dies if the metaclasses are incompatible.
911
912 In actuality, Moose fixes incompatibility for I<all> of a class's
913 metaclasses, not just the class metaclass. That includes the instance
914 metaclass, attribute metaclass, as well as its constructor class and
915 destructor class. However, for simplicity this discussion will just
916 refer to "metaclass", meaning the class metaclass, most of the time.
917
918 Moose has two algorithms for fixing metaclass incompatibility.
919
920 The first algorithm is very simple. If all the metaclass for the
921 parent is a I<subclass> of the child's metaclass, then we simply
922 replace the child's metaclass with the parent's.
923
924 The second algorithm is more complicated. It tries to determine if the
925 metaclasses only "differ by roles". This means that the parent and
926 child's metaclass share a common ancestor in their respective
927 hierarchies, and that the subclasses under the common ancestor are
928 only different because of role applications. This case is actually
929 fairly common when you mix and match various C<MooseX::*> modules,
930 many of which apply roles to the metaclass.
931
932 If the parent and child do differ by roles, Moose replaces the
933 metaclass in the child with a newly created metaclass. This metaclass
934 is a subclass of the parent's metaclass, does all of the roles that
935 the child's metaclass did before being replaced. Effectively, this
936 means the new metaclass does all of the roles done by both the
937 parent's and child's original metaclasses.
938
939 Ultimately, this is all transparent to you except in the case of an
940 unresolvable conflict.
941
942 =head2 The MooseX:: namespace
943
944 Generally if you're writing an extension I<for> Moose itself you'll want 
945 to put your extension in the C<MooseX::> namespace. This namespace is 
946 specifically for extensions that make Moose better or different in some 
947 fundamental way. It is traditionally B<not> for a package that just happens 
948 to use Moose. This namespace follows from the examples of the C<LWPx::> 
949 and C<DBIx::> namespaces that perform the same function for C<LWP> and C<DBI>
950 respectively.
951
952 =head1 CAVEATS
953
954 =over 4
955
956 =item *
957
958 It should be noted that C<super> and C<inner> B<cannot> be used in the same
959 method. However, they may be combined within the same class hierarchy; see
960 F<t/014_override_augment_inner_super.t> for an example.
961
962 The reason for this is that C<super> is only valid within a method
963 with the C<override> modifier, and C<inner> will never be valid within an
964 C<override> method. In fact, C<augment> will skip over any C<override> methods
965 when searching for its appropriate C<inner>.
966
967 This might seem like a restriction, but I am of the opinion that keeping these
968 two features separate (yet interoperable) actually makes them easy to use, since
969 their behavior is then easier to predict. Time will tell whether I am right or
970 not (UPDATE: so far so good).
971
972 =back
973
974 =head1 ACKNOWLEDGEMENTS
975
976 =over 4
977
978 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
979
980 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
981
982 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
983 and it certainly wouldn't have this name ;P
984
985 =item The basis of the TypeContraints module was Rob Kinyon's idea
986 originally, I just ran with it.
987
988 =item Thanks to mst & chansen and the whole #moose posse for all the
989 early ideas/feature-requests/encouragement/bug-finding.
990
991 =item Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
992
993 =back
994
995 =head1 SEE ALSO
996
997 =over 4
998
999 =item L<http://www.iinteractive.com/moose>
1000
1001 This is the official web home of Moose, it contains links to our public SVN repo
1002 as well as links to a number of talks and articles on Moose and Moose related
1003 technologies.
1004
1005 =item L<Moose::Cookbook> - How to cook a Moose
1006
1007 =item The Moose is flying, a tutorial by Randal Schwartz
1008
1009 Part 1 - L<http://www.stonehenge.com/merlyn/LinuxMag/col94.html>
1010
1011 Part 2 - L<http://www.stonehenge.com/merlyn/LinuxMag/col95.html>
1012
1013 =item L<Class::MOP> documentation
1014
1015 =item The #moose channel on irc.perl.org
1016
1017 =item The Moose mailing list - moose@perl.org
1018
1019 =item Moose stats on ohloh.net - L<http://www.ohloh.net/projects/moose>
1020
1021 =item Several Moose extension modules in the C<MooseX::> namespace.
1022
1023 See L<http://search.cpan.org/search?query=MooseX::> for extensions.
1024
1025 =back
1026
1027 =head2 Books
1028
1029 =over 4
1030
1031 =item The Art of the MetaObject Protocol
1032
1033 I mention this in the L<Class::MOP> docs too, this book was critical in 
1034 the development of both modules and is highly recommended.
1035
1036 =back
1037
1038 =head2 Papers
1039
1040 =over 4
1041
1042 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
1043
1044 This paper (suggested by lbr on #moose) was what lead to the implementation
1045 of the C<super>/C<override> and C<inner>/C<augment> features. If you really
1046 want to understand them, I suggest you read this.
1047
1048 =back
1049
1050 =head1 BUGS
1051
1052 All complex software has bugs lurking in it, and this module is no
1053 exception. If you find a bug please either email me, or add the bug
1054 to cpan-RT.
1055
1056 =head1 FEATURE REQUESTS
1057
1058 We are very strict about what features we add to the Moose core, especially 
1059 the user-visible features. Instead we have made sure that the underlying 
1060 meta-system of Moose is as extensible as possible so that you can add your 
1061 own features easily. That said, occasionally there is a feature needed in the 
1062 meta-system to support your planned extension, in which case you should 
1063 either email the mailing list or join us on irc at #moose to discuss.
1064
1065 =head1 AUTHOR
1066
1067 Moose is an open project, there are at this point dozens of people who have 
1068 contributed, and can contribute. If you have added anything to the Moose 
1069 project you have a commit bit on this file and can add your name to the list.
1070
1071 =head2 CABAL
1072
1073 However there are only a few people with the rights to release a new version 
1074 of Moose. The Moose Cabal are the people to go to with questions regarding
1075 the wider purview of Moose, and help out maintaining not just the code
1076 but the community as well.
1077
1078 Stevan (stevan) Little E<lt>stevan@iinteractive.comE<gt>
1079
1080 Yuval (nothingmuch) Kogman
1081
1082 Shawn (sartak) Moore
1083
1084 Dave (autarch) Rolsky E<lt>autarch@urth.orgE<gt>
1085
1086 =head2 OTHER CONTRIBUTORS
1087
1088 Aankhen
1089
1090 Adam (Alias) Kennedy
1091
1092 Anders (Debolaz) Nor Berle
1093
1094 Nathan (kolibre) Gray
1095
1096 Christian (chansen) Hansen
1097
1098 Hans Dieter (confound) Pearcey
1099
1100 Eric (ewilhelm) Wilhelm
1101
1102 Guillermo (groditi) Roditi
1103
1104 Jess (castaway) Robinson
1105
1106 Matt (mst) Trout
1107
1108 Robert (phaylon) Sedlacek
1109
1110 Robert (rlb3) Boone
1111
1112 Scott (konobi) McWhirter
1113
1114 Shlomi (rindolf) Fish
1115
1116 Chris (perigrin) Prather
1117
1118 Wallace (wreis) Reis
1119
1120 Jonathan (jrockway) Rockway
1121
1122 Piotr (dexter) Roszatycki
1123
1124 Sam (mugwump) Vilain
1125
1126 Cory (gphat) Watson
1127
1128 ... and many other #moose folks
1129
1130 =head1 COPYRIGHT AND LICENSE
1131
1132 Copyright 2006-2008 by Infinity Interactive, Inc.
1133
1134 L<http://www.iinteractive.com>
1135
1136 This library is free software; you can redistribute it and/or modify
1137 it under the same terms as Perl itself.
1138
1139 =cut