lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.59';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type as where message optimize_as
  51             coerce from via
  52             enum
  53             find_type_constraint
  54             register_type_constraint )
  55     ],
  56     _export_to_main => 1,
  57 );
  58
  59 ## --------------------------------------------------------
  60 ## type registry and some useful functions for it
  61 ## --------------------------------------------------------
  62
  63 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  64
  65 sub get_type_constraint_registry         { $REGISTRY }
  66 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  67 sub export_type_constraints_as_functions {
  68     my $pkg = caller();
  69     no strict 'refs';
  70     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  71         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  72         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  73     }
  74 }
  75
  76 sub create_type_constraint_union {
  77     my @type_constraint_names;
  78
  79     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  80         @type_constraint_names = _parse_type_constraint_union($_[0]);
  81     }
  82     else {
  83         @type_constraint_names = @_;
  84     }
  85
  86     (scalar @type_constraint_names >= 2)
  87         || Moose->throw_error("You must pass in at least 2 type names to make a union");
  88
  89     my @type_constraints = map {
  90         find_or_parse_type_constraint($_) ||
  91          Moose->throw_error("Could not locate type constraint ($_) for the union");
  92     } @type_constraint_names;
  93
  94     return Moose::Meta::TypeConstraint::Union->new(
  95         type_constraints => \@type_constraints
  96     );
  97 }
  98
  99 sub create_parameterized_type_constraint {
 100     my $type_constraint_name = shift;
 101     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 102
 103     (defined $base_type && defined $type_parameter)
 104         || Moose->throw_error("Could not parse type name ($type_constraint_name) correctly");
 105
 106     if ($REGISTRY->has_type_constraint($base_type)) {
 107         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 108         return _create_parameterized_type_constraint(
 109             $base_type_tc,
 110             $type_parameter
 111         );
 112     } else {
 113         Moose->throw_error("Could not locate the base type ($base_type)");
 114     }
 115 }
 116
 117 sub _create_parameterized_type_constraint {
 118     my ( $base_type_tc, $type_parameter ) = @_;
 119     if ( $base_type_tc->can('parameterize') ) {
 120         return $base_type_tc->parameterize($type_parameter);
 121     } else {
 122         return Moose::Meta::TypeConstraint::Parameterized->new(
 123             name => $base_type_tc->name . '[' . $type_parameter . ']',
 124             parent => $base_type_tc,
 125             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 126         );
 127     }
 128 }
 129
 130 #should we also support optimized checks?
 131 sub create_class_type_constraint {
 132     my ( $class, $options ) = @_;
 133
 134     # too early for this check
 135     #find_type_constraint("ClassName")->check($class)
 136     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 137
 138     my %options = (
 139         class => $class,
 140         name  => $class,
 141         %{ $options || {} },
 142     );
 143
 144     $options{name} ||= "__ANON__";
 145
 146     Moose::Meta::TypeConstraint::Class->new( %options );
 147 }
 148
 149 sub create_role_type_constraint {
 150     my ( $role, $options ) = @_;
 151
 152     # too early for this check
 153     #find_type_constraint("ClassName")->check($class)
 154     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 155
 156     my %options = (
 157         role => $role,
 158         name => $role,
 159         %{ $options || {} },
 160     );
 161
 162     $options{name} ||= "__ANON__";
 163
 164     Moose::Meta::TypeConstraint::Role->new( %options );
 165 }
 166
 167
 168 sub find_or_create_type_constraint {
 169     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 170
 171     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 172         return $constraint;
 173     }
 174     elsif ( defined $options_for_anon_type ) {
 175         # NOTE:
 176         # if there is no $options_for_anon_type
 177         # specified, then we assume they don't
 178         # want to create one, and return nothing.
 179
 180         # otherwise assume that we should create
 181         # an ANON type with the $options_for_anon_type
 182         # options which can be passed in. It should
 183         # be noted that these don't get registered
 184         # so we need to return it.
 185         # - SL
 186         return Moose::Meta::TypeConstraint->new(
 187             name => '__ANON__',
 188             %{$options_for_anon_type}
 189         );
 190     }
 191
 192     return;
 193 }
 194
 195 sub find_or_create_isa_type_constraint {
 196     my $type_constraint_name = shift;
 197     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 198 }
 199
 200 sub find_or_create_does_type_constraint {
 201     my $type_constraint_name = shift;
 202     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 203 }
 204
 205 sub find_or_parse_type_constraint {
 206     my $type_constraint_name = normalize_type_constraint_name(shift);
 207     my $constraint;
 208
 209     if ($constraint = find_type_constraint($type_constraint_name)) {
 210         return $constraint;
 211     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 212         $constraint = create_type_constraint_union($type_constraint_name);
 213     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 214         $constraint = create_parameterized_type_constraint($type_constraint_name);
 215     } else {
 216         return;
 217     }
 218
 219     $REGISTRY->add_type_constraint($constraint);
 220     return $constraint;
 221 }
 222
 223 sub normalize_type_constraint_name {
 224     my $type_constraint_name = shift;
 225     $type_constraint_name =~ s/\s//g;
 226     return $type_constraint_name;
 227 }
 228
 229 sub _confess {
 230     my $error = shift;
 231
 232     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 233     Carp::confess($error);
 234 }
 235
 236 ## --------------------------------------------------------
 237 ## exported functions ...
 238 ## --------------------------------------------------------
 239
 240 sub find_type_constraint {
 241     my $type = shift;
 242
 243     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 244         return $type;
 245     }
 246     else {
 247         return unless $REGISTRY->has_type_constraint($type);
 248         return $REGISTRY->get_type_constraint($type);
 249     }
 250 }
 251
 252 sub register_type_constraint {
 253     my $constraint = shift;
 254     Moose->throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 255     $REGISTRY->add_type_constraint($constraint);
 256     return $constraint;
 257 }
 258
 259 # type constructors
 260
 261 sub type {
 262     splice(@_, 1, 0, undef);
 263     goto &_create_type_constraint;
 264 }
 265
 266 sub subtype {
 267     # NOTE:
 268     # this adds an undef for the name
 269     # if this is an anon-subtype:
 270     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 271     #     or
 272     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 273     #
 274     # but if the last arg is not a code ref then it is a subtype
 275     # alias:
 276     #
 277     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 278     # ... yeah I know it's ugly code
 279     # - SL
 280     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 281     unshift @_ => undef
 282         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 283     goto &_create_type_constraint;
 284 }
 285
 286 sub class_type {
 287     register_type_constraint(
 288         create_class_type_constraint(
 289             $_[0],
 290             ( defined($_[1]) ? $_[1] : () ),
 291         )
 292     );
 293 }
 294
 295 sub role_type ($;$) {
 296     register_type_constraint(
 297         create_role_type_constraint(
 298             $_[0],
 299             ( defined($_[1]) ? $_[1] : () ),
 300         )
 301     );
 302 }
 303
 304 sub coerce {
 305     my ($type_name, @coercion_map) = @_;
 306     _install_type_coercions($type_name, \@coercion_map);
 307 }
 308
 309 sub as          { @_ }
 310 sub from        { @_ }
 311 sub where   (&) { $_[0] }
 312 sub via     (&) { $_[0] }
 313
 314 sub message     (&) { +{ message   => $_[0] } }
 315 sub optimize_as (&) { +{ optimized => $_[0] } }
 316
 317 sub enum {
 318     my ($type_name, @values) = @_;
 319     # NOTE:
 320     # if only an array-ref is passed then
 321     # you get an anon-enum
 322     # - SL
 323     if (ref $type_name eq 'ARRAY' && !@values) {
 324         @values    = @$type_name;
 325         $type_name = undef;
 326     }
 327     (scalar @values >= 2)
 328         || Moose->throw_error("You must have at least two values to enumerate through");
 329     my %valid = map { $_ => 1 } @values;
 330
 331     register_type_constraint(
 332         create_enum_type_constraint(
 333             $type_name,
 334             \@values,
 335         )
 336     );
 337 }
 338
 339 sub create_enum_type_constraint {
 340     my ( $type_name, $values ) = @_;
 341
 342     Moose::Meta::TypeConstraint::Enum->new(
 343         name   => $type_name || '__ANON__',
 344         values => $values,
 345     );
 346 }
 347
 348 ## --------------------------------------------------------
 349 ## desugaring functions ...
 350 ## --------------------------------------------------------
 351
 352 sub _create_type_constraint ($$$;$$) {
 353     my $name   = shift;
 354     my $parent = shift;
 355     my $check  = shift;
 356
 357     my ($message, $optimized);
 358     for (@_) {
 359         $message   = $_->{message}   if exists $_->{message};
 360         $optimized = $_->{optimized} if exists $_->{optimized};
 361     }
 362
 363     my $pkg_defined_in = scalar(caller(0));
 364
 365     if (defined $name) {
 366         my $type = $REGISTRY->get_type_constraint($name);
 367
 368         ( $type->_package_defined_in eq $pkg_defined_in )
 369             || _confess(
 370                   "The type constraint '$name' has already been created in "
 371                 . $type->_package_defined_in
 372                 . " and cannot be created again in "
 373                 . $pkg_defined_in )
 374             if defined $type;
 375     }
 376
 377     ## Here are the basic options we will use to create the constraint.  These
 378     ## may be altered depending on the parent type, etc.
 379
 380     my %opts = (
 381         name => $name || '__ANON__',
 382         package_defined_in => $pkg_defined_in,
 383
 384         ($check     ? (constraint => $check)     : ()),
 385         ($message   ? (message    => $message)   : ()),
 386         ($optimized ? (optimized  => $optimized) : ()),
 387     );
 388
 389     ## If we have a parent we make sure to instantiate this new type constraint
 390     ## as a subclass of the parents meta class.  We need to see if the $parent
 391     ## is already a blessed TC or if we need to go make it based on it's name
 392
 393     my $constraint;
 394
 395     if(
 396         defined $parent
 397         and $parent = blessed $parent ? $parent:find_or_parse_type_constraint($parent)
 398     ) {
 399         ## creating the child is a job we delegate to the parent, since each
 400         ## parent may have local customization needs to influence it's child.
 401         $constraint = $parent->create_childtype(%opts);
 402     } else {
 403         ## If for some reason the above couldn't create a type constraint, let's
 404         ## make sure to create something.
 405         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 406     }
 407
 408     ## Unless we have a request to make an anonynmous constraint, let's add it
 409     ## to the $REGISTRY so that it gets cached for quicker lookups next time
 410
 411     $REGISTRY->add_type_constraint($constraint)
 412         if defined $name;
 413
 414     return $constraint;
 415 }
 416
 417 sub _install_type_coercions ($$) {
 418     my ($type_name, $coercion_map) = @_;
 419     my $type = find_type_constraint($type_name);
 420     (defined $type)
 421         || Moose->throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 422     if ($type->has_coercion) {
 423         $type->coercion->add_type_coercions(@$coercion_map);
 424     }
 425     else {
 426         my $type_coercion = Moose::Meta::TypeCoercion->new(
 427             type_coercion_map => $coercion_map,
 428             type_constraint   => $type
 429         );
 430         $type->coercion($type_coercion);
 431     }
 432 }
 433
 434 ## --------------------------------------------------------
 435 ## type notation parsing ...
 436 ## --------------------------------------------------------
 437
 438 {
 439     # All I have to say is mugwump++ cause I know
 440     # do not even have enough regexp-fu to be able
 441     # to have written this (I can only barely
 442     # understand it as it is)
 443     # - SL
 444
 445     use re "eval";
 446
 447     my $valid_chars = qr{[\w:]};
 448     my $type_atom   = qr{ $valid_chars+ };
 449
 450     my $any;
 451
 452     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 453     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 454     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 455
 456     my $op_union = qr{ \s* \| \s* }x;
 457     my $union    = qr{ $type (?: $op_union $type )+ }x;
 458
 459     $any = qr{ $type | $union }x;
 460
 461     sub _parse_parameterized_type_constraint {
 462         { no warnings 'void'; $any; } # force capture of interpolated lexical
 463         $_[0] =~ m{ $type_capture_parts }x;
 464         return ($1, $2);
 465     }
 466
 467     sub _detect_parameterized_type_constraint {
 468         { no warnings 'void'; $any; } # force capture of interpolated lexical
 469         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 470     }
 471
 472     sub _parse_type_constraint_union {
 473         { no warnings 'void'; $any; } # force capture of interpolated lexical
 474         my $given = shift;
 475         my @rv;
 476         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 477             push @rv => $1;
 478         }
 479         (pos($given) eq length($given))
 480             || Moose->throw_error("'$given' didn't parse (parse-pos="
 481                      . pos($given)
 482                      . " and str-length="
 483                      . length($given)
 484                      . ")");
 485         @rv;
 486     }
 487
 488     sub _detect_type_constraint_union {
 489         { no warnings 'void'; $any; } # force capture of interpolated lexical
 490         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 491     }
 492 }
 493
 494 ## --------------------------------------------------------
 495 # define some basic built-in types
 496 ## --------------------------------------------------------
 497
 498 type 'Any'  => where { 1 }; # meta-type including all
 499 type 'Item' => where { 1 }; # base-type
 500
 501 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 502 subtype 'Defined' => as 'Item' => where {  defined($_) };
 503
 504 subtype 'Bool'
 505     => as 'Item'
 506     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 507
 508 subtype 'Value'
 509     => as 'Defined'
 510     => where { !ref($_) }
 511     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 512
 513 subtype 'Ref'
 514     => as 'Defined'
 515     => where {  ref($_) }
 516     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 517
 518 subtype 'Str'
 519     => as 'Value'
 520     => where { 1 }
 521     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 522
 523 subtype 'Num'
 524     => as 'Value'
 525     => where { Scalar::Util::looks_like_number($_) }
 526     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 527
 528 subtype 'Int'
 529     => as 'Num'
 530     => where { "$_" =~ /^-?[0-9]+$/ }
 531     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 532
 533 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 534 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 535 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 536 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 537
 538 # NOTE:
 539 # scalar filehandles are GLOB refs,
 540 # but a GLOB ref is not always a filehandle
 541 subtype 'FileHandle'
 542     => as 'GlobRef'
 543     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 544     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 545
 546 # NOTE:
 547 # blessed(qr/.../) returns true,.. how odd
 548 subtype 'Object'
 549     => as 'Ref'
 550     => where { blessed($_) && blessed($_) ne 'Regexp' }
 551     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 552
 553 subtype 'Role'
 554     => as 'Object'
 555     => where { $_->can('does') }
 556     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 557
 558 my $_class_name_checker = sub {
 559 };
 560
 561 subtype 'ClassName'
 562     => as 'Str'
 563     => where { Class::MOP::is_class_loaded($_) }
 564     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 565
 566 ## --------------------------------------------------------
 567 # parameterizable types ...
 568
 569 $REGISTRY->add_type_constraint(
 570     Moose::Meta::TypeConstraint::Parameterizable->new(
 571         name                 => 'ArrayRef',
 572         package_defined_in   => __PACKAGE__,
 573         parent               => find_type_constraint('Ref'),
 574         constraint           => sub { ref($_) eq 'ARRAY'  },
 575         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 576         constraint_generator => sub {
 577             my $type_parameter = shift;
 578             my $check = $type_parameter->_compiled_type_constraint;
 579             return sub {
 580                 foreach my $x (@$_) {
 581                     ($check->($x)) || return
 582                 } 1;
 583             }
 584         }
 585     )
 586 );
 587
 588 $REGISTRY->add_type_constraint(
 589     Moose::Meta::TypeConstraint::Parameterizable->new(
 590         name                 => 'HashRef',
 591         package_defined_in   => __PACKAGE__,
 592         parent               => find_type_constraint('Ref'),
 593         constraint           => sub { ref($_) eq 'HASH'  },
 594         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 595         constraint_generator => sub {
 596             my $type_parameter = shift;
 597             my $check = $type_parameter->_compiled_type_constraint;
 598             return sub {
 599                 foreach my $x (values %$_) {
 600                     ($check->($x)) || return
 601                 } 1;
 602             }
 603         }
 604     )
 605 );
 606
 607 $REGISTRY->add_type_constraint(
 608     Moose::Meta::TypeConstraint::Parameterizable->new(
 609         name                 => 'Maybe',
 610         package_defined_in   => __PACKAGE__,
 611         parent               => find_type_constraint('Item'),
 612         constraint           => sub { 1 },
 613         constraint_generator => sub {
 614             my $type_parameter = shift;
 615             my $check = $type_parameter->_compiled_type_constraint;
 616             return sub {
 617                 return 1 if not(defined($_)) || $check->($_);
 618                 return;
 619             }
 620         }
 621     )
 622 );
 623
 624 my @PARAMETERIZABLE_TYPES = map {
 625     $REGISTRY->get_type_constraint($_)
 626 } qw[ArrayRef HashRef Maybe];
 627
 628 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 629 sub add_parameterizable_type {
 630     my $type = shift;
 631     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 632         || Moose->throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 633     push @PARAMETERIZABLE_TYPES => $type;
 634 }
 635
 636 ## --------------------------------------------------------
 637 # end of built-in types ...
 638 ## --------------------------------------------------------
 639
 640 {
 641     my @BUILTINS = list_all_type_constraints();
 642     sub list_all_builtin_type_constraints { @BUILTINS }
 643 }
 644
 645 1;
 646
 647 __END__
 648
 649 =pod
 650
 651 =head1 NAME
 652
 653 Moose::Util::TypeConstraints - Type constraint system for Moose
 654
 655 =head1 SYNOPSIS
 656
 657   use Moose::Util::TypeConstraints;
 658
 659   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 660
 661   subtype 'Natural'
 662       => as 'Int'
 663       => where { $_ > 0 };
 664
 665   subtype 'NaturalLessThanTen'
 666       => as 'Natural'
 667       => where { $_ < 10 }
 668       => message { "This number ($_) is not less than ten!" };
 669
 670   coerce 'Num'
 671       => from 'Str'
 672         => via { 0+$_ };
 673
 674   enum 'RGBColors' => qw(red green blue);
 675
 676 =head1 DESCRIPTION
 677
 678 This module provides Moose with the ability to create custom type
 679 contraints to be used in attribute definition.
 680
 681 =head2 Important Caveat
 682
 683 This is B<NOT> a type system for Perl 5. These are type constraints,
 684 and they are not used by Moose unless you tell it to. No type
 685 inference is performed, expression are not typed, etc. etc. etc.
 686
 687 This is simply a means of creating small constraint functions which
 688 can be used to simplify your own type-checking code, with the added
 689 side benefit of making your intentions clearer through self-documentation.
 690
 691 =head2 Slightly Less Important Caveat
 692
 693 It is B<always> a good idea to quote your type and subtype names.
 694
 695 This is to prevent perl from trying to execute the call as an indirect
 696 object call. This issue only seems to come up when you have a subtype
 697 the same name as a valid class, but when the issue does arise it tends
 698 to be quite annoying to debug.
 699
 700 So for instance, this:
 701
 702   subtype DateTime => as Object => where { $_->isa('DateTime') };
 703
 704 will I<Just Work>, while this:
 705
 706   use DateTime;
 707   subtype DateTime => as Object => where { $_->isa('DateTime') };
 708
 709 will fail silently and cause many headaches. The simple way to solve
 710 this, as well as future proof your subtypes from classes which have
 711 yet to have been created yet, is to simply do this:
 712
 713   use DateTime;
 714   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 715
 716 =head2 Default Type Constraints
 717
 718 This module also provides a simple hierarchy for Perl 5 types, here is
 719 that hierarchy represented visually.
 720
 721   Any
 722   Item
 723       Bool
 724       Maybe[`a]
 725       Undef
 726       Defined
 727           Value
 728               Num
 729                 Int
 730               Str
 731                 ClassName
 732           Ref
 733               ScalarRef
 734               ArrayRef[`a]
 735               HashRef[`a]
 736               CodeRef
 737               RegexpRef
 738               GlobRef
 739                 FileHandle
 740               Object
 741                   Role
 742
 743 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 744 parameterized, this means you can say:
 745
 746   ArrayRef[Int]    # an array of integers
 747   HashRef[CodeRef] # a hash of str to CODE ref mappings
 748   Maybe[Str]       # value may be a string, may be undefined
 749
 750 B<NOTE:> Unless you parameterize a type, then it is invalid to
 751 include the square brackets. I.e. C<ArrayRef[]> will be
 752 literally interpreted as a type name.
 753
 754 B<NOTE:> The C<Undef> type constraint for the most part works
 755 correctly now, but edge cases may still exist, please use it
 756 sparringly.
 757
 758 B<NOTE:> The C<ClassName> type constraint does a complex package
 759 existence check. This means that your class B<must> be loaded for
 760 this type constraint to pass. I know this is not ideal for all,
 761 but it is a saner restriction than most others.
 762
 763 =head2 Type Constraint Naming
 764
 765 Since the types created by this module are global, it is suggested
 766 that you namespace your types just as you would namespace your
 767 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 768 module, you would call the type I<My::Graphics::Color> instead.
 769
 770 =head2 Use with Other Constraint Modules
 771
 772 This module should play fairly nicely with other constraint
 773 modules with only some slight tweaking. The C<where> clause
 774 in types is expected to be a C<CODE> reference which checks
 775 it's first argument and returns a boolean. Since most constraint
 776 modules work in a similar way, it should be simple to adapt
 777 them to work with Moose.
 778
 779 For instance, this is how you could use it with
 780 L<Declare::Constraints::Simple> to declare a completely new type.
 781
 782   type 'HashOfArrayOfObjects'
 783       => IsHashRef(
 784           -keys   => HasLength,
 785           -values => IsArrayRef( IsObject ));
 786
 787 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 788 test file.
 789
 790 Here is an example of using L<Test::Deep> and it's non-test
 791 related C<eq_deeply> function.
 792
 793   type 'ArrayOfHashOfBarsAndRandomNumbers'
 794       => where {
 795           eq_deeply($_,
 796               array_each(subhashof({
 797                   bar           => isa('Bar'),
 798                   random_number => ignore()
 799               })))
 800         };
 801
 802 For a complete example see the
 803 F<t/200_examples/205_example_w_TestDeep.t> test file.
 804
 805 =head1 FUNCTIONS
 806
 807 =head2 Type Constraint Constructors
 808
 809 The following functions are used to create type constraints.
 810 They will then register the type constraints in a global store
 811 where Moose can get to them if it needs to.
 812
 813 See the L<SYNOPSIS> for an example of how to use these.
 814
 815 =over 4
 816
 817 =item B<type ($name, $where_clause)>
 818
 819 This creates a base type, which has no parent.
 820
 821 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 822
 823 This creates a named subtype.
 824
 825 =item B<subtype ($parent, $where_clause, ?$message)>
 826
 827 This creates an unnamed subtype and will return the type
 828 constraint meta-object, which will be an instance of
 829 L<Moose::Meta::TypeConstraint>.
 830
 831 =item B<class_type ($class, ?$options)>
 832
 833 Creates a type constraint with the name C<$class> and the metaclass
 834 L<Moose::Meta::TypeConstraint::Class>.
 835
 836 =item B<role_type ($role, ?$options)>
 837
 838 Creates a type constraint with the name C<$role> and the metaclass
 839 L<Moose::Meta::TypeConstraint::Role>.
 840
 841 =item B<enum ($name, @values)>
 842
 843 This will create a basic subtype for a given set of strings.
 844 The resulting constraint will be a subtype of C<Str> and
 845 will match any of the items in C<@values>. It is case sensitive.
 846 See the L<SYNOPSIS> for a simple example.
 847
 848 B<NOTE:> This is not a true proper enum type, it is simple
 849 a convient constraint builder.
 850
 851 =item B<enum (\@values)>
 852
 853 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 854 this will create an unnamed enum. This can then be used in an attribute
 855 definition like so:
 856
 857   has 'sort_order' => (
 858       is  => 'ro',
 859       isa => enum([qw[ ascending descending ]]),
 860   );
 861
 862 =item B<as>
 863
 864 This is just sugar for the type constraint construction syntax.
 865
 866 =item B<where>
 867
 868 This is just sugar for the type constraint construction syntax.
 869
 870 Takes a block/code ref as an argument. When the type constraint is
 871 tested, the supplied code is run with the value to be tested in
 872 $_. This block should return true or false to indicate whether or not
 873 the constraint check passed.
 874
 875 =item B<message>
 876
 877 This is just sugar for the type constraint construction syntax.
 878
 879 Takes a block/code ref as an argument. When the type constraint fails,
 880 then the code block is run (with the value provided in $_). This code
 881 ref should return a string, which will be used in the text of the
 882 exception thrown.
 883
 884 =item B<optimize_as>
 885
 886 This can be used to define a "hand optimized" version of your
 887 type constraint which can be used to avoid traversing a subtype
 888 constraint heirarchy.
 889
 890 B<NOTE:> You should only use this if you know what you are doing,
 891 all the built in types use this, so your subtypes (assuming they
 892 are shallow) will not likely need to use this.
 893
 894 =back
 895
 896 =head2 Type Coercion Constructors
 897
 898 Type constraints can also contain type coercions as well. If you
 899 ask your accessor to coerce, then Moose will run the type-coercion
 900 code first, followed by the type constraint check. This feature
 901 should be used carefully as it is very powerful and could easily
 902 take off a limb if you are not careful.
 903
 904 See the L<SYNOPSIS> for an example of how to use these.
 905
 906 =over 4
 907
 908 =item B<coerce>
 909
 910 =item B<from>
 911
 912 This is just sugar for the type coercion construction syntax.
 913
 914 =item B<via>
 915
 916 This is just sugar for the type coercion construction syntax.
 917
 918 =back
 919
 920 =head2 Type Constraint Construction & Locating
 921
 922 =over 4
 923
 924 =item B<normalize_type_constraint_name ($type_constraint_name)>
 925
 926 Given a string that is expected to match a type constraint, will normalize the
 927 string so that extra whitespace and newlines are removed.
 928
 929 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 930
 931 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 932 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 933
 934 =item B<create_parameterized_type_constraint ($type_name)>
 935
 936 Given a C<$type_name> in the form of:
 937
 938   BaseType[ContainerType]
 939
 940 this will extract the base type and container type and build an instance of
 941 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 942
 943 =item B<create_class_type_constraint ($class, ?$options)>
 944
 945 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 946 object for that class name.
 947
 948 =item B<create_role_type_constraint ($role, ?$options)>
 949
 950 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 951 object for that role name.
 952
 953 =item B<create_enum_type_constraint ($name, $values)>
 954
 955 =item B<find_or_parse_type_constraint ($type_name)>
 956
 957 This will attempt to find or create a type constraint given the a C<$type_name>.
 958 If it cannot find it in the registry, it will see if it should be a union or
 959 container type an create one if appropriate
 960
 961 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 962
 963 This function will first call C<find_or_parse_type_constraint> with the type name.
 964
 965 If no type is found or created, but C<$options_for_anon_type> are provided, it
 966 will create the corresponding type.
 967
 968 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 969 and are now superseded by C<find_or_create_isa_type_constraint> and
 970 C<find_or_create_does_type_constraint>.
 971
 972 =item B<find_or_create_isa_type_constraint ($type_name)>
 973
 974 =item B<find_or_create_does_type_constraint ($type_name)>
 975
 976 Attempts to parse the type name using L<find_or_parse_type_constraint> and if
 977 no appropriate constraint is found will create a new anonymous one.
 978
 979 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
 980 variant will use C<create_role_type_constraint>.
 981
 982 =item B<find_type_constraint ($type_name)>
 983
 984 This function can be used to locate a specific type constraint
 985 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
 986 derivative. What you do with it from there is up to you :)
 987
 988 =item B<register_type_constraint ($type_object)>
 989
 990 This function will register a named type constraint with the type registry.
 991
 992 =item B<get_type_constraint_registry>
 993
 994 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
 995 keeps track of all type constraints.
 996
 997 =item B<list_all_type_constraints>
 998
 999 This will return a list of type constraint names, you can then
1000 fetch them using C<find_type_constraint ($type_name)> if you
1001 want to.
1002
1003 =item B<list_all_builtin_type_constraints>
1004
1005 This will return a list of builtin type constraints, meaning,
1006 those which are defined in this module. See the section
1007 labeled L<Default Type Constraints> for a complete list.
1008
1009 =item B<export_type_constraints_as_functions>
1010
1011 This will export all the current type constraints as functions
1012 into the caller's namespace. Right now, this is mostly used for
1013 testing, but it might prove useful to others.
1014
1015 =item B<get_all_parameterizable_types>
1016
1017 This returns all the parameterizable types that have been registered.
1018
1019 =item B<add_parameterizable_type ($type)>
1020
1021 Adds C<$type> to the list of parameterizable types
1022
1023 =back
1024
1025 =head2 Namespace Management
1026
1027 =over 4
1028
1029 =item B<unimport>
1030
1031 This will remove all the type constraint keywords from the
1032 calling class namespace.
1033
1034 =back
1035
1036 =head1 BUGS
1037
1038 All complex software has bugs lurking in it, and this module is no
1039 exception. If you find a bug please either email me, or add the bug
1040 to cpan-RT.
1041
1042 =head1 AUTHOR
1043
1044 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1045
1046 =head1 COPYRIGHT AND LICENSE
1047
1048 Copyright 2006-2008 by Infinity Interactive, Inc.
1049
1050 L<http://www.iinteractive.com>
1051
1052 This library is free software; you can redistribute it and/or modify
1053 it under the same terms as Perl itself.
1054
1055 =cut