lib/Moose/Util.pm

   1 package Moose::Util;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Sub::Exporter;
   7 use Scalar::Util 'blessed';
   8 use Carp         'confess';
   9 use Class::MOP   ();
  10
  11 our $VERSION   = '0.03';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 my @exports = qw[
  15     find_meta
  16     does_role
  17     search_class_by_role
  18     apply_all_roles
  19     get_all_init_args
  20     get_all_attribute_values
  21 ];
  22
  23 Sub::Exporter::setup_exporter({
  24     exports => \@exports,
  25     groups  => { all => \@exports }
  26 });
  27
  28 ## some utils for the utils ...
  29
  30 sub find_meta {
  31     return unless $_[0];
  32     return Class::MOP::get_metaclass_by_name(blessed($_[0]) || $_[0]);
  33 }
  34
  35 ## the functions ...
  36
  37 sub does_role {
  38     my ($class_or_obj, $role) = @_;
  39
  40     my $meta = find_meta($class_or_obj);
  41
  42     return unless defined $meta;
  43
  44     return 1 if $meta->does_role($role);
  45     return;
  46 }
  47
  48 sub search_class_by_role {
  49     my ($class_or_obj, $role_name) = @_;
  50
  51     my $meta = find_meta($class_or_obj);
  52
  53     return unless defined $meta;
  54
  55     foreach my $class ($meta->class_precedence_list) {
  56
  57         my $_meta = find_meta($class);
  58
  59         next unless defined $_meta;
  60
  61         foreach my $role (@{ $_meta->roles || [] }) {
  62             return $class if $role->name eq $role_name;
  63         }
  64     }
  65
  66     return;
  67 }
  68
  69 sub apply_all_roles {
  70     my $applicant = shift;
  71
  72     confess "Must specify at least one role to apply to $applicant" unless @_;
  73
  74     my $roles = Data::OptList::mkopt([ @_ ]);
  75
  76     #use Data::Dumper;
  77     #warn Dumper $roles;
  78
  79     my $meta = (blessed $applicant ? $applicant : find_meta($applicant));
  80
  81     Class::MOP::load_class($_->[0]) for @$roles;
  82
  83     ($_->[0]->can('meta') && $_->[0]->meta->isa('Moose::Meta::Role'))
  84         || confess "You can only consume roles, " . $_->[0] . " is not a Moose role"
  85             foreach @$roles;
  86
  87     if (scalar @$roles == 1) {
  88         my ($role, $params) = @{$roles->[0]};
  89         $role->meta->apply($meta, (defined $params ? %$params : ()));
  90     }
  91     else {
  92         Moose::Meta::Role->combine(
  93             @$roles
  94         )->apply($meta);
  95     }
  96 }
  97
  98 # instance deconstruction ...
  99
 100 sub get_all_attribute_values {
 101     my ($class, $instance) = @_;
 102     return +{
 103         map { $_->name => $_->get_value($instance) }
 104             grep { $_->has_value($instance) }
 105                 $class->compute_all_applicable_attributes
 106     };
 107 }
 108
 109 sub get_all_init_args {
 110     my ($class, $instance) = @_;
 111     return +{
 112         map { $_->init_arg => $_->get_value($instance) }
 113             grep { $_->has_value($instance) }
 114                 grep { defined($_->init_arg) }
 115                     $class->compute_all_applicable_attributes
 116     };
 117 }
 118
 119
 120 1;
 121
 122 __END__
 123
 124 =pod
 125
 126 =head1 NAME
 127
 128 Moose::Util - Utilities for working with Moose classes
 129
 130 =head1 SYNOPSIS
 131
 132   use Moose::Util qw/find_meta does_role search_class_by_role/;
 133
 134   my $meta = find_meta($object) || die "No metaclass found";
 135
 136   if (does_role($object, $role)) {
 137     print "The object can do $role!\n";
 138   }
 139
 140   my $class = search_class_by_role($object, 'FooRole');
 141   print "Nearest class with 'FooRole' is $class\n";
 142
 143 =head1 DESCRIPTION
 144
 145 This is a set of utility functions to help working with Moose classes. This
 146 is an experimental module, and it's not 100% clear what purpose it will serve.
 147 That said, ideas, suggestions and contributions to this collection are most
 148 welcome. See the L<TODO> section below for a list of ideas for possible
 149 functions to write.
 150
 151 =head1 EXPORTED FUNCTIONS
 152
 153 =over 4
 154
 155 =item B<find_meta ($class_or_obj)>
 156
 157 This will attempt to locate a metaclass for the given C<$class_or_obj>
 158 and return it.
 159
 160 =item B<does_role ($class_or_obj, $role_name)>
 161
 162 Returns true if C<$class_or_obj> can do the role C<$role_name>.
 163
 164 =item B<search_class_by_role ($class_or_obj, $role_name)>
 165
 166 Returns first class in precedence list that consumed C<$role_name>.
 167
 168 =item B<apply_all_roles ($applicant, @roles)>
 169
 170 Given an C<$applicant> (which can somehow be turned into either a
 171 metaclass or a metarole) and a list of C<@roles> this will do the
 172 right thing to apply the C<@roles> to the C<$applicant>. This is
 173 actually used internally by both L<Moose> and L<Moose::Role>, and the
 174 C<@roles> will be pre-processed through L<Data::OptList::mkopt>
 175 to allow for the additional arguments to be passed.
 176
 177 =item B<get_all_attribute_values($meta, $instance)>
 178
 179 Returns the values of the C<$instance>'s fields keyed by the attribute names.
 180
 181 =item B<get_all_init_args($meta, $instance)>
 182
 183 Returns a hash reference where the keys are all the attributes' C<init_arg>s
 184 and the values are the instance's fields. Attributes without an C<init_arg>
 185 will be skipped.
 186
 187 =back
 188
 189 =head1 TODO
 190
 191 Here is a list of possible functions to write
 192
 193 =over 4
 194
 195 =item discovering original method from modified method
 196
 197 =item search for origin class of a method or attribute
 198
 199 =back
 200
 201 =head1 BUGS
 202
 203 All complex software has bugs lurking in it, and this module is no
 204 exception. If you find a bug please either email me, or add the bug
 205 to cpan-RT.
 206
 207 =head1 AUTHOR
 208
 209 Anders Nor Berle E<lt>debolaz@gmail.comE<gt>
 210
 211 B<with contributions from:>
 212
 213 Robert (phaylon) Sedlacek
 214
 215 Stevan Little
 216
 217 =head1 COPYRIGHT AND LICENSE
 218
 219 Copyright 2007-2008 by Infinity Interactive, Inc.
 220
 221 L<http://www.iinteractive.com>
 222
 223 This library is free software; you can redistribute it and/or modify
 224 it under the same terms as Perl itself.
 225
 226 =cut
 227