lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed';
   9 use Sub::Exporter;
  10
  11 our $VERSION   = '0.24';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 ## --------------------------------------------------------
  15 # Prototyped subs must be predeclared because we have a
  16 # circular dependency with Moose::Meta::Attribute et. al.
  17 # so in case of us being use'd first the predeclaration
  18 # ensures the prototypes are in scope when consumers are
  19 # compiled.
  20
  21 # creation and location
  22 sub find_type_constraint                 ($);
  23 sub register_type_constraint             ($);
  24 sub find_or_create_type_constraint       ($;$);
  25 sub find_or_parse_type_constraint        ($);
  26 sub find_or_create_isa_type_constraint   ($);
  27 sub find_or_create_does_type_constraint  ($);
  28 sub create_type_constraint_union         (@);
  29 sub create_parameterized_type_constraint ($);
  30 sub create_class_type_constraint         ($;$);
  31 sub create_role_type_constraint          ($;$);
  32 sub create_enum_type_constraint          ($$);
  33
  34 # dah sugah!
  35 sub type        ($$;$$);
  36 sub subtype     ($$;$$$);
  37 sub class_type  ($;$);
  38 sub coerce      ($@);
  39 sub as          ($);
  40 sub from        ($);
  41 sub where       (&);
  42 sub via         (&);
  43 sub message     (&);
  44 sub optimize_as (&);
  45 sub enum        ($;@);
  46
  47 ## private stuff ...
  48 sub _create_type_constraint ($$$;$$);
  49 sub _install_type_coercions ($$);
  50
  51 ## --------------------------------------------------------
  52
  53 use Moose::Meta::TypeConstraint;
  54 use Moose::Meta::TypeConstraint::Union;
  55 use Moose::Meta::TypeConstraint::Parameterized;
  56 use Moose::Meta::TypeConstraint::Parameterizable;
  57 use Moose::Meta::TypeConstraint::Class;
  58 use Moose::Meta::TypeConstraint::Role;
  59 use Moose::Meta::TypeConstraint::Enum;
  60 use Moose::Meta::TypeCoercion;
  61 use Moose::Meta::TypeCoercion::Union;
  62 use Moose::Meta::TypeConstraint::Registry;
  63 use Moose::Util::TypeConstraints::OptimizedConstraints;
  64
  65 my @exports = qw/
  66     type subtype class_type role_type as where message optimize_as
  67     coerce from via
  68     enum
  69     find_type_constraint
  70     register_type_constraint
  71 /;
  72
  73 Sub::Exporter::setup_exporter({
  74     exports => \@exports,
  75     groups  => { default => [':all'] }
  76 });
  77
  78 sub unimport {
  79     no strict 'refs';
  80     my $class = caller();
  81     # loop through the exports ...
  82     foreach my $name (@exports) {
  83         # if we find one ...
  84         if (defined &{$class . '::' . $name}) {
  85             my $keyword = \&{$class . '::' . $name};
  86
  87             # make sure it is from Moose
  88             my ($pkg_name) = Class::MOP::get_code_info($keyword);
  89             next if $@;
  90             next if $pkg_name ne 'Moose::Util::TypeConstraints';
  91
  92             # and if it is from Moose then undef the slot
  93             delete ${$class . '::'}{$name};
  94         }
  95     }
  96 }
  97
  98 ## --------------------------------------------------------
  99 ## type registry and some useful functions for it
 100 ## --------------------------------------------------------
 101
 102 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
 103
 104 sub get_type_constraint_registry         { $REGISTRY }
 105 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
 106 sub export_type_constraints_as_functions {
 107     my $pkg = caller();
 108     no strict 'refs';
 109     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
 110         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
 111         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef };
 112     }
 113 }
 114
 115 sub create_type_constraint_union (@) {
 116     my @type_constraint_names;
 117
 118     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
 119         @type_constraint_names = _parse_type_constraint_union($_[0]);
 120     }
 121     else {
 122         @type_constraint_names = @_;
 123     }
 124
 125     (scalar @type_constraint_names >= 2)
 126         || confess "You must pass in at least 2 type names to make a union";
 127
 128     ($REGISTRY->has_type_constraint($_))
 129         || confess "Could not locate type constraint ($_) for the union"
 130             foreach @type_constraint_names;
 131
 132     return Moose::Meta::TypeConstraint::Union->new(
 133         type_constraints => [
 134             map {
 135                 $REGISTRY->get_type_constraint($_)
 136             } @type_constraint_names
 137         ],
 138     );
 139 }
 140
 141 sub create_parameterized_type_constraint ($) {
 142     my $type_constraint_name = shift;
 143
 144     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 145
 146     (defined $base_type && defined $type_parameter)
 147         || confess "Could not parse type name ($type_constraint_name) correctly";
 148
 149     ($REGISTRY->has_type_constraint($base_type))
 150         || confess "Could not locate the base type ($base_type)";
 151
 152     return Moose::Meta::TypeConstraint::Parameterized->new(
 153         name           => $type_constraint_name,
 154         parent         => $REGISTRY->get_type_constraint($base_type),
 155         type_parameter => find_or_create_isa_type_constraint($type_parameter),
 156     );
 157 }
 158
 159 #should we also support optimized checks?
 160 sub create_class_type_constraint ($;$) {
 161     my ( $class, $options ) = @_;
 162
 163     # too early for this check
 164     #find_type_constraint("ClassName")->check($class)
 165     #    || confess "Can't create a class type constraint because '$class' is not a class name";
 166
 167     my %options = (
 168         class => $class,
 169         name  => $class,
 170         %{ $options || {} },
 171     );
 172
 173     $options{name} ||= "__ANON__";
 174
 175     Moose::Meta::TypeConstraint::Class->new( %options );
 176 }
 177
 178 sub create_role_type_constraint ($;$) {
 179     my ( $role, $options ) = @_;
 180
 181     # too early for this check
 182     #find_type_constraint("ClassName")->check($class)
 183     #    || confess "Can't create a class type constraint because '$class' is not a class name";
 184
 185     my %options = (
 186         role => $role,
 187         name => $role,
 188         %{ $options || {} },
 189     );
 190
 191     $options{name} ||= "__ANON__";
 192
 193     Moose::Meta::TypeConstraint::Role->new( %options );
 194 }
 195
 196
 197 sub find_or_create_type_constraint ($;$) {
 198     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 199
 200     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 201         return $constraint;
 202     }
 203     elsif ( defined $options_for_anon_type ) {
 204         # NOTE:
 205         # if there is no $options_for_anon_type
 206         # specified, then we assume they don't
 207         # want to create one, and return nothing.
 208
 209         # otherwise assume that we should create
 210         # an ANON type with the $options_for_anon_type
 211         # options which can be passed in. It should
 212         # be noted that these don't get registered
 213         # so we need to return it.
 214         # - SL
 215         return Moose::Meta::TypeConstraint->new(
 216             name => '__ANON__',
 217             %{$options_for_anon_type}
 218         );
 219     }
 220
 221     return;
 222 }
 223
 224 sub find_or_create_isa_type_constraint ($) {
 225     my $type_constraint_name = shift;
 226     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 227 }
 228
 229 sub find_or_create_does_type_constraint ($) {
 230     my $type_constraint_name = shift;
 231     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 232 }
 233
 234 sub find_or_parse_type_constraint ($) {
 235     my $type_constraint_name = shift;
 236
 237     return $REGISTRY->get_type_constraint($type_constraint_name)
 238         if $REGISTRY->has_type_constraint($type_constraint_name);
 239
 240     my $constraint;
 241
 242     if (_detect_type_constraint_union($type_constraint_name)) {
 243         $constraint = create_type_constraint_union($type_constraint_name);
 244     }
 245     elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 246         $constraint = create_parameterized_type_constraint($type_constraint_name);
 247     } else {
 248         return;
 249     }
 250
 251     $REGISTRY->add_type_constraint($constraint);
 252     return $constraint;
 253 }
 254
 255 ## --------------------------------------------------------
 256 ## exported functions ...
 257 ## --------------------------------------------------------
 258
 259 sub find_type_constraint ($) {
 260     my $type = shift;
 261
 262     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 263         return $type;
 264     } else {
 265         return $REGISTRY->get_type_constraint($type);
 266     }
 267 }
 268
 269 sub register_type_constraint ($) {
 270     my $constraint = shift;
 271     confess "can't register an unnamed type constraint" unless defined $constraint->name;
 272     $REGISTRY->add_type_constraint($constraint);
 273     return $constraint;
 274 }
 275
 276 # type constructors
 277
 278 sub type ($$;$$) {
 279     splice(@_, 1, 0, undef);
 280     goto &_create_type_constraint;
 281 }
 282
 283 sub subtype ($$;$$$) {
 284     # NOTE:
 285     # this adds an undef for the name
 286     # if this is an anon-subtype:
 287     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 288     # but if the last arg is not a code
 289     # ref then it is a subtype alias:
 290     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 291     # ... yeah I know it's ugly code
 292     # - SL
 293     unshift @_ => undef if scalar @_ <= 2 && ('CODE' eq ref($_[1]));
 294     goto &_create_type_constraint;
 295 }
 296
 297 sub class_type ($;$) {
 298     register_type_constraint(
 299         create_class_type_constraint(
 300             $_[0],
 301             ( defined($_[1]) ? $_[1] : () ),
 302         )
 303     );
 304 }
 305
 306 sub role_type ($;$) {
 307     register_type_constraint(
 308         create_role_type_constraint(
 309             $_[0],
 310             ( defined($_[1]) ? $_[1] : () ),
 311         )
 312     );
 313 }
 314
 315 sub coerce ($@) {
 316     my ($type_name, @coercion_map) = @_;
 317     _install_type_coercions($type_name, \@coercion_map);
 318 }
 319
 320 sub as      ($) { $_[0] }
 321 sub from    ($) { $_[0] }
 322 sub where   (&) { $_[0] }
 323 sub via     (&) { $_[0] }
 324
 325 sub message     (&) { +{ message   => $_[0] } }
 326 sub optimize_as (&) { +{ optimized => $_[0] } }
 327
 328 sub enum ($;@) {
 329     my ($type_name, @values) = @_;
 330     # NOTE:
 331     # if only an array-ref is passed then
 332     # you get an anon-enum
 333     # - SL
 334     if (ref $type_name eq 'ARRAY' && !@values) {
 335         @values    = @$type_name;
 336         $type_name = undef;
 337     }
 338     (scalar @values >= 2)
 339         || confess "You must have at least two values to enumerate through";
 340     my %valid = map { $_ => 1 } @values;
 341
 342     register_type_constraint(
 343         create_enum_type_constraint(
 344             $type_name,
 345             \@values,
 346         )
 347     );
 348 }
 349
 350 sub create_enum_type_constraint ($$) {
 351     my ( $type_name, $values ) = @_;
 352
 353     Moose::Meta::TypeConstraint::Enum->new(
 354         name   => $type_name || '__ANON__',
 355         values => $values,
 356     );
 357 }
 358
 359 ## --------------------------------------------------------
 360 ## desugaring functions ...
 361 ## --------------------------------------------------------
 362
 363 sub _create_type_constraint ($$$;$$) {
 364     my $name   = shift;
 365     my $parent = shift;
 366     my $check  = shift;
 367
 368     my ($message, $optimized);
 369     for (@_) {
 370         $message   = $_->{message}   if exists $_->{message};
 371         $optimized = $_->{optimized} if exists $_->{optimized};
 372     }
 373
 374     my $pkg_defined_in = scalar(caller(0));
 375
 376     if (defined $name) {
 377         my $type = $REGISTRY->get_type_constraint($name);
 378
 379         ($type->_package_defined_in eq $pkg_defined_in)
 380             || confess ("The type constraint '$name' has already been created in "
 381                        . $type->_package_defined_in . " and cannot be created again in "
 382                        . $pkg_defined_in)
 383                  if defined $type;
 384     }
 385
 386     my $class = "Moose::Meta::TypeConstraint";
 387
 388     # FIXME should probably not be a special case
 389     if ( defined $parent and $parent = find_or_parse_type_constraint($parent) ) {
 390         $class = "Moose::Meta::TypeConstraint::Parameterizable"
 391             if $parent->isa("Moose::Meta::TypeConstraint::Parameterizable");
 392     }
 393
 394     my $constraint = $class->new(
 395         name               => $name || '__ANON__',
 396         package_defined_in => $pkg_defined_in,
 397
 398         ($parent    ? (parent     => $parent )   : ()),
 399         ($check     ? (constraint => $check)     : ()),
 400         ($message   ? (message    => $message)   : ()),
 401         ($optimized ? (optimized  => $optimized) : ()),
 402     );
 403
 404     # NOTE:
 405     # if we have a type constraint union, and no
 406     # type check, this means we are just aliasing
 407     # the union constraint, which means we need to
 408     # handle this differently.
 409     # - SL
 410     if (not(defined $check)
 411         && $parent->isa('Moose::Meta::TypeConstraint::Union')
 412         && $parent->has_coercion
 413         ){
 414         $constraint->coercion(Moose::Meta::TypeCoercion::Union->new(
 415             type_constraint => $parent
 416         ));
 417     }
 418
 419     $REGISTRY->add_type_constraint($constraint)
 420         if defined $name;
 421
 422     return $constraint;
 423 }
 424
 425 sub _install_type_coercions ($$) {
 426     my ($type_name, $coercion_map) = @_;
 427     my $type = $REGISTRY->get_type_constraint($type_name);
 428     (defined $type)
 429         || confess "Cannot find type '$type_name', perhaps you forgot to load it.";
 430     if ($type->has_coercion) {
 431         $type->coercion->add_type_coercions(@$coercion_map);
 432     }
 433     else {
 434         my $type_coercion = Moose::Meta::TypeCoercion->new(
 435             type_coercion_map => $coercion_map,
 436             type_constraint   => $type
 437         );
 438         $type->coercion($type_coercion);
 439     }
 440 }
 441
 442 ## --------------------------------------------------------
 443 ## type notation parsing ...
 444 ## --------------------------------------------------------
 445
 446 {
 447     # All I have to say is mugwump++ cause I know
 448     # do not even have enough regexp-fu to be able
 449     # to have written this (I can only barely
 450     # understand it as it is)
 451     # - SL
 452
 453     use re "eval";
 454
 455     my $valid_chars = qr{[\w:]};
 456     my $type_atom   = qr{ $valid_chars+ };
 457
 458     my $type                = qr{  $valid_chars+  (?: \[  (??{$any})  \] )? }x;
 459     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ ((??{$any})) \] )? }x;
 460     my $type_with_parameter = qr{  $valid_chars+      \[  (??{$any})  \]    }x;
 461
 462     my $op_union = qr{ \s* \| \s* }x;
 463     my $union    = qr{ $type (?: $op_union $type )+ }x;
 464
 465     our $any = qr{ $type | $union }x;
 466
 467     sub _parse_parameterized_type_constraint {
 468         $_[0] =~ m{ $type_capture_parts }x;
 469         return ($1, $2);
 470     }
 471
 472     sub _detect_parameterized_type_constraint {
 473         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 474     }
 475
 476     sub _parse_type_constraint_union {
 477         my $given = shift;
 478         my @rv;
 479         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 480             push @rv => $1;
 481         }
 482         (pos($given) eq length($given))
 483             || confess "'$given' didn't parse (parse-pos="
 484                      . pos($given)
 485                      . " and str-length="
 486                      . length($given)
 487                      . ")";
 488         @rv;
 489     }
 490
 491     sub _detect_type_constraint_union {
 492         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 493     }
 494 }
 495
 496 ## --------------------------------------------------------
 497 # define some basic built-in types
 498 ## --------------------------------------------------------
 499
 500 type 'Any'  => where { 1 }; # meta-type including all
 501 type 'Item' => where { 1 }; # base-type
 502
 503 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 504 subtype 'Defined' => as 'Item' => where {  defined($_) };
 505
 506 subtype 'Bool'
 507     => as 'Item'
 508     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 509
 510 subtype 'Value'
 511     => as 'Defined'
 512     => where { !ref($_) }
 513     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 514
 515 subtype 'Ref'
 516     => as 'Defined'
 517     => where {  ref($_) }
 518     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 519
 520 subtype 'Str'
 521     => as 'Value'
 522     => where { 1 }
 523     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 524
 525 subtype 'Num'
 526     => as 'Value'
 527     => where { Scalar::Util::looks_like_number($_) }
 528     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 529
 530 subtype 'Int'
 531     => as 'Num'
 532     => where { "$_" =~ /^-?[0-9]+$/ }
 533     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 534
 535 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 536 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 537 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 538 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 539
 540 # NOTE:
 541 # scalar filehandles are GLOB refs,
 542 # but a GLOB ref is not always a filehandle
 543 subtype 'FileHandle'
 544     => as 'GlobRef'
 545     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 546     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 547
 548 # NOTE:
 549 # blessed(qr/.../) returns true,.. how odd
 550 subtype 'Object'
 551     => as 'Ref'
 552     => where { blessed($_) && blessed($_) ne 'Regexp' }
 553     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 554
 555 subtype 'Role'
 556     => as 'Object'
 557     => where { $_->can('does') }
 558     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 559
 560 my $_class_name_checker = sub {
 561     return if ref($_[0]);
 562     return unless defined($_[0]) && length($_[0]);
 563
 564     # walk the symbol table tree to avoid autovififying
 565     # \*{${main::}{"Foo::"}} == \*main::Foo::
 566
 567     my $pack = \*::;
 568     foreach my $part (split('::', $_[0])) {
 569         return unless exists ${$$pack}{"${part}::"};
 570         $pack = \*{${$$pack}{"${part}::"}};
 571     }
 572
 573     # check for $VERSION or @ISA
 574     return 1 if exists ${$$pack}{VERSION}
 575              && defined *{${$$pack}{VERSION}}{SCALAR};
 576     return 1 if exists ${$$pack}{ISA}
 577              && defined *{${$$pack}{ISA}}{ARRAY};
 578
 579     # check for any method
 580     foreach ( keys %{$$pack} ) {
 581         next if substr($_, -2, 2) eq '::';
 582         return 1 if defined *{${$$pack}{$_}}{CODE};
 583     }
 584
 585     # fail
 586     return;
 587 };
 588
 589 subtype 'ClassName'
 590     => as 'Str'
 591     => $_class_name_checker # where ...
 592     => { optimize => $_class_name_checker };
 593
 594 ## --------------------------------------------------------
 595 # parameterizable types ...
 596
 597 $REGISTRY->add_type_constraint(
 598     Moose::Meta::TypeConstraint::Parameterizable->new(
 599         name                 => 'ArrayRef',
 600         package_defined_in   => __PACKAGE__,
 601         parent               => find_type_constraint('Ref'),
 602         constraint           => sub { ref($_) eq 'ARRAY'  },
 603         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 604         constraint_generator => sub {
 605             my $type_parameter = shift;
 606             my $check = $type_parameter->_compiled_type_constraint;
 607             return sub {
 608                 foreach my $x (@$_) {
 609                     ($check->($x)) || return
 610                 } 1;
 611             }
 612         }
 613     )
 614 );
 615
 616 $REGISTRY->add_type_constraint(
 617     Moose::Meta::TypeConstraint::Parameterizable->new(
 618         name                 => 'HashRef',
 619         package_defined_in   => __PACKAGE__,
 620         parent               => find_type_constraint('Ref'),
 621         constraint           => sub { ref($_) eq 'HASH'  },
 622         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 623         constraint_generator => sub {
 624             my $type_parameter = shift;
 625             my $check = $type_parameter->_compiled_type_constraint;
 626             return sub {
 627                 foreach my $x (values %$_) {
 628                     ($check->($x)) || return
 629                 } 1;
 630             }
 631         }
 632     )
 633 );
 634
 635 $REGISTRY->add_type_constraint(
 636     Moose::Meta::TypeConstraint::Parameterizable->new(
 637         name                 => 'Maybe',
 638         package_defined_in   => __PACKAGE__,
 639         parent               => find_type_constraint('Item'),
 640         constraint           => sub { 1 },
 641         constraint_generator => sub {
 642             my $type_parameter = shift;
 643             my $check = $type_parameter->_compiled_type_constraint;
 644             return sub {
 645                 return 1 if not(defined($_)) || $check->($_);
 646                 return;
 647             }
 648         }
 649     )
 650 );
 651
 652 my @PARAMETERIZABLE_TYPES = map {
 653     $REGISTRY->get_type_constraint($_)
 654 } qw[ArrayRef HashRef Maybe];
 655
 656 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 657 sub add_parameterizable_type {
 658     my $type = shift;
 659     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 660         || confess "Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type";
 661     push @PARAMETERIZABLE_TYPES => $type;
 662 }
 663
 664 ## --------------------------------------------------------
 665 # end of built-in types ...
 666 ## --------------------------------------------------------
 667
 668 {
 669     my @BUILTINS = list_all_type_constraints();
 670     sub list_all_builtin_type_constraints { @BUILTINS }
 671 }
 672
 673 1;
 674
 675 __END__
 676
 677 =pod
 678
 679 =head1 NAME
 680
 681 Moose::Util::TypeConstraints - Type constraint system for Moose
 682
 683 =head1 SYNOPSIS
 684
 685   use Moose::Util::TypeConstraints;
 686
 687   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 688
 689   subtype 'Natural'
 690       => as 'Num'
 691       => where { $_ > 0 };
 692
 693   subtype 'NaturalLessThanTen'
 694       => as 'Natural'
 695       => where { $_ < 10 }
 696       => message { "This number ($_) is not less than ten!" };
 697
 698   coerce 'Num'
 699       => from 'Str'
 700         => via { 0+$_ };
 701
 702   enum 'RGBColors' => qw(red green blue);
 703
 704 =head1 DESCRIPTION
 705
 706 This module provides Moose with the ability to create custom type
 707 contraints to be used in attribute definition.
 708
 709 =head2 Important Caveat
 710
 711 This is B<NOT> a type system for Perl 5. These are type constraints,
 712 and they are not used by Moose unless you tell it to. No type
 713 inference is performed, expression are not typed, etc. etc. etc.
 714
 715 This is simply a means of creating small constraint functions which
 716 can be used to simplify your own type-checking code, with the added
 717 side benefit of making your intentions clearer through self-documentation.
 718
 719 =head2 Slightly Less Important Caveat
 720
 721 It is B<always> a good idea to quote your type and subtype names.
 722
 723 This is to prevent perl from trying to execute the call as an indirect
 724 object call. This issue only seems to come up when you have a subtype
 725 the same name as a valid class, but when the issue does arise it tends
 726 to be quite annoying to debug.
 727
 728 So for instance, this:
 729
 730   subtype DateTime => as Object => where { $_->isa('DateTime') };
 731
 732 will I<Just Work>, while this:
 733
 734   use DateTime;
 735   subtype DateTime => as Object => where { $_->isa('DateTime') };
 736
 737 will fail silently and cause many headaches. The simple way to solve
 738 this, as well as future proof your subtypes from classes which have
 739 yet to have been created yet, is to simply do this:
 740
 741   use DateTime;
 742   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 743
 744 =head2 Default Type Constraints
 745
 746 This module also provides a simple hierarchy for Perl 5 types, here is
 747 that hierarchy represented visually.
 748
 749   Any
 750   Item
 751       Bool
 752       Maybe[`a]
 753       Undef
 754       Defined
 755           Value
 756               Num
 757                 Int
 758               Str
 759                 ClassName
 760           Ref
 761               ScalarRef
 762               ArrayRef[`a]
 763               HashRef[`a]
 764               CodeRef
 765               RegexpRef
 766               GlobRef
 767                 FileHandle
 768               Object
 769                   Role
 770
 771 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 772 parameterized, this means you can say:
 773
 774   ArrayRef[Int]    # an array of intergers
 775   HashRef[CodeRef] # a hash of str to CODE ref mappings
 776   Maybe[Str]       # value may be a string, may be undefined
 777
 778 B<NOTE:> The C<Undef> type constraint for the most part works
 779 correctly now, but edge cases may still exist, please use it
 780 sparringly.
 781
 782 B<NOTE:> The C<ClassName> type constraint does a complex package
 783 existence check. This means that your class B<must> be loaded for
 784 this type constraint to pass. I know this is not ideal for all,
 785 but it is a saner restriction than most others.
 786
 787 =head2 Type Constraint Naming
 788
 789 Since the types created by this module are global, it is suggested
 790 that you namespace your types just as you would namespace your
 791 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 792 module, you would call the type I<My::Graphics::Color> instead.
 793
 794 =head2 Use with Other Constraint Modules
 795
 796 This module should play fairly nicely with other constraint
 797 modules with only some slight tweaking. The C<where> clause
 798 in types is expected to be a C<CODE> reference which checks
 799 it's first argument and returns a boolean. Since most constraint
 800 modules work in a similar way, it should be simple to adapt
 801 them to work with Moose.
 802
 803 For instance, this is how you could use it with
 804 L<Declare::Constraints::Simple> to declare a completely new type.
 805
 806   type 'HashOfArrayOfObjects'
 807       => IsHashRef(
 808           -keys   => HasLength,
 809           -values => IsArrayRef( IsObject ));
 810
 811 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 812 test file.
 813
 814 Here is an example of using L<Test::Deep> and it's non-test
 815 related C<eq_deeply> function.
 816
 817   type 'ArrayOfHashOfBarsAndRandomNumbers'
 818       => where {
 819           eq_deeply($_,
 820               array_each(subhashof({
 821                   bar           => isa('Bar'),
 822                   random_number => ignore()
 823               })))
 824         };
 825
 826 For a complete example see the
 827 F<t/200_examples/205_example_w_TestDeep.t> test file.
 828
 829 =head1 FUNCTIONS
 830
 831 =head2 Type Constraint Constructors
 832
 833 The following functions are used to create type constraints.
 834 They will then register the type constraints in a global store
 835 where Moose can get to them if it needs to.
 836
 837 See the L<SYNOPSIS> for an example of how to use these.
 838
 839 =over 4
 840
 841 =item B<type ($name, $where_clause)>
 842
 843 This creates a base type, which has no parent.
 844
 845 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 846
 847 This creates a named subtype.
 848
 849 =item B<subtype ($parent, $where_clause, ?$message)>
 850
 851 This creates an unnamed subtype and will return the type
 852 constraint meta-object, which will be an instance of
 853 L<Moose::Meta::TypeConstraint>.
 854
 855 =item B<class_type ($class, ?$options)>
 856
 857 Creates a type constraint with the name C<$class> and the metaclass
 858 L<Moose::Meta::TypeConstraint::Class>.
 859
 860 =item B<role_type ($role, ?$options)>
 861
 862 Creates a type constraint with the name C<$role> and the metaclass
 863 L<Moose::Meta::TypeConstraint::Role>.
 864
 865 =item B<enum ($name, @values)>
 866
 867 This will create a basic subtype for a given set of strings.
 868 The resulting constraint will be a subtype of C<Str> and
 869 will match any of the items in C<@values>. It is case sensitive.
 870 See the L<SYNOPSIS> for a simple example.
 871
 872 B<NOTE:> This is not a true proper enum type, it is simple
 873 a convient constraint builder.
 874
 875 =item B<enum (\@values)>
 876
 877 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 878 this will create an unnamed enum. This can then be used in an attribute
 879 definition like so:
 880
 881   has 'sort_order' => (
 882       is  => 'ro',
 883       isa => enum([qw[ ascending descending ]]),
 884   );
 885
 886 =item B<as>
 887
 888 This is just sugar for the type constraint construction syntax.
 889
 890 =item B<where>
 891
 892 This is just sugar for the type constraint construction syntax.
 893
 894 =item B<message>
 895
 896 This is just sugar for the type constraint construction syntax.
 897
 898 =item B<optimize_as>
 899
 900 This can be used to define a "hand optimized" version of your
 901 type constraint which can be used to avoid traversing a subtype
 902 constraint heirarchy.
 903
 904 B<NOTE:> You should only use this if you know what you are doing,
 905 all the built in types use this, so your subtypes (assuming they
 906 are shallow) will not likely need to use this.
 907
 908 =back
 909
 910 =head2 Type Coercion Constructors
 911
 912 Type constraints can also contain type coercions as well. If you
 913 ask your accessor to coerce, then Moose will run the type-coercion
 914 code first, followed by the type constraint check. This feature
 915 should be used carefully as it is very powerful and could easily
 916 take off a limb if you are not careful.
 917
 918 See the L<SYNOPSIS> for an example of how to use these.
 919
 920 =over 4
 921
 922 =item B<coerce>
 923
 924 =item B<from>
 925
 926 This is just sugar for the type coercion construction syntax.
 927
 928 =item B<via>
 929
 930 This is just sugar for the type coercion construction syntax.
 931
 932 =back
 933
 934 =head2 Type Constraint Construction & Locating
 935
 936 =over 4
 937
 938 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 939
 940 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 941 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 942
 943 =item B<create_parameterized_type_constraint ($type_name)>
 944
 945 Given a C<$type_name> in the form of:
 946
 947   BaseType[ContainerType]
 948
 949 this will extract the base type and container type and build an instance of
 950 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 951
 952 =item B<create_class_type_constraint ($class, ?$options)>
 953
 954 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 955 object for that class name.
 956
 957 =item B<create_role_type_constraint ($role, ?$options)>
 958
 959 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 960 object for that role name.
 961
 962 =item B<create_enum_type_constraint ($name, $values)>
 963
 964 =item B<find_or_parse_type_constraint ($type_name)>
 965
 966 This will attempt to find or create a type constraint given the a C<$type_name>.
 967 If it cannot find it in the registry, it will see if it should be a union or
 968 container type an create one if appropriate
 969
 970 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 971
 972 This function will first call C<find_or_parse_type_constraint> with the type name.
 973
 974 If no type is found or created, but C<$options_for_anon_type> are provided, it
 975 will create the corresponding type.
 976
 977 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 978 and are now superseded by C<find_or_create_isa_type_constraint> and
 979 C<find_or_create_does_type_constraint>.
 980
 981 =item B<find_or_create_isa_type_constraint ($type_name)>
 982
 983 =item B<find_or_create_does_type_constraint ($type_name)>
 984
 985 Attempts to parse the type name using L<find_or_parse_type_constraint> and if
 986 no appropriate constraint is found will create a new anonymous one.
 987
 988 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
 989 variant will use C<create_role_type_constraint>.
 990
 991 =item B<find_type_constraint ($type_name)>
 992
 993 This function can be used to locate a specific type constraint
 994 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
 995 derivative. What you do with it from there is up to you :)
 996
 997 =item B<register_type_constraint ($type_object)>
 998
 999 This function will register a named type constraint with the type registry.
1000
1001 =item B<get_type_constraint_registry>
1002
1003 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
1004 keeps track of all type constraints.
1005
1006 =item B<list_all_type_constraints>
1007
1008 This will return a list of type constraint names, you can then
1009 fetch them using C<find_type_constraint ($type_name)> if you
1010 want to.
1011
1012 =item B<list_all_builtin_type_constraints>
1013
1014 This will return a list of builtin type constraints, meaning,
1015 those which are defined in this module. See the section
1016 labeled L<Default Type Constraints> for a complete list.
1017
1018 =item B<export_type_constraints_as_functions>
1019
1020 This will export all the current type constraints as functions
1021 into the caller's namespace. Right now, this is mostly used for
1022 testing, but it might prove useful to others.
1023
1024 =item B<get_all_parameterizable_types>
1025
1026 This returns all the parameterizable types that have been registered.
1027
1028 =item B<add_parameterizable_type ($type)>
1029
1030 Adds C<$type> to the list of parameterizable types
1031
1032 =back
1033
1034 =head2 Namespace Management
1035
1036 =over 4
1037
1038 =item B<unimport>
1039
1040 This will remove all the type constraint keywords from the
1041 calling class namespace.
1042
1043 =back
1044
1045 =head1 BUGS
1046
1047 All complex software has bugs lurking in it, and this module is no
1048 exception. If you find a bug please either email me, or add the bug
1049 to cpan-RT.
1050
1051 =head1 AUTHOR
1052
1053 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1054
1055 =head1 COPYRIGHT AND LICENSE
1056
1057 Copyright 2006-2008 by Infinity Interactive, Inc.
1058
1059 L<http://www.iinteractive.com>
1060
1061 This library is free software; you can redistribute it and/or modify
1062 it under the same terms as Perl itself.
1063
1064 =cut