lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.65';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type maybe_type
  51             as where message optimize_as
  52             coerce from via
  53             enum
  54             find_type_constraint
  55             register_type_constraint )
  56     ],
  57     _export_to_main => 1,
  58 );
  59
  60 ## --------------------------------------------------------
  61 ## type registry and some useful functions for it
  62 ## --------------------------------------------------------
  63
  64 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  65
  66 sub get_type_constraint_registry         { $REGISTRY }
  67 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  68 sub export_type_constraints_as_functions {
  69     my $pkg = caller();
  70     no strict 'refs';
  71     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  72         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  73         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  74     }
  75 }
  76
  77 sub create_type_constraint_union {
  78     my @type_constraint_names;
  79
  80     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  81         @type_constraint_names = _parse_type_constraint_union($_[0]);
  82     }
  83     else {
  84         @type_constraint_names = @_;
  85     }
  86
  87     (scalar @type_constraint_names >= 2)
  88         || __PACKAGE__->_throw_error("You must pass in at least 2 type names to make a union");
  89
  90     my @type_constraints = map {
  91         find_or_parse_type_constraint($_) ||
  92          __PACKAGE__->_throw_error("Could not locate type constraint ($_) for the union");
  93     } @type_constraint_names;
  94
  95     return Moose::Meta::TypeConstraint::Union->new(
  96         type_constraints => \@type_constraints
  97     );
  98 }
  99
 100 sub create_parameterized_type_constraint {
 101     my $type_constraint_name = shift;
 102     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 103
 104     (defined $base_type && defined $type_parameter)
 105         || __PACKAGE__->_throw_error("Could not parse type name ($type_constraint_name) correctly");
 106
 107     if ($REGISTRY->has_type_constraint($base_type)) {
 108         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 109         return _create_parameterized_type_constraint(
 110             $base_type_tc,
 111             $type_parameter
 112         );
 113     } else {
 114         __PACKAGE__->_throw_error("Could not locate the base type ($base_type)");
 115     }
 116 }
 117
 118 sub _create_parameterized_type_constraint {
 119     my ( $base_type_tc, $type_parameter ) = @_;
 120     if ( $base_type_tc->can('parameterize') ) {
 121         return $base_type_tc->parameterize($type_parameter);
 122     } else {
 123         return Moose::Meta::TypeConstraint::Parameterized->new(
 124             name => $base_type_tc->name . '[' . $type_parameter . ']',
 125             parent => $base_type_tc,
 126             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 127         );
 128     }
 129 }
 130
 131 #should we also support optimized checks?
 132 sub create_class_type_constraint {
 133     my ( $class, $options ) = @_;
 134
 135     # too early for this check
 136     #find_type_constraint("ClassName")->check($class)
 137     #    || __PACKAGE__->_throw_error("Can't create a class type constraint because '$class' is not a class name");
 138
 139     my %options = (
 140         class => $class,
 141         name  => $class,
 142         %{ $options || {} },
 143     );
 144
 145     $options{name} ||= "__ANON__";
 146
 147     Moose::Meta::TypeConstraint::Class->new( %options );
 148 }
 149
 150 sub create_role_type_constraint {
 151     my ( $role, $options ) = @_;
 152
 153     # too early for this check
 154     #find_type_constraint("ClassName")->check($class)
 155     #    || __PACKAGE__->_throw_error("Can't create a class type constraint because '$class' is not a class name");
 156
 157     my %options = (
 158         role => $role,
 159         name => $role,
 160         %{ $options || {} },
 161     );
 162
 163     $options{name} ||= "__ANON__";
 164
 165     Moose::Meta::TypeConstraint::Role->new( %options );
 166 }
 167
 168
 169 sub find_or_create_type_constraint {
 170     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 171
 172     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 173         return $constraint;
 174     }
 175     elsif ( defined $options_for_anon_type ) {
 176         # NOTE:
 177         # if there is no $options_for_anon_type
 178         # specified, then we assume they don't
 179         # want to create one, and return nothing.
 180
 181         # otherwise assume that we should create
 182         # an ANON type with the $options_for_anon_type
 183         # options which can be passed in. It should
 184         # be noted that these don't get registered
 185         # so we need to return it.
 186         # - SL
 187         return Moose::Meta::TypeConstraint->new(
 188             name => '__ANON__',
 189             %{$options_for_anon_type}
 190         );
 191     }
 192
 193     return;
 194 }
 195
 196 sub find_or_create_isa_type_constraint {
 197     my $type_constraint_name = shift;
 198     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 199 }
 200
 201 sub find_or_create_does_type_constraint {
 202     my $type_constraint_name = shift;
 203     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 204 }
 205
 206 sub find_or_parse_type_constraint {
 207     my $type_constraint_name = normalize_type_constraint_name(shift);
 208     my $constraint;
 209
 210     if ($constraint = find_type_constraint($type_constraint_name)) {
 211         return $constraint;
 212     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 213         $constraint = create_type_constraint_union($type_constraint_name);
 214     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 215         $constraint = create_parameterized_type_constraint($type_constraint_name);
 216     } else {
 217         return;
 218     }
 219
 220     $REGISTRY->add_type_constraint($constraint);
 221     return $constraint;
 222 }
 223
 224 sub normalize_type_constraint_name {
 225     my $type_constraint_name = shift;
 226     $type_constraint_name =~ s/\s//g;
 227     return $type_constraint_name;
 228 }
 229
 230 sub _confess {
 231     my $error = shift;
 232
 233     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 234     Carp::confess($error);
 235 }
 236
 237 ## --------------------------------------------------------
 238 ## exported functions ...
 239 ## --------------------------------------------------------
 240
 241 sub find_type_constraint {
 242     my $type = shift;
 243
 244     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 245         return $type;
 246     }
 247     else {
 248         return unless $REGISTRY->has_type_constraint($type);
 249         return $REGISTRY->get_type_constraint($type);
 250     }
 251 }
 252
 253 sub register_type_constraint {
 254     my $constraint = shift;
 255     __PACKAGE__->_throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 256     $REGISTRY->add_type_constraint($constraint);
 257     return $constraint;
 258 }
 259
 260 # type constructors
 261
 262 sub type {
 263     splice(@_, 1, 0, undef);
 264     goto &_create_type_constraint;
 265 }
 266
 267 sub subtype {
 268     # NOTE:
 269     # this adds an undef for the name
 270     # if this is an anon-subtype:
 271     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 272     #     or
 273     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 274     #
 275     # but if the last arg is not a code ref then it is a subtype
 276     # alias:
 277     #
 278     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 279     # ... yeah I know it's ugly code
 280     # - SL
 281     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 282     unshift @_ => undef
 283         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 284     goto &_create_type_constraint;
 285 }
 286
 287 sub class_type {
 288     register_type_constraint(
 289         create_class_type_constraint(
 290             $_[0],
 291             ( defined($_[1]) ? $_[1] : () ),
 292         )
 293     );
 294 }
 295
 296 sub role_type ($;$) {
 297     register_type_constraint(
 298         create_role_type_constraint(
 299             $_[0],
 300             ( defined($_[1]) ? $_[1] : () ),
 301         )
 302     );
 303 }
 304
 305 sub maybe_type {
 306     my ($type_parameter) = @_;
 307
 308     register_type_constraint(
 309         $REGISTRY->get_type_constraint('Maybe')->parameterize($type_parameter)
 310     );
 311 }
 312
 313 sub coerce {
 314     my ($type_name, @coercion_map) = @_;
 315     _install_type_coercions($type_name, \@coercion_map);
 316 }
 317
 318 sub as          { @_ }
 319 sub from        { @_ }
 320 sub where   (&) { $_[0] }
 321 sub via     (&) { $_[0] }
 322
 323 sub message     (&) { +{ message   => $_[0] } }
 324 sub optimize_as (&) { +{ optimized => $_[0] } }
 325
 326 sub enum {
 327     my ($type_name, @values) = @_;
 328     # NOTE:
 329     # if only an array-ref is passed then
 330     # you get an anon-enum
 331     # - SL
 332     if (ref $type_name eq 'ARRAY' && !@values) {
 333         @values    = @$type_name;
 334         $type_name = undef;
 335     }
 336     (scalar @values >= 2)
 337         || __PACKAGE__->_throw_error("You must have at least two values to enumerate through");
 338     my %valid = map { $_ => 1 } @values;
 339
 340     register_type_constraint(
 341         create_enum_type_constraint(
 342             $type_name,
 343             \@values,
 344         )
 345     );
 346 }
 347
 348 sub create_enum_type_constraint {
 349     my ( $type_name, $values ) = @_;
 350
 351     Moose::Meta::TypeConstraint::Enum->new(
 352         name   => $type_name || '__ANON__',
 353         values => $values,
 354     );
 355 }
 356
 357 ## --------------------------------------------------------
 358 ## desugaring functions ...
 359 ## --------------------------------------------------------
 360
 361 sub _create_type_constraint ($$$;$$) {
 362     my $name   = shift;
 363     my $parent = shift;
 364     my $check  = shift;
 365
 366     my ( $message, $optimized );
 367     for (@_) {
 368         $message   = $_->{message}   if exists $_->{message};
 369         $optimized = $_->{optimized} if exists $_->{optimized};
 370     }
 371
 372     my $pkg_defined_in = scalar( caller(0) );
 373
 374     if ( defined $name ) {
 375         my $type = $REGISTRY->get_type_constraint($name);
 376
 377         ( $type->_package_defined_in eq $pkg_defined_in )
 378             || _confess(
 379                   "The type constraint '$name' has already been created in "
 380                 . $type->_package_defined_in
 381                 . " and cannot be created again in "
 382                 . $pkg_defined_in )
 383             if defined $type;
 384     }
 385
 386     my %opts = (
 387         name => $name,
 388         package_defined_in => $pkg_defined_in,
 389
 390         ( $check     ? ( constraint => $check )     : () ),
 391         ( $message   ? ( message    => $message )   : () ),
 392         ( $optimized ? ( optimized  => $optimized ) : () ),
 393     );
 394
 395     my $constraint;
 396     if ( defined $parent
 397         and $parent
 398         = blessed $parent ? $parent : find_or_create_isa_type_constraint($parent) )
 399     {
 400         $constraint = $parent->create_child_type(%opts);
 401     }
 402     else {
 403         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 404     }
 405
 406     $REGISTRY->add_type_constraint($constraint)
 407         if defined $name;
 408
 409     return $constraint;
 410 }
 411
 412 sub _install_type_coercions ($$) {
 413     my ($type_name, $coercion_map) = @_;
 414     my $type = find_type_constraint($type_name);
 415     (defined $type)
 416         || __PACKAGE__->_throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 417     if ($type->has_coercion) {
 418         $type->coercion->add_type_coercions(@$coercion_map);
 419     }
 420     else {
 421         my $type_coercion = Moose::Meta::TypeCoercion->new(
 422             type_coercion_map => $coercion_map,
 423             type_constraint   => $type
 424         );
 425         $type->coercion($type_coercion);
 426     }
 427 }
 428
 429 ## --------------------------------------------------------
 430 ## type notation parsing ...
 431 ## --------------------------------------------------------
 432
 433 {
 434     # All I have to say is mugwump++ cause I know
 435     # do not even have enough regexp-fu to be able
 436     # to have written this (I can only barely
 437     # understand it as it is)
 438     # - SL
 439
 440     use re "eval";
 441
 442     my $valid_chars = qr{[\w:]};
 443     my $type_atom   = qr{ $valid_chars+ };
 444
 445     my $any;
 446
 447     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 448     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 449     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 450
 451     my $op_union = qr{ \s* \| \s* }x;
 452     my $union    = qr{ $type (?: $op_union $type )+ }x;
 453
 454     $any = qr{ $type | $union }x;
 455
 456     sub _parse_parameterized_type_constraint {
 457         { no warnings 'void'; $any; } # force capture of interpolated lexical
 458         $_[0] =~ m{ $type_capture_parts }x;
 459         return ($1, $2);
 460     }
 461
 462     sub _detect_parameterized_type_constraint {
 463         { no warnings 'void'; $any; } # force capture of interpolated lexical
 464         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 465     }
 466
 467     sub _parse_type_constraint_union {
 468         { no warnings 'void'; $any; } # force capture of interpolated lexical
 469         my $given = shift;
 470         my @rv;
 471         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 472             push @rv => $1;
 473         }
 474         (pos($given) eq length($given))
 475             || __PACKAGE__->_throw_error("'$given' didn't parse (parse-pos="
 476                      . pos($given)
 477                      . " and str-length="
 478                      . length($given)
 479                      . ")");
 480         @rv;
 481     }
 482
 483     sub _detect_type_constraint_union {
 484         { no warnings 'void'; $any; } # force capture of interpolated lexical
 485         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 486     }
 487 }
 488
 489 ## --------------------------------------------------------
 490 # define some basic built-in types
 491 ## --------------------------------------------------------
 492
 493 # By making these classes immutable before creating all the types we
 494 # below, we avoid repeatedly calling the slow MOP-based accessors.
 495 $_->make_immutable(
 496     inline_constructor => 1,
 497     constructor_name   => "_new",
 498
 499     # these are Class::MOP accessors, so they need inlining
 500     inline_accessors => 1
 501     ) for grep { $_->is_mutable }
 502     map { $_->meta }
 503     qw(
 504     Moose::Meta::TypeConstraint
 505     Moose::Meta::TypeConstraint::Union
 506     Moose::Meta::TypeConstraint::Parameterized
 507     Moose::Meta::TypeConstraint::Parameterizable
 508     Moose::Meta::TypeConstraint::Class
 509     Moose::Meta::TypeConstraint::Role
 510     Moose::Meta::TypeConstraint::Enum
 511     Moose::Meta::TypeConstraint::Registry
 512 );
 513
 514 type 'Any'  => where { 1 }; # meta-type including all
 515 type 'Item' => where { 1 }; # base-type
 516
 517 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 518 subtype 'Defined' => as 'Item' => where {  defined($_) };
 519
 520 subtype 'Bool'
 521     => as 'Item'
 522     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 523
 524 subtype 'Value'
 525     => as 'Defined'
 526     => where { !ref($_) }
 527     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 528
 529 subtype 'Ref'
 530     => as 'Defined'
 531     => where {  ref($_) }
 532     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 533
 534 subtype 'Str'
 535     => as 'Value'
 536     => where { 1 }
 537     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 538
 539 subtype 'Num'
 540     => as 'Value'
 541     => where { Scalar::Util::looks_like_number($_) }
 542     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 543
 544 subtype 'Int'
 545     => as 'Num'
 546     => where { "$_" =~ /^-?[0-9]+$/ }
 547     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 548
 549 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 550 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 551 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 552 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 553
 554 # NOTE:
 555 # scalar filehandles are GLOB refs,
 556 # but a GLOB ref is not always a filehandle
 557 subtype 'FileHandle'
 558     => as 'GlobRef'
 559     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 560     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 561
 562 # NOTE:
 563 # blessed(qr/.../) returns true,.. how odd
 564 subtype 'Object'
 565     => as 'Ref'
 566     => where { blessed($_) && blessed($_) ne 'Regexp' }
 567     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 568
 569 subtype 'Role'
 570     => as 'Object'
 571     => where { $_->can('does') }
 572     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 573
 574 my $_class_name_checker = sub {
 575 };
 576
 577 subtype 'ClassName'
 578     => as 'Str'
 579     => where { Class::MOP::is_class_loaded($_) }
 580     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 581
 582 ## --------------------------------------------------------
 583 # parameterizable types ...
 584
 585 $REGISTRY->add_type_constraint(
 586     Moose::Meta::TypeConstraint::Parameterizable->new(
 587         name                 => 'ArrayRef',
 588         package_defined_in   => __PACKAGE__,
 589         parent               => find_type_constraint('Ref'),
 590         constraint           => sub { ref($_) eq 'ARRAY'  },
 591         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 592         constraint_generator => sub {
 593             my $type_parameter = shift;
 594             my $check = $type_parameter->_compiled_type_constraint;
 595             return sub {
 596                 foreach my $x (@$_) {
 597                     ($check->($x)) || return
 598                 } 1;
 599             }
 600         }
 601     )
 602 );
 603
 604 $REGISTRY->add_type_constraint(
 605     Moose::Meta::TypeConstraint::Parameterizable->new(
 606         name                 => 'HashRef',
 607         package_defined_in   => __PACKAGE__,
 608         parent               => find_type_constraint('Ref'),
 609         constraint           => sub { ref($_) eq 'HASH'  },
 610         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 611         constraint_generator => sub {
 612             my $type_parameter = shift;
 613             my $check = $type_parameter->_compiled_type_constraint;
 614             return sub {
 615                 foreach my $x (values %$_) {
 616                     ($check->($x)) || return
 617                 } 1;
 618             }
 619         }
 620     )
 621 );
 622
 623 $REGISTRY->add_type_constraint(
 624     Moose::Meta::TypeConstraint::Parameterizable->new(
 625         name                 => 'Maybe',
 626         package_defined_in   => __PACKAGE__,
 627         parent               => find_type_constraint('Item'),
 628         constraint           => sub { 1 },
 629         constraint_generator => sub {
 630             my $type_parameter = shift;
 631             my $check = $type_parameter->_compiled_type_constraint;
 632             return sub {
 633                 return 1 if not(defined($_)) || $check->($_);
 634                 return;
 635             }
 636         }
 637     )
 638 );
 639
 640 my @PARAMETERIZABLE_TYPES = map {
 641     $REGISTRY->get_type_constraint($_)
 642 } qw[ArrayRef HashRef Maybe];
 643
 644 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 645 sub add_parameterizable_type {
 646     my $type = shift;
 647     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 648         || __PACKAGE__->_throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 649     push @PARAMETERIZABLE_TYPES => $type;
 650 }
 651
 652 ## --------------------------------------------------------
 653 # end of built-in types ...
 654 ## --------------------------------------------------------
 655
 656 {
 657     my @BUILTINS = list_all_type_constraints();
 658     sub list_all_builtin_type_constraints { @BUILTINS }
 659 }
 660
 661 sub _throw_error {
 662     require Moose;
 663     unshift @_, 'Moose';
 664     goto &Moose::throw_error;
 665 }
 666
 667 1;
 668
 669 __END__
 670
 671 =pod
 672
 673 =head1 NAME
 674
 675 Moose::Util::TypeConstraints - Type constraint system for Moose
 676
 677 =head1 SYNOPSIS
 678
 679   use Moose::Util::TypeConstraints;
 680
 681   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 682
 683   subtype 'Natural'
 684       => as 'Int'
 685       => where { $_ > 0 };
 686
 687   subtype 'NaturalLessThanTen'
 688       => as 'Natural'
 689       => where { $_ < 10 }
 690       => message { "This number ($_) is not less than ten!" };
 691
 692   coerce 'Num'
 693       => from 'Str'
 694         => via { 0+$_ };
 695
 696   enum 'RGBColors' => qw(red green blue);
 697
 698 =head1 DESCRIPTION
 699
 700 This module provides Moose with the ability to create custom type
 701 contraints to be used in attribute definition.
 702
 703 =head2 Important Caveat
 704
 705 This is B<NOT> a type system for Perl 5. These are type constraints,
 706 and they are not used by Moose unless you tell it to. No type
 707 inference is performed, expression are not typed, etc. etc. etc.
 708
 709 This is simply a means of creating small constraint functions which
 710 can be used to simplify your own type-checking code, with the added
 711 side benefit of making your intentions clearer through self-documentation.
 712
 713 =head2 Slightly Less Important Caveat
 714
 715 It is B<always> a good idea to quote your type and subtype names.
 716
 717 This is to prevent perl from trying to execute the call as an indirect
 718 object call. This issue only seems to come up when you have a subtype
 719 the same name as a valid class, but when the issue does arise it tends
 720 to be quite annoying to debug.
 721
 722 So for instance, this:
 723
 724   subtype DateTime => as Object => where { $_->isa('DateTime') };
 725
 726 will I<Just Work>, while this:
 727
 728   use DateTime;
 729   subtype DateTime => as Object => where { $_->isa('DateTime') };
 730
 731 will fail silently and cause many headaches. The simple way to solve
 732 this, as well as future proof your subtypes from classes which have
 733 yet to have been created yet, is to simply do this:
 734
 735   use DateTime;
 736   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 737
 738 =head2 Default Type Constraints
 739
 740 This module also provides a simple hierarchy for Perl 5 types, here is
 741 that hierarchy represented visually.
 742
 743   Any
 744   Item
 745       Bool
 746       Maybe[`a]
 747       Undef
 748       Defined
 749           Value
 750               Num
 751                 Int
 752               Str
 753                 ClassName
 754           Ref
 755               ScalarRef
 756               ArrayRef[`a]
 757               HashRef[`a]
 758               CodeRef
 759               RegexpRef
 760               GlobRef
 761                 FileHandle
 762               Object
 763                 Role
 764
 765 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 766 parameterized, this means you can say:
 767
 768   ArrayRef[Int]    # an array of integers
 769   HashRef[CodeRef] # a hash of str to CODE ref mappings
 770   Maybe[Str]       # value may be a string, may be undefined
 771
 772 If Moose finds a name in brackets that it does not recognize as an
 773 existing type, it assumes that this is a class name, for example
 774 C<ArrayRef[DateTime]>.
 775
 776 B<NOTE:> Unless you parameterize a type, then it is invalid to
 777 include the square brackets. I.e. C<ArrayRef[]> will be
 778 literally interpreted as a type name.
 779
 780 B<NOTE:> The C<Undef> type constraint for the most part works
 781 correctly now, but edge cases may still exist, please use it
 782 sparringly.
 783
 784 B<NOTE:> The C<ClassName> type constraint does a complex package
 785 existence check. This means that your class B<must> be loaded for
 786 this type constraint to pass. I know this is not ideal for all,
 787 but it is a saner restriction than most others.
 788
 789 =head2 Type Constraint Naming
 790
 791 Since the types created by this module are global, it is suggested
 792 that you namespace your types just as you would namespace your
 793 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 794 module, you would call the type I<My.Graphics.Color> instead.
 795
 796 =head2 Use with Other Constraint Modules
 797
 798 This module should play fairly nicely with other constraint
 799 modules with only some slight tweaking. The C<where> clause
 800 in types is expected to be a C<CODE> reference which checks
 801 it's first argument and returns a boolean. Since most constraint
 802 modules work in a similar way, it should be simple to adapt
 803 them to work with Moose.
 804
 805 For instance, this is how you could use it with
 806 L<Declare::Constraints::Simple> to declare a completely new type.
 807
 808   type 'HashOfArrayOfObjects'
 809       => IsHashRef(
 810           -keys   => HasLength,
 811           -values => IsArrayRef( IsObject ));
 812
 813 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 814 test file.
 815
 816 Here is an example of using L<Test::Deep> and it's non-test
 817 related C<eq_deeply> function.
 818
 819   type 'ArrayOfHashOfBarsAndRandomNumbers'
 820       => where {
 821           eq_deeply($_,
 822               array_each(subhashof({
 823                   bar           => isa('Bar'),
 824                   random_number => ignore()
 825               })))
 826         };
 827
 828 For a complete example see the
 829 F<t/200_examples/205_example_w_TestDeep.t> test file.
 830
 831 =head1 FUNCTIONS
 832
 833 =head2 Type Constraint Constructors
 834
 835 The following functions are used to create type constraints.
 836 They will then register the type constraints in a global store
 837 where Moose can get to them if it needs to.
 838
 839 See the L<SYNOPSIS> for an example of how to use these.
 840
 841 =over 4
 842
 843 =item B<type ($name, $where_clause)>
 844
 845 This creates a base type, which has no parent.
 846
 847 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 848
 849 This creates a named subtype.
 850
 851 If you provide a parent that Moose does not recognize, it will
 852 automatically create a new class type constraint for this name.
 853
 854 =item B<subtype ($parent, $where_clause, ?$message)>
 855
 856 This creates an unnamed subtype and will return the type
 857 constraint meta-object, which will be an instance of
 858 L<Moose::Meta::TypeConstraint>.
 859
 860 =item B<class_type ($class, ?$options)>
 861
 862 Creates a type constraint with the name C<$class> and the metaclass
 863 L<Moose::Meta::TypeConstraint::Class>.
 864
 865 =item B<role_type ($role, ?$options)>
 866
 867 Creates a type constraint with the name C<$role> and the metaclass
 868 L<Moose::Meta::TypeConstraint::Role>.
 869
 870 =item B<maybe_type ($type)>
 871
 872 Creates a type constraint for either C<undef> or something of the
 873 given type.
 874
 875 =item B<enum ($name, @values)>
 876
 877 This will create a basic subtype for a given set of strings.
 878 The resulting constraint will be a subtype of C<Str> and
 879 will match any of the items in C<@values>. It is case sensitive.
 880 See the L<SYNOPSIS> for a simple example.
 881
 882 B<NOTE:> This is not a true proper enum type, it is simple
 883 a convient constraint builder.
 884
 885 =item B<enum (\@values)>
 886
 887 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 888 this will create an unnamed enum. This can then be used in an attribute
 889 definition like so:
 890
 891   has 'sort_order' => (
 892       is  => 'ro',
 893       isa => enum([qw[ ascending descending ]]),
 894   );
 895
 896 =item B<as>
 897
 898 This is just sugar for the type constraint construction syntax.
 899
 900 =item B<where>
 901
 902 This is just sugar for the type constraint construction syntax.
 903
 904 Takes a block/code ref as an argument. When the type constraint is
 905 tested, the supplied code is run with the value to be tested in
 906 $_. This block should return true or false to indicate whether or not
 907 the constraint check passed.
 908
 909 =item B<message>
 910
 911 This is just sugar for the type constraint construction syntax.
 912
 913 Takes a block/code ref as an argument. When the type constraint fails,
 914 then the code block is run (with the value provided in $_). This code
 915 ref should return a string, which will be used in the text of the
 916 exception thrown.
 917
 918 =item B<optimize_as>
 919
 920 This can be used to define a "hand optimized" version of your
 921 type constraint which can be used to avoid traversing a subtype
 922 constraint heirarchy.
 923
 924 B<NOTE:> You should only use this if you know what you are doing,
 925 all the built in types use this, so your subtypes (assuming they
 926 are shallow) will not likely need to use this.
 927
 928 =back
 929
 930 =head2 Type Coercion Constructors
 931
 932 Type constraints can also contain type coercions as well. If you
 933 ask your accessor to coerce, then Moose will run the type-coercion
 934 code first, followed by the type constraint check. This feature
 935 should be used carefully as it is very powerful and could easily
 936 take off a limb if you are not careful.
 937
 938 See the L<SYNOPSIS> for an example of how to use these.
 939
 940 =over 4
 941
 942 =item B<coerce>
 943
 944 =item B<from>
 945
 946 This is just sugar for the type coercion construction syntax.
 947
 948 =item B<via>
 949
 950 This is just sugar for the type coercion construction syntax.
 951
 952 =back
 953
 954 =head2 Type Constraint Construction & Locating
 955
 956 =over 4
 957
 958 =item B<normalize_type_constraint_name ($type_constraint_name)>
 959
 960 Given a string that is expected to match a type constraint, will normalize the
 961 string so that extra whitespace and newlines are removed.
 962
 963 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 964
 965 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 966 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 967
 968 =item B<create_parameterized_type_constraint ($type_name)>
 969
 970 Given a C<$type_name> in the form of:
 971
 972   BaseType[ContainerType]
 973
 974 this will extract the base type and container type and build an instance of
 975 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 976
 977 =item B<create_class_type_constraint ($class, ?$options)>
 978
 979 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 980 object for that class name.
 981
 982 =item B<create_role_type_constraint ($role, ?$options)>
 983
 984 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 985 object for that role name.
 986
 987 =item B<create_enum_type_constraint ($name, $values)>
 988
 989 =item B<find_or_parse_type_constraint ($type_name)>
 990
 991 This will attempt to find or create a type constraint given the a C<$type_name>.
 992 If it cannot find it in the registry, it will see if it should be a union or
 993 container type an create one if appropriate
 994
 995 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 996
 997 This function will first call C<find_or_parse_type_constraint> with the type name.
 998
 999 If no type is found or created, but C<$options_for_anon_type> are provided, it
1000 will create the corresponding type.
1001
1002 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
1003 and are now superseded by C<find_or_create_isa_type_constraint> and
1004 C<find_or_create_does_type_constraint>.
1005
1006 =item B<find_or_create_isa_type_constraint ($type_name)>
1007
1008 =item B<find_or_create_does_type_constraint ($type_name)>
1009
1010 Attempts to parse the type name using C<find_or_parse_type_constraint> and if
1011 no appropriate constraint is found will create a new anonymous one.
1012
1013 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
1014 variant will use C<create_role_type_constraint>.
1015
1016 =item B<find_type_constraint ($type_name)>
1017
1018 This function can be used to locate a specific type constraint
1019 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
1020 derivative. What you do with it from there is up to you :)
1021
1022 =item B<register_type_constraint ($type_object)>
1023
1024 This function will register a named type constraint with the type registry.
1025
1026 =item B<get_type_constraint_registry>
1027
1028 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
1029 keeps track of all type constraints.
1030
1031 =item B<list_all_type_constraints>
1032
1033 This will return a list of type constraint names, you can then
1034 fetch them using C<find_type_constraint ($type_name)> if you
1035 want to.
1036
1037 =item B<list_all_builtin_type_constraints>
1038
1039 This will return a list of builtin type constraints, meaning,
1040 those which are defined in this module. See the section
1041 labeled L<Default Type Constraints> for a complete list.
1042
1043 =item B<export_type_constraints_as_functions>
1044
1045 This will export all the current type constraints as functions
1046 into the caller's namespace. Right now, this is mostly used for
1047 testing, but it might prove useful to others.
1048
1049 =item B<get_all_parameterizable_types>
1050
1051 This returns all the parameterizable types that have been registered.
1052
1053 =item B<add_parameterizable_type ($type)>
1054
1055 Adds C<$type> to the list of parameterizable types
1056
1057 =back
1058
1059 =head2 Namespace Management
1060
1061 =over 4
1062
1063 =item B<unimport>
1064
1065 This will remove all the type constraint keywords from the
1066 calling class namespace.
1067
1068 =back
1069
1070 =head1 BUGS
1071
1072 All complex software has bugs lurking in it, and this module is no
1073 exception. If you find a bug please either email me, or add the bug
1074 to cpan-RT.
1075
1076 =head1 AUTHOR
1077
1078 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1079
1080 =head1 COPYRIGHT AND LICENSE
1081
1082 Copyright 2006-2008 by Infinity Interactive, Inc.
1083
1084 L<http://www.iinteractive.com>
1085
1086 This library is free software; you can redistribute it and/or modify
1087 it under the same terms as Perl itself.
1088
1089 =cut