lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'reftype';
   9 use Sub::Exporter;
  10
  11 our $VERSION   = '0.22';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 ## --------------------------------------------------------
  15 # Prototyped subs must be predeclared because we have a
  16 # circular dependency with Moose::Meta::Attribute et. al.
  17 # so in case of us being use'd first the predeclaration
  18 # ensures the prototypes are in scope when consumers are
  19 # compiled.
  20
  21 # creation and location
  22 sub find_type_constraint                 ($);
  23 sub register_type_constraint             ($);
  24 sub find_or_create_type_constraint       ($;$);
  25 sub find_or_parse_type_constraint        ($);
  26 sub find_or_create_isa_type_constraint   ($);
  27 sub find_or_create_does_type_constraint  ($);
  28 sub create_type_constraint_union         (@);
  29 sub create_parameterized_type_constraint ($);
  30 sub create_class_type_constraint         ($;$);
  31 sub create_role_type_constraint          ($;$);
  32 sub create_enum_type_constraint          ($$);
  33
  34 # dah sugah!
  35 sub type        ($$;$$);
  36 sub subtype     ($$;$$$);
  37 sub class_type  ($;$);
  38 sub coerce      ($@);
  39 sub as          ($);
  40 sub from        ($);
  41 sub where       (&);
  42 sub via         (&);
  43 sub message     (&);
  44 sub optimize_as (&);
  45 sub enum        ($;@);
  46
  47 ## private stuff ...
  48 sub _create_type_constraint ($$$;$$);
  49 sub _install_type_coercions ($$);
  50
  51 ## --------------------------------------------------------
  52
  53 use Moose::Meta::TypeConstraint;
  54 use Moose::Meta::TypeConstraint::Union;
  55 use Moose::Meta::TypeConstraint::Parameterized;
  56 use Moose::Meta::TypeConstraint::Parameterizable;
  57 use Moose::Meta::TypeConstraint::Class;
  58 use Moose::Meta::TypeConstraint::Role;
  59 use Moose::Meta::TypeConstraint::Enum;
  60 use Moose::Meta::TypeCoercion;
  61 use Moose::Meta::TypeCoercion::Union;
  62 use Moose::Meta::TypeConstraint::Registry;
  63 use Moose::Util::TypeConstraints::OptimizedConstraints;
  64
  65 my @exports = qw/
  66     type subtype class_type role_type as where message optimize_as
  67     coerce from via
  68     enum
  69     find_type_constraint
  70     register_type_constraint
  71 /;
  72
  73 Sub::Exporter::setup_exporter({
  74     exports => \@exports,
  75     groups  => { default => [':all'] }
  76 });
  77
  78 sub unimport {
  79     no strict 'refs';
  80     my $class = caller();
  81     # loop through the exports ...
  82     foreach my $name (@exports) {
  83         # if we find one ...
  84         if (defined &{$class . '::' . $name}) {
  85             my $keyword = \&{$class . '::' . $name};
  86
  87             # make sure it is from Moose
  88             my ($pkg_name) = Class::MOP::get_code_info($keyword);
  89             next if $@;
  90             next if $pkg_name ne 'Moose::Util::TypeConstraints';
  91
  92             # and if it is from Moose then undef the slot
  93             delete ${$class . '::'}{$name};
  94         }
  95     }
  96 }
  97
  98 ## --------------------------------------------------------
  99 ## type registry and some useful functions for it
 100 ## --------------------------------------------------------
 101
 102 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
 103
 104 sub get_type_constraint_registry         { $REGISTRY }
 105 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
 106 sub export_type_constraints_as_functions {
 107     my $pkg = caller();
 108     no strict 'refs';
 109     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
 110         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
 111         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef };
 112     }
 113 }
 114
 115 sub create_type_constraint_union (@) {
 116     my @type_constraint_names;
 117
 118     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
 119         @type_constraint_names = _parse_type_constraint_union($_[0]);
 120     }
 121     else {
 122         @type_constraint_names = @_;
 123     }
 124
 125     (scalar @type_constraint_names >= 2)
 126         || confess "You must pass in at least 2 type names to make a union";
 127
 128     ($REGISTRY->has_type_constraint($_))
 129         || confess "Could not locate type constraint ($_) for the union"
 130             foreach @type_constraint_names;
 131
 132     return Moose::Meta::TypeConstraint::Union->new(
 133         type_constraints => [
 134             map {
 135                 $REGISTRY->get_type_constraint($_)
 136             } @type_constraint_names
 137         ],
 138     );
 139 }
 140
 141 sub create_parameterized_type_constraint ($) {
 142     my $type_constraint_name = shift;
 143
 144     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 145
 146     (defined $base_type && defined $type_parameter)
 147         || confess "Could not parse type name ($type_constraint_name) correctly";
 148
 149     ($REGISTRY->has_type_constraint($base_type))
 150         || confess "Could not locate the base type ($base_type)";
 151
 152     return Moose::Meta::TypeConstraint::Parameterized->new(
 153         name           => $type_constraint_name,
 154         parent         => $REGISTRY->get_type_constraint($base_type),
 155         type_parameter => find_or_create_isa_type_constraint($type_parameter),
 156     );
 157 }
 158
 159 #should we also support optimized checks?
 160 sub create_class_type_constraint ($;$) {
 161     my ( $class, $options ) = @_;
 162
 163     # too early for this check
 164     #find_type_constraint("ClassName")->check($class)
 165     #    || confess "Can't create a class type constraint because '$class' is not a class name";
 166
 167     my %options = (
 168         class => $class,
 169         name  => $class,
 170         %{ $options || {} },
 171     );
 172
 173     $options{name} ||= "__ANON__";
 174
 175     Moose::Meta::TypeConstraint::Class->new( %options );
 176 }
 177
 178 sub create_role_type_constraint ($;$) {
 179     my ( $role, $options ) = @_;
 180
 181     # too early for this check
 182     #find_type_constraint("ClassName")->check($class)
 183     #    || confess "Can't create a class type constraint because '$class' is not a class name";
 184
 185     my %options = (
 186         role => $role,
 187         name => $role,
 188         %{ $options || {} },
 189     );
 190
 191     $options{name} ||= "__ANON__";
 192
 193     Moose::Meta::TypeConstraint::Role->new( %options );
 194 }
 195
 196
 197 sub find_or_create_type_constraint ($;$) {
 198     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 199
 200     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 201         return $constraint;
 202     }
 203     elsif ( defined $options_for_anon_type ) {
 204         # NOTE:
 205         # if there is no $options_for_anon_type
 206         # specified, then we assume they don't
 207         # want to create one, and return nothing.
 208
 209         # otherwise assume that we should create
 210         # an ANON type with the $options_for_anon_type
 211         # options which can be passed in. It should
 212         # be noted that these don't get registered
 213         # so we need to return it.
 214         # - SL
 215         return Moose::Meta::TypeConstraint->new(
 216             name => '__ANON__',
 217             %{$options_for_anon_type}
 218         );
 219     }
 220
 221     return;
 222 }
 223
 224 sub find_or_create_isa_type_constraint ($) {
 225     my $type_constraint_name = shift;
 226     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 227 }
 228
 229 sub find_or_create_does_type_constraint ($) {
 230     my $type_constraint_name = shift;
 231     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 232 }
 233
 234 sub find_or_parse_type_constraint ($) {
 235     my $type_constraint_name = shift;
 236
 237     return $REGISTRY->get_type_constraint($type_constraint_name)
 238         if $REGISTRY->has_type_constraint($type_constraint_name);
 239
 240     my $constraint;
 241
 242     if (_detect_type_constraint_union($type_constraint_name)) {
 243         $constraint = create_type_constraint_union($type_constraint_name);
 244     }
 245     elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 246         $constraint = create_parameterized_type_constraint($type_constraint_name);
 247     } else {
 248         return;
 249     }
 250
 251     $REGISTRY->add_type_constraint($constraint);
 252     return $constraint;
 253 }
 254
 255 ## --------------------------------------------------------
 256 ## exported functions ...
 257 ## --------------------------------------------------------
 258
 259 sub find_type_constraint ($) {
 260     my $type = shift;
 261
 262     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 263         return $type;
 264     } else {
 265         return $REGISTRY->get_type_constraint($type);
 266     }
 267 }
 268
 269 sub register_type_constraint ($) {
 270     my $constraint = shift;
 271     confess "can't register an unnamed type constraint" unless defined $constraint->name;
 272     $REGISTRY->add_type_constraint($constraint);
 273     return $constraint;
 274 }
 275
 276 # type constructors
 277
 278 sub type ($$;$$) {
 279     splice(@_, 1, 0, undef);
 280     goto &_create_type_constraint;
 281 }
 282
 283 sub subtype ($$;$$$) {
 284     # NOTE:
 285     # this adds an undef for the name
 286     # if this is an anon-subtype:
 287     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 288     # but if the last arg is not a code
 289     # ref then it is a subtype alias:
 290     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 291     # ... yeah I know it's ugly code
 292     # - SL
 293     unshift @_ => undef if scalar @_ <= 2 && (reftype($_[1]) || '') eq 'CODE';
 294     goto &_create_type_constraint;
 295 }
 296
 297 sub class_type ($;$) {
 298     register_type_constraint(
 299         create_class_type_constraint(
 300             $_[0],
 301             ( defined($_[1]) ? $_[1] : () ),
 302         )
 303     );
 304 }
 305
 306 sub role_type ($;$) {
 307     register_type_constraint(
 308         create_role_type_constraint(
 309             $_[0],
 310             ( defined($_[1]) ? $_[1] : () ),
 311         )
 312     );
 313 }
 314
 315 sub coerce ($@) {
 316     my ($type_name, @coercion_map) = @_;
 317     _install_type_coercions($type_name, \@coercion_map);
 318 }
 319
 320 sub as      ($) { $_[0] }
 321 sub from    ($) { $_[0] }
 322 sub where   (&) { $_[0] }
 323 sub via     (&) { $_[0] }
 324
 325 sub message     (&) { +{ message   => $_[0] } }
 326 sub optimize_as (&) { +{ optimized => $_[0] } }
 327
 328 sub enum ($;@) {
 329     my ($type_name, @values) = @_;
 330     # NOTE:
 331     # if only an array-ref is passed then
 332     # you get an anon-enum
 333     # - SL
 334     if (ref $type_name eq 'ARRAY' && !@values) {
 335         @values    = @$type_name;
 336         $type_name = undef;
 337     }
 338     (scalar @values >= 2)
 339         || confess "You must have at least two values to enumerate through";
 340     my %valid = map { $_ => 1 } @values;
 341
 342     register_type_constraint(
 343         create_enum_type_constraint(
 344             $type_name,
 345             \@values,
 346         )
 347     );
 348 }
 349
 350 sub create_enum_type_constraint ($$) {
 351     my ( $type_name, $values ) = @_;
 352
 353     Moose::Meta::TypeConstraint::Enum->new(
 354         name   => $type_name || '__ANON__',
 355         values => $values,
 356     );
 357 }
 358
 359 ## --------------------------------------------------------
 360 ## desugaring functions ...
 361 ## --------------------------------------------------------
 362
 363 sub _create_type_constraint ($$$;$$) {
 364     my $name   = shift;
 365     my $parent = shift;
 366     my $check  = shift;
 367
 368     my ($message, $optimized);
 369     for (@_) {
 370         $message   = $_->{message}   if exists $_->{message};
 371         $optimized = $_->{optimized} if exists $_->{optimized};
 372     }
 373
 374     my $pkg_defined_in = scalar(caller(0));
 375
 376     if (defined $name) {
 377         my $type = $REGISTRY->get_type_constraint($name);
 378
 379         ($type->_package_defined_in eq $pkg_defined_in)
 380             || confess ("The type constraint '$name' has already been created in "
 381                        . $type->_package_defined_in . " and cannot be created again in "
 382                        . $pkg_defined_in)
 383                  if defined $type;
 384     }
 385
 386     $parent = find_or_parse_type_constraint($parent) if defined $parent;
 387
 388     my $constraint = Moose::Meta::TypeConstraint->new(
 389         name               => $name || '__ANON__',
 390         package_defined_in => $pkg_defined_in,
 391
 392         ($parent    ? (parent     => $parent )   : ()),
 393         ($check     ? (constraint => $check)     : ()),
 394         ($message   ? (message    => $message)   : ()),
 395         ($optimized ? (optimized  => $optimized) : ()),
 396     );
 397
 398     # NOTE:
 399     # if we have a type constraint union, and no
 400     # type check, this means we are just aliasing
 401     # the union constraint, which means we need to
 402     # handle this differently.
 403     # - SL
 404     if (not(defined $check)
 405         && $parent->isa('Moose::Meta::TypeConstraint::Union')
 406         && $parent->has_coercion
 407         ){
 408         $constraint->coercion(Moose::Meta::TypeCoercion::Union->new(
 409             type_constraint => $parent
 410         ));
 411     }
 412
 413     $REGISTRY->add_type_constraint($constraint)
 414         if defined $name;
 415
 416     return $constraint;
 417 }
 418
 419 sub _install_type_coercions ($$) {
 420     my ($type_name, $coercion_map) = @_;
 421     my $type = $REGISTRY->get_type_constraint($type_name);
 422     (defined $type)
 423         || confess "Cannot find type '$type_name', perhaps you forgot to load it.";
 424     if ($type->has_coercion) {
 425         $type->coercion->add_type_coercions(@$coercion_map);
 426     }
 427     else {
 428         my $type_coercion = Moose::Meta::TypeCoercion->new(
 429             type_coercion_map => $coercion_map,
 430             type_constraint   => $type
 431         );
 432         $type->coercion($type_coercion);
 433     }
 434 }
 435
 436 ## --------------------------------------------------------
 437 ## type notation parsing ...
 438 ## --------------------------------------------------------
 439
 440 {
 441     # All I have to say is mugwump++ cause I know
 442     # do not even have enough regexp-fu to be able
 443     # to have written this (I can only barely
 444     # understand it as it is)
 445     # - SL
 446
 447     use re "eval";
 448
 449     my $valid_chars = qr{[\w:]};
 450     my $type_atom   = qr{ $valid_chars+ };
 451
 452     my $type                = qr{  $valid_chars+  (?: \[  (??{$any})  \] )? }x;
 453     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ ((??{$any})) \] )? }x;
 454     my $type_with_parameter = qr{  $valid_chars+      \[  (??{$any})  \]    }x;
 455
 456     my $op_union = qr{ \s* \| \s* }x;
 457     my $union    = qr{ $type (?: $op_union $type )+ }x;
 458
 459     our $any = qr{ $type | $union }x;
 460
 461     sub _parse_parameterized_type_constraint {
 462         $_[0] =~ m{ $type_capture_parts }x;
 463         return ($1, $2);
 464     }
 465
 466     sub _detect_parameterized_type_constraint {
 467         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 468     }
 469
 470     sub _parse_type_constraint_union {
 471         my $given = shift;
 472         my @rv;
 473         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 474             push @rv => $1;
 475         }
 476         (pos($given) eq length($given))
 477             || confess "'$given' didn't parse (parse-pos="
 478                      . pos($given)
 479                      . " and str-length="
 480                      . length($given)
 481                      . ")";
 482         @rv;
 483     }
 484
 485     sub _detect_type_constraint_union {
 486         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 487     }
 488 }
 489
 490 ## --------------------------------------------------------
 491 # define some basic built-in types
 492 ## --------------------------------------------------------
 493
 494 type 'Any'  => where { 1 }; # meta-type including all
 495 type 'Item' => where { 1 }; # base-type
 496
 497 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 498 subtype 'Defined' => as 'Item' => where {  defined($_) };
 499
 500 subtype 'Bool'
 501     => as 'Item'
 502     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 503
 504 subtype 'Value'
 505     => as 'Defined'
 506     => where { !ref($_) }
 507     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 508
 509 subtype 'Ref'
 510     => as 'Defined'
 511     => where {  ref($_) }
 512     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 513
 514 subtype 'Str'
 515     => as 'Value'
 516     => where { 1 }
 517     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 518
 519 subtype 'Num'
 520     => as 'Value'
 521     => where { Scalar::Util::looks_like_number($_) }
 522     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 523
 524 subtype 'Int'
 525     => as 'Num'
 526     => where { "$_" =~ /^-?[0-9]+$/ }
 527     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 528
 529 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 530 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 531 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 532 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 533
 534 # NOTE:
 535 # scalar filehandles are GLOB refs,
 536 # but a GLOB ref is not always a filehandle
 537 subtype 'FileHandle'
 538     => as 'GlobRef'
 539     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 540     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 541
 542 # NOTE:
 543 # blessed(qr/.../) returns true,.. how odd
 544 subtype 'Object'
 545     => as 'Ref'
 546     => where { blessed($_) && blessed($_) ne 'Regexp' }
 547     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 548
 549 subtype 'Role'
 550     => as 'Object'
 551     => where { $_->can('does') }
 552     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 553
 554 my $_class_name_checker = sub {
 555     return if ref($_[0]);
 556     return unless defined($_[0]) && length($_[0]);
 557
 558     # walk the symbol table tree to avoid autovififying
 559     # \*{${main::}{"Foo::"}} == \*main::Foo::
 560
 561     my $pack = \*::;
 562     foreach my $part (split('::', $_[0])) {
 563         return unless exists ${$$pack}{"${part}::"};
 564         $pack = \*{${$$pack}{"${part}::"}};
 565     }
 566
 567     # check for $VERSION or @ISA
 568     return 1 if exists ${$$pack}{VERSION}
 569              && defined *{${$$pack}{VERSION}}{SCALAR};
 570     return 1 if exists ${$$pack}{ISA}
 571              && defined *{${$$pack}{ISA}}{ARRAY};
 572
 573     # check for any method
 574     foreach ( keys %{$$pack} ) {
 575         next if substr($_, -2, 2) eq '::';
 576         return 1 if defined *{${$$pack}{$_}}{CODE};
 577     }
 578
 579     # fail
 580     return;
 581 };
 582
 583 subtype 'ClassName'
 584     => as 'Str'
 585     => $_class_name_checker # where ...
 586     => { optimize => $_class_name_checker };
 587
 588 ## --------------------------------------------------------
 589 # parameterizable types ...
 590
 591 $REGISTRY->add_type_constraint(
 592     Moose::Meta::TypeConstraint::Parameterizable->new(
 593         name                 => 'ArrayRef',
 594         package_defined_in   => __PACKAGE__,
 595         parent               => find_type_constraint('Ref'),
 596         constraint           => sub { ref($_) eq 'ARRAY'  },
 597         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 598         constraint_generator => sub {
 599             my $type_parameter = shift;
 600             my $check = $type_parameter->_compiled_type_constraint;
 601             return sub {
 602                 foreach my $x (@$_) {
 603                     ($check->($x)) || return
 604                 } 1;
 605             }
 606         }
 607     )
 608 );
 609
 610 $REGISTRY->add_type_constraint(
 611     Moose::Meta::TypeConstraint::Parameterizable->new(
 612         name                 => 'HashRef',
 613         package_defined_in   => __PACKAGE__,
 614         parent               => find_type_constraint('Ref'),
 615         constraint           => sub { ref($_) eq 'HASH'  },
 616         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 617         constraint_generator => sub {
 618             my $type_parameter = shift;
 619             my $check = $type_parameter->_compiled_type_constraint;
 620             return sub {
 621                 foreach my $x (values %$_) {
 622                     ($check->($x)) || return
 623                 } 1;
 624             }
 625         }
 626     )
 627 );
 628
 629 $REGISTRY->add_type_constraint(
 630     Moose::Meta::TypeConstraint::Parameterizable->new(
 631         name                 => 'Maybe',
 632         package_defined_in   => __PACKAGE__,
 633         parent               => find_type_constraint('Item'),
 634         constraint           => sub { 1 },
 635         constraint_generator => sub {
 636             my $type_parameter = shift;
 637             my $check = $type_parameter->_compiled_type_constraint;
 638             return sub {
 639                 return 1 if not(defined($_)) || $check->($_);
 640                 return;
 641             }
 642         }
 643     )
 644 );
 645
 646 my @PARAMETERIZABLE_TYPES = map {
 647     $REGISTRY->get_type_constraint($_)
 648 } qw[ArrayRef HashRef Maybe];
 649
 650 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 651 sub add_parameterizable_type {
 652     my $type = shift;
 653     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 654         || confess "Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type";
 655     push @PARAMETERIZABLE_TYPES => $type;
 656 }
 657
 658 ## --------------------------------------------------------
 659 # end of built-in types ...
 660 ## --------------------------------------------------------
 661
 662 {
 663     my @BUILTINS = list_all_type_constraints();
 664     sub list_all_builtin_type_constraints { @BUILTINS }
 665 }
 666
 667 1;
 668
 669 __END__
 670
 671 =pod
 672
 673 =head1 NAME
 674
 675 Moose::Util::TypeConstraints - Type constraint system for Moose
 676
 677 =head1 SYNOPSIS
 678
 679   use Moose::Util::TypeConstraints;
 680
 681   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 682
 683   subtype 'Natural'
 684       => as 'Num'
 685       => where { $_ > 0 };
 686
 687   subtype 'NaturalLessThanTen'
 688       => as 'Natural'
 689       => where { $_ < 10 }
 690       => message { "This number ($_) is not less than ten!" };
 691
 692   coerce 'Num'
 693       => from 'Str'
 694         => via { 0+$_ };
 695
 696   enum 'RGBColors' => qw(red green blue);
 697
 698 =head1 DESCRIPTION
 699
 700 This module provides Moose with the ability to create custom type
 701 contraints to be used in attribute definition.
 702
 703 =head2 Important Caveat
 704
 705 This is B<NOT> a type system for Perl 5. These are type constraints,
 706 and they are not used by Moose unless you tell it to. No type
 707 inference is performed, expression are not typed, etc. etc. etc.
 708
 709 This is simply a means of creating small constraint functions which
 710 can be used to simplify your own type-checking code, with the added
 711 side benefit of making your intentions clearer through self-documentation.
 712
 713 =head2 Slightly Less Important Caveat
 714
 715 It is B<always> a good idea to quote your type and subtype names.
 716
 717 This is to prevent perl from trying to execute the call as an indirect
 718 object call. This issue only seems to come up when you have a subtype
 719 the same name as a valid class, but when the issue does arise it tends
 720 to be quite annoying to debug.
 721
 722 So for instance, this:
 723
 724   subtype DateTime => as Object => where { $_->isa('DateTime') };
 725
 726 will I<Just Work>, while this:
 727
 728   use DateTime;
 729   subtype DateTime => as Object => where { $_->isa('DateTime') };
 730
 731 will fail silently and cause many headaches. The simple way to solve
 732 this, as well as future proof your subtypes from classes which have
 733 yet to have been created yet, is to simply do this:
 734
 735   use DateTime;
 736   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 737
 738 =head2 Default Type Constraints
 739
 740 This module also provides a simple hierarchy for Perl 5 types, here is
 741 that hierarchy represented visually.
 742
 743   Any
 744   Item
 745       Bool
 746       Maybe[`a]
 747       Undef
 748       Defined
 749           Value
 750               Num
 751                 Int
 752               Str
 753                 ClassName
 754           Ref
 755               ScalarRef
 756               ArrayRef[`a]
 757               HashRef[`a]
 758               CodeRef
 759               RegexpRef
 760               GlobRef
 761                 FileHandle
 762               Object
 763                   Role
 764
 765 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 766 parameterized, this means you can say:
 767
 768   ArrayRef[Int]    # an array of intergers
 769   HashRef[CodeRef] # a hash of str to CODE ref mappings
 770   Maybe[Str]       # value may be a string, may be undefined
 771
 772 B<NOTE:> The C<Undef> type constraint for the most part works
 773 correctly now, but edge cases may still exist, please use it
 774 sparringly.
 775
 776 B<NOTE:> The C<ClassName> type constraint does a complex package
 777 existence check. This means that your class B<must> be loaded for
 778 this type constraint to pass. I know this is not ideal for all,
 779 but it is a saner restriction than most others.
 780
 781 =head2 Type Constraint Naming
 782
 783 Since the types created by this module are global, it is suggested
 784 that you namespace your types just as you would namespace your
 785 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 786 module, you would call the type I<My::Graphics::Color> instead.
 787
 788 =head2 Use with Other Constraint Modules
 789
 790 This module should play fairly nicely with other constraint
 791 modules with only some slight tweaking. The C<where> clause
 792 in types is expected to be a C<CODE> reference which checks
 793 it's first argument and returns a boolean. Since most constraint
 794 modules work in a similar way, it should be simple to adapt
 795 them to work with Moose.
 796
 797 For instance, this is how you could use it with
 798 L<Declare::Constraints::Simple> to declare a completely new type.
 799
 800   type 'HashOfArrayOfObjects'
 801       => IsHashRef(
 802           -keys   => HasLength,
 803           -values => IsArrayRef( IsObject ));
 804
 805 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 806 test file.
 807
 808 Here is an example of using L<Test::Deep> and it's non-test
 809 related C<eq_deeply> function.
 810
 811   type 'ArrayOfHashOfBarsAndRandomNumbers'
 812       => where {
 813           eq_deeply($_,
 814               array_each(subhashof({
 815                   bar           => isa('Bar'),
 816                   random_number => ignore()
 817               })))
 818         };
 819
 820 For a complete example see the
 821 F<t/200_examples/205_example_w_TestDeep.t> test file.
 822
 823 =head1 FUNCTIONS
 824
 825 =head2 Type Constraint Constructors
 826
 827 The following functions are used to create type constraints.
 828 They will then register the type constraints in a global store
 829 where Moose can get to them if it needs to.
 830
 831 See the L<SYNOPSIS> for an example of how to use these.
 832
 833 =over 4
 834
 835 =item B<type ($name, $where_clause)>
 836
 837 This creates a base type, which has no parent.
 838
 839 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 840
 841 This creates a named subtype.
 842
 843 =item B<subtype ($parent, $where_clause, ?$message)>
 844
 845 This creates an unnamed subtype and will return the type
 846 constraint meta-object, which will be an instance of
 847 L<Moose::Meta::TypeConstraint>.
 848
 849 =item B<class_type ($class, ?$options)>
 850
 851 Creates a type constraint with the name C<$class> and the metaclass
 852 L<Moose::Meta::TypeConstraint::Class>.
 853
 854 =item B<role_type ($role, ?$options)>
 855
 856 Creates a type constraint with the name C<$role> and the metaclass
 857 L<Moose::Meta::TypeConstraint::Role>.
 858
 859 =item B<enum ($name, @values)>
 860
 861 This will create a basic subtype for a given set of strings.
 862 The resulting constraint will be a subtype of C<Str> and
 863 will match any of the items in C<@values>. It is case sensitive.
 864 See the L<SYNOPSIS> for a simple example.
 865
 866 B<NOTE:> This is not a true proper enum type, it is simple
 867 a convient constraint builder.
 868
 869 =item B<enum (\@values)>
 870
 871 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 872 this will create an unnamed enum. This can then be used in an attribute
 873 definition like so:
 874
 875   has 'sort_order' => (
 876       is  => 'ro',
 877       isa => enum([qw[ ascending descending ]]),
 878   );
 879
 880 =item B<as>
 881
 882 This is just sugar for the type constraint construction syntax.
 883
 884 =item B<where>
 885
 886 This is just sugar for the type constraint construction syntax.
 887
 888 =item B<message>
 889
 890 This is just sugar for the type constraint construction syntax.
 891
 892 =item B<optimize_as>
 893
 894 This can be used to define a "hand optimized" version of your
 895 type constraint which can be used to avoid traversing a subtype
 896 constraint heirarchy.
 897
 898 B<NOTE:> You should only use this if you know what you are doing,
 899 all the built in types use this, so your subtypes (assuming they
 900 are shallow) will not likely need to use this.
 901
 902 =back
 903
 904 =head2 Type Coercion Constructors
 905
 906 Type constraints can also contain type coercions as well. If you
 907 ask your accessor to coerce, then Moose will run the type-coercion
 908 code first, followed by the type constraint check. This feature
 909 should be used carefully as it is very powerful and could easily
 910 take off a limb if you are not careful.
 911
 912 See the L<SYNOPSIS> for an example of how to use these.
 913
 914 =over 4
 915
 916 =item B<coerce>
 917
 918 =item B<from>
 919
 920 This is just sugar for the type coercion construction syntax.
 921
 922 =item B<via>
 923
 924 This is just sugar for the type coercion construction syntax.
 925
 926 =back
 927
 928 =head2 Type Constraint Construction & Locating
 929
 930 =over 4
 931
 932 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 933
 934 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 935 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 936
 937 =item B<create_parameterized_type_constraint ($type_name)>
 938
 939 Given a C<$type_name> in the form of:
 940
 941   BaseType[ContainerType]
 942
 943 this will extract the base type and container type and build an instance of
 944 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 945
 946 =item B<create_class_type_constraint ($class, ?$options)>
 947
 948 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 949 object for that class name.
 950
 951 =item B<create_role_type_constraint ($role, ?$options)>
 952
 953 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 954 object for that role name.
 955
 956 =item B<create_enum_type_constraint ($name, $values)>
 957
 958 =item B<find_or_parse_type_constraint ($type_name)>
 959
 960 This will attempt to find or create a type constraint given the a C<$type_name>.
 961 If it cannot find it in the registry, it will see if it should be a union or
 962 container type an create one if appropriate
 963
 964 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 965
 966 This function will first call C<find_or_parse_type_constraint> with the type name.
 967
 968 If no type is found or created, but C<$options_for_anon_type> are provided, it
 969 will create the corresponding type.
 970
 971 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 972 and are now superseded by C<find_or_create_isa_type_constraint> and
 973 C<find_or_create_does_type_constraint>.
 974
 975 =item B<find_or_create_isa_type_constraint ($type_name)>
 976
 977 =item B<find_or_create_does_type_constraint ($type_name)>
 978
 979 Attempts to parse the type name using L<find_or_parse_type_constraint> and if
 980 no appropriate constraint is found will create a new anonymous one.
 981
 982 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
 983 variant will use C<create_role_type_constraint>.
 984
 985 =item B<find_type_constraint ($type_name)>
 986
 987 This function can be used to locate a specific type constraint
 988 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
 989 derivative. What you do with it from there is up to you :)
 990
 991 =item B<register_type_constraint ($type_object)>
 992
 993 This function will register a named type constraint with the type registry.
 994
 995 =item B<get_type_constraint_registry>
 996
 997 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
 998 keeps track of all type constraints.
 999
1000 =item B<list_all_type_constraints>
1001
1002 This will return a list of type constraint names, you can then
1003 fetch them using C<find_type_constraint ($type_name)> if you
1004 want to.
1005
1006 =item B<list_all_builtin_type_constraints>
1007
1008 This will return a list of builtin type constraints, meaning,
1009 those which are defined in this module. See the section
1010 labeled L<Default Type Constraints> for a complete list.
1011
1012 =item B<export_type_constraints_as_functions>
1013
1014 This will export all the current type constraints as functions
1015 into the caller's namespace. Right now, this is mostly used for
1016 testing, but it might prove useful to others.
1017
1018 =item B<get_all_parameterizable_types>
1019
1020 This returns all the parameterizable types that have been registered.
1021
1022 =item B<add_parameterizable_type ($type)>
1023
1024 Adds C<$type> to the list of parameterizable types
1025
1026 =back
1027
1028 =head2 Namespace Management
1029
1030 =over 4
1031
1032 =item B<unimport>
1033
1034 This will remove all the type constraint keywords from the
1035 calling class namespace.
1036
1037 =back
1038
1039 =head1 BUGS
1040
1041 All complex software has bugs lurking in it, and this module is no
1042 exception. If you find a bug please either email me, or add the bug
1043 to cpan-RT.
1044
1045 =head1 AUTHOR
1046
1047 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1048
1049 =head1 COPYRIGHT AND LICENSE
1050
1051 Copyright 2006-2008 by Infinity Interactive, Inc.
1052
1053 L<http://www.iinteractive.com>
1054
1055 This library is free software; you can redistribute it and/or modify
1056 it under the same terms as Perl itself.
1057
1058 =cut