lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.64';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type maybe_type
  51             as where message optimize_as
  52             coerce from via
  53             enum
  54             find_type_constraint
  55             register_type_constraint )
  56     ],
  57     _export_to_main => 1,
  58 );
  59
  60 ## --------------------------------------------------------
  61 ## type registry and some useful functions for it
  62 ## --------------------------------------------------------
  63
  64 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  65
  66 sub get_type_constraint_registry         { $REGISTRY }
  67 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  68 sub export_type_constraints_as_functions {
  69     my $pkg = caller();
  70     no strict 'refs';
  71     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  72         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  73         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  74     }
  75 }
  76
  77 sub create_type_constraint_union {
  78     my @type_constraint_names;
  79
  80     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  81         @type_constraint_names = _parse_type_constraint_union($_[0]);
  82     }
  83     else {
  84         @type_constraint_names = @_;
  85     }
  86
  87     (scalar @type_constraint_names >= 2)
  88         || Moose->throw_error("You must pass in at least 2 type names to make a union");
  89
  90     my @type_constraints = map {
  91         find_or_parse_type_constraint($_) ||
  92          Moose->throw_error("Could not locate type constraint ($_) for the union");
  93     } @type_constraint_names;
  94
  95     return Moose::Meta::TypeConstraint::Union->new(
  96         type_constraints => \@type_constraints
  97     );
  98 }
  99
 100 sub create_parameterized_type_constraint {
 101     my $type_constraint_name = shift;
 102     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 103
 104     (defined $base_type && defined $type_parameter)
 105         || Moose->throw_error("Could not parse type name ($type_constraint_name) correctly");
 106
 107     if ($REGISTRY->has_type_constraint($base_type)) {
 108         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 109         return _create_parameterized_type_constraint(
 110             $base_type_tc,
 111             $type_parameter
 112         );
 113     } else {
 114         Moose->throw_error("Could not locate the base type ($base_type)");
 115     }
 116 }
 117
 118 sub _create_parameterized_type_constraint {
 119     my ( $base_type_tc, $type_parameter ) = @_;
 120     if ( $base_type_tc->can('parameterize') ) {
 121         return $base_type_tc->parameterize($type_parameter);
 122     } else {
 123         return Moose::Meta::TypeConstraint::Parameterized->new(
 124             name => $base_type_tc->name . '[' . $type_parameter . ']',
 125             parent => $base_type_tc,
 126             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 127         );
 128     }
 129 }
 130
 131 #should we also support optimized checks?
 132 sub create_class_type_constraint {
 133     my ( $class, $options ) = @_;
 134
 135     # too early for this check
 136     #find_type_constraint("ClassName")->check($class)
 137     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 138
 139     my %options = (
 140         class => $class,
 141         name  => $class,
 142         %{ $options || {} },
 143     );
 144
 145     $options{name} ||= "__ANON__";
 146
 147     Moose::Meta::TypeConstraint::Class->new( %options );
 148 }
 149
 150 sub create_role_type_constraint {
 151     my ( $role, $options ) = @_;
 152
 153     # too early for this check
 154     #find_type_constraint("ClassName")->check($class)
 155     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 156
 157     my %options = (
 158         role => $role,
 159         name => $role,
 160         %{ $options || {} },
 161     );
 162
 163     $options{name} ||= "__ANON__";
 164
 165     Moose::Meta::TypeConstraint::Role->new( %options );
 166 }
 167
 168
 169 sub find_or_create_type_constraint {
 170     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 171
 172     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 173         return $constraint;
 174     }
 175     elsif ( defined $options_for_anon_type ) {
 176         # NOTE:
 177         # if there is no $options_for_anon_type
 178         # specified, then we assume they don't
 179         # want to create one, and return nothing.
 180
 181         # otherwise assume that we should create
 182         # an ANON type with the $options_for_anon_type
 183         # options which can be passed in. It should
 184         # be noted that these don't get registered
 185         # so we need to return it.
 186         # - SL
 187         return Moose::Meta::TypeConstraint->new(
 188             name => '__ANON__',
 189             %{$options_for_anon_type}
 190         );
 191     }
 192
 193     return;
 194 }
 195
 196 sub find_or_create_isa_type_constraint {
 197     my $type_constraint_name = shift;
 198     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 199 }
 200
 201 sub find_or_create_does_type_constraint {
 202     my $type_constraint_name = shift;
 203     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 204 }
 205
 206 sub find_or_parse_type_constraint {
 207     my $type_constraint_name = normalize_type_constraint_name(shift);
 208     my $constraint;
 209
 210     if ($constraint = find_type_constraint($type_constraint_name)) {
 211         return $constraint;
 212     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 213         $constraint = create_type_constraint_union($type_constraint_name);
 214     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 215         $constraint = create_parameterized_type_constraint($type_constraint_name);
 216     } else {
 217         return;
 218     }
 219
 220     $REGISTRY->add_type_constraint($constraint);
 221     return $constraint;
 222 }
 223
 224 sub normalize_type_constraint_name {
 225     my $type_constraint_name = shift;
 226     $type_constraint_name =~ s/\s//g;
 227     return $type_constraint_name;
 228 }
 229
 230 sub _confess {
 231     my $error = shift;
 232
 233     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 234     Carp::confess($error);
 235 }
 236
 237 ## --------------------------------------------------------
 238 ## exported functions ...
 239 ## --------------------------------------------------------
 240
 241 sub find_type_constraint {
 242     my $type = shift;
 243
 244     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 245         return $type;
 246     }
 247     else {
 248         return unless $REGISTRY->has_type_constraint($type);
 249         return $REGISTRY->get_type_constraint($type);
 250     }
 251 }
 252
 253 sub register_type_constraint {
 254     my $constraint = shift;
 255     Moose->throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 256     $REGISTRY->add_type_constraint($constraint);
 257     return $constraint;
 258 }
 259
 260 # type constructors
 261
 262 sub type {
 263     splice(@_, 1, 0, undef);
 264     goto &_create_type_constraint;
 265 }
 266
 267 sub subtype {
 268     # NOTE:
 269     # this adds an undef for the name
 270     # if this is an anon-subtype:
 271     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 272     #     or
 273     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 274     #
 275     # but if the last arg is not a code ref then it is a subtype
 276     # alias:
 277     #
 278     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 279     # ... yeah I know it's ugly code
 280     # - SL
 281     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 282     unshift @_ => undef
 283         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 284     goto &_create_type_constraint;
 285 }
 286
 287 sub class_type {
 288     register_type_constraint(
 289         create_class_type_constraint(
 290             $_[0],
 291             ( defined($_[1]) ? $_[1] : () ),
 292         )
 293     );
 294 }
 295
 296 sub role_type ($;$) {
 297     register_type_constraint(
 298         create_role_type_constraint(
 299             $_[0],
 300             ( defined($_[1]) ? $_[1] : () ),
 301         )
 302     );
 303 }
 304
 305 sub maybe_type {
 306     my ($type_parameter) = @_;
 307
 308     register_type_constraint(
 309       $REGISTRY->get_type_constraint('Maybe')
 310        ->generate_constraint_for($type_parameter)
 311       # Moose::Meta::TypeConstraint->new(
 312       #     parent               => find_type_constraint('Item'),
 313       #     constraint           => sub {
 314       #         my $check = $type_parameter->_compiled_type_constraint;
 315       #         return 1 if not(defined($_)) || $check->($_);
 316       #         return;
 317       #     }
 318       # )
 319     );
 320 }
 321
 322 sub coerce {
 323     my ($type_name, @coercion_map) = @_;
 324     _install_type_coercions($type_name, \@coercion_map);
 325 }
 326
 327 sub as          { @_ }
 328 sub from        { @_ }
 329 sub where   (&) { $_[0] }
 330 sub via     (&) { $_[0] }
 331
 332 sub message     (&) { +{ message   => $_[0] } }
 333 sub optimize_as (&) { +{ optimized => $_[0] } }
 334
 335 sub enum {
 336     my ($type_name, @values) = @_;
 337     # NOTE:
 338     # if only an array-ref is passed then
 339     # you get an anon-enum
 340     # - SL
 341     if (ref $type_name eq 'ARRAY' && !@values) {
 342         @values    = @$type_name;
 343         $type_name = undef;
 344     }
 345     (scalar @values >= 2)
 346         || Moose->throw_error("You must have at least two values to enumerate through");
 347     my %valid = map { $_ => 1 } @values;
 348
 349     register_type_constraint(
 350         create_enum_type_constraint(
 351             $type_name,
 352             \@values,
 353         )
 354     );
 355 }
 356
 357 sub create_enum_type_constraint {
 358     my ( $type_name, $values ) = @_;
 359
 360     Moose::Meta::TypeConstraint::Enum->new(
 361         name   => $type_name || '__ANON__',
 362         values => $values,
 363     );
 364 }
 365
 366 ## --------------------------------------------------------
 367 ## desugaring functions ...
 368 ## --------------------------------------------------------
 369
 370 sub _create_type_constraint ($$$;$$) {
 371     my $name   = shift;
 372     my $parent = shift;
 373     my $check  = shift;
 374
 375     my ( $message, $optimized );
 376     for (@_) {
 377         $message   = $_->{message}   if exists $_->{message};
 378         $optimized = $_->{optimized} if exists $_->{optimized};
 379     }
 380
 381     my $pkg_defined_in = scalar( caller(0) );
 382
 383     if ( defined $name ) {
 384         my $type = $REGISTRY->get_type_constraint($name);
 385
 386         ( $type->_package_defined_in eq $pkg_defined_in )
 387             || _confess(
 388                   "The type constraint '$name' has already been created in "
 389                 . $type->_package_defined_in
 390                 . " and cannot be created again in "
 391                 . $pkg_defined_in )
 392             if defined $type;
 393     }
 394
 395     my %opts = (
 396         name => $name,
 397         package_defined_in => $pkg_defined_in,
 398
 399         ( $check     ? ( constraint => $check )     : () ),
 400         ( $message   ? ( message    => $message )   : () ),
 401         ( $optimized ? ( optimized  => $optimized ) : () ),
 402     );
 403
 404     my $constraint;
 405     if ( defined $parent
 406         and $parent
 407         = blessed $parent ? $parent : find_or_parse_type_constraint($parent) )
 408     {
 409         $constraint = $parent->create_child_type(%opts);
 410     }
 411     else {
 412         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 413     }
 414
 415     $REGISTRY->add_type_constraint($constraint)
 416         if defined $name;
 417
 418     return $constraint;
 419 }
 420
 421 sub _install_type_coercions ($$) {
 422     my ($type_name, $coercion_map) = @_;
 423     my $type = find_type_constraint($type_name);
 424     (defined $type)
 425         || Moose->throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 426     if ($type->has_coercion) {
 427         $type->coercion->add_type_coercions(@$coercion_map);
 428     }
 429     else {
 430         my $type_coercion = Moose::Meta::TypeCoercion->new(
 431             type_coercion_map => $coercion_map,
 432             type_constraint   => $type
 433         );
 434         $type->coercion($type_coercion);
 435     }
 436 }
 437
 438 ## --------------------------------------------------------
 439 ## type notation parsing ...
 440 ## --------------------------------------------------------
 441
 442 {
 443     # All I have to say is mugwump++ cause I know
 444     # do not even have enough regexp-fu to be able
 445     # to have written this (I can only barely
 446     # understand it as it is)
 447     # - SL
 448
 449     use re "eval";
 450
 451     my $valid_chars = qr{[\w:]};
 452     my $type_atom   = qr{ $valid_chars+ };
 453
 454     my $any;
 455
 456     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 457     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 458     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 459
 460     my $op_union = qr{ \s* \| \s* }x;
 461     my $union    = qr{ $type (?: $op_union $type )+ }x;
 462
 463     $any = qr{ $type | $union }x;
 464
 465     sub _parse_parameterized_type_constraint {
 466         { no warnings 'void'; $any; } # force capture of interpolated lexical
 467         $_[0] =~ m{ $type_capture_parts }x;
 468         return ($1, $2);
 469     }
 470
 471     sub _detect_parameterized_type_constraint {
 472         { no warnings 'void'; $any; } # force capture of interpolated lexical
 473         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 474     }
 475
 476     sub _parse_type_constraint_union {
 477         { no warnings 'void'; $any; } # force capture of interpolated lexical
 478         my $given = shift;
 479         my @rv;
 480         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 481             push @rv => $1;
 482         }
 483         (pos($given) eq length($given))
 484             || Moose->throw_error("'$given' didn't parse (parse-pos="
 485                      . pos($given)
 486                      . " and str-length="
 487                      . length($given)
 488                      . ")");
 489         @rv;
 490     }
 491
 492     sub _detect_type_constraint_union {
 493         { no warnings 'void'; $any; } # force capture of interpolated lexical
 494         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 495     }
 496 }
 497
 498 ## --------------------------------------------------------
 499 # define some basic built-in types
 500 ## --------------------------------------------------------
 501
 502 # By making these classes immutable before creating all the types we
 503 # below, we avoid repeatedly calling the slow MOP-based accessors.
 504 $_->make_immutable(
 505     inline_constructor => 1,
 506     constructor_name   => "_new",
 507
 508     # these are Class::MOP accessors, so they need inlining
 509     inline_accessors => 1
 510     ) for grep { $_->is_mutable }
 511     map { $_->meta }
 512     qw(
 513     Moose::Meta::TypeConstraint
 514     Moose::Meta::TypeConstraint::Union
 515     Moose::Meta::TypeConstraint::Parameterized
 516     Moose::Meta::TypeConstraint::Parameterizable
 517     Moose::Meta::TypeConstraint::Class
 518     Moose::Meta::TypeConstraint::Role
 519     Moose::Meta::TypeConstraint::Enum
 520     Moose::Meta::TypeConstraint::Registry
 521 );
 522
 523 type 'Any'  => where { 1 }; # meta-type including all
 524 type 'Item' => where { 1 }; # base-type
 525
 526 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 527 subtype 'Defined' => as 'Item' => where {  defined($_) };
 528
 529 subtype 'Bool'
 530     => as 'Item'
 531     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 532
 533 subtype 'Value'
 534     => as 'Defined'
 535     => where { !ref($_) }
 536     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 537
 538 subtype 'Ref'
 539     => as 'Defined'
 540     => where {  ref($_) }
 541     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 542
 543 subtype 'Str'
 544     => as 'Value'
 545     => where { 1 }
 546     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 547
 548 subtype 'Num'
 549     => as 'Value'
 550     => where { Scalar::Util::looks_like_number($_) }
 551     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 552
 553 subtype 'Int'
 554     => as 'Num'
 555     => where { "$_" =~ /^-?[0-9]+$/ }
 556     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 557
 558 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 559 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 560 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 561 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 562
 563 # NOTE:
 564 # scalar filehandles are GLOB refs,
 565 # but a GLOB ref is not always a filehandle
 566 subtype 'FileHandle'
 567     => as 'GlobRef'
 568     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 569     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 570
 571 # NOTE:
 572 # blessed(qr/.../) returns true,.. how odd
 573 subtype 'Object'
 574     => as 'Ref'
 575     => where { blessed($_) && blessed($_) ne 'Regexp' }
 576     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 577
 578 subtype 'Role'
 579     => as 'Object'
 580     => where { $_->can('does') }
 581     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 582
 583 my $_class_name_checker = sub {
 584 };
 585
 586 subtype 'ClassName'
 587     => as 'Str'
 588     => where { Class::MOP::is_class_loaded($_) }
 589     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 590
 591 ## --------------------------------------------------------
 592 # parameterizable types ...
 593
 594 $REGISTRY->add_type_constraint(
 595     Moose::Meta::TypeConstraint::Parameterizable->new(
 596         name                 => 'ArrayRef',
 597         package_defined_in   => __PACKAGE__,
 598         parent               => find_type_constraint('Ref'),
 599         constraint           => sub { ref($_) eq 'ARRAY'  },
 600         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 601         constraint_generator => sub {
 602             my $type_parameter = shift;
 603             my $check = $type_parameter->_compiled_type_constraint;
 604             return sub {
 605                 foreach my $x (@$_) {
 606                     ($check->($x)) || return
 607                 } 1;
 608             }
 609         }
 610     )
 611 );
 612
 613 $REGISTRY->add_type_constraint(
 614     Moose::Meta::TypeConstraint::Parameterizable->new(
 615         name                 => 'HashRef',
 616         package_defined_in   => __PACKAGE__,
 617         parent               => find_type_constraint('Ref'),
 618         constraint           => sub { ref($_) eq 'HASH'  },
 619         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 620         constraint_generator => sub {
 621             my $type_parameter = shift;
 622             my $check = $type_parameter->_compiled_type_constraint;
 623             return sub {
 624                 foreach my $x (values %$_) {
 625                     ($check->($x)) || return
 626                 } 1;
 627             }
 628         }
 629     )
 630 );
 631
 632 $REGISTRY->add_type_constraint(
 633     Moose::Meta::TypeConstraint::Parameterizable->new(
 634         name                 => 'Maybe',
 635         package_defined_in   => __PACKAGE__,
 636         parent               => find_type_constraint('Item'),
 637         constraint           => sub { 1 },
 638         constraint_generator => sub {
 639             my $type_parameter = shift;
 640             my $check = $type_parameter->_compiled_type_constraint;
 641             return sub {
 642                 return 1 if not(defined($_)) || $check->($_);
 643                 return;
 644             }
 645         }
 646     )
 647 );
 648
 649 my @PARAMETERIZABLE_TYPES = map {
 650     $REGISTRY->get_type_constraint($_)
 651 } qw[ArrayRef HashRef Maybe];
 652
 653 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 654 sub add_parameterizable_type {
 655     my $type = shift;
 656     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 657         || Moose->throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 658     push @PARAMETERIZABLE_TYPES => $type;
 659 }
 660
 661 ## --------------------------------------------------------
 662 # end of built-in types ...
 663 ## --------------------------------------------------------
 664
 665 {
 666     my @BUILTINS = list_all_type_constraints();
 667     sub list_all_builtin_type_constraints { @BUILTINS }
 668 }
 669
 670 1;
 671
 672 __END__
 673
 674 =pod
 675
 676 =head1 NAME
 677
 678 Moose::Util::TypeConstraints - Type constraint system for Moose
 679
 680 =head1 SYNOPSIS
 681
 682   use Moose::Util::TypeConstraints;
 683
 684   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 685
 686   subtype 'Natural'
 687       => as 'Int'
 688       => where { $_ > 0 };
 689
 690   subtype 'NaturalLessThanTen'
 691       => as 'Natural'
 692       => where { $_ < 10 }
 693       => message { "This number ($_) is not less than ten!" };
 694
 695   coerce 'Num'
 696       => from 'Str'
 697         => via { 0+$_ };
 698
 699   enum 'RGBColors' => qw(red green blue);
 700
 701 =head1 DESCRIPTION
 702
 703 This module provides Moose with the ability to create custom type
 704 contraints to be used in attribute definition.
 705
 706 =head2 Important Caveat
 707
 708 This is B<NOT> a type system for Perl 5. These are type constraints,
 709 and they are not used by Moose unless you tell it to. No type
 710 inference is performed, expression are not typed, etc. etc. etc.
 711
 712 This is simply a means of creating small constraint functions which
 713 can be used to simplify your own type-checking code, with the added
 714 side benefit of making your intentions clearer through self-documentation.
 715
 716 =head2 Slightly Less Important Caveat
 717
 718 It is B<always> a good idea to quote your type and subtype names.
 719
 720 This is to prevent perl from trying to execute the call as an indirect
 721 object call. This issue only seems to come up when you have a subtype
 722 the same name as a valid class, but when the issue does arise it tends
 723 to be quite annoying to debug.
 724
 725 So for instance, this:
 726
 727   subtype DateTime => as Object => where { $_->isa('DateTime') };
 728
 729 will I<Just Work>, while this:
 730
 731   use DateTime;
 732   subtype DateTime => as Object => where { $_->isa('DateTime') };
 733
 734 will fail silently and cause many headaches. The simple way to solve
 735 this, as well as future proof your subtypes from classes which have
 736 yet to have been created yet, is to simply do this:
 737
 738   use DateTime;
 739   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 740
 741 =head2 Default Type Constraints
 742
 743 This module also provides a simple hierarchy for Perl 5 types, here is
 744 that hierarchy represented visually.
 745
 746   Any
 747   Item
 748       Bool
 749       Maybe[`a]
 750       Undef
 751       Defined
 752           Value
 753               Num
 754                 Int
 755               Str
 756                 ClassName
 757           Ref
 758               ScalarRef
 759               ArrayRef[`a]
 760               HashRef[`a]
 761               CodeRef
 762               RegexpRef
 763               GlobRef
 764                 FileHandle
 765               Object
 766                   Role
 767
 768 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 769 parameterized, this means you can say:
 770
 771   ArrayRef[Int]    # an array of integers
 772   HashRef[CodeRef] # a hash of str to CODE ref mappings
 773   Maybe[Str]       # value may be a string, may be undefined
 774
 775 B<NOTE:> Unless you parameterize a type, then it is invalid to
 776 include the square brackets. I.e. C<ArrayRef[]> will be
 777 literally interpreted as a type name.
 778
 779 B<NOTE:> The C<Undef> type constraint for the most part works
 780 correctly now, but edge cases may still exist, please use it
 781 sparringly.
 782
 783 B<NOTE:> The C<ClassName> type constraint does a complex package
 784 existence check. This means that your class B<must> be loaded for
 785 this type constraint to pass. I know this is not ideal for all,
 786 but it is a saner restriction than most others.
 787
 788 =head2 Type Constraint Naming
 789
 790 Since the types created by this module are global, it is suggested
 791 that you namespace your types just as you would namespace your
 792 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 793 module, you would call the type I<My::Graphics::Color> instead.
 794
 795 =head2 Use with Other Constraint Modules
 796
 797 This module should play fairly nicely with other constraint
 798 modules with only some slight tweaking. The C<where> clause
 799 in types is expected to be a C<CODE> reference which checks
 800 it's first argument and returns a boolean. Since most constraint
 801 modules work in a similar way, it should be simple to adapt
 802 them to work with Moose.
 803
 804 For instance, this is how you could use it with
 805 L<Declare::Constraints::Simple> to declare a completely new type.
 806
 807   type 'HashOfArrayOfObjects'
 808       => IsHashRef(
 809           -keys   => HasLength,
 810           -values => IsArrayRef( IsObject ));
 811
 812 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 813 test file.
 814
 815 Here is an example of using L<Test::Deep> and it's non-test
 816 related C<eq_deeply> function.
 817
 818   type 'ArrayOfHashOfBarsAndRandomNumbers'
 819       => where {
 820           eq_deeply($_,
 821               array_each(subhashof({
 822                   bar           => isa('Bar'),
 823                   random_number => ignore()
 824               })))
 825         };
 826
 827 For a complete example see the
 828 F<t/200_examples/205_example_w_TestDeep.t> test file.
 829
 830 =head1 FUNCTIONS
 831
 832 =head2 Type Constraint Constructors
 833
 834 The following functions are used to create type constraints.
 835 They will then register the type constraints in a global store
 836 where Moose can get to them if it needs to.
 837
 838 See the L<SYNOPSIS> for an example of how to use these.
 839
 840 =over 4
 841
 842 =item B<type ($name, $where_clause)>
 843
 844 This creates a base type, which has no parent.
 845
 846 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 847
 848 This creates a named subtype.
 849
 850 =item B<subtype ($parent, $where_clause, ?$message)>
 851
 852 This creates an unnamed subtype and will return the type
 853 constraint meta-object, which will be an instance of
 854 L<Moose::Meta::TypeConstraint>.
 855
 856 =item B<class_type ($class, ?$options)>
 857
 858 Creates a type constraint with the name C<$class> and the metaclass
 859 L<Moose::Meta::TypeConstraint::Class>.
 860
 861 =item B<role_type ($role, ?$options)>
 862
 863 Creates a type constraint with the name C<$role> and the metaclass
 864 L<Moose::Meta::TypeConstraint::Role>.
 865
 866 =item B<maybe_type ($type)>
 867
 868 Creates a type constraint for either C<undef> or something of the
 869 given type.
 870
 871 =item B<enum ($name, @values)>
 872
 873 This will create a basic subtype for a given set of strings.
 874 The resulting constraint will be a subtype of C<Str> and
 875 will match any of the items in C<@values>. It is case sensitive.
 876 See the L<SYNOPSIS> for a simple example.
 877
 878 B<NOTE:> This is not a true proper enum type, it is simple
 879 a convient constraint builder.
 880
 881 =item B<enum (\@values)>
 882
 883 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 884 this will create an unnamed enum. This can then be used in an attribute
 885 definition like so:
 886
 887   has 'sort_order' => (
 888       is  => 'ro',
 889       isa => enum([qw[ ascending descending ]]),
 890   );
 891
 892 =item B<as>
 893
 894 This is just sugar for the type constraint construction syntax.
 895
 896 =item B<where>
 897
 898 This is just sugar for the type constraint construction syntax.
 899
 900 Takes a block/code ref as an argument. When the type constraint is
 901 tested, the supplied code is run with the value to be tested in
 902 $_. This block should return true or false to indicate whether or not
 903 the constraint check passed.
 904
 905 =item B<message>
 906
 907 This is just sugar for the type constraint construction syntax.
 908
 909 Takes a block/code ref as an argument. When the type constraint fails,
 910 then the code block is run (with the value provided in $_). This code
 911 ref should return a string, which will be used in the text of the
 912 exception thrown.
 913
 914 =item B<optimize_as>
 915
 916 This can be used to define a "hand optimized" version of your
 917 type constraint which can be used to avoid traversing a subtype
 918 constraint heirarchy.
 919
 920 B<NOTE:> You should only use this if you know what you are doing,
 921 all the built in types use this, so your subtypes (assuming they
 922 are shallow) will not likely need to use this.
 923
 924 =back
 925
 926 =head2 Type Coercion Constructors
 927
 928 Type constraints can also contain type coercions as well. If you
 929 ask your accessor to coerce, then Moose will run the type-coercion
 930 code first, followed by the type constraint check. This feature
 931 should be used carefully as it is very powerful and could easily
 932 take off a limb if you are not careful.
 933
 934 See the L<SYNOPSIS> for an example of how to use these.
 935
 936 =over 4
 937
 938 =item B<coerce>
 939
 940 =item B<from>
 941
 942 This is just sugar for the type coercion construction syntax.
 943
 944 =item B<via>
 945
 946 This is just sugar for the type coercion construction syntax.
 947
 948 =back
 949
 950 =head2 Type Constraint Construction & Locating
 951
 952 =over 4
 953
 954 =item B<normalize_type_constraint_name ($type_constraint_name)>
 955
 956 Given a string that is expected to match a type constraint, will normalize the
 957 string so that extra whitespace and newlines are removed.
 958
 959 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 960
 961 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 962 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 963
 964 =item B<create_parameterized_type_constraint ($type_name)>
 965
 966 Given a C<$type_name> in the form of:
 967
 968   BaseType[ContainerType]
 969
 970 this will extract the base type and container type and build an instance of
 971 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 972
 973 =item B<create_class_type_constraint ($class, ?$options)>
 974
 975 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 976 object for that class name.
 977
 978 =item B<create_role_type_constraint ($role, ?$options)>
 979
 980 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 981 object for that role name.
 982
 983 =item B<create_enum_type_constraint ($name, $values)>
 984
 985 =item B<find_or_parse_type_constraint ($type_name)>
 986
 987 This will attempt to find or create a type constraint given the a C<$type_name>.
 988 If it cannot find it in the registry, it will see if it should be a union or
 989 container type an create one if appropriate
 990
 991 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 992
 993 This function will first call C<find_or_parse_type_constraint> with the type name.
 994
 995 If no type is found or created, but C<$options_for_anon_type> are provided, it
 996 will create the corresponding type.
 997
 998 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 999 and are now superseded by C<find_or_create_isa_type_constraint> and
1000 C<find_or_create_does_type_constraint>.
1001
1002 =item B<find_or_create_isa_type_constraint ($type_name)>
1003
1004 =item B<find_or_create_does_type_constraint ($type_name)>
1005
1006 Attempts to parse the type name using C<find_or_parse_type_constraint> and if
1007 no appropriate constraint is found will create a new anonymous one.
1008
1009 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
1010 variant will use C<create_role_type_constraint>.
1011
1012 =item B<find_type_constraint ($type_name)>
1013
1014 This function can be used to locate a specific type constraint
1015 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
1016 derivative. What you do with it from there is up to you :)
1017
1018 =item B<register_type_constraint ($type_object)>
1019
1020 This function will register a named type constraint with the type registry.
1021
1022 =item B<get_type_constraint_registry>
1023
1024 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
1025 keeps track of all type constraints.
1026
1027 =item B<list_all_type_constraints>
1028
1029 This will return a list of type constraint names, you can then
1030 fetch them using C<find_type_constraint ($type_name)> if you
1031 want to.
1032
1033 =item B<list_all_builtin_type_constraints>
1034
1035 This will return a list of builtin type constraints, meaning,
1036 those which are defined in this module. See the section
1037 labeled L<Default Type Constraints> for a complete list.
1038
1039 =item B<export_type_constraints_as_functions>
1040
1041 This will export all the current type constraints as functions
1042 into the caller's namespace. Right now, this is mostly used for
1043 testing, but it might prove useful to others.
1044
1045 =item B<get_all_parameterizable_types>
1046
1047 This returns all the parameterizable types that have been registered.
1048
1049 =item B<add_parameterizable_type ($type)>
1050
1051 Adds C<$type> to the list of parameterizable types
1052
1053 =back
1054
1055 =head2 Namespace Management
1056
1057 =over 4
1058
1059 =item B<unimport>
1060
1061 This will remove all the type constraint keywords from the
1062 calling class namespace.
1063
1064 =back
1065
1066 =head1 BUGS
1067
1068 All complex software has bugs lurking in it, and this module is no
1069 exception. If you find a bug please either email me, or add the bug
1070 to cpan-RT.
1071
1072 =head1 AUTHOR
1073
1074 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1075
1076 =head1 COPYRIGHT AND LICENSE
1077
1078 Copyright 2006-2008 by Infinity Interactive, Inc.
1079
1080 L<http://www.iinteractive.com>
1081
1082 This library is free software; you can redistribute it and/or modify
1083 it under the same terms as Perl itself.
1084
1085 =cut