lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed';
   9 use Sub::Exporter;
  10
  11 our $VERSION   = '0.54';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 ## --------------------------------------------------------
  15 # Prototyped subs must be predeclared because we have a
  16 # circular dependency with Moose::Meta::Attribute et. al.
  17 # so in case of us being use'd first the predeclaration
  18 # ensures the prototypes are in scope when consumers are
  19 # compiled.
  20
  21 # creation and location
  22 sub find_type_constraint                 ($);
  23 sub register_type_constraint             ($);
  24 sub find_or_create_type_constraint       ($;$);
  25 sub find_or_parse_type_constraint        ($);
  26 sub find_or_create_isa_type_constraint   ($);
  27 sub find_or_create_does_type_constraint  ($);
  28 sub create_type_constraint_union         (@);
  29 sub create_parameterized_type_constraint ($);
  30 sub create_class_type_constraint         ($;$);
  31 sub create_role_type_constraint          ($;$);
  32 sub create_enum_type_constraint          ($$);
  33
  34 # dah sugah!
  35 sub type        ($$;$$);
  36 sub subtype     ($$;$$$);
  37 sub class_type  ($;$);
  38 sub coerce      ($@);
  39 sub as          ($);
  40 sub from        ($);
  41 sub where       (&);
  42 sub via         (&);
  43 sub message     (&);
  44 sub optimize_as (&);
  45 sub enum        ($;@);
  46
  47 ## private stuff ...
  48 sub _create_type_constraint ($$$;$$);
  49 sub _install_type_coercions ($$);
  50
  51 ## --------------------------------------------------------
  52
  53 use Moose::Meta::TypeConstraint;
  54 use Moose::Meta::TypeConstraint::Union;
  55 use Moose::Meta::TypeConstraint::Parameterized;
  56 use Moose::Meta::TypeConstraint::Parameterizable;
  57 use Moose::Meta::TypeConstraint::Class;
  58 use Moose::Meta::TypeConstraint::Role;
  59 use Moose::Meta::TypeConstraint::Enum;
  60 use Moose::Meta::TypeCoercion;
  61 use Moose::Meta::TypeCoercion::Union;
  62 use Moose::Meta::TypeConstraint::Registry;
  63 use Moose::Util::TypeConstraints::OptimizedConstraints;
  64
  65 my @exports = qw/
  66     type subtype class_type role_type as where message optimize_as
  67     coerce from via
  68     enum
  69     find_type_constraint
  70     register_type_constraint
  71 /;
  72
  73 Sub::Exporter::setup_exporter({
  74     exports => \@exports,
  75     groups  => { default => [':all'] }
  76 });
  77
  78 sub unimport {
  79     no strict 'refs';
  80     my $class = caller();
  81     # loop through the exports ...
  82     foreach my $name (@exports) {
  83         # if we find one ...
  84         if (defined &{$class . '::' . $name}) {
  85             my $keyword = \&{$class . '::' . $name};
  86
  87             # make sure it is from Moose
  88             my ($pkg_name) = Class::MOP::get_code_info($keyword);
  89             next if $@;
  90             next if $pkg_name ne 'Moose::Util::TypeConstraints';
  91
  92             # and if it is from Moose then undef the slot
  93             delete ${$class . '::'}{$name};
  94         }
  95     }
  96 }
  97
  98 ## --------------------------------------------------------
  99 ## type registry and some useful functions for it
 100 ## --------------------------------------------------------
 101
 102 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
 103
 104 sub get_type_constraint_registry         { $REGISTRY }
 105 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
 106 sub export_type_constraints_as_functions {
 107     my $pkg = caller();
 108     no strict 'refs';
 109     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
 110         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
 111         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
 112     }
 113 }
 114
 115 sub create_type_constraint_union (@) {
 116     my @type_constraint_names;
 117
 118     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
 119         @type_constraint_names = _parse_type_constraint_union($_[0]);
 120     }
 121     else {
 122         @type_constraint_names = @_;
 123     }
 124
 125     (scalar @type_constraint_names >= 2)
 126         || confess "You must pass in at least 2 type names to make a union";
 127
 128     ($REGISTRY->has_type_constraint($_))
 129         || confess "Could not locate type constraint ($_) for the union"
 130             foreach @type_constraint_names;
 131
 132     return Moose::Meta::TypeConstraint::Union->new(
 133         type_constraints => [
 134             map {
 135                 $REGISTRY->get_type_constraint($_)
 136             } @type_constraint_names
 137         ],
 138     );
 139 }
 140
 141 sub create_parameterized_type_constraint ($) {
 142     my $type_constraint_name = shift;
 143
 144     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 145
 146     (defined $base_type && defined $type_parameter)
 147         || confess "Could not parse type name ($type_constraint_name) correctly";
 148
 149     ($REGISTRY->has_type_constraint($base_type))
 150         || confess "Could not locate the base type ($base_type)";
 151
 152     return Moose::Meta::TypeConstraint::Parameterized->new(
 153         name           => $type_constraint_name,
 154         parent         => $REGISTRY->get_type_constraint($base_type),
 155         type_parameter => find_or_create_isa_type_constraint($type_parameter),
 156     );
 157 }
 158
 159 #should we also support optimized checks?
 160 sub create_class_type_constraint ($;$) {
 161     my ( $class, $options ) = @_;
 162
 163     # too early for this check
 164     #find_type_constraint("ClassName")->check($class)
 165     #    || confess "Can't create a class type constraint because '$class' is not a class name";
 166
 167     my %options = (
 168         class => $class,
 169         name  => $class,
 170         %{ $options || {} },
 171     );
 172
 173     $options{name} ||= "__ANON__";
 174
 175     Moose::Meta::TypeConstraint::Class->new( %options );
 176 }
 177
 178 sub create_role_type_constraint ($;$) {
 179     my ( $role, $options ) = @_;
 180
 181     # too early for this check
 182     #find_type_constraint("ClassName")->check($class)
 183     #    || confess "Can't create a class type constraint because '$class' is not a class name";
 184
 185     my %options = (
 186         role => $role,
 187         name => $role,
 188         %{ $options || {} },
 189     );
 190
 191     $options{name} ||= "__ANON__";
 192
 193     Moose::Meta::TypeConstraint::Role->new( %options );
 194 }
 195
 196
 197 sub find_or_create_type_constraint ($;$) {
 198     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 199
 200     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 201         return $constraint;
 202     }
 203     elsif ( defined $options_for_anon_type ) {
 204         # NOTE:
 205         # if there is no $options_for_anon_type
 206         # specified, then we assume they don't
 207         # want to create one, and return nothing.
 208
 209         # otherwise assume that we should create
 210         # an ANON type with the $options_for_anon_type
 211         # options which can be passed in. It should
 212         # be noted that these don't get registered
 213         # so we need to return it.
 214         # - SL
 215         return Moose::Meta::TypeConstraint->new(
 216             name => '__ANON__',
 217             %{$options_for_anon_type}
 218         );
 219     }
 220
 221     return;
 222 }
 223
 224 sub find_or_create_isa_type_constraint ($) {
 225     my $type_constraint_name = shift;
 226     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 227 }
 228
 229 sub find_or_create_does_type_constraint ($) {
 230     my $type_constraint_name = shift;
 231     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 232 }
 233
 234 sub find_or_parse_type_constraint ($) {
 235     my $type_constraint_name = shift;
 236
 237     return $REGISTRY->get_type_constraint($type_constraint_name)
 238         if $REGISTRY->has_type_constraint($type_constraint_name);
 239
 240     my $constraint;
 241
 242     if (_detect_type_constraint_union($type_constraint_name)) {
 243         $constraint = create_type_constraint_union($type_constraint_name);
 244     }
 245     elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 246         $constraint = create_parameterized_type_constraint($type_constraint_name);
 247     } else {
 248         return;
 249     }
 250
 251     $REGISTRY->add_type_constraint($constraint);
 252     return $constraint;
 253 }
 254
 255 ## --------------------------------------------------------
 256 ## exported functions ...
 257 ## --------------------------------------------------------
 258
 259 sub find_type_constraint ($) {
 260     my $type = shift;
 261
 262     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 263         return $type;
 264     } else {
 265         return $REGISTRY->get_type_constraint($type);
 266     }
 267 }
 268
 269 sub register_type_constraint ($) {
 270     my $constraint = shift;
 271     confess "can't register an unnamed type constraint" unless defined $constraint->name;
 272     $REGISTRY->add_type_constraint($constraint);
 273     return $constraint;
 274 }
 275
 276 # type constructors
 277
 278 sub type ($$;$$) {
 279     splice(@_, 1, 0, undef);
 280     goto &_create_type_constraint;
 281 }
 282
 283 sub subtype ($$;$$$) {
 284     # NOTE:
 285     # this adds an undef for the name
 286     # if this is an anon-subtype:
 287     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 288     # but if the last arg is not a code
 289     # ref then it is a subtype alias:
 290     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 291     # ... yeah I know it's ugly code
 292     # - SL
 293     unshift @_ => undef if scalar @_ <= 2 && ('CODE' eq ref($_[1]));
 294     goto &_create_type_constraint;
 295 }
 296
 297 sub class_type ($;$) {
 298     register_type_constraint(
 299         create_class_type_constraint(
 300             $_[0],
 301             ( defined($_[1]) ? $_[1] : () ),
 302         )
 303     );
 304 }
 305
 306 sub role_type ($;$) {
 307     register_type_constraint(
 308         create_role_type_constraint(
 309             $_[0],
 310             ( defined($_[1]) ? $_[1] : () ),
 311         )
 312     );
 313 }
 314
 315 sub coerce ($@) {
 316     my ($type_name, @coercion_map) = @_;
 317     _install_type_coercions($type_name, \@coercion_map);
 318 }
 319
 320 sub as      ($) { $_[0] }
 321 sub from    ($) { $_[0] }
 322 sub where   (&) { $_[0] }
 323 sub via     (&) { $_[0] }
 324
 325 sub message     (&) { +{ message   => $_[0] } }
 326 sub optimize_as (&) { +{ optimized => $_[0] } }
 327
 328 sub enum ($;@) {
 329     my ($type_name, @values) = @_;
 330     # NOTE:
 331     # if only an array-ref is passed then
 332     # you get an anon-enum
 333     # - SL
 334     if (ref $type_name eq 'ARRAY' && !@values) {
 335         @values    = @$type_name;
 336         $type_name = undef;
 337     }
 338     (scalar @values >= 2)
 339         || confess "You must have at least two values to enumerate through";
 340     my %valid = map { $_ => 1 } @values;
 341
 342     register_type_constraint(
 343         create_enum_type_constraint(
 344             $type_name,
 345             \@values,
 346         )
 347     );
 348 }
 349
 350 sub create_enum_type_constraint ($$) {
 351     my ( $type_name, $values ) = @_;
 352
 353     Moose::Meta::TypeConstraint::Enum->new(
 354         name   => $type_name || '__ANON__',
 355         values => $values,
 356     );
 357 }
 358
 359 ## --------------------------------------------------------
 360 ## desugaring functions ...
 361 ## --------------------------------------------------------
 362
 363 sub _create_type_constraint ($$$;$$) {
 364     my $name   = shift;
 365     my $parent = shift;
 366     my $check  = shift;
 367
 368     my ($message, $optimized);
 369     for (@_) {
 370         $message   = $_->{message}   if exists $_->{message};
 371         $optimized = $_->{optimized} if exists $_->{optimized};
 372     }
 373
 374     my $pkg_defined_in = scalar(caller(0));
 375
 376     if (defined $name) {
 377         my $type = $REGISTRY->get_type_constraint($name);
 378
 379         ($type->_package_defined_in eq $pkg_defined_in)
 380             || confess ("The type constraint '$name' has already been created in "
 381                        . $type->_package_defined_in . " and cannot be created again in "
 382                        . $pkg_defined_in)
 383                  if defined $type;
 384     }
 385
 386     my $class = "Moose::Meta::TypeConstraint";
 387
 388     # FIXME should probably not be a special case
 389     if ( defined $parent and $parent = find_or_parse_type_constraint($parent) ) {
 390         $class = "Moose::Meta::TypeConstraint::Parameterizable"
 391             if $parent->isa("Moose::Meta::TypeConstraint::Parameterizable");
 392     }
 393
 394     my $constraint = $class->new(
 395         name               => $name || '__ANON__',
 396         package_defined_in => $pkg_defined_in,
 397
 398         ($parent    ? (parent     => $parent )   : ()),
 399         ($check     ? (constraint => $check)     : ()),
 400         ($message   ? (message    => $message)   : ()),
 401         ($optimized ? (optimized  => $optimized) : ()),
 402     );
 403
 404     # NOTE:
 405     # if we have a type constraint union, and no
 406     # type check, this means we are just aliasing
 407     # the union constraint, which means we need to
 408     # handle this differently.
 409     # - SL
 410     if (not(defined $check)
 411         && $parent->isa('Moose::Meta::TypeConstraint::Union')
 412         && $parent->has_coercion
 413         ){
 414         $constraint->coercion(Moose::Meta::TypeCoercion::Union->new(
 415             type_constraint => $parent
 416         ));
 417     }
 418
 419     $REGISTRY->add_type_constraint($constraint)
 420         if defined $name;
 421
 422     return $constraint;
 423 }
 424
 425 sub _install_type_coercions ($$) {
 426     my ($type_name, $coercion_map) = @_;
 427     my $type = $REGISTRY->get_type_constraint($type_name);
 428     (defined $type)
 429         || confess "Cannot find type '$type_name', perhaps you forgot to load it.";
 430     if ($type->has_coercion) {
 431         $type->coercion->add_type_coercions(@$coercion_map);
 432     }
 433     else {
 434         my $type_coercion = Moose::Meta::TypeCoercion->new(
 435             type_coercion_map => $coercion_map,
 436             type_constraint   => $type
 437         );
 438         $type->coercion($type_coercion);
 439     }
 440 }
 441
 442 ## --------------------------------------------------------
 443 ## type notation parsing ...
 444 ## --------------------------------------------------------
 445
 446 {
 447     # All I have to say is mugwump++ cause I know
 448     # do not even have enough regexp-fu to be able
 449     # to have written this (I can only barely
 450     # understand it as it is)
 451     # - SL
 452
 453     use re "eval";
 454
 455     my $valid_chars = qr{[\w:]};
 456     my $type_atom   = qr{ $valid_chars+ };
 457
 458     my $any;
 459
 460     my $type                = qr{  $valid_chars+  (?: \[  (??{$any})  \] )? }x;
 461     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ ((??{$any})) \] )? }x;
 462     my $type_with_parameter = qr{  $valid_chars+      \[  (??{$any})  \]    }x;
 463
 464     my $op_union = qr{ \s* \| \s* }x;
 465     my $union    = qr{ $type (?: $op_union $type )+ }x;
 466
 467     $any = qr{ $type | $union }x;
 468
 469     sub _parse_parameterized_type_constraint {
 470         { no warnings 'void'; $any; } # force capture of interpolated lexical
 471         $_[0] =~ m{ $type_capture_parts }x;
 472         return ($1, $2);
 473     }
 474
 475     sub _detect_parameterized_type_constraint {
 476         { no warnings 'void'; $any; } # force capture of interpolated lexical
 477         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 478     }
 479
 480     sub _parse_type_constraint_union {
 481         { no warnings 'void'; $any; } # force capture of interpolated lexical
 482         my $given = shift;
 483         my @rv;
 484         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 485             push @rv => $1;
 486         }
 487         (pos($given) eq length($given))
 488             || confess "'$given' didn't parse (parse-pos="
 489                      . pos($given)
 490                      . " and str-length="
 491                      . length($given)
 492                      . ")";
 493         @rv;
 494     }
 495
 496     sub _detect_type_constraint_union {
 497         { no warnings 'void'; $any; } # force capture of interpolated lexical
 498         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 499     }
 500 }
 501
 502 ## --------------------------------------------------------
 503 # define some basic built-in types
 504 ## --------------------------------------------------------
 505
 506 type 'Any'  => where { 1 }; # meta-type including all
 507 type 'Item' => where { 1 }; # base-type
 508
 509 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 510 subtype 'Defined' => as 'Item' => where {  defined($_) };
 511
 512 subtype 'Bool'
 513     => as 'Item'
 514     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 515
 516 subtype 'Value'
 517     => as 'Defined'
 518     => where { !ref($_) }
 519     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 520
 521 subtype 'Ref'
 522     => as 'Defined'
 523     => where {  ref($_) }
 524     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 525
 526 subtype 'Str'
 527     => as 'Value'
 528     => where { 1 }
 529     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 530
 531 subtype 'Num'
 532     => as 'Value'
 533     => where { Scalar::Util::looks_like_number($_) }
 534     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 535
 536 subtype 'Int'
 537     => as 'Num'
 538     => where { "$_" =~ /^-?[0-9]+$/ }
 539     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 540
 541 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 542 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 543 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 544 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 545
 546 # NOTE:
 547 # scalar filehandles are GLOB refs,
 548 # but a GLOB ref is not always a filehandle
 549 subtype 'FileHandle'
 550     => as 'GlobRef'
 551     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 552     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 553
 554 # NOTE:
 555 # blessed(qr/.../) returns true,.. how odd
 556 subtype 'Object'
 557     => as 'Ref'
 558     => where { blessed($_) && blessed($_) ne 'Regexp' }
 559     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 560
 561 subtype 'Role'
 562     => as 'Object'
 563     => where { $_->can('does') }
 564     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 565
 566 my $_class_name_checker = sub {
 567 };
 568
 569 subtype 'ClassName'
 570     => as 'Str'
 571     => where { Class::MOP::is_class_loaded($_) }
 572     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 573
 574 ## --------------------------------------------------------
 575 # parameterizable types ...
 576
 577 $REGISTRY->add_type_constraint(
 578     Moose::Meta::TypeConstraint::Parameterizable->new(
 579         name                 => 'ArrayRef',
 580         package_defined_in   => __PACKAGE__,
 581         parent               => find_type_constraint('Ref'),
 582         constraint           => sub { ref($_) eq 'ARRAY'  },
 583         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 584         constraint_generator => sub {
 585             my $type_parameter = shift;
 586             my $check = $type_parameter->_compiled_type_constraint;
 587             return sub {
 588                 foreach my $x (@$_) {
 589                     ($check->($x)) || return
 590                 } 1;
 591             }
 592         }
 593     )
 594 );
 595
 596 $REGISTRY->add_type_constraint(
 597     Moose::Meta::TypeConstraint::Parameterizable->new(
 598         name                 => 'HashRef',
 599         package_defined_in   => __PACKAGE__,
 600         parent               => find_type_constraint('Ref'),
 601         constraint           => sub { ref($_) eq 'HASH'  },
 602         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 603         constraint_generator => sub {
 604             my $type_parameter = shift;
 605             my $check = $type_parameter->_compiled_type_constraint;
 606             return sub {
 607                 foreach my $x (values %$_) {
 608                     ($check->($x)) || return
 609                 } 1;
 610             }
 611         }
 612     )
 613 );
 614
 615 $REGISTRY->add_type_constraint(
 616     Moose::Meta::TypeConstraint::Parameterizable->new(
 617         name                 => 'Maybe',
 618         package_defined_in   => __PACKAGE__,
 619         parent               => find_type_constraint('Item'),
 620         constraint           => sub { 1 },
 621         constraint_generator => sub {
 622             my $type_parameter = shift;
 623             my $check = $type_parameter->_compiled_type_constraint;
 624             return sub {
 625                 return 1 if not(defined($_)) || $check->($_);
 626                 return;
 627             }
 628         }
 629     )
 630 );
 631
 632 my @PARAMETERIZABLE_TYPES = map {
 633     $REGISTRY->get_type_constraint($_)
 634 } qw[ArrayRef HashRef Maybe];
 635
 636 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 637 sub add_parameterizable_type {
 638     my $type = shift;
 639     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 640         || confess "Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type";
 641     push @PARAMETERIZABLE_TYPES => $type;
 642 }
 643
 644 ## --------------------------------------------------------
 645 # end of built-in types ...
 646 ## --------------------------------------------------------
 647
 648 {
 649     my @BUILTINS = list_all_type_constraints();
 650     sub list_all_builtin_type_constraints { @BUILTINS }
 651 }
 652
 653 1;
 654
 655 __END__
 656
 657 =pod
 658
 659 =head1 NAME
 660
 661 Moose::Util::TypeConstraints - Type constraint system for Moose
 662
 663 =head1 SYNOPSIS
 664
 665   use Moose::Util::TypeConstraints;
 666
 667   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 668
 669   subtype 'Natural'
 670       => as 'Num'
 671       => where { $_ > 0 };
 672
 673   subtype 'NaturalLessThanTen'
 674       => as 'Natural'
 675       => where { $_ < 10 }
 676       => message { "This number ($_) is not less than ten!" };
 677
 678   coerce 'Num'
 679       => from 'Str'
 680         => via { 0+$_ };
 681
 682   enum 'RGBColors' => qw(red green blue);
 683
 684 =head1 DESCRIPTION
 685
 686 This module provides Moose with the ability to create custom type
 687 contraints to be used in attribute definition.
 688
 689 =head2 Important Caveat
 690
 691 This is B<NOT> a type system for Perl 5. These are type constraints,
 692 and they are not used by Moose unless you tell it to. No type
 693 inference is performed, expression are not typed, etc. etc. etc.
 694
 695 This is simply a means of creating small constraint functions which
 696 can be used to simplify your own type-checking code, with the added
 697 side benefit of making your intentions clearer through self-documentation.
 698
 699 =head2 Slightly Less Important Caveat
 700
 701 It is B<always> a good idea to quote your type and subtype names.
 702
 703 This is to prevent perl from trying to execute the call as an indirect
 704 object call. This issue only seems to come up when you have a subtype
 705 the same name as a valid class, but when the issue does arise it tends
 706 to be quite annoying to debug.
 707
 708 So for instance, this:
 709
 710   subtype DateTime => as Object => where { $_->isa('DateTime') };
 711
 712 will I<Just Work>, while this:
 713
 714   use DateTime;
 715   subtype DateTime => as Object => where { $_->isa('DateTime') };
 716
 717 will fail silently and cause many headaches. The simple way to solve
 718 this, as well as future proof your subtypes from classes which have
 719 yet to have been created yet, is to simply do this:
 720
 721   use DateTime;
 722   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 723
 724 =head2 Default Type Constraints
 725
 726 This module also provides a simple hierarchy for Perl 5 types, here is
 727 that hierarchy represented visually.
 728
 729   Any
 730   Item
 731       Bool
 732       Maybe[`a]
 733       Undef
 734       Defined
 735           Value
 736               Num
 737                 Int
 738               Str
 739                 ClassName
 740           Ref
 741               ScalarRef
 742               ArrayRef[`a]
 743               HashRef[`a]
 744               CodeRef
 745               RegexpRef
 746               GlobRef
 747                 FileHandle
 748               Object
 749                   Role
 750
 751 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 752 parameterized, this means you can say:
 753
 754   ArrayRef[Int]    # an array of intergers
 755   HashRef[CodeRef] # a hash of str to CODE ref mappings
 756   Maybe[Str]       # value may be a string, may be undefined
 757
 758 B<NOTE:> The C<Undef> type constraint for the most part works
 759 correctly now, but edge cases may still exist, please use it
 760 sparringly.
 761
 762 B<NOTE:> The C<ClassName> type constraint does a complex package
 763 existence check. This means that your class B<must> be loaded for
 764 this type constraint to pass. I know this is not ideal for all,
 765 but it is a saner restriction than most others.
 766
 767 =head2 Type Constraint Naming
 768
 769 Since the types created by this module are global, it is suggested
 770 that you namespace your types just as you would namespace your
 771 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 772 module, you would call the type I<My::Graphics::Color> instead.
 773
 774 =head2 Use with Other Constraint Modules
 775
 776 This module should play fairly nicely with other constraint
 777 modules with only some slight tweaking. The C<where> clause
 778 in types is expected to be a C<CODE> reference which checks
 779 it's first argument and returns a boolean. Since most constraint
 780 modules work in a similar way, it should be simple to adapt
 781 them to work with Moose.
 782
 783 For instance, this is how you could use it with
 784 L<Declare::Constraints::Simple> to declare a completely new type.
 785
 786   type 'HashOfArrayOfObjects'
 787       => IsHashRef(
 788           -keys   => HasLength,
 789           -values => IsArrayRef( IsObject ));
 790
 791 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 792 test file.
 793
 794 Here is an example of using L<Test::Deep> and it's non-test
 795 related C<eq_deeply> function.
 796
 797   type 'ArrayOfHashOfBarsAndRandomNumbers'
 798       => where {
 799           eq_deeply($_,
 800               array_each(subhashof({
 801                   bar           => isa('Bar'),
 802                   random_number => ignore()
 803               })))
 804         };
 805
 806 For a complete example see the
 807 F<t/200_examples/205_example_w_TestDeep.t> test file.
 808
 809 =head1 FUNCTIONS
 810
 811 =head2 Type Constraint Constructors
 812
 813 The following functions are used to create type constraints.
 814 They will then register the type constraints in a global store
 815 where Moose can get to them if it needs to.
 816
 817 See the L<SYNOPSIS> for an example of how to use these.
 818
 819 =over 4
 820
 821 =item B<type ($name, $where_clause)>
 822
 823 This creates a base type, which has no parent.
 824
 825 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 826
 827 This creates a named subtype.
 828
 829 =item B<subtype ($parent, $where_clause, ?$message)>
 830
 831 This creates an unnamed subtype and will return the type
 832 constraint meta-object, which will be an instance of
 833 L<Moose::Meta::TypeConstraint>.
 834
 835 =item B<class_type ($class, ?$options)>
 836
 837 Creates a type constraint with the name C<$class> and the metaclass
 838 L<Moose::Meta::TypeConstraint::Class>.
 839
 840 =item B<role_type ($role, ?$options)>
 841
 842 Creates a type constraint with the name C<$role> and the metaclass
 843 L<Moose::Meta::TypeConstraint::Role>.
 844
 845 =item B<enum ($name, @values)>
 846
 847 This will create a basic subtype for a given set of strings.
 848 The resulting constraint will be a subtype of C<Str> and
 849 will match any of the items in C<@values>. It is case sensitive.
 850 See the L<SYNOPSIS> for a simple example.
 851
 852 B<NOTE:> This is not a true proper enum type, it is simple
 853 a convient constraint builder.
 854
 855 =item B<enum (\@values)>
 856
 857 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 858 this will create an unnamed enum. This can then be used in an attribute
 859 definition like so:
 860
 861   has 'sort_order' => (
 862       is  => 'ro',
 863       isa => enum([qw[ ascending descending ]]),
 864   );
 865
 866 =item B<as>
 867
 868 This is just sugar for the type constraint construction syntax.
 869
 870 =item B<where>
 871
 872 This is just sugar for the type constraint construction syntax.
 873
 874 =item B<message>
 875
 876 This is just sugar for the type constraint construction syntax.
 877
 878 =item B<optimize_as>
 879
 880 This can be used to define a "hand optimized" version of your
 881 type constraint which can be used to avoid traversing a subtype
 882 constraint heirarchy.
 883
 884 B<NOTE:> You should only use this if you know what you are doing,
 885 all the built in types use this, so your subtypes (assuming they
 886 are shallow) will not likely need to use this.
 887
 888 =back
 889
 890 =head2 Type Coercion Constructors
 891
 892 Type constraints can also contain type coercions as well. If you
 893 ask your accessor to coerce, then Moose will run the type-coercion
 894 code first, followed by the type constraint check. This feature
 895 should be used carefully as it is very powerful and could easily
 896 take off a limb if you are not careful.
 897
 898 See the L<SYNOPSIS> for an example of how to use these.
 899
 900 =over 4
 901
 902 =item B<coerce>
 903
 904 =item B<from>
 905
 906 This is just sugar for the type coercion construction syntax.
 907
 908 =item B<via>
 909
 910 This is just sugar for the type coercion construction syntax.
 911
 912 =back
 913
 914 =head2 Type Constraint Construction & Locating
 915
 916 =over 4
 917
 918 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 919
 920 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 921 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 922
 923 =item B<create_parameterized_type_constraint ($type_name)>
 924
 925 Given a C<$type_name> in the form of:
 926
 927   BaseType[ContainerType]
 928
 929 this will extract the base type and container type and build an instance of
 930 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 931
 932 =item B<create_class_type_constraint ($class, ?$options)>
 933
 934 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 935 object for that class name.
 936
 937 =item B<create_role_type_constraint ($role, ?$options)>
 938
 939 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 940 object for that role name.
 941
 942 =item B<create_enum_type_constraint ($name, $values)>
 943
 944 =item B<find_or_parse_type_constraint ($type_name)>
 945
 946 This will attempt to find or create a type constraint given the a C<$type_name>.
 947 If it cannot find it in the registry, it will see if it should be a union or
 948 container type an create one if appropriate
 949
 950 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 951
 952 This function will first call C<find_or_parse_type_constraint> with the type name.
 953
 954 If no type is found or created, but C<$options_for_anon_type> are provided, it
 955 will create the corresponding type.
 956
 957 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 958 and are now superseded by C<find_or_create_isa_type_constraint> and
 959 C<find_or_create_does_type_constraint>.
 960
 961 =item B<find_or_create_isa_type_constraint ($type_name)>
 962
 963 =item B<find_or_create_does_type_constraint ($type_name)>
 964
 965 Attempts to parse the type name using L<find_or_parse_type_constraint> and if
 966 no appropriate constraint is found will create a new anonymous one.
 967
 968 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
 969 variant will use C<create_role_type_constraint>.
 970
 971 =item B<find_type_constraint ($type_name)>
 972
 973 This function can be used to locate a specific type constraint
 974 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
 975 derivative. What you do with it from there is up to you :)
 976
 977 =item B<register_type_constraint ($type_object)>
 978
 979 This function will register a named type constraint with the type registry.
 980
 981 =item B<get_type_constraint_registry>
 982
 983 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
 984 keeps track of all type constraints.
 985
 986 =item B<list_all_type_constraints>
 987
 988 This will return a list of type constraint names, you can then
 989 fetch them using C<find_type_constraint ($type_name)> if you
 990 want to.
 991
 992 =item B<list_all_builtin_type_constraints>
 993
 994 This will return a list of builtin type constraints, meaning,
 995 those which are defined in this module. See the section
 996 labeled L<Default Type Constraints> for a complete list.
 997
 998 =item B<export_type_constraints_as_functions>
 999
1000 This will export all the current type constraints as functions
1001 into the caller's namespace. Right now, this is mostly used for
1002 testing, but it might prove useful to others.
1003
1004 =item B<get_all_parameterizable_types>
1005
1006 This returns all the parameterizable types that have been registered.
1007
1008 =item B<add_parameterizable_type ($type)>
1009
1010 Adds C<$type> to the list of parameterizable types
1011
1012 =back
1013
1014 =head2 Namespace Management
1015
1016 =over 4
1017
1018 =item B<unimport>
1019
1020 This will remove all the type constraint keywords from the
1021 calling class namespace.
1022
1023 =back
1024
1025 =head1 BUGS
1026
1027 All complex software has bugs lurking in it, and this module is no
1028 exception. If you find a bug please either email me, or add the bug
1029 to cpan-RT.
1030
1031 =head1 AUTHOR
1032
1033 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1034
1035 =head1 COPYRIGHT AND LICENSE
1036
1037 Copyright 2006-2008 by Infinity Interactive, Inc.
1038
1039 L<http://www.iinteractive.com>
1040
1041 This library is free software; you can redistribute it and/or modify
1042 it under the same terms as Perl itself.
1043
1044 =cut