lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.64';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type maybe_type
  51             as where message optimize_as
  52             coerce from via
  53             enum
  54             find_type_constraint
  55             register_type_constraint )
  56     ],
  57     _export_to_main => 1,
  58 );
  59
  60 ## --------------------------------------------------------
  61 ## type registry and some useful functions for it
  62 ## --------------------------------------------------------
  63
  64 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  65
  66 sub get_type_constraint_registry         { $REGISTRY }
  67 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  68 sub export_type_constraints_as_functions {
  69     my $pkg = caller();
  70     no strict 'refs';
  71     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  72         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  73         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  74     }
  75 }
  76
  77 sub create_type_constraint_union {
  78     my @type_constraint_names;
  79
  80     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  81         @type_constraint_names = _parse_type_constraint_union($_[0]);
  82     }
  83     else {
  84         @type_constraint_names = @_;
  85     }
  86
  87     (scalar @type_constraint_names >= 2)
  88         || Moose->throw_error("You must pass in at least 2 type names to make a union");
  89
  90     my @type_constraints = map {
  91         find_or_parse_type_constraint($_) ||
  92          Moose->throw_error("Could not locate type constraint ($_) for the union");
  93     } @type_constraint_names;
  94
  95     return Moose::Meta::TypeConstraint::Union->new(
  96         type_constraints => \@type_constraints
  97     );
  98 }
  99
 100 sub create_parameterized_type_constraint {
 101     my $type_constraint_name = shift;
 102     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 103
 104     (defined $base_type && defined $type_parameter)
 105         || Moose->throw_error("Could not parse type name ($type_constraint_name) correctly");
 106
 107     if ($REGISTRY->has_type_constraint($base_type)) {
 108         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 109         return _create_parameterized_type_constraint(
 110             $base_type_tc,
 111             $type_parameter
 112         );
 113     } else {
 114         Moose->throw_error("Could not locate the base type ($base_type)");
 115     }
 116 }
 117
 118 sub _create_parameterized_type_constraint {
 119     my ( $base_type_tc, $type_parameter ) = @_;
 120     if ( $base_type_tc->can('parameterize') ) {
 121         return $base_type_tc->parameterize($type_parameter);
 122     } else {
 123         return Moose::Meta::TypeConstraint::Parameterized->new(
 124             name => $base_type_tc->name . '[' . $type_parameter . ']',
 125             parent => $base_type_tc,
 126             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 127         );
 128     }
 129 }
 130
 131 #should we also support optimized checks?
 132 sub create_class_type_constraint {
 133     my ( $class, $options ) = @_;
 134
 135     # too early for this check
 136     #find_type_constraint("ClassName")->check($class)
 137     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 138
 139     my %options = (
 140         class => $class,
 141         name  => $class,
 142         %{ $options || {} },
 143     );
 144
 145     $options{name} ||= "__ANON__";
 146
 147     Moose::Meta::TypeConstraint::Class->new( %options );
 148 }
 149
 150 sub create_role_type_constraint {
 151     my ( $role, $options ) = @_;
 152
 153     # too early for this check
 154     #find_type_constraint("ClassName")->check($class)
 155     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 156
 157     my %options = (
 158         role => $role,
 159         name => $role,
 160         %{ $options || {} },
 161     );
 162
 163     $options{name} ||= "__ANON__";
 164
 165     Moose::Meta::TypeConstraint::Role->new( %options );
 166 }
 167
 168
 169 sub find_or_create_type_constraint {
 170     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 171
 172     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 173         return $constraint;
 174     }
 175     elsif ( defined $options_for_anon_type ) {
 176         # NOTE:
 177         # if there is no $options_for_anon_type
 178         # specified, then we assume they don't
 179         # want to create one, and return nothing.
 180
 181         # otherwise assume that we should create
 182         # an ANON type with the $options_for_anon_type
 183         # options which can be passed in. It should
 184         # be noted that these don't get registered
 185         # so we need to return it.
 186         # - SL
 187         return Moose::Meta::TypeConstraint->new(
 188             name => '__ANON__',
 189             %{$options_for_anon_type}
 190         );
 191     }
 192
 193     return;
 194 }
 195
 196 sub find_or_create_isa_type_constraint {
 197     my $type_constraint_name = shift;
 198     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 199 }
 200
 201 sub find_or_create_does_type_constraint {
 202     my $type_constraint_name = shift;
 203     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 204 }
 205
 206 sub find_or_parse_type_constraint {
 207     my $type_constraint_name = normalize_type_constraint_name(shift);
 208     my $constraint;
 209
 210     if ($constraint = find_type_constraint($type_constraint_name)) {
 211         return $constraint;
 212     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 213         $constraint = create_type_constraint_union($type_constraint_name);
 214     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 215         $constraint = create_parameterized_type_constraint($type_constraint_name);
 216     } else {
 217         return;
 218     }
 219
 220     $REGISTRY->add_type_constraint($constraint);
 221     return $constraint;
 222 }
 223
 224 sub normalize_type_constraint_name {
 225     my $type_constraint_name = shift;
 226     $type_constraint_name =~ s/\s//g;
 227     return $type_constraint_name;
 228 }
 229
 230 sub _confess {
 231     my $error = shift;
 232
 233     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 234     Carp::confess($error);
 235 }
 236
 237 ## --------------------------------------------------------
 238 ## exported functions ...
 239 ## --------------------------------------------------------
 240
 241 sub find_type_constraint {
 242     my $type = shift;
 243
 244     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 245         return $type;
 246     }
 247     else {
 248         return unless $REGISTRY->has_type_constraint($type);
 249         return $REGISTRY->get_type_constraint($type);
 250     }
 251 }
 252
 253 sub register_type_constraint {
 254     my $constraint = shift;
 255     Moose->throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 256     $REGISTRY->add_type_constraint($constraint);
 257     return $constraint;
 258 }
 259
 260 # type constructors
 261
 262 sub type {
 263     splice(@_, 1, 0, undef);
 264     goto &_create_type_constraint;
 265 }
 266
 267 sub subtype {
 268     # NOTE:
 269     # this adds an undef for the name
 270     # if this is an anon-subtype:
 271     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 272     #     or
 273     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 274     #
 275     # but if the last arg is not a code ref then it is a subtype
 276     # alias:
 277     #
 278     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 279     # ... yeah I know it's ugly code
 280     # - SL
 281     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 282     unshift @_ => undef
 283         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 284     goto &_create_type_constraint;
 285 }
 286
 287 sub class_type {
 288     register_type_constraint(
 289         create_class_type_constraint(
 290             $_[0],
 291             ( defined($_[1]) ? $_[1] : () ),
 292         )
 293     );
 294 }
 295
 296 sub role_type ($;$) {
 297     register_type_constraint(
 298         create_role_type_constraint(
 299             $_[0],
 300             ( defined($_[1]) ? $_[1] : () ),
 301         )
 302     );
 303 }
 304
 305 sub maybe_type {
 306     my ($type_parameter) = @_;
 307
 308     Moose::Meta::TypeConstraint->new(
 309         parent               => find_type_constraint('Item'),
 310         constraint           => sub {
 311             my $check = $type_parameter->_compiled_type_constraint;
 312             return 1 if not(defined($_)) || $check->($_);
 313             return;
 314         }
 315     )
 316 }
 317
 318 sub coerce {
 319     my ($type_name, @coercion_map) = @_;
 320     _install_type_coercions($type_name, \@coercion_map);
 321 }
 322
 323 sub as          { @_ }
 324 sub from        { @_ }
 325 sub where   (&) { $_[0] }
 326 sub via     (&) { $_[0] }
 327
 328 sub message     (&) { +{ message   => $_[0] } }
 329 sub optimize_as (&) { +{ optimized => $_[0] } }
 330
 331 sub enum {
 332     my ($type_name, @values) = @_;
 333     # NOTE:
 334     # if only an array-ref is passed then
 335     # you get an anon-enum
 336     # - SL
 337     if (ref $type_name eq 'ARRAY' && !@values) {
 338         @values    = @$type_name;
 339         $type_name = undef;
 340     }
 341     (scalar @values >= 2)
 342         || Moose->throw_error("You must have at least two values to enumerate through");
 343     my %valid = map { $_ => 1 } @values;
 344
 345     register_type_constraint(
 346         create_enum_type_constraint(
 347             $type_name,
 348             \@values,
 349         )
 350     );
 351 }
 352
 353 sub create_enum_type_constraint {
 354     my ( $type_name, $values ) = @_;
 355
 356     Moose::Meta::TypeConstraint::Enum->new(
 357         name   => $type_name || '__ANON__',
 358         values => $values,
 359     );
 360 }
 361
 362 ## --------------------------------------------------------
 363 ## desugaring functions ...
 364 ## --------------------------------------------------------
 365
 366 sub _create_type_constraint ($$$;$$) {
 367     my $name   = shift;
 368     my $parent = shift;
 369     my $check  = shift;
 370
 371     my ( $message, $optimized );
 372     for (@_) {
 373         $message   = $_->{message}   if exists $_->{message};
 374         $optimized = $_->{optimized} if exists $_->{optimized};
 375     }
 376
 377     my $pkg_defined_in = scalar( caller(0) );
 378
 379     if ( defined $name ) {
 380         my $type = $REGISTRY->get_type_constraint($name);
 381
 382         ( $type->_package_defined_in eq $pkg_defined_in )
 383             || _confess(
 384                   "The type constraint '$name' has already been created in "
 385                 . $type->_package_defined_in
 386                 . " and cannot be created again in "
 387                 . $pkg_defined_in )
 388             if defined $type;
 389     }
 390
 391     my %opts = (
 392         name => $name,
 393         package_defined_in => $pkg_defined_in,
 394
 395         ( $check     ? ( constraint => $check )     : () ),
 396         ( $message   ? ( message    => $message )   : () ),
 397         ( $optimized ? ( optimized  => $optimized ) : () ),
 398     );
 399
 400     my $constraint;
 401     if ( defined $parent
 402         and $parent
 403         = blessed $parent ? $parent : find_or_parse_type_constraint($parent) )
 404     {
 405         $constraint = $parent->create_child_type(%opts);
 406     }
 407     else {
 408         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 409     }
 410
 411     $REGISTRY->add_type_constraint($constraint)
 412         if defined $name;
 413
 414     return $constraint;
 415 }
 416
 417 sub _install_type_coercions ($$) {
 418     my ($type_name, $coercion_map) = @_;
 419     my $type = find_type_constraint($type_name);
 420     (defined $type)
 421         || Moose->throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 422     if ($type->has_coercion) {
 423         $type->coercion->add_type_coercions(@$coercion_map);
 424     }
 425     else {
 426         my $type_coercion = Moose::Meta::TypeCoercion->new(
 427             type_coercion_map => $coercion_map,
 428             type_constraint   => $type
 429         );
 430         $type->coercion($type_coercion);
 431     }
 432 }
 433
 434 ## --------------------------------------------------------
 435 ## type notation parsing ...
 436 ## --------------------------------------------------------
 437
 438 {
 439     # All I have to say is mugwump++ cause I know
 440     # do not even have enough regexp-fu to be able
 441     # to have written this (I can only barely
 442     # understand it as it is)
 443     # - SL
 444
 445     use re "eval";
 446
 447     my $valid_chars = qr{[\w:]};
 448     my $type_atom   = qr{ $valid_chars+ };
 449
 450     my $any;
 451
 452     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 453     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 454     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 455
 456     my $op_union = qr{ \s* \| \s* }x;
 457     my $union    = qr{ $type (?: $op_union $type )+ }x;
 458
 459     $any = qr{ $type | $union }x;
 460
 461     sub _parse_parameterized_type_constraint {
 462         { no warnings 'void'; $any; } # force capture of interpolated lexical
 463         $_[0] =~ m{ $type_capture_parts }x;
 464         return ($1, $2);
 465     }
 466
 467     sub _detect_parameterized_type_constraint {
 468         { no warnings 'void'; $any; } # force capture of interpolated lexical
 469         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 470     }
 471
 472     sub _parse_type_constraint_union {
 473         { no warnings 'void'; $any; } # force capture of interpolated lexical
 474         my $given = shift;
 475         my @rv;
 476         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 477             push @rv => $1;
 478         }
 479         (pos($given) eq length($given))
 480             || Moose->throw_error("'$given' didn't parse (parse-pos="
 481                      . pos($given)
 482                      . " and str-length="
 483                      . length($given)
 484                      . ")");
 485         @rv;
 486     }
 487
 488     sub _detect_type_constraint_union {
 489         { no warnings 'void'; $any; } # force capture of interpolated lexical
 490         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 491     }
 492 }
 493
 494 ## --------------------------------------------------------
 495 # define some basic built-in types
 496 ## --------------------------------------------------------
 497
 498 # By making these classes immutable before creating all the types we
 499 # below, we avoid repeatedly calling the slow MOP-based accessors.
 500 $_->make_immutable(
 501     inline_constructor => 1,
 502     constructor_name   => "_new",
 503
 504     # these are Class::MOP accessors, so they need inlining
 505     inline_accessors => 1
 506     ) for grep { $_->is_mutable }
 507     map { $_->meta }
 508     qw(
 509     Moose::Meta::TypeConstraint
 510     Moose::Meta::TypeConstraint::Union
 511     Moose::Meta::TypeConstraint::Parameterized
 512     Moose::Meta::TypeConstraint::Parameterizable
 513     Moose::Meta::TypeConstraint::Class
 514     Moose::Meta::TypeConstraint::Role
 515     Moose::Meta::TypeConstraint::Enum
 516     Moose::Meta::TypeConstraint::Registry
 517 );
 518
 519 type 'Any'  => where { 1 }; # meta-type including all
 520 type 'Item' => where { 1 }; # base-type
 521
 522 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 523 subtype 'Defined' => as 'Item' => where {  defined($_) };
 524
 525 subtype 'Bool'
 526     => as 'Item'
 527     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 528
 529 subtype 'Value'
 530     => as 'Defined'
 531     => where { !ref($_) }
 532     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 533
 534 subtype 'Ref'
 535     => as 'Defined'
 536     => where {  ref($_) }
 537     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 538
 539 subtype 'Str'
 540     => as 'Value'
 541     => where { 1 }
 542     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 543
 544 subtype 'Num'
 545     => as 'Value'
 546     => where { Scalar::Util::looks_like_number($_) }
 547     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 548
 549 subtype 'Int'
 550     => as 'Num'
 551     => where { "$_" =~ /^-?[0-9]+$/ }
 552     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 553
 554 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 555 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 556 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 557 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 558
 559 # NOTE:
 560 # scalar filehandles are GLOB refs,
 561 # but a GLOB ref is not always a filehandle
 562 subtype 'FileHandle'
 563     => as 'GlobRef'
 564     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 565     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 566
 567 # NOTE:
 568 # blessed(qr/.../) returns true,.. how odd
 569 subtype 'Object'
 570     => as 'Ref'
 571     => where { blessed($_) && blessed($_) ne 'Regexp' }
 572     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 573
 574 subtype 'Role'
 575     => as 'Object'
 576     => where { $_->can('does') }
 577     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 578
 579 my $_class_name_checker = sub {
 580 };
 581
 582 subtype 'ClassName'
 583     => as 'Str'
 584     => where { Class::MOP::is_class_loaded($_) }
 585     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 586
 587 ## --------------------------------------------------------
 588 # parameterizable types ...
 589
 590 $REGISTRY->add_type_constraint(
 591     Moose::Meta::TypeConstraint::Parameterizable->new(
 592         name                 => 'ArrayRef',
 593         package_defined_in   => __PACKAGE__,
 594         parent               => find_type_constraint('Ref'),
 595         constraint           => sub { ref($_) eq 'ARRAY'  },
 596         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 597         constraint_generator => sub {
 598             my $type_parameter = shift;
 599             my $check = $type_parameter->_compiled_type_constraint;
 600             return sub {
 601                 foreach my $x (@$_) {
 602                     ($check->($x)) || return
 603                 } 1;
 604             }
 605         }
 606     )
 607 );
 608
 609 $REGISTRY->add_type_constraint(
 610     Moose::Meta::TypeConstraint::Parameterizable->new(
 611         name                 => 'HashRef',
 612         package_defined_in   => __PACKAGE__,
 613         parent               => find_type_constraint('Ref'),
 614         constraint           => sub { ref($_) eq 'HASH'  },
 615         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 616         constraint_generator => sub {
 617             my $type_parameter = shift;
 618             my $check = $type_parameter->_compiled_type_constraint;
 619             return sub {
 620                 foreach my $x (values %$_) {
 621                     ($check->($x)) || return
 622                 } 1;
 623             }
 624         }
 625     )
 626 );
 627
 628 $REGISTRY->add_type_constraint(
 629     Moose::Meta::TypeConstraint::Parameterizable->new(
 630         name                 => 'Maybe',
 631         package_defined_in   => __PACKAGE__,
 632         parent               => find_type_constraint('Item'),
 633         constraint           => sub { 1 },
 634         constraint_generator => sub {
 635             my $type_parameter = shift;
 636             my $check = $type_parameter->_compiled_type_constraint;
 637             return sub {
 638                 return 1 if not(defined($_)) || $check->($_);
 639                 return;
 640             }
 641         }
 642     )
 643 );
 644
 645 my @PARAMETERIZABLE_TYPES = map {
 646     $REGISTRY->get_type_constraint($_)
 647 } qw[ArrayRef HashRef Maybe];
 648
 649 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 650 sub add_parameterizable_type {
 651     my $type = shift;
 652     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 653         || Moose->throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 654     push @PARAMETERIZABLE_TYPES => $type;
 655 }
 656
 657 ## --------------------------------------------------------
 658 # end of built-in types ...
 659 ## --------------------------------------------------------
 660
 661 {
 662     my @BUILTINS = list_all_type_constraints();
 663     sub list_all_builtin_type_constraints { @BUILTINS }
 664 }
 665
 666 1;
 667
 668 __END__
 669
 670 =pod
 671
 672 =head1 NAME
 673
 674 Moose::Util::TypeConstraints - Type constraint system for Moose
 675
 676 =head1 SYNOPSIS
 677
 678   use Moose::Util::TypeConstraints;
 679
 680   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 681
 682   subtype 'Natural'
 683       => as 'Int'
 684       => where { $_ > 0 };
 685
 686   subtype 'NaturalLessThanTen'
 687       => as 'Natural'
 688       => where { $_ < 10 }
 689       => message { "This number ($_) is not less than ten!" };
 690
 691   coerce 'Num'
 692       => from 'Str'
 693         => via { 0+$_ };
 694
 695   enum 'RGBColors' => qw(red green blue);
 696
 697 =head1 DESCRIPTION
 698
 699 This module provides Moose with the ability to create custom type
 700 contraints to be used in attribute definition.
 701
 702 =head2 Important Caveat
 703
 704 This is B<NOT> a type system for Perl 5. These are type constraints,
 705 and they are not used by Moose unless you tell it to. No type
 706 inference is performed, expression are not typed, etc. etc. etc.
 707
 708 This is simply a means of creating small constraint functions which
 709 can be used to simplify your own type-checking code, with the added
 710 side benefit of making your intentions clearer through self-documentation.
 711
 712 =head2 Slightly Less Important Caveat
 713
 714 It is B<always> a good idea to quote your type and subtype names.
 715
 716 This is to prevent perl from trying to execute the call as an indirect
 717 object call. This issue only seems to come up when you have a subtype
 718 the same name as a valid class, but when the issue does arise it tends
 719 to be quite annoying to debug.
 720
 721 So for instance, this:
 722
 723   subtype DateTime => as Object => where { $_->isa('DateTime') };
 724
 725 will I<Just Work>, while this:
 726
 727   use DateTime;
 728   subtype DateTime => as Object => where { $_->isa('DateTime') };
 729
 730 will fail silently and cause many headaches. The simple way to solve
 731 this, as well as future proof your subtypes from classes which have
 732 yet to have been created yet, is to simply do this:
 733
 734   use DateTime;
 735   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 736
 737 =head2 Default Type Constraints
 738
 739 This module also provides a simple hierarchy for Perl 5 types, here is
 740 that hierarchy represented visually.
 741
 742   Any
 743   Item
 744       Bool
 745       Maybe[`a]
 746       Undef
 747       Defined
 748           Value
 749               Num
 750                 Int
 751               Str
 752                 ClassName
 753           Ref
 754               ScalarRef
 755               ArrayRef[`a]
 756               HashRef[`a]
 757               CodeRef
 758               RegexpRef
 759               GlobRef
 760                 FileHandle
 761               Object
 762                   Role
 763
 764 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 765 parameterized, this means you can say:
 766
 767   ArrayRef[Int]    # an array of integers
 768   HashRef[CodeRef] # a hash of str to CODE ref mappings
 769   Maybe[Str]       # value may be a string, may be undefined
 770
 771 B<NOTE:> Unless you parameterize a type, then it is invalid to
 772 include the square brackets. I.e. C<ArrayRef[]> will be
 773 literally interpreted as a type name.
 774
 775 B<NOTE:> The C<Undef> type constraint for the most part works
 776 correctly now, but edge cases may still exist, please use it
 777 sparringly.
 778
 779 B<NOTE:> The C<ClassName> type constraint does a complex package
 780 existence check. This means that your class B<must> be loaded for
 781 this type constraint to pass. I know this is not ideal for all,
 782 but it is a saner restriction than most others.
 783
 784 =head2 Type Constraint Naming
 785
 786 Since the types created by this module are global, it is suggested
 787 that you namespace your types just as you would namespace your
 788 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 789 module, you would call the type I<My::Graphics::Color> instead.
 790
 791 =head2 Use with Other Constraint Modules
 792
 793 This module should play fairly nicely with other constraint
 794 modules with only some slight tweaking. The C<where> clause
 795 in types is expected to be a C<CODE> reference which checks
 796 it's first argument and returns a boolean. Since most constraint
 797 modules work in a similar way, it should be simple to adapt
 798 them to work with Moose.
 799
 800 For instance, this is how you could use it with
 801 L<Declare::Constraints::Simple> to declare a completely new type.
 802
 803   type 'HashOfArrayOfObjects'
 804       => IsHashRef(
 805           -keys   => HasLength,
 806           -values => IsArrayRef( IsObject ));
 807
 808 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 809 test file.
 810
 811 Here is an example of using L<Test::Deep> and it's non-test
 812 related C<eq_deeply> function.
 813
 814   type 'ArrayOfHashOfBarsAndRandomNumbers'
 815       => where {
 816           eq_deeply($_,
 817               array_each(subhashof({
 818                   bar           => isa('Bar'),
 819                   random_number => ignore()
 820               })))
 821         };
 822
 823 For a complete example see the
 824 F<t/200_examples/205_example_w_TestDeep.t> test file.
 825
 826 =head1 FUNCTIONS
 827
 828 =head2 Type Constraint Constructors
 829
 830 The following functions are used to create type constraints.
 831 They will then register the type constraints in a global store
 832 where Moose can get to them if it needs to.
 833
 834 See the L<SYNOPSIS> for an example of how to use these.
 835
 836 =over 4
 837
 838 =item B<type ($name, $where_clause)>
 839
 840 This creates a base type, which has no parent.
 841
 842 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 843
 844 This creates a named subtype.
 845
 846 =item B<subtype ($parent, $where_clause, ?$message)>
 847
 848 This creates an unnamed subtype and will return the type
 849 constraint meta-object, which will be an instance of
 850 L<Moose::Meta::TypeConstraint>.
 851
 852 =item B<class_type ($class, ?$options)>
 853
 854 Creates a type constraint with the name C<$class> and the metaclass
 855 L<Moose::Meta::TypeConstraint::Class>.
 856
 857 =item B<role_type ($role, ?$options)>
 858
 859 Creates a type constraint with the name C<$role> and the metaclass
 860 L<Moose::Meta::TypeConstraint::Role>.
 861
 862 =item B<maybe_type ($type)>
 863
 864 Creates a type constraint for either C<undef> or something of the
 865 given type.
 866
 867 =item B<enum ($name, @values)>
 868
 869 This will create a basic subtype for a given set of strings.
 870 The resulting constraint will be a subtype of C<Str> and
 871 will match any of the items in C<@values>. It is case sensitive.
 872 See the L<SYNOPSIS> for a simple example.
 873
 874 B<NOTE:> This is not a true proper enum type, it is simple
 875 a convient constraint builder.
 876
 877 =item B<enum (\@values)>
 878
 879 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 880 this will create an unnamed enum. This can then be used in an attribute
 881 definition like so:
 882
 883   has 'sort_order' => (
 884       is  => 'ro',
 885       isa => enum([qw[ ascending descending ]]),
 886   );
 887
 888 =item B<as>
 889
 890 This is just sugar for the type constraint construction syntax.
 891
 892 =item B<where>
 893
 894 This is just sugar for the type constraint construction syntax.
 895
 896 Takes a block/code ref as an argument. When the type constraint is
 897 tested, the supplied code is run with the value to be tested in
 898 $_. This block should return true or false to indicate whether or not
 899 the constraint check passed.
 900
 901 =item B<message>
 902
 903 This is just sugar for the type constraint construction syntax.
 904
 905 Takes a block/code ref as an argument. When the type constraint fails,
 906 then the code block is run (with the value provided in $_). This code
 907 ref should return a string, which will be used in the text of the
 908 exception thrown.
 909
 910 =item B<optimize_as>
 911
 912 This can be used to define a "hand optimized" version of your
 913 type constraint which can be used to avoid traversing a subtype
 914 constraint heirarchy.
 915
 916 B<NOTE:> You should only use this if you know what you are doing,
 917 all the built in types use this, so your subtypes (assuming they
 918 are shallow) will not likely need to use this.
 919
 920 =back
 921
 922 =head2 Type Coercion Constructors
 923
 924 Type constraints can also contain type coercions as well. If you
 925 ask your accessor to coerce, then Moose will run the type-coercion
 926 code first, followed by the type constraint check. This feature
 927 should be used carefully as it is very powerful and could easily
 928 take off a limb if you are not careful.
 929
 930 See the L<SYNOPSIS> for an example of how to use these.
 931
 932 =over 4
 933
 934 =item B<coerce>
 935
 936 =item B<from>
 937
 938 This is just sugar for the type coercion construction syntax.
 939
 940 =item B<via>
 941
 942 This is just sugar for the type coercion construction syntax.
 943
 944 =back
 945
 946 =head2 Type Constraint Construction & Locating
 947
 948 =over 4
 949
 950 =item B<normalize_type_constraint_name ($type_constraint_name)>
 951
 952 Given a string that is expected to match a type constraint, will normalize the
 953 string so that extra whitespace and newlines are removed.
 954
 955 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 956
 957 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 958 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 959
 960 =item B<create_parameterized_type_constraint ($type_name)>
 961
 962 Given a C<$type_name> in the form of:
 963
 964   BaseType[ContainerType]
 965
 966 this will extract the base type and container type and build an instance of
 967 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 968
 969 =item B<create_class_type_constraint ($class, ?$options)>
 970
 971 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 972 object for that class name.
 973
 974 =item B<create_role_type_constraint ($role, ?$options)>
 975
 976 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 977 object for that role name.
 978
 979 =item B<create_enum_type_constraint ($name, $values)>
 980
 981 =item B<find_or_parse_type_constraint ($type_name)>
 982
 983 This will attempt to find or create a type constraint given the a C<$type_name>.
 984 If it cannot find it in the registry, it will see if it should be a union or
 985 container type an create one if appropriate
 986
 987 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 988
 989 This function will first call C<find_or_parse_type_constraint> with the type name.
 990
 991 If no type is found or created, but C<$options_for_anon_type> are provided, it
 992 will create the corresponding type.
 993
 994 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 995 and are now superseded by C<find_or_create_isa_type_constraint> and
 996 C<find_or_create_does_type_constraint>.
 997
 998 =item B<find_or_create_isa_type_constraint ($type_name)>
 999
1000 =item B<find_or_create_does_type_constraint ($type_name)>
1001
1002 Attempts to parse the type name using C<find_or_parse_type_constraint> and if
1003 no appropriate constraint is found will create a new anonymous one.
1004
1005 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
1006 variant will use C<create_role_type_constraint>.
1007
1008 =item B<find_type_constraint ($type_name)>
1009
1010 This function can be used to locate a specific type constraint
1011 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
1012 derivative. What you do with it from there is up to you :)
1013
1014 =item B<register_type_constraint ($type_object)>
1015
1016 This function will register a named type constraint with the type registry.
1017
1018 =item B<get_type_constraint_registry>
1019
1020 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
1021 keeps track of all type constraints.
1022
1023 =item B<list_all_type_constraints>
1024
1025 This will return a list of type constraint names, you can then
1026 fetch them using C<find_type_constraint ($type_name)> if you
1027 want to.
1028
1029 =item B<list_all_builtin_type_constraints>
1030
1031 This will return a list of builtin type constraints, meaning,
1032 those which are defined in this module. See the section
1033 labeled L<Default Type Constraints> for a complete list.
1034
1035 =item B<export_type_constraints_as_functions>
1036
1037 This will export all the current type constraints as functions
1038 into the caller's namespace. Right now, this is mostly used for
1039 testing, but it might prove useful to others.
1040
1041 =item B<get_all_parameterizable_types>
1042
1043 This returns all the parameterizable types that have been registered.
1044
1045 =item B<add_parameterizable_type ($type)>
1046
1047 Adds C<$type> to the list of parameterizable types
1048
1049 =back
1050
1051 =head2 Namespace Management
1052
1053 =over 4
1054
1055 =item B<unimport>
1056
1057 This will remove all the type constraint keywords from the
1058 calling class namespace.
1059
1060 =back
1061
1062 =head1 BUGS
1063
1064 All complex software has bugs lurking in it, and this module is no
1065 exception. If you find a bug please either email me, or add the bug
1066 to cpan-RT.
1067
1068 =head1 AUTHOR
1069
1070 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1071
1072 =head1 COPYRIGHT AND LICENSE
1073
1074 Copyright 2006-2008 by Infinity Interactive, Inc.
1075
1076 L<http://www.iinteractive.com>
1077
1078 This library is free software; you can redistribute it and/or modify
1079 it under the same terms as Perl itself.
1080
1081 =cut