2 package Moose::Util::TypeConstraints;
5 use List::MoreUtils qw( all any );
6 use Scalar::Util qw( blessed reftype );
10 $VERSION = eval $VERSION;
11 our $AUTHORITY = 'cpan:STEVAN';
13 ## --------------------------------------------------------
14 # Prototyped subs must be predeclared because we have a
15 # circular dependency with Moose::Meta::Attribute et. al.
16 # so in case of us being use'd first the predeclaration
17 # ensures the prototypes are in scope when consumers are
26 ## --------------------------------------------------------
28 use Moose::Meta::TypeConstraint;
29 use Moose::Meta::TypeConstraint::Union;
30 use Moose::Meta::TypeConstraint::Parameterized;
31 use Moose::Meta::TypeConstraint::Parameterizable;
32 use Moose::Meta::TypeConstraint::Class;
33 use Moose::Meta::TypeConstraint::Role;
34 use Moose::Meta::TypeConstraint::Enum;
35 use Moose::Meta::TypeConstraint::DuckType;
36 use Moose::Meta::TypeCoercion;
37 use Moose::Meta::TypeCoercion::Union;
38 use Moose::Meta::TypeConstraint::Registry;
39 use Moose::Util::TypeConstraints::OptimizedConstraints;
41 Moose::Exporter->setup_import_methods(
44 type subtype class_type role_type maybe_type duck_type
45 as where message optimize_as
49 register_type_constraint
55 ## --------------------------------------------------------
56 ## type registry and some useful functions for it
57 ## --------------------------------------------------------
59 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
61 sub get_type_constraint_registry {$REGISTRY}
62 sub list_all_type_constraints { keys %{ $REGISTRY->type_constraints } }
64 sub export_type_constraints_as_functions {
67 foreach my $constraint ( keys %{ $REGISTRY->type_constraints } ) {
68 my $tc = $REGISTRY->get_type_constraint($constraint)
69 ->_compiled_type_constraint;
70 *{"${pkg}::${constraint}"}
71 = sub { $tc->( $_[0] ) ? 1 : undef }; # the undef is for compat
75 sub create_type_constraint_union {
76 my @type_constraint_names;
78 if ( scalar @_ == 1 && _detect_type_constraint_union( $_[0] ) ) {
79 @type_constraint_names = _parse_type_constraint_union( $_[0] );
82 @type_constraint_names = @_;
85 ( scalar @type_constraint_names >= 2 )
86 || __PACKAGE__->_throw_error(
87 "You must pass in at least 2 type names to make a union");
89 my @type_constraints = map {
90 find_or_parse_type_constraint($_)
91 || __PACKAGE__->_throw_error(
92 "Could not locate type constraint ($_) for the union");
93 } @type_constraint_names;
95 return Moose::Meta::TypeConstraint::Union->new(
96 type_constraints => \@type_constraints );
99 sub create_parameterized_type_constraint {
100 my $type_constraint_name = shift;
101 my ( $base_type, $type_parameter )
102 = _parse_parameterized_type_constraint($type_constraint_name);
104 ( defined $base_type && defined $type_parameter )
105 || __PACKAGE__->_throw_error(
106 "Could not parse type name ($type_constraint_name) correctly");
108 if ( $REGISTRY->has_type_constraint($base_type) ) {
109 my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
110 return _create_parameterized_type_constraint(
116 __PACKAGE__->_throw_error(
117 "Could not locate the base type ($base_type)");
121 sub _create_parameterized_type_constraint {
122 my ( $base_type_tc, $type_parameter ) = @_;
123 if ( $base_type_tc->can('parameterize') ) {
124 return $base_type_tc->parameterize($type_parameter);
127 return Moose::Meta::TypeConstraint::Parameterized->new(
128 name => $base_type_tc->name . '[' . $type_parameter . ']',
129 parent => $base_type_tc,
131 find_or_create_isa_type_constraint($type_parameter),
136 #should we also support optimized checks?
137 sub create_class_type_constraint {
138 my ( $class, $options ) = @_;
140 # too early for this check
141 #find_type_constraint("ClassName")->check($class)
142 # || __PACKAGE__->_throw_error("Can't create a class type constraint because '$class' is not a class name");
150 $options{name} ||= "__ANON__";
152 Moose::Meta::TypeConstraint::Class->new(%options);
155 sub create_role_type_constraint {
156 my ( $role, $options ) = @_;
158 # too early for this check
159 #find_type_constraint("ClassName")->check($class)
160 # || __PACKAGE__->_throw_error("Can't create a class type constraint because '$class' is not a class name");
168 $options{name} ||= "__ANON__";
170 Moose::Meta::TypeConstraint::Role->new(%options);
173 sub find_or_create_type_constraint {
174 my ( $type_constraint_name, $options_for_anon_type ) = @_;
177 = find_or_parse_type_constraint($type_constraint_name) ) {
180 elsif ( defined $options_for_anon_type ) {
183 # if there is no $options_for_anon_type
184 # specified, then we assume they don't
185 # want to create one, and return nothing.
187 # otherwise assume that we should create
188 # an ANON type with the $options_for_anon_type
189 # options which can be passed in. It should
190 # be noted that these don't get registered
191 # so we need to return it.
193 return Moose::Meta::TypeConstraint->new(
195 %{$options_for_anon_type}
202 sub find_or_create_isa_type_constraint {
203 my $type_constraint_name = shift;
204 find_or_parse_type_constraint($type_constraint_name)
205 || create_class_type_constraint($type_constraint_name);
208 sub find_or_create_does_type_constraint {
209 my $type_constraint_name = shift;
210 find_or_parse_type_constraint($type_constraint_name)
211 || create_role_type_constraint($type_constraint_name);
214 sub find_or_parse_type_constraint {
215 my $type_constraint_name = normalize_type_constraint_name(shift);
218 if ( $constraint = find_type_constraint($type_constraint_name) ) {
221 elsif ( _detect_type_constraint_union($type_constraint_name) ) {
222 $constraint = create_type_constraint_union($type_constraint_name);
224 elsif ( _detect_parameterized_type_constraint($type_constraint_name) ) {
226 = create_parameterized_type_constraint($type_constraint_name);
232 $REGISTRY->add_type_constraint($constraint);
236 sub normalize_type_constraint_name {
237 my $type_constraint_name = shift;
238 $type_constraint_name =~ s/\s//g;
239 return $type_constraint_name;
245 local $Carp::CarpLevel = $Carp::CarpLevel + 1;
246 Carp::confess($error);
249 ## --------------------------------------------------------
250 ## exported functions ...
251 ## --------------------------------------------------------
253 sub find_type_constraint {
256 if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
260 return unless $REGISTRY->has_type_constraint($type);
261 return $REGISTRY->get_type_constraint($type);
265 sub register_type_constraint {
266 my $constraint = shift;
267 __PACKAGE__->_throw_error("can't register an unnamed type constraint")
268 unless defined $constraint->name;
269 $REGISTRY->add_type_constraint($constraint);
277 # back-compat version, called without sugar
278 if ( !any { ( reftype($_) || '' ) eq 'HASH' } @_ ) {
279 return _create_type_constraint( $_[0], undef, $_[1] );
284 my %p = map { %{$_} } @_;
286 return _create_type_constraint(
287 $name, undef, $p{where}, $p{message},
294 # crazy back-compat code for being called without sugar ...
296 # subtype 'Parent', sub { where };
297 if ( scalar @_ == 2 && ( reftype( $_[1] ) || '' ) eq 'CODE' ) {
298 return _create_type_constraint( undef, @_ );
301 # subtype 'Parent', sub { where }, sub { message };
302 # subtype 'Parent', sub { where }, sub { message }, sub { optimized };
303 if ( scalar @_ >= 3 && all { ( reftype($_) || '' ) eq 'CODE' }
305 return _create_type_constraint( undef, @_ );
308 # subtype 'Name', 'Parent', ...
309 if ( scalar @_ >= 2 && all { !ref } @_[ 0, 1 ] ) {
310 return _create_type_constraint(@_);
313 if ( @_ == 1 && !ref $_[0] ) {
314 __PACKAGE__->_throw_error(
315 'A subtype cannot consist solely of a name, it must have a parent'
319 # The blessed check is mostly to accommodate MooseX::Types, which
320 # uses an object which overloads stringification as a type name.
321 my $name = ref $_[0] && !blessed $_[0] ? undef : shift;
323 my %p = map { %{$_} } @_;
325 # subtype Str => where { ... };
326 if ( !exists $p{as} ) {
331 return _create_type_constraint(
332 $name, $p{as}, $p{where}, $p{message},
338 register_type_constraint(
339 create_class_type_constraint(
341 ( defined( $_[1] ) ? $_[1] : () ),
346 sub role_type ($;$) {
347 register_type_constraint(
348 create_role_type_constraint(
350 ( defined( $_[1] ) ? $_[1] : () ),
356 my ($type_parameter) = @_;
358 register_type_constraint(
359 $REGISTRY->get_type_constraint('Maybe')->parameterize($type_parameter)
364 my ( $type_name, @methods ) = @_;
365 if ( ref $type_name eq 'ARRAY' && !@methods ) {
366 @methods = @$type_name;
370 register_type_constraint(
371 create_duck_type_constraint(
379 my ( $type_name, @coercion_map ) = @_;
380 _install_type_coercions( $type_name, \@coercion_map );
383 # The trick of returning @_ lets us avoid having to specify a
384 # prototype. Perl will parse this:
392 # subtype( 'Foo', as( 'Str', where { ... } ) );
394 # If as() returns all it's extra arguments, this just works, and
395 # preserves backwards compatibility.
396 sub as { { as => shift }, @_ }
397 sub where (&) { { where => $_[0] } }
398 sub message (&) { { message => $_[0] } }
399 sub optimize_as (&) { { optimize_as => $_[0] } }
402 sub via (&) { $_[0] }
405 my ( $type_name, @values ) = @_;
408 # if only an array-ref is passed then
409 # you get an anon-enum
411 if ( ref $type_name eq 'ARRAY' && !@values ) {
412 @values = @$type_name;
415 ( scalar @values >= 2 )
416 || __PACKAGE__->_throw_error(
417 "You must have at least two values to enumerate through");
418 my %valid = map { $_ => 1 } @values;
420 register_type_constraint(
421 create_enum_type_constraint(
428 sub create_enum_type_constraint {
429 my ( $type_name, $values ) = @_;
431 Moose::Meta::TypeConstraint::Enum->new(
432 name => $type_name || '__ANON__',
437 sub create_duck_type_constraint {
438 my ( $type_name, $methods ) = @_;
440 Moose::Meta::TypeConstraint::DuckType->new(
441 name => $type_name || '__ANON__',
447 my ($to_match, @cases) = @_;
449 if (@cases % 2 != 0) {
450 $default = pop @cases;
451 (ref $default eq 'CODE')
452 || __PACKAGE__->_throw_error("Default case must be a CODE ref, not $default");
455 my ($type, $action) = splice @cases, 0, 2;
457 unless (blessed $type && $type->isa('Moose::Meta::TypeConstraint')) {
458 $type = find_or_parse_type_constraint($type)
459 || __PACKAGE__->_throw_error("Cannot find or parse the type '$type'")
462 (ref $action eq 'CODE')
463 || __PACKAGE__->_throw_error("Match action must be a CODE ref, not $action");
465 if ($type->check($to_match)) {
466 local $_ = $to_match;
467 return $action->($to_match);
471 local $_ = $to_match;
472 return $default->($to_match) if $default;
477 ## --------------------------------------------------------
478 ## desugaring functions ...
479 ## --------------------------------------------------------
481 sub _create_type_constraint ($$$;$$) {
486 my $optimized = shift;
488 my $pkg_defined_in = scalar( caller(1) );
490 if ( defined $name ) {
491 my $type = $REGISTRY->get_type_constraint($name);
493 ( $type->_package_defined_in eq $pkg_defined_in )
495 "The type constraint '$name' has already been created in "
496 . $type->_package_defined_in
497 . " and cannot be created again in "
501 $name =~ /^[\w:\.]+$/
502 or die qq{$name contains invalid characters for a type name.}
503 . qq{ Names can contain alphanumeric character, ":", and "."\n};
508 package_defined_in => $pkg_defined_in,
510 ( $check ? ( constraint => $check ) : () ),
511 ( $message ? ( message => $message ) : () ),
512 ( $optimized ? ( optimized => $optimized ) : () ),
521 : find_or_create_isa_type_constraint($parent)
523 $constraint = $parent->create_child_type(%opts);
526 $constraint = Moose::Meta::TypeConstraint->new(%opts);
529 $REGISTRY->add_type_constraint($constraint)
535 sub _install_type_coercions ($$) {
536 my ( $type_name, $coercion_map ) = @_;
537 my $type = find_type_constraint($type_name);
539 || __PACKAGE__->_throw_error(
540 "Cannot find type '$type_name', perhaps you forgot to load it");
541 if ( $type->has_coercion ) {
542 $type->coercion->add_type_coercions(@$coercion_map);
545 my $type_coercion = Moose::Meta::TypeCoercion->new(
546 type_coercion_map => $coercion_map,
547 type_constraint => $type
549 $type->coercion($type_coercion);
553 ## --------------------------------------------------------
554 ## type notation parsing ...
555 ## --------------------------------------------------------
559 # All I have to say is mugwump++ cause I know
560 # do not even have enough regexp-fu to be able
561 # to have written this (I can only barely
562 # understand it as it is)
567 my $valid_chars = qr{[\w:\.]};
568 my $type_atom = qr{ $valid_chars+ };
572 my $type = qr{ $valid_chars+ (?: \[ \s* (??{$any}) \s* \] )? }x;
573 my $type_capture_parts
574 = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
575 my $type_with_parameter
576 = qr{ $valid_chars+ \[ \s* (??{$any}) \s* \] }x;
578 my $op_union = qr{ \s* \| \s* }x;
579 my $union = qr{ $type (?: $op_union $type )+ }x;
581 $any = qr{ $type | $union }x;
583 sub _parse_parameterized_type_constraint {
584 { no warnings 'void'; $any; } # force capture of interpolated lexical
585 $_[0] =~ m{ $type_capture_parts }x;
589 sub _detect_parameterized_type_constraint {
590 { no warnings 'void'; $any; } # force capture of interpolated lexical
591 $_[0] =~ m{ ^ $type_with_parameter $ }x;
594 sub _parse_type_constraint_union {
595 { no warnings 'void'; $any; } # force capture of interpolated lexical
598 while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
601 ( pos($given) eq length($given) )
602 || __PACKAGE__->_throw_error( "'$given' didn't parse (parse-pos="
610 sub _detect_type_constraint_union {
611 { no warnings 'void'; $any; } # force capture of interpolated lexical
612 $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
616 ## --------------------------------------------------------
617 # define some basic built-in types
618 ## --------------------------------------------------------
620 # By making these classes immutable before creating all the types we
621 # below, we avoid repeatedly calling the slow MOP-based accessors.
623 inline_constructor => 1,
624 constructor_name => "_new",
626 # these are Class::MOP accessors, so they need inlining
627 inline_accessors => 1
628 ) for grep { $_->is_mutable }
629 map { Class::MOP::class_of($_) }
631 Moose::Meta::TypeConstraint
632 Moose::Meta::TypeConstraint::Union
633 Moose::Meta::TypeConstraint::Parameterized
634 Moose::Meta::TypeConstraint::Parameterizable
635 Moose::Meta::TypeConstraint::Class
636 Moose::Meta::TypeConstraint::Role
637 Moose::Meta::TypeConstraint::Enum
638 Moose::Meta::TypeConstraint::DuckType
639 Moose::Meta::TypeConstraint::Registry
642 type 'Any' => where {1}; # meta-type including all
643 subtype 'Item' => as 'Any'; # base-type
645 subtype 'Undef' => as 'Item' => where { !defined($_) };
646 subtype 'Defined' => as 'Item' => where { defined($_) };
648 subtype 'Bool' => as 'Item' =>
649 where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
651 subtype 'Value' => as 'Defined' => where { !ref($_) } =>
652 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
654 subtype 'Ref' => as 'Defined' => where { ref($_) } =>
655 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
657 subtype 'Str' => as 'Value' => where {1} =>
658 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
660 subtype 'Num' => as 'Str' =>
661 where { Scalar::Util::looks_like_number($_) } =>
662 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
664 subtype 'Int' => as 'Num' => where { "$_" =~ /^-?[0-9]+$/ } =>
665 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
667 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } =>
669 \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
670 subtype 'CodeRef' => as 'Ref' => where { ref($_) eq 'CODE' } =>
671 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
672 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } =>
674 \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
675 subtype 'GlobRef' => as 'Ref' => where { ref($_) eq 'GLOB' } =>
676 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
679 # scalar filehandles are GLOB refs,
680 # but a GLOB ref is not always a filehandle
681 subtype 'FileHandle' => as 'GlobRef' => where {
682 Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") );
684 \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
687 # blessed(qr/.../) returns true,.. how odd
688 subtype 'Object' => as 'Ref' =>
689 where { blessed($_) && blessed($_) ne 'Regexp' } =>
690 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
692 # This type is deprecated.
693 subtype 'Role' => as 'Object' => where { $_->can('does') } =>
694 optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
696 my $_class_name_checker = sub { };
698 subtype 'ClassName' => as 'Str' =>
699 where { Class::MOP::is_class_loaded($_) } => optimize_as
700 \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
702 subtype 'RoleName' => as 'ClassName' => where {
703 (Class::MOP::class_of($_) || return)->isa('Moose::Meta::Role');
705 \&Moose::Util::TypeConstraints::OptimizedConstraints::RoleName;
707 ## --------------------------------------------------------
708 # parameterizable types ...
710 $REGISTRY->add_type_constraint(
711 Moose::Meta::TypeConstraint::Parameterizable->new(
713 package_defined_in => __PACKAGE__,
714 parent => find_type_constraint('Ref'),
715 constraint => sub { ref($_) eq 'ARRAY' },
717 \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
718 constraint_generator => sub {
719 my $type_parameter = shift;
720 my $check = $type_parameter->_compiled_type_constraint;
722 foreach my $x (@$_) {
723 ( $check->($x) ) || return;
731 $REGISTRY->add_type_constraint(
732 Moose::Meta::TypeConstraint::Parameterizable->new(
734 package_defined_in => __PACKAGE__,
735 parent => find_type_constraint('Ref'),
736 constraint => sub { ref($_) eq 'HASH' },
738 \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
739 constraint_generator => sub {
740 my $type_parameter = shift;
741 my $check = $type_parameter->_compiled_type_constraint;
743 foreach my $x ( values %$_ ) {
744 ( $check->($x) ) || return;
752 $REGISTRY->add_type_constraint(
753 Moose::Meta::TypeConstraint::Parameterizable->new(
755 package_defined_in => __PACKAGE__,
756 parent => find_type_constraint('Item'),
757 constraint => sub {1},
758 constraint_generator => sub {
759 my $type_parameter = shift;
760 my $check = $type_parameter->_compiled_type_constraint;
762 return 1 if not( defined($_) ) || $check->($_);
769 my @PARAMETERIZABLE_TYPES
770 = map { $REGISTRY->get_type_constraint($_) } qw[ArrayRef HashRef Maybe];
772 sub get_all_parameterizable_types {@PARAMETERIZABLE_TYPES}
774 sub add_parameterizable_type {
777 && $type->isa('Moose::Meta::TypeConstraint::Parameterizable') )
778 || __PACKAGE__->_throw_error(
779 "Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type"
781 push @PARAMETERIZABLE_TYPES => $type;
784 ## --------------------------------------------------------
785 # end of built-in types ...
786 ## --------------------------------------------------------
789 my @BUILTINS = list_all_type_constraints();
790 sub list_all_builtin_type_constraints {@BUILTINS}
797 goto &Moose::throw_error;
808 Moose::Util::TypeConstraints - Type constraint system for Moose
812 use Moose::Util::TypeConstraints;
818 subtype 'NaturalLessThanTen'
821 => message { "This number ($_) is not less than ten!" };
827 enum 'RGBColors' => qw(red green blue);
829 no Moose::Util::TypeConstraints;
833 This module provides Moose with the ability to create custom type
834 constraints to be used in attribute definition.
836 =head2 Important Caveat
838 This is B<NOT> a type system for Perl 5. These are type constraints,
839 and they are not used by Moose unless you tell it to. No type
840 inference is performed, expressions are not typed, etc. etc. etc.
842 A type constraint is at heart a small "check if a value is valid"
843 function. A constraint can be associated with an attribute. This
844 simplifies parameter validation, and makes your code clearer to read,
845 because you can refer to constraints by name.
847 =head2 Slightly Less Important Caveat
849 It is B<always> a good idea to quote your type names.
851 This prevents Perl from trying to execute the call as an indirect
852 object call. This can be an issue when you have a subtype with the
853 same name as a valid class.
857 subtype DateTime => as Object => where { $_->isa('DateTime') };
859 will I<just work>, while this:
862 subtype DateTime => as Object => where { $_->isa('DateTime') };
864 will fail silently and cause many headaches. The simple way to solve
865 this, as well as future proof your subtypes from classes which have
866 yet to have been created, is to quote the type name:
869 subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
871 =head2 Default Type Constraints
873 This module also provides a simple hierarchy for Perl 5 types, here is
874 that hierarchy represented visually.
898 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
899 parameterized, this means you can say:
901 ArrayRef[Int] # an array of integers
902 HashRef[CodeRef] # a hash of str to CODE ref mappings
903 Maybe[Str] # value may be a string, may be undefined
905 If Moose finds a name in brackets that it does not recognize as an
906 existing type, it assumes that this is a class name, for example
907 C<ArrayRef[DateTime]>.
909 B<NOTE:> Unless you parameterize a type, then it is invalid to include
910 the square brackets. I.e. C<ArrayRef[]> will be treated as a new type
911 name, I<not> as a parameterization of C<ArrayRef>.
913 B<NOTE:> The C<Undef> type constraint for the most part works
914 correctly now, but edge cases may still exist, please use it
917 B<NOTE:> The C<ClassName> type constraint does a complex package
918 existence check. This means that your class B<must> be loaded for this
919 type constraint to pass.
921 B<NOTE:> The C<RoleName> constraint checks a string is a I<package
922 name> which is a role, like C<'MyApp::Role::Comparable'>.
924 =head2 Type Constraint Naming
926 Type name declared via this module can only contain alphanumeric
927 characters, colons (:), and periods (.).
929 Since the types created by this module are global, it is suggested
930 that you namespace your types just as you would namespace your
931 modules. So instead of creating a I<Color> type for your
932 B<My::Graphics> module, you would call the type
933 I<My::Graphics::Types::Color> instead.
935 =head2 Use with Other Constraint Modules
937 This module can play nicely with other constraint modules with some
938 slight tweaking. The C<where> clause in types is expected to be a
939 C<CODE> reference which checks it's first argument and returns a
940 boolean. Since most constraint modules work in a similar way, it
941 should be simple to adapt them to work with Moose.
943 For instance, this is how you could use it with
944 L<Declare::Constraints::Simple> to declare a completely new type.
946 type 'HashOfArrayOfObjects',
950 -values => IsArrayRef(IsObject)
954 For more examples see the F<t/200_examples/004_example_w_DCS.t> test
957 Here is an example of using L<Test::Deep> and it's non-test
958 related C<eq_deeply> function.
960 type 'ArrayOfHashOfBarsAndRandomNumbers'
963 array_each(subhashof({
965 random_number => ignore()
969 For a complete example see the
970 F<t/200_examples/005_example_w_TestDeep.t> test file.
974 =head2 Type Constraint Constructors
976 The following functions are used to create type constraints. They
977 will also register the type constraints your create in a global
978 registry that is used to look types up by name.
980 See the L<SYNOPSIS> for an example of how to use these.
984 =item B<< subtype 'Name' => as 'Parent' => where { } ... >>
986 This creates a named subtype.
988 If you provide a parent that Moose does not recognize, it will
989 automatically create a new class type constraint for this name.
991 When creating a named type, the C<subtype> function should either be
992 called with the sugar helpers (C<where>, C<message>, etc), or with a
993 name and a hashref of parameters:
995 subtype( 'Foo', { where => ..., message => ... } );
997 The valid hashref keys are C<as> (the parent), C<where>, C<message>,
1000 =item B<< subtype as 'Parent' => where { } ... >>
1002 This creates an unnamed subtype and will return the type
1003 constraint meta-object, which will be an instance of
1004 L<Moose::Meta::TypeConstraint>.
1006 When creating an anonymous type, the C<subtype> function should either
1007 be called with the sugar helpers (C<where>, C<message>, etc), or with
1008 just a hashref of parameters:
1010 subtype( { where => ..., message => ... } );
1012 =item B<class_type ($class, ?$options)>
1014 Creates a new subtype of C<Object> with the name C<$class> and the
1015 metaclass L<Moose::Meta::TypeConstraint::Class>.
1017 =item B<role_type ($role, ?$options)>
1019 Creates a C<Role> type constraint with the name C<$role> and the
1020 metaclass L<Moose::Meta::TypeConstraint::Role>.
1022 =item B<maybe_type ($type)>
1024 Creates a type constraint for either C<undef> or something of the
1027 =item B<duck_type ($name, @methods)>
1029 This will create a subtype of Object and test to make sure the value
1030 C<can()> do the methods in C<@methods>.
1032 This is intended as an easy way to accept non-Moose objects that
1033 provide a certain interface. If you're using Moose classes, we
1034 recommend that you use a C<requires>-only Role instead.
1036 =item B<duck_type (\@methods)>
1038 If passed an ARRAY reference instead of the C<$name>, C<@methods>
1039 pair, this will create an unnamed duck type. This can be used in an
1040 attribute definition like so:
1044 isa => duck_type( [qw( get_set )] ),
1047 =item B<enum ($name, @values)>
1049 This will create a basic subtype for a given set of strings.
1050 The resulting constraint will be a subtype of C<Str> and
1051 will match any of the items in C<@values>. It is case sensitive.
1052 See the L<SYNOPSIS> for a simple example.
1054 B<NOTE:> This is not a true proper enum type, it is simply
1055 a convenient constraint builder.
1057 =item B<enum (\@values)>
1059 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
1060 this will create an unnamed enum. This can then be used in an attribute
1063 has 'sort_order' => (
1065 isa => enum([qw[ ascending descending ]]),
1068 =item B<as 'Parent'>
1070 This is just sugar for the type constraint construction syntax.
1072 It takes a single argument, which is the name of a parent type.
1074 =item B<where { ... }>
1076 This is just sugar for the type constraint construction syntax.
1078 It takes a subroutine reference as an argument. When the type
1079 constraint is tested, the reference is run with the value to be tested
1080 in C<$_>. This reference should return true or false to indicate
1081 whether or not the constraint check passed.
1083 =item B<message { ... }>
1085 This is just sugar for the type constraint construction syntax.
1087 It takes a subroutine reference as an argument. When the type
1088 constraint fails, then the code block is run with the value provided
1089 in C<$_>. This reference should return a string, which will be used in
1090 the text of the exception thrown.
1092 =item B<optimize_as { ... }>
1094 This can be used to define a "hand optimized" version of your
1095 type constraint which can be used to avoid traversing a subtype
1096 constraint hierarchy.
1098 B<NOTE:> You should only use this if you know what you are doing,
1099 all the built in types use this, so your subtypes (assuming they
1100 are shallow) will not likely need to use this.
1102 =item B<< type 'Name' => where { } ... >>
1104 This creates a base type, which has no parent.
1106 The C<type> function should either be called with the sugar helpers
1107 (C<where>, C<message>, etc), or with a name and a hashref of
1110 type( 'Foo', { where => ..., message => ... } );
1112 The valid hashref keys are C<where>, C<message>, and C<optimize_as>.
1116 =head2 Type Constraint Utilities
1120 =item B<< match_on_type $value => ( $type => \&action, ... ?\&default ) >>
1122 This is a utility function for doing simple type based dispatching
1123 similar to match/case in O'Caml and case/of in Haskell. It does not
1124 claim to be as featureful as either of those and does not support any
1125 kind of automatic destructuring bind. However it is suitable for a fair
1126 amount of your dispatching needs, for instance, here is a simple
1127 Perl pretty printer dispatching over the core Moose types.
1134 '{ ' . (join ", " => map {
1135 $_ . ' => ' . ppprint( $hash->{ $_ } )
1136 } sort keys %$hash ) . ' }' },
1139 '[ '.(join ", " => map { ppprint( $_ ) } @$array ).' ]' },
1140 CodeRef => sub { 'sub { ... }' },
1141 RegexpRef => sub { 'qr/' . $_ . '/' },
1142 GlobRef => sub { '*' . B::svref_2object($_)->NAME },
1143 Object => sub { $_->can('to_string') ? $_->to_string : $_ },
1144 ScalarRef => sub { '\\' . ppprint( ${$_} ) },
1146 Str => sub { '"'. $_ . '"' },
1147 Undef => sub { 'undef' },
1148 => sub { die "I don't know what $_ is" };
1151 Based on a mapping of C<$type> to C<\&action>, where C<$type> can be
1152 either a string type or a L<Moose::Meta::TypeConstraint> object, and
1153 C<\&action> is a CODE ref, this function will dispatch on the first
1154 match for C<$value>. It is possible to have a catch-all at the end
1155 in the form of a C<\&default> CODE ref
1159 =head2 Type Coercion Constructors
1161 You can define coercions for type constraints, which allow you to
1162 automatically transform values to something valid for the type
1163 constraint. If you ask your accessor to coerce, then Moose will run
1164 the type-coercion code first, followed by the type constraint
1165 check. This feature should be used carefully as it is very powerful
1166 and could easily take off a limb if you are not careful.
1168 See the L<SYNOPSIS> for an example of how to use these.
1172 =item B<< coerce 'Name' => from 'OtherName' => via { ... } >>
1174 This defines a coercion from one type to another. The C<Name> argument
1175 is the type you are coercing I<to>.
1177 =item B<from 'OtherName'>
1179 This is just sugar for the type coercion construction syntax.
1181 It takes a single type name (or type object), which is the type being
1184 =item B<via { ... }>
1186 This is just sugar for the type coercion construction syntax.
1188 It takes a subroutine reference. This reference will be called with
1189 the value to be coerced in C<$_>. It is expected to return a new value
1190 of the proper type for the coercion.
1194 =head2 Creating and Finding Type Constraints
1196 These are additional functions for creating and finding type
1197 constraints. Most of these functions are not available for
1198 importing. The ones that are importable as specified.
1202 =item B<find_type_constraint($type_name)>
1204 This function can be used to locate the L<Moose::Meta::TypeConstraint>
1205 object for a named type.
1207 This function is importable.
1209 =item B<register_type_constraint($type_object)>
1211 This function will register a L<Moose::Meta::TypeConstraint> with the
1212 global type registry.
1214 This function is importable.
1216 =item B<normalize_type_constraint_name($type_constraint_name)>
1218 This method takes a type constraint name and returns the normalized
1219 form. This removes any whitespace in the string.
1221 =item B<create_type_constraint_union($pipe_separated_types | @type_constraint_names)>
1223 This can take a union type specification like C<'Int|ArrayRef[Int]'>,
1224 or a list of names. It returns a new
1225 L<Moose::Meta::TypeConstraint::Union> object.
1227 =item B<create_parameterized_type_constraint($type_name)>
1229 Given a C<$type_name> in the form of C<'BaseType[ContainerType]'>,
1230 this will create a new L<Moose::Meta::TypeConstraint::Parameterized>
1231 object. The C<BaseType> must exist already exist as a parameterizable
1234 =item B<create_class_type_constraint($class, $options)>
1236 Given a class name this function will create a new
1237 L<Moose::Meta::TypeConstraint::Class> object for that class name.
1239 The C<$options> is a hash reference that will be passed to the
1240 L<Moose::Meta::TypeConstraint::Class> constructor (as a hash).
1242 =item B<create_role_type_constraint($role, $options)>
1244 Given a role name this function will create a new
1245 L<Moose::Meta::TypeConstraint::Role> object for that role name.
1247 The C<$options> is a hash reference that will be passed to the
1248 L<Moose::Meta::TypeConstraint::Role> constructor (as a hash).
1250 =item B<create_enum_type_constraint($name, $values)>
1252 Given a enum name this function will create a new
1253 L<Moose::Meta::TypeConstraint::Enum> object for that enum name.
1255 =item B<create_duck_type_constraint($name, $methods)>
1257 Given a duck type name this function will create a new
1258 L<Moose::Meta::TypeConstraint::DuckType> object for that enum name.
1260 =item B<find_or_parse_type_constraint($type_name)>
1262 Given a type name, this first attempts to find a matching constraint
1263 in the global registry.
1265 If the type name is a union or parameterized type, it will create a
1266 new object of the appropriate, but if given a "regular" type that does
1267 not yet exist, it simply returns false.
1269 When given a union or parameterized type, the member or base type must
1272 If it creates a new union or parameterized type, it will add it to the
1275 =item B<find_or_create_isa_type_constraint($type_name)>
1277 =item B<find_or_create_does_type_constraint($type_name)>
1279 These functions will first call C<find_or_parse_type_constraint>. If
1280 that function does not return a type, a new anonymous type object will
1283 The C<isa> variant will use C<create_class_type_constraint> and the
1284 C<does> variant will use C<create_role_type_constraint>.
1286 =item B<get_type_constraint_registry>
1288 Returns the L<Moose::Meta::TypeConstraint::Registry> object which
1289 keeps track of all type constraints.
1291 =item B<list_all_type_constraints>
1293 This will return a list of type constraint names in the global
1294 registry. You can then fetch the actual type object using
1295 C<find_type_constraint($type_name)>.
1297 =item B<list_all_builtin_type_constraints>
1299 This will return a list of builtin type constraints, meaning those
1300 which are defined in this module. See the L<Default Type Constraints>
1301 section for a complete list.
1303 =item B<export_type_constraints_as_functions>
1305 This will export all the current type constraints as functions into
1306 the caller's namespace (C<Int()>, C<Str()>, etc). Right now, this is
1307 mostly used for testing, but it might prove useful to others.
1309 =item B<get_all_parameterizable_types>
1311 This returns all the parameterizable types that have been registered,
1312 as a list of type objects.
1314 =item B<add_parameterizable_type($type)>
1316 Adds C<$type> to the list of parameterizable types
1322 All complex software has bugs lurking in it, and this module is no
1323 exception. If you find a bug please either email me, or add the bug
1328 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1330 =head1 COPYRIGHT AND LICENSE
1332 Copyright 2006-2009 by Infinity Interactive, Inc.
1334 L<http://www.iinteractive.com>
1336 This library is free software; you can redistribute it and/or modify
1337 it under the same terms as Perl itself.