lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.65';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type maybe_type
  51             as where message optimize_as
  52             coerce from via
  53             enum
  54             find_type_constraint
  55             register_type_constraint )
  56     ],
  57     _export_to_main => 1,
  58 );
  59
  60 ## --------------------------------------------------------
  61 ## type registry and some useful functions for it
  62 ## --------------------------------------------------------
  63
  64 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  65
  66 sub get_type_constraint_registry         { $REGISTRY }
  67 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  68 sub export_type_constraints_as_functions {
  69     my $pkg = caller();
  70     no strict 'refs';
  71     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  72         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  73         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  74     }
  75 }
  76
  77 sub create_type_constraint_union {
  78     my @type_constraint_names;
  79
  80     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  81         @type_constraint_names = _parse_type_constraint_union($_[0]);
  82     }
  83     else {
  84         @type_constraint_names = @_;
  85     }
  86
  87     (scalar @type_constraint_names >= 2)
  88         || Moose->throw_error("You must pass in at least 2 type names to make a union");
  89
  90     my @type_constraints = map {
  91         find_or_parse_type_constraint($_) ||
  92          Moose->throw_error("Could not locate type constraint ($_) for the union");
  93     } @type_constraint_names;
  94
  95     return Moose::Meta::TypeConstraint::Union->new(
  96         type_constraints => \@type_constraints
  97     );
  98 }
  99
 100 sub create_parameterized_type_constraint {
 101     my $type_constraint_name = shift;
 102     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 103
 104     (defined $base_type && defined $type_parameter)
 105         || Moose->throw_error("Could not parse type name ($type_constraint_name) correctly");
 106
 107     if ($REGISTRY->has_type_constraint($base_type)) {
 108         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 109         return _create_parameterized_type_constraint(
 110             $base_type_tc,
 111             $type_parameter
 112         );
 113     } else {
 114         Moose->throw_error("Could not locate the base type ($base_type)");
 115     }
 116 }
 117
 118 sub _create_parameterized_type_constraint {
 119     my ( $base_type_tc, $type_parameter ) = @_;
 120     if ( $base_type_tc->can('parameterize') ) {
 121         return $base_type_tc->parameterize($type_parameter);
 122     } else {
 123         return Moose::Meta::TypeConstraint::Parameterized->new(
 124             name => $base_type_tc->name . '[' . $type_parameter . ']',
 125             parent => $base_type_tc,
 126             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 127         );
 128     }
 129 }
 130
 131 #should we also support optimized checks?
 132 sub create_class_type_constraint {
 133     my ( $class, $options ) = @_;
 134
 135     # too early for this check
 136     #find_type_constraint("ClassName")->check($class)
 137     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 138
 139     my %options = (
 140         class => $class,
 141         name  => $class,
 142         %{ $options || {} },
 143     );
 144
 145     $options{name} ||= "__ANON__";
 146
 147     Moose::Meta::TypeConstraint::Class->new( %options );
 148 }
 149
 150 sub create_role_type_constraint {
 151     my ( $role, $options ) = @_;
 152
 153     # too early for this check
 154     #find_type_constraint("ClassName")->check($class)
 155     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 156
 157     my %options = (
 158         role => $role,
 159         name => $role,
 160         %{ $options || {} },
 161     );
 162
 163     $options{name} ||= "__ANON__";
 164
 165     Moose::Meta::TypeConstraint::Role->new( %options );
 166 }
 167
 168
 169 sub find_or_create_type_constraint {
 170     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 171
 172     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 173         return $constraint;
 174     }
 175     elsif ( defined $options_for_anon_type ) {
 176         # NOTE:
 177         # if there is no $options_for_anon_type
 178         # specified, then we assume they don't
 179         # want to create one, and return nothing.
 180
 181         # otherwise assume that we should create
 182         # an ANON type with the $options_for_anon_type
 183         # options which can be passed in. It should
 184         # be noted that these don't get registered
 185         # so we need to return it.
 186         # - SL
 187         return Moose::Meta::TypeConstraint->new(
 188             name => '__ANON__',
 189             %{$options_for_anon_type}
 190         );
 191     }
 192
 193     return;
 194 }
 195
 196 sub find_or_create_isa_type_constraint {
 197     my $type_constraint_name = shift;
 198     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 199 }
 200
 201 sub find_or_create_does_type_constraint {
 202     my $type_constraint_name = shift;
 203     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 204 }
 205
 206 sub find_or_parse_type_constraint {
 207     my $type_constraint_name = normalize_type_constraint_name(shift);
 208     my $constraint;
 209
 210     if ($constraint = find_type_constraint($type_constraint_name)) {
 211         return $constraint;
 212     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 213         $constraint = create_type_constraint_union($type_constraint_name);
 214     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 215         $constraint = create_parameterized_type_constraint($type_constraint_name);
 216     } else {
 217         return;
 218     }
 219
 220     $REGISTRY->add_type_constraint($constraint);
 221     return $constraint;
 222 }
 223
 224 sub normalize_type_constraint_name {
 225     my $type_constraint_name = shift;
 226     $type_constraint_name =~ s/\s//g;
 227     return $type_constraint_name;
 228 }
 229
 230 sub _confess {
 231     my $error = shift;
 232
 233     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 234     Carp::confess($error);
 235 }
 236
 237 ## --------------------------------------------------------
 238 ## exported functions ...
 239 ## --------------------------------------------------------
 240
 241 sub find_type_constraint {
 242     my $type = shift;
 243
 244     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 245         return $type;
 246     }
 247     else {
 248         return unless $REGISTRY->has_type_constraint($type);
 249         return $REGISTRY->get_type_constraint($type);
 250     }
 251 }
 252
 253 sub register_type_constraint {
 254     my $constraint = shift;
 255     Moose->throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 256     $REGISTRY->add_type_constraint($constraint);
 257     return $constraint;
 258 }
 259
 260 # type constructors
 261
 262 sub type {
 263     splice(@_, 1, 0, undef);
 264     goto &_create_type_constraint;
 265 }
 266
 267 sub subtype {
 268     # NOTE:
 269     # this adds an undef for the name
 270     # if this is an anon-subtype:
 271     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 272     #     or
 273     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 274     #
 275     # but if the last arg is not a code ref then it is a subtype
 276     # alias:
 277     #
 278     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 279     # ... yeah I know it's ugly code
 280     # - SL
 281     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 282     unshift @_ => undef
 283         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 284     goto &_create_type_constraint;
 285 }
 286
 287 sub class_type {
 288     register_type_constraint(
 289         create_class_type_constraint(
 290             $_[0],
 291             ( defined($_[1]) ? $_[1] : () ),
 292         )
 293     );
 294 }
 295
 296 sub role_type ($;$) {
 297     register_type_constraint(
 298         create_role_type_constraint(
 299             $_[0],
 300             ( defined($_[1]) ? $_[1] : () ),
 301         )
 302     );
 303 }
 304
 305 sub maybe_type {
 306     my ($type_parameter) = @_;
 307
 308     register_type_constraint(
 309         $REGISTRY->get_type_constraint('Maybe')->parameterize($type_parameter)
 310     );
 311 }
 312
 313 sub coerce {
 314     my ($type_name, @coercion_map) = @_;
 315     _install_type_coercions($type_name, \@coercion_map);
 316 }
 317
 318 sub as          { @_ }
 319 sub from        { @_ }
 320 sub where   (&) { $_[0] }
 321 sub via     (&) { $_[0] }
 322
 323 sub message     (&) { +{ message   => $_[0] } }
 324 sub optimize_as (&) { +{ optimized => $_[0] } }
 325
 326 sub enum {
 327     my ($type_name, @values) = @_;
 328     # NOTE:
 329     # if only an array-ref is passed then
 330     # you get an anon-enum
 331     # - SL
 332     if (ref $type_name eq 'ARRAY' && !@values) {
 333         @values    = @$type_name;
 334         $type_name = undef;
 335     }
 336     (scalar @values >= 2)
 337         || Moose->throw_error("You must have at least two values to enumerate through");
 338     my %valid = map { $_ => 1 } @values;
 339
 340     register_type_constraint(
 341         create_enum_type_constraint(
 342             $type_name,
 343             \@values,
 344         )
 345     );
 346 }
 347
 348 sub create_enum_type_constraint {
 349     my ( $type_name, $values ) = @_;
 350
 351     Moose::Meta::TypeConstraint::Enum->new(
 352         name   => $type_name || '__ANON__',
 353         values => $values,
 354     );
 355 }
 356
 357 ## --------------------------------------------------------
 358 ## desugaring functions ...
 359 ## --------------------------------------------------------
 360
 361 sub _create_type_constraint ($$$;$$) {
 362     my $name   = shift;
 363     my $parent = shift;
 364     my $check  = shift;
 365
 366     my ( $message, $optimized );
 367     for (@_) {
 368         $message   = $_->{message}   if exists $_->{message};
 369         $optimized = $_->{optimized} if exists $_->{optimized};
 370     }
 371
 372     my $pkg_defined_in = scalar( caller(0) );
 373
 374     if ( defined $name ) {
 375         my $type = $REGISTRY->get_type_constraint($name);
 376
 377         ( $type->_package_defined_in eq $pkg_defined_in )
 378             || _confess(
 379                   "The type constraint '$name' has already been created in "
 380                 . $type->_package_defined_in
 381                 . " and cannot be created again in "
 382                 . $pkg_defined_in )
 383             if defined $type;
 384     }
 385
 386     my %opts = (
 387         name => $name,
 388         package_defined_in => $pkg_defined_in,
 389
 390         ( $check     ? ( constraint => $check )     : () ),
 391         ( $message   ? ( message    => $message )   : () ),
 392         ( $optimized ? ( optimized  => $optimized ) : () ),
 393     );
 394
 395     my $constraint;
 396     if ( defined $parent
 397         and $parent
 398         = blessed $parent ? $parent : find_or_create_isa_type_constraint($parent) )
 399     {
 400         $constraint = $parent->create_child_type(%opts);
 401     }
 402     else {
 403         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 404     }
 405
 406     $REGISTRY->add_type_constraint($constraint)
 407         if defined $name;
 408
 409     return $constraint;
 410 }
 411
 412 sub _install_type_coercions ($$) {
 413     my ($type_name, $coercion_map) = @_;
 414     my $type = find_type_constraint($type_name);
 415     (defined $type)
 416         || Moose->throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 417     if ($type->has_coercion) {
 418         $type->coercion->add_type_coercions(@$coercion_map);
 419     }
 420     else {
 421         my $type_coercion = Moose::Meta::TypeCoercion->new(
 422             type_coercion_map => $coercion_map,
 423             type_constraint   => $type
 424         );
 425         $type->coercion($type_coercion);
 426     }
 427 }
 428
 429 ## --------------------------------------------------------
 430 ## type notation parsing ...
 431 ## --------------------------------------------------------
 432
 433 {
 434     # All I have to say is mugwump++ cause I know
 435     # do not even have enough regexp-fu to be able
 436     # to have written this (I can only barely
 437     # understand it as it is)
 438     # - SL
 439
 440     use re "eval";
 441
 442     my $valid_chars = qr{[\w:]};
 443     my $type_atom   = qr{ $valid_chars+ };
 444
 445     my $any;
 446
 447     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 448     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 449     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 450
 451     my $op_union = qr{ \s* \| \s* }x;
 452     my $union    = qr{ $type (?: $op_union $type )+ }x;
 453
 454     $any = qr{ $type | $union }x;
 455
 456     sub _parse_parameterized_type_constraint {
 457         { no warnings 'void'; $any; } # force capture of interpolated lexical
 458         $_[0] =~ m{ $type_capture_parts }x;
 459         return ($1, $2);
 460     }
 461
 462     sub _detect_parameterized_type_constraint {
 463         { no warnings 'void'; $any; } # force capture of interpolated lexical
 464         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 465     }
 466
 467     sub _parse_type_constraint_union {
 468         { no warnings 'void'; $any; } # force capture of interpolated lexical
 469         my $given = shift;
 470         my @rv;
 471         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 472             push @rv => $1;
 473         }
 474         (pos($given) eq length($given))
 475             || Moose->throw_error("'$given' didn't parse (parse-pos="
 476                      . pos($given)
 477                      . " and str-length="
 478                      . length($given)
 479                      . ")");
 480         @rv;
 481     }
 482
 483     sub _detect_type_constraint_union {
 484         { no warnings 'void'; $any; } # force capture of interpolated lexical
 485         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 486     }
 487 }
 488
 489 ## --------------------------------------------------------
 490 # define some basic built-in types
 491 ## --------------------------------------------------------
 492
 493 # By making these classes immutable before creating all the types we
 494 # below, we avoid repeatedly calling the slow MOP-based accessors.
 495 $_->make_immutable(
 496     inline_constructor => 1,
 497     constructor_name   => "_new",
 498
 499     # these are Class::MOP accessors, so they need inlining
 500     inline_accessors => 1
 501     ) for grep { $_->is_mutable }
 502     map { $_->meta }
 503     qw(
 504     Moose::Meta::TypeConstraint
 505     Moose::Meta::TypeConstraint::Union
 506     Moose::Meta::TypeConstraint::Parameterized
 507     Moose::Meta::TypeConstraint::Parameterizable
 508     Moose::Meta::TypeConstraint::Class
 509     Moose::Meta::TypeConstraint::Role
 510     Moose::Meta::TypeConstraint::Enum
 511     Moose::Meta::TypeConstraint::Registry
 512 );
 513
 514 type 'Any'  => where { 1 }; # meta-type including all
 515 type 'Item' => where { 1 }; # base-type
 516
 517 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 518 subtype 'Defined' => as 'Item' => where {  defined($_) };
 519
 520 subtype 'Bool'
 521     => as 'Item'
 522     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 523
 524 subtype 'Value'
 525     => as 'Defined'
 526     => where { !ref($_) }
 527     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 528
 529 subtype 'Ref'
 530     => as 'Defined'
 531     => where {  ref($_) }
 532     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 533
 534 subtype 'Str'
 535     => as 'Value'
 536     => where { 1 }
 537     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 538
 539 subtype 'Num'
 540     => as 'Value'
 541     => where { Scalar::Util::looks_like_number($_) }
 542     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 543
 544 subtype 'Int'
 545     => as 'Num'
 546     => where { "$_" =~ /^-?[0-9]+$/ }
 547     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 548
 549 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 550 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 551 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 552 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 553
 554 # NOTE:
 555 # scalar filehandles are GLOB refs,
 556 # but a GLOB ref is not always a filehandle
 557 subtype 'FileHandle'
 558     => as 'GlobRef'
 559     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 560     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 561
 562 # NOTE:
 563 # blessed(qr/.../) returns true,.. how odd
 564 subtype 'Object'
 565     => as 'Ref'
 566     => where { blessed($_) && blessed($_) ne 'Regexp' }
 567     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 568
 569 subtype 'Role'
 570     => as 'Object'
 571     => where { $_->can('does') }
 572     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 573
 574 my $_class_name_checker = sub {
 575 };
 576
 577 subtype 'ClassName'
 578     => as 'Str'
 579     => where { Class::MOP::is_class_loaded($_) }
 580     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 581
 582 ## --------------------------------------------------------
 583 # parameterizable types ...
 584
 585 $REGISTRY->add_type_constraint(
 586     Moose::Meta::TypeConstraint::Parameterizable->new(
 587         name                 => 'ArrayRef',
 588         package_defined_in   => __PACKAGE__,
 589         parent               => find_type_constraint('Ref'),
 590         constraint           => sub { ref($_) eq 'ARRAY'  },
 591         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 592         constraint_generator => sub {
 593             my $type_parameter = shift;
 594             my $check = $type_parameter->_compiled_type_constraint;
 595             return sub {
 596                 foreach my $x (@$_) {
 597                     ($check->($x)) || return
 598                 } 1;
 599             }
 600         }
 601     )
 602 );
 603
 604 $REGISTRY->add_type_constraint(
 605     Moose::Meta::TypeConstraint::Parameterizable->new(
 606         name                 => 'HashRef',
 607         package_defined_in   => __PACKAGE__,
 608         parent               => find_type_constraint('Ref'),
 609         constraint           => sub { ref($_) eq 'HASH'  },
 610         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 611         constraint_generator => sub {
 612             my $type_parameter = shift;
 613             my $check = $type_parameter->_compiled_type_constraint;
 614             return sub {
 615                 foreach my $x (values %$_) {
 616                     ($check->($x)) || return
 617                 } 1;
 618             }
 619         }
 620     )
 621 );
 622
 623 $REGISTRY->add_type_constraint(
 624     Moose::Meta::TypeConstraint::Parameterizable->new(
 625         name                 => 'Maybe',
 626         package_defined_in   => __PACKAGE__,
 627         parent               => find_type_constraint('Item'),
 628         constraint           => sub { 1 },
 629         constraint_generator => sub {
 630             my $type_parameter = shift;
 631             my $check = $type_parameter->_compiled_type_constraint;
 632             return sub {
 633                 return 1 if not(defined($_)) || $check->($_);
 634                 return;
 635             }
 636         }
 637     )
 638 );
 639
 640 my @PARAMETERIZABLE_TYPES = map {
 641     $REGISTRY->get_type_constraint($_)
 642 } qw[ArrayRef HashRef Maybe];
 643
 644 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 645 sub add_parameterizable_type {
 646     my $type = shift;
 647     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 648         || Moose->throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 649     push @PARAMETERIZABLE_TYPES => $type;
 650 }
 651
 652 ## --------------------------------------------------------
 653 # end of built-in types ...
 654 ## --------------------------------------------------------
 655
 656 {
 657     my @BUILTINS = list_all_type_constraints();
 658     sub list_all_builtin_type_constraints { @BUILTINS }
 659 }
 660
 661 1;
 662
 663 __END__
 664
 665 =pod
 666
 667 =head1 NAME
 668
 669 Moose::Util::TypeConstraints - Type constraint system for Moose
 670
 671 =head1 SYNOPSIS
 672
 673   use Moose::Util::TypeConstraints;
 674
 675   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 676
 677   subtype 'Natural'
 678       => as 'Int'
 679       => where { $_ > 0 };
 680
 681   subtype 'NaturalLessThanTen'
 682       => as 'Natural'
 683       => where { $_ < 10 }
 684       => message { "This number ($_) is not less than ten!" };
 685
 686   coerce 'Num'
 687       => from 'Str'
 688         => via { 0+$_ };
 689
 690   enum 'RGBColors' => qw(red green blue);
 691
 692 =head1 DESCRIPTION
 693
 694 This module provides Moose with the ability to create custom type
 695 contraints to be used in attribute definition.
 696
 697 =head2 Important Caveat
 698
 699 This is B<NOT> a type system for Perl 5. These are type constraints,
 700 and they are not used by Moose unless you tell it to. No type
 701 inference is performed, expression are not typed, etc. etc. etc.
 702
 703 This is simply a means of creating small constraint functions which
 704 can be used to simplify your own type-checking code, with the added
 705 side benefit of making your intentions clearer through self-documentation.
 706
 707 =head2 Slightly Less Important Caveat
 708
 709 It is B<always> a good idea to quote your type and subtype names.
 710
 711 This is to prevent perl from trying to execute the call as an indirect
 712 object call. This issue only seems to come up when you have a subtype
 713 the same name as a valid class, but when the issue does arise it tends
 714 to be quite annoying to debug.
 715
 716 So for instance, this:
 717
 718   subtype DateTime => as Object => where { $_->isa('DateTime') };
 719
 720 will I<Just Work>, while this:
 721
 722   use DateTime;
 723   subtype DateTime => as Object => where { $_->isa('DateTime') };
 724
 725 will fail silently and cause many headaches. The simple way to solve
 726 this, as well as future proof your subtypes from classes which have
 727 yet to have been created yet, is to simply do this:
 728
 729   use DateTime;
 730   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 731
 732 =head2 Default Type Constraints
 733
 734 This module also provides a simple hierarchy for Perl 5 types, here is
 735 that hierarchy represented visually.
 736
 737   Any
 738   Item
 739       Bool
 740       Maybe[`a]
 741       Undef
 742       Defined
 743           Value
 744               Num
 745                 Int
 746               Str
 747                 ClassName
 748           Ref
 749               ScalarRef
 750               ArrayRef[`a]
 751               HashRef[`a]
 752               CodeRef
 753               RegexpRef
 754               GlobRef
 755                 FileHandle
 756               Object
 757                 Role
 758
 759 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 760 parameterized, this means you can say:
 761
 762   ArrayRef[Int]    # an array of integers
 763   HashRef[CodeRef] # a hash of str to CODE ref mappings
 764   Maybe[Str]       # value may be a string, may be undefined
 765
 766 If Moose finds a name in brackets that it does not recognize as an
 767 existing type, it assumes that this is a class name, for example
 768 C<ArrayRef[DateTime]>.
 769
 770 B<NOTE:> Unless you parameterize a type, then it is invalid to
 771 include the square brackets. I.e. C<ArrayRef[]> will be
 772 literally interpreted as a type name.
 773
 774 B<NOTE:> The C<Undef> type constraint for the most part works
 775 correctly now, but edge cases may still exist, please use it
 776 sparringly.
 777
 778 B<NOTE:> The C<ClassName> type constraint does a complex package
 779 existence check. This means that your class B<must> be loaded for
 780 this type constraint to pass. I know this is not ideal for all,
 781 but it is a saner restriction than most others.
 782
 783 =head2 Type Constraint Naming
 784
 785 Since the types created by this module are global, it is suggested
 786 that you namespace your types just as you would namespace your
 787 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 788 module, you would call the type I<My::Graphics::Color> instead.
 789
 790 =head2 Use with Other Constraint Modules
 791
 792 This module should play fairly nicely with other constraint
 793 modules with only some slight tweaking. The C<where> clause
 794 in types is expected to be a C<CODE> reference which checks
 795 it's first argument and returns a boolean. Since most constraint
 796 modules work in a similar way, it should be simple to adapt
 797 them to work with Moose.
 798
 799 For instance, this is how you could use it with
 800 L<Declare::Constraints::Simple> to declare a completely new type.
 801
 802   type 'HashOfArrayOfObjects'
 803       => IsHashRef(
 804           -keys   => HasLength,
 805           -values => IsArrayRef( IsObject ));
 806
 807 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 808 test file.
 809
 810 Here is an example of using L<Test::Deep> and it's non-test
 811 related C<eq_deeply> function.
 812
 813   type 'ArrayOfHashOfBarsAndRandomNumbers'
 814       => where {
 815           eq_deeply($_,
 816               array_each(subhashof({
 817                   bar           => isa('Bar'),
 818                   random_number => ignore()
 819               })))
 820         };
 821
 822 For a complete example see the
 823 F<t/200_examples/205_example_w_TestDeep.t> test file.
 824
 825 =head1 FUNCTIONS
 826
 827 =head2 Type Constraint Constructors
 828
 829 The following functions are used to create type constraints.
 830 They will then register the type constraints in a global store
 831 where Moose can get to them if it needs to.
 832
 833 See the L<SYNOPSIS> for an example of how to use these.
 834
 835 =over 4
 836
 837 =item B<type ($name, $where_clause)>
 838
 839 This creates a base type, which has no parent.
 840
 841 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 842
 843 This creates a named subtype.
 844
 845 If you provide a parent that Moose does not recognize, it will
 846 automatically create a new class type constraint for this name.
 847
 848 =item B<subtype ($parent, $where_clause, ?$message)>
 849
 850 This creates an unnamed subtype and will return the type
 851 constraint meta-object, which will be an instance of
 852 L<Moose::Meta::TypeConstraint>.
 853
 854 =item B<class_type ($class, ?$options)>
 855
 856 Creates a type constraint with the name C<$class> and the metaclass
 857 L<Moose::Meta::TypeConstraint::Class>.
 858
 859 =item B<role_type ($role, ?$options)>
 860
 861 Creates a type constraint with the name C<$role> and the metaclass
 862 L<Moose::Meta::TypeConstraint::Role>.
 863
 864 =item B<maybe_type ($type)>
 865
 866 Creates a type constraint for either C<undef> or something of the
 867 given type.
 868
 869 =item B<enum ($name, @values)>
 870
 871 This will create a basic subtype for a given set of strings.
 872 The resulting constraint will be a subtype of C<Str> and
 873 will match any of the items in C<@values>. It is case sensitive.
 874 See the L<SYNOPSIS> for a simple example.
 875
 876 B<NOTE:> This is not a true proper enum type, it is simple
 877 a convient constraint builder.
 878
 879 =item B<enum (\@values)>
 880
 881 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 882 this will create an unnamed enum. This can then be used in an attribute
 883 definition like so:
 884
 885   has 'sort_order' => (
 886       is  => 'ro',
 887       isa => enum([qw[ ascending descending ]]),
 888   );
 889
 890 =item B<as>
 891
 892 This is just sugar for the type constraint construction syntax.
 893
 894 =item B<where>
 895
 896 This is just sugar for the type constraint construction syntax.
 897
 898 Takes a block/code ref as an argument. When the type constraint is
 899 tested, the supplied code is run with the value to be tested in
 900 $_. This block should return true or false to indicate whether or not
 901 the constraint check passed.
 902
 903 =item B<message>
 904
 905 This is just sugar for the type constraint construction syntax.
 906
 907 Takes a block/code ref as an argument. When the type constraint fails,
 908 then the code block is run (with the value provided in $_). This code
 909 ref should return a string, which will be used in the text of the
 910 exception thrown.
 911
 912 =item B<optimize_as>
 913
 914 This can be used to define a "hand optimized" version of your
 915 type constraint which can be used to avoid traversing a subtype
 916 constraint heirarchy.
 917
 918 B<NOTE:> You should only use this if you know what you are doing,
 919 all the built in types use this, so your subtypes (assuming they
 920 are shallow) will not likely need to use this.
 921
 922 =back
 923
 924 =head2 Type Coercion Constructors
 925
 926 Type constraints can also contain type coercions as well. If you
 927 ask your accessor to coerce, then Moose will run the type-coercion
 928 code first, followed by the type constraint check. This feature
 929 should be used carefully as it is very powerful and could easily
 930 take off a limb if you are not careful.
 931
 932 See the L<SYNOPSIS> for an example of how to use these.
 933
 934 =over 4
 935
 936 =item B<coerce>
 937
 938 =item B<from>
 939
 940 This is just sugar for the type coercion construction syntax.
 941
 942 =item B<via>
 943
 944 This is just sugar for the type coercion construction syntax.
 945
 946 =back
 947
 948 =head2 Type Constraint Construction & Locating
 949
 950 =over 4
 951
 952 =item B<normalize_type_constraint_name ($type_constraint_name)>
 953
 954 Given a string that is expected to match a type constraint, will normalize the
 955 string so that extra whitespace and newlines are removed.
 956
 957 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 958
 959 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 960 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 961
 962 =item B<create_parameterized_type_constraint ($type_name)>
 963
 964 Given a C<$type_name> in the form of:
 965
 966   BaseType[ContainerType]
 967
 968 this will extract the base type and container type and build an instance of
 969 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 970
 971 =item B<create_class_type_constraint ($class, ?$options)>
 972
 973 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 974 object for that class name.
 975
 976 =item B<create_role_type_constraint ($role, ?$options)>
 977
 978 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 979 object for that role name.
 980
 981 =item B<create_enum_type_constraint ($name, $values)>
 982
 983 =item B<find_or_parse_type_constraint ($type_name)>
 984
 985 This will attempt to find or create a type constraint given the a C<$type_name>.
 986 If it cannot find it in the registry, it will see if it should be a union or
 987 container type an create one if appropriate
 988
 989 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 990
 991 This function will first call C<find_or_parse_type_constraint> with the type name.
 992
 993 If no type is found or created, but C<$options_for_anon_type> are provided, it
 994 will create the corresponding type.
 995
 996 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 997 and are now superseded by C<find_or_create_isa_type_constraint> and
 998 C<find_or_create_does_type_constraint>.
 999
1000 =item B<find_or_create_isa_type_constraint ($type_name)>
1001
1002 =item B<find_or_create_does_type_constraint ($type_name)>
1003
1004 Attempts to parse the type name using C<find_or_parse_type_constraint> and if
1005 no appropriate constraint is found will create a new anonymous one.
1006
1007 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
1008 variant will use C<create_role_type_constraint>.
1009
1010 =item B<find_type_constraint ($type_name)>
1011
1012 This function can be used to locate a specific type constraint
1013 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
1014 derivative. What you do with it from there is up to you :)
1015
1016 =item B<register_type_constraint ($type_object)>
1017
1018 This function will register a named type constraint with the type registry.
1019
1020 =item B<get_type_constraint_registry>
1021
1022 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
1023 keeps track of all type constraints.
1024
1025 =item B<list_all_type_constraints>
1026
1027 This will return a list of type constraint names, you can then
1028 fetch them using C<find_type_constraint ($type_name)> if you
1029 want to.
1030
1031 =item B<list_all_builtin_type_constraints>
1032
1033 This will return a list of builtin type constraints, meaning,
1034 those which are defined in this module. See the section
1035 labeled L<Default Type Constraints> for a complete list.
1036
1037 =item B<export_type_constraints_as_functions>
1038
1039 This will export all the current type constraints as functions
1040 into the caller's namespace. Right now, this is mostly used for
1041 testing, but it might prove useful to others.
1042
1043 =item B<get_all_parameterizable_types>
1044
1045 This returns all the parameterizable types that have been registered.
1046
1047 =item B<add_parameterizable_type ($type)>
1048
1049 Adds C<$type> to the list of parameterizable types
1050
1051 =back
1052
1053 =head2 Namespace Management
1054
1055 =over 4
1056
1057 =item B<unimport>
1058
1059 This will remove all the type constraint keywords from the
1060 calling class namespace.
1061
1062 =back
1063
1064 =head1 BUGS
1065
1066 All complex software has bugs lurking in it, and this module is no
1067 exception. If you find a bug please either email me, or add the bug
1068 to cpan-RT.
1069
1070 =head1 AUTHOR
1071
1072 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1073
1074 =head1 COPYRIGHT AND LICENSE
1075
1076 Copyright 2006-2008 by Infinity Interactive, Inc.
1077
1078 L<http://www.iinteractive.com>
1079
1080 This library is free software; you can redistribute it and/or modify
1081 it under the same terms as Perl itself.
1082
1083 =cut