lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed';
   9
  10 our $VERSION = '0.05';
  11
  12 use Moose::Meta::TypeConstraint;
  13 use Moose::Meta::TypeCoercion;
  14
  15 {
  16     require Sub::Exporter;
  17
  18     my @exports = qw[type subtype as where message coerce from via find_type_constraint];
  19
  20     Sub::Exporter->import(
  21         -setup => {
  22             exports => \@exports,
  23             groups  => {
  24                 default => [':all']
  25             }
  26         }
  27     );
  28 }
  29
  30 {
  31     my %TYPES;
  32     sub find_type_constraint {
  33         return $TYPES{$_[0]}->[1]
  34             if exists $TYPES{$_[0]};
  35         return;
  36     }
  37
  38     sub _dump_type_constraints {
  39         require Data::Dumper;
  40         Data::Dumper::Dumper(\%TYPES);
  41     }
  42
  43     sub _create_type_constraint {
  44         my ($name, $parent, $check, $message) = @_;
  45         my $pkg_defined_in = scalar(caller(1));
  46         ($TYPES{$name}->[0] eq $pkg_defined_in)
  47             || confess "The type constraint '$name' has already been created "
  48                  if defined $name && exists $TYPES{$name};
  49         $parent = find_type_constraint($parent) if defined $parent;
  50         my $constraint = Moose::Meta::TypeConstraint->new(
  51             name       => $name || '__ANON__',
  52             parent     => $parent,
  53             constraint => $check,
  54             message    => $message,
  55         );
  56         $TYPES{$name} = [ $pkg_defined_in, $constraint ] if defined $name;
  57         return $constraint;
  58     }
  59
  60     sub _install_type_coercions {
  61         my ($type_name, $coercion_map) = @_;
  62         my $type = find_type_constraint($type_name);
  63         (!$type->has_coercion)
  64             || confess "The type coercion for '$type_name' has already been registered";
  65         my $type_coercion = Moose::Meta::TypeCoercion->new(
  66             type_coercion_map => $coercion_map,
  67             type_constraint   => $type
  68         );
  69         $type->coercion($type_coercion);
  70     }
  71
  72     sub export_type_contstraints_as_functions {
  73         my $pkg = caller();
  74             no strict 'refs';
  75         foreach my $constraint (keys %TYPES) {
  76                 *{"${pkg}::${constraint}"} = find_type_constraint($constraint)->_compiled_type_constraint;
  77         }
  78     }
  79 }
  80
  81 # type constructors
  82
  83 sub type ($$) {
  84         my ($name, $check) = @_;
  85         _create_type_constraint($name, undef, $check);
  86 }
  87
  88 sub subtype ($$;$$) {
  89         unshift @_ => undef if scalar @_ <= 2;
  90         _create_type_constraint(@_);
  91 }
  92
  93 sub coerce ($@) {
  94     my ($type_name, @coercion_map) = @_;
  95     _install_type_coercions($type_name, \@coercion_map);
  96 }
  97
  98 sub as      ($) { $_[0] }
  99 sub from    ($) { $_[0] }
 100 sub where   (&) { $_[0] }
 101 sub via     (&) { $_[0] }
 102 sub message (&) { $_[0] }
 103
 104 # define some basic types
 105
 106 type 'Any'  => where { 1 }; # meta-type including all
 107 type 'Item' => where { 1 }; # base-type
 108
 109 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 110 subtype 'Defined' => as 'Item' => where {  defined($_) };
 111
 112 subtype 'Value' => as 'Item' => where { !ref($_) };
 113 subtype 'Ref'   => as 'Item' => where {  ref($_) };
 114
 115 subtype 'Bool'  => as 'Item' => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 116
 117 subtype 'Str' => as 'Value' => where { defined($_) };
 118
 119 subtype 'Num' => as 'Value' => where { Scalar::Util::looks_like_number($_) };
 120 subtype 'Int' => as 'Num'   => where { "$_" =~ /^[0-9]+$/ };
 121
 122 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' };
 123
 124 subtype 'CollectionRef' => as 'Ref' => where { ref($_) eq 'ARRAY' || ref($_) eq 'HASH' };
 125
 126 subtype 'ArrayRef' => as 'CollectionRef' => where { ref($_) eq 'ARRAY'  };
 127 subtype 'HashRef'  => as 'CollectionRef' => where { ref($_) eq 'HASH'   };
 128
 129 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   };
 130 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' };
 131
 132 # NOTE:
 133 # blessed(qr/.../) returns true,.. how odd
 134 subtype 'Object' => as 'Ref' => where { blessed($_) && blessed($_) ne 'Regexp' };
 135
 136 subtype 'Role' => as 'Object' => where { $_->can('does') };
 137
 138 1;
 139
 140 __END__
 141
 142 =pod
 143
 144 =head1 NAME
 145
 146 Moose::Util::TypeConstraints - Type constraint system for Moose
 147
 148 =head1 SYNOPSIS
 149
 150   use Moose::Util::TypeConstraints;
 151
 152   type Num => where { Scalar::Util::looks_like_number($_) };
 153
 154   subtype Natural
 155       => as Num
 156       => where { $_ > 0 };
 157
 158   subtype NaturalLessThanTen
 159       => as Natural
 160       => where { $_ < 10 }
 161       => message { "This number ($_) is not less than ten!" };
 162
 163   coerce Num
 164       => from Str
 165         => via { 0+$_ };
 166
 167 =head1 DESCRIPTION
 168
 169 This module provides Moose with the ability to create type contraints
 170 to be are used in both attribute definitions and for method argument
 171 validation.
 172
 173 =head2 Important Caveat
 174
 175 This is B<NOT> a type system for Perl 5. These are type constraints,
 176 and they are not used by Moose unless you tell it to. No type
 177 inference is performed, expression are not typed, etc. etc. etc.
 178
 179 This is simply a means of creating small constraint functions which
 180 can be used to simplify your own type-checking code.
 181
 182 =head2 Default Type Constraints
 183
 184 This module also provides a simple hierarchy for Perl 5 types, this
 185 could probably use some work, but it works for me at the moment.
 186
 187   Any
 188
 189   Item
 190       Undef
 191       Defined
 192       Bool
 193       Value
 194           Int
 195           Str
 196       Ref
 197           ScalarRef
 198           CollectionRef
 199               ArrayRef
 200               HashRef
 201           CodeRef
 202           RegexpRef
 203           Object
 204               Role
 205
 206 Suggestions for improvement are welcome.
 207
 208 =head1 FUNCTIONS
 209
 210 =head2 Type Constraint Registry
 211
 212 =over 4
 213
 214 =item B<find_type_constraint ($type_name)>
 215
 216 This function can be used to locate a specific type constraint
 217 meta-object. What you do with it from there is up to you :)
 218
 219 =item B<export_type_contstraints_as_functions>
 220
 221 This will export all the current type constraints as functions
 222 into the caller's namespace. Right now, this is mostly used for
 223 testing, but it might prove useful to others.
 224
 225 =back
 226
 227 =head2 Type Constraint Constructors
 228
 229 The following functions are used to create type constraints.
 230 They will then register the type constraints in a global store
 231 where Moose can get to them if it needs to.
 232
 233 See the L<SYNOPOSIS> for an example of how to use these.
 234
 235 =over 4
 236
 237 =item B<type ($name, $where_clause)>
 238
 239 This creates a base type, which has no parent.
 240
 241 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 242
 243 This creates a named subtype.
 244
 245 =item B<subtype ($parent, $where_clause, ?$message)>
 246
 247 This creates an unnamed subtype and will return the type
 248 constraint meta-object, which will be an instance of
 249 L<Moose::Meta::TypeConstraint>.
 250
 251 =item B<as>
 252
 253 This is just sugar for the type constraint construction syntax.
 254
 255 =item B<where>
 256
 257 This is just sugar for the type constraint construction syntax.
 258
 259 =item B<message>
 260
 261 This is just sugar for the type constraint construction syntax.
 262
 263 =back
 264
 265 =head2 Type Coercion Constructors
 266
 267 Type constraints can also contain type coercions as well. In most
 268 cases Moose will run the type-coercion code first, followed by the
 269 type constraint check. This feature should be used carefully as it
 270 is very powerful and could easily take off a limb if you are not
 271 careful.
 272
 273 See the L<SYNOPOSIS> for an example of how to use these.
 274
 275 =over 4
 276
 277 =item B<coerce>
 278
 279 =item B<from>
 280
 281 This is just sugar for the type coercion construction syntax.
 282
 283 =item B<via>
 284
 285 This is just sugar for the type coercion construction syntax.
 286
 287 =back
 288
 289 =head1 BUGS
 290
 291 All complex software has bugs lurking in it, and this module is no
 292 exception. If you find a bug please either email me, or add the bug
 293 to cpan-RT.
 294
 295 =head1 AUTHOR
 296
 297 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 298
 299 =head1 COPYRIGHT AND LICENSE
 300
 301 Copyright 2006 by Infinity Interactive, Inc.
 302
 303 L<http://www.iinteractive.com>
 304
 305 This library is free software; you can redistribute it and/or modify
 306 it under the same terms as Perl itself.
 307
 308 =cut