lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.62';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type as where message optimize_as
  51             coerce from via
  52             enum
  53             find_type_constraint
  54             register_type_constraint )
  55     ],
  56     _export_to_main => 1,
  57 );
  58
  59 ## --------------------------------------------------------
  60 ## type registry and some useful functions for it
  61 ## --------------------------------------------------------
  62
  63 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  64
  65 sub get_type_constraint_registry         { $REGISTRY }
  66 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  67 sub export_type_constraints_as_functions {
  68     my $pkg = caller();
  69     no strict 'refs';
  70     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  71         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  72         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  73     }
  74 }
  75
  76 sub create_type_constraint_union {
  77     my @type_constraint_names;
  78
  79     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  80         @type_constraint_names = _parse_type_constraint_union($_[0]);
  81     }
  82     else {
  83         @type_constraint_names = @_;
  84     }
  85
  86     (scalar @type_constraint_names >= 2)
  87         || Moose->throw_error("You must pass in at least 2 type names to make a union");
  88
  89     my @type_constraints = map {
  90         find_or_parse_type_constraint($_) ||
  91          Moose->throw_error("Could not locate type constraint ($_) for the union");
  92     } @type_constraint_names;
  93
  94     return Moose::Meta::TypeConstraint::Union->new(
  95         type_constraints => \@type_constraints
  96     );
  97 }
  98
  99 sub create_parameterized_type_constraint {
 100     my $type_constraint_name = shift;
 101     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 102
 103     (defined $base_type && defined $type_parameter)
 104         || Moose->throw_error("Could not parse type name ($type_constraint_name) correctly");
 105
 106     if ($REGISTRY->has_type_constraint($base_type)) {
 107         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 108         return _create_parameterized_type_constraint(
 109             $base_type_tc,
 110             $type_parameter
 111         );
 112     } else {
 113         Moose->throw_error("Could not locate the base type ($base_type)");
 114     }
 115 }
 116
 117 sub _create_parameterized_type_constraint {
 118     my ( $base_type_tc, $type_parameter ) = @_;
 119     if ( $base_type_tc->can('parameterize') ) {
 120         return $base_type_tc->parameterize($type_parameter);
 121     } else {
 122         return Moose::Meta::TypeConstraint::Parameterized->new(
 123             name => $base_type_tc->name . '[' . $type_parameter . ']',
 124             parent => $base_type_tc,
 125             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 126         );
 127     }
 128 }
 129
 130 #should we also support optimized checks?
 131 sub create_class_type_constraint {
 132     my ( $class, $options ) = @_;
 133
 134     # too early for this check
 135     #find_type_constraint("ClassName")->check($class)
 136     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 137
 138     my %options = (
 139         class => $class,
 140         name  => $class,
 141         %{ $options || {} },
 142     );
 143
 144     $options{name} ||= "__ANON__";
 145
 146     Moose::Meta::TypeConstraint::Class->new( %options );
 147 }
 148
 149 sub create_role_type_constraint {
 150     my ( $role, $options ) = @_;
 151
 152     # too early for this check
 153     #find_type_constraint("ClassName")->check($class)
 154     #    || Moose->throw_error("Can't create a class type constraint because '$class' is not a class name");
 155
 156     my %options = (
 157         role => $role,
 158         name => $role,
 159         %{ $options || {} },
 160     );
 161
 162     $options{name} ||= "__ANON__";
 163
 164     Moose::Meta::TypeConstraint::Role->new( %options );
 165 }
 166
 167
 168 sub find_or_create_type_constraint {
 169     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 170
 171     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 172         return $constraint;
 173     }
 174     elsif ( defined $options_for_anon_type ) {
 175         # NOTE:
 176         # if there is no $options_for_anon_type
 177         # specified, then we assume they don't
 178         # want to create one, and return nothing.
 179
 180         # otherwise assume that we should create
 181         # an ANON type with the $options_for_anon_type
 182         # options which can be passed in. It should
 183         # be noted that these don't get registered
 184         # so we need to return it.
 185         # - SL
 186         return Moose::Meta::TypeConstraint->new(
 187             name => '__ANON__',
 188             %{$options_for_anon_type}
 189         );
 190     }
 191
 192     return;
 193 }
 194
 195 sub find_or_create_isa_type_constraint {
 196     my $type_constraint_name = shift;
 197     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 198 }
 199
 200 sub find_or_create_does_type_constraint {
 201     my $type_constraint_name = shift;
 202     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 203 }
 204
 205 sub find_or_parse_type_constraint {
 206     my $type_constraint_name = normalize_type_constraint_name(shift);
 207     my $constraint;
 208
 209     if ($constraint = find_type_constraint($type_constraint_name)) {
 210         return $constraint;
 211     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 212         $constraint = create_type_constraint_union($type_constraint_name);
 213     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 214         $constraint = create_parameterized_type_constraint($type_constraint_name);
 215     } else {
 216         return;
 217     }
 218
 219     $REGISTRY->add_type_constraint($constraint);
 220     return $constraint;
 221 }
 222
 223 sub normalize_type_constraint_name {
 224     my $type_constraint_name = shift;
 225     $type_constraint_name =~ s/\s//g;
 226     return $type_constraint_name;
 227 }
 228
 229 sub _confess {
 230     my $error = shift;
 231
 232     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 233     Carp::confess($error);
 234 }
 235
 236 ## --------------------------------------------------------
 237 ## exported functions ...
 238 ## --------------------------------------------------------
 239
 240 sub find_type_constraint {
 241     my $type = shift;
 242
 243     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 244         return $type;
 245     }
 246     else {
 247         return unless $REGISTRY->has_type_constraint($type);
 248         return $REGISTRY->get_type_constraint($type);
 249     }
 250 }
 251
 252 sub register_type_constraint {
 253     my $constraint = shift;
 254     Moose->throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 255     $REGISTRY->add_type_constraint($constraint);
 256     return $constraint;
 257 }
 258
 259 # type constructors
 260
 261 sub type {
 262     splice(@_, 1, 0, undef);
 263     goto &_create_type_constraint;
 264 }
 265
 266 sub subtype {
 267     # NOTE:
 268     # this adds an undef for the name
 269     # if this is an anon-subtype:
 270     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 271     #     or
 272     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 273     #
 274     # but if the last arg is not a code ref then it is a subtype
 275     # alias:
 276     #
 277     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 278     # ... yeah I know it's ugly code
 279     # - SL
 280     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 281     unshift @_ => undef
 282         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 283     goto &_create_type_constraint;
 284 }
 285
 286 sub class_type {
 287     register_type_constraint(
 288         create_class_type_constraint(
 289             $_[0],
 290             ( defined($_[1]) ? $_[1] : () ),
 291         )
 292     );
 293 }
 294
 295 sub role_type ($;$) {
 296     register_type_constraint(
 297         create_role_type_constraint(
 298             $_[0],
 299             ( defined($_[1]) ? $_[1] : () ),
 300         )
 301     );
 302 }
 303
 304 sub coerce {
 305     my ($type_name, @coercion_map) = @_;
 306     _install_type_coercions($type_name, \@coercion_map);
 307 }
 308
 309 sub as          { @_ }
 310 sub from        { @_ }
 311 sub where   (&) { $_[0] }
 312 sub via     (&) { $_[0] }
 313
 314 sub message     (&) { +{ message   => $_[0] } }
 315 sub optimize_as (&) { +{ optimized => $_[0] } }
 316
 317 sub enum {
 318     my ($type_name, @values) = @_;
 319     # NOTE:
 320     # if only an array-ref is passed then
 321     # you get an anon-enum
 322     # - SL
 323     if (ref $type_name eq 'ARRAY' && !@values) {
 324         @values    = @$type_name;
 325         $type_name = undef;
 326     }
 327     (scalar @values >= 2)
 328         || Moose->throw_error("You must have at least two values to enumerate through");
 329     my %valid = map { $_ => 1 } @values;
 330
 331     register_type_constraint(
 332         create_enum_type_constraint(
 333             $type_name,
 334             \@values,
 335         )
 336     );
 337 }
 338
 339 sub create_enum_type_constraint {
 340     my ( $type_name, $values ) = @_;
 341
 342     Moose::Meta::TypeConstraint::Enum->new(
 343         name   => $type_name || '__ANON__',
 344         values => $values,
 345     );
 346 }
 347
 348 ## --------------------------------------------------------
 349 ## desugaring functions ...
 350 ## --------------------------------------------------------
 351
 352 sub _create_type_constraint ($$$;$$) {
 353     my $name   = shift;
 354     my $parent = shift;
 355     my $check  = shift;
 356
 357     my ( $message, $optimized );
 358     for (@_) {
 359         $message   = $_->{message}   if exists $_->{message};
 360         $optimized = $_->{optimized} if exists $_->{optimized};
 361     }
 362
 363     my $pkg_defined_in = scalar( caller(0) );
 364
 365     if ( defined $name ) {
 366         my $type = $REGISTRY->get_type_constraint($name);
 367
 368         ( $type->_package_defined_in eq $pkg_defined_in )
 369             || _confess(
 370                   "The type constraint '$name' has already been created in "
 371                 . $type->_package_defined_in
 372                 . " and cannot be created again in "
 373                 . $pkg_defined_in )
 374             if defined $type;
 375     }
 376
 377     my %opts = (
 378         name => $name,
 379         package_defined_in => $pkg_defined_in,
 380
 381         ( $check     ? ( constraint => $check )     : () ),
 382         ( $message   ? ( message    => $message )   : () ),
 383         ( $optimized ? ( optimized  => $optimized ) : () ),
 384     );
 385
 386     my $constraint;
 387     if ( defined $parent
 388         and $parent
 389         = blessed $parent ? $parent : find_or_parse_type_constraint($parent) )
 390     {
 391         $constraint = $parent->create_child_type(%opts);
 392     }
 393     else {
 394         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 395     }
 396
 397     $REGISTRY->add_type_constraint($constraint)
 398         if defined $name;
 399
 400     return $constraint;
 401 }
 402
 403 sub _install_type_coercions ($$) {
 404     my ($type_name, $coercion_map) = @_;
 405     my $type = find_type_constraint($type_name);
 406     (defined $type)
 407         || Moose->throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 408     if ($type->has_coercion) {
 409         $type->coercion->add_type_coercions(@$coercion_map);
 410     }
 411     else {
 412         my $type_coercion = Moose::Meta::TypeCoercion->new(
 413             type_coercion_map => $coercion_map,
 414             type_constraint   => $type
 415         );
 416         $type->coercion($type_coercion);
 417     }
 418 }
 419
 420 ## --------------------------------------------------------
 421 ## type notation parsing ...
 422 ## --------------------------------------------------------
 423
 424 {
 425     # All I have to say is mugwump++ cause I know
 426     # do not even have enough regexp-fu to be able
 427     # to have written this (I can only barely
 428     # understand it as it is)
 429     # - SL
 430
 431     use re "eval";
 432
 433     my $valid_chars = qr{[\w:]};
 434     my $type_atom   = qr{ $valid_chars+ };
 435
 436     my $any;
 437
 438     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 439     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 440     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 441
 442     my $op_union = qr{ \s* \| \s* }x;
 443     my $union    = qr{ $type (?: $op_union $type )+ }x;
 444
 445     $any = qr{ $type | $union }x;
 446
 447     sub _parse_parameterized_type_constraint {
 448         { no warnings 'void'; $any; } # force capture of interpolated lexical
 449         $_[0] =~ m{ $type_capture_parts }x;
 450         return ($1, $2);
 451     }
 452
 453     sub _detect_parameterized_type_constraint {
 454         { no warnings 'void'; $any; } # force capture of interpolated lexical
 455         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 456     }
 457
 458     sub _parse_type_constraint_union {
 459         { no warnings 'void'; $any; } # force capture of interpolated lexical
 460         my $given = shift;
 461         my @rv;
 462         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 463             push @rv => $1;
 464         }
 465         (pos($given) eq length($given))
 466             || Moose->throw_error("'$given' didn't parse (parse-pos="
 467                      . pos($given)
 468                      . " and str-length="
 469                      . length($given)
 470                      . ")");
 471         @rv;
 472     }
 473
 474     sub _detect_type_constraint_union {
 475         { no warnings 'void'; $any; } # force capture of interpolated lexical
 476         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 477     }
 478 }
 479
 480 ## --------------------------------------------------------
 481 # define some basic built-in types
 482 ## --------------------------------------------------------
 483
 484 type 'Any'  => where { 1 }; # meta-type including all
 485 type 'Item' => where { 1 }; # base-type
 486
 487 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 488 subtype 'Defined' => as 'Item' => where {  defined($_) };
 489
 490 subtype 'Bool'
 491     => as 'Item'
 492     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 493
 494 subtype 'Value'
 495     => as 'Defined'
 496     => where { !ref($_) }
 497     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 498
 499 subtype 'Ref'
 500     => as 'Defined'
 501     => where {  ref($_) }
 502     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 503
 504 subtype 'Str'
 505     => as 'Value'
 506     => where { 1 }
 507     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 508
 509 subtype 'Num'
 510     => as 'Value'
 511     => where { Scalar::Util::looks_like_number($_) }
 512     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 513
 514 subtype 'Int'
 515     => as 'Num'
 516     => where { "$_" =~ /^-?[0-9]+$/ }
 517     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 518
 519 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 520 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 521 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 522 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 523
 524 # NOTE:
 525 # scalar filehandles are GLOB refs,
 526 # but a GLOB ref is not always a filehandle
 527 subtype 'FileHandle'
 528     => as 'GlobRef'
 529     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 530     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 531
 532 # NOTE:
 533 # blessed(qr/.../) returns true,.. how odd
 534 subtype 'Object'
 535     => as 'Ref'
 536     => where { blessed($_) && blessed($_) ne 'Regexp' }
 537     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 538
 539 subtype 'Role'
 540     => as 'Object'
 541     => where { $_->can('does') }
 542     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 543
 544 my $_class_name_checker = sub {
 545 };
 546
 547 subtype 'ClassName'
 548     => as 'Str'
 549     => where { Class::MOP::is_class_loaded($_) }
 550     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 551
 552 ## --------------------------------------------------------
 553 # parameterizable types ...
 554
 555 $REGISTRY->add_type_constraint(
 556     Moose::Meta::TypeConstraint::Parameterizable->new(
 557         name                 => 'ArrayRef',
 558         package_defined_in   => __PACKAGE__,
 559         parent               => find_type_constraint('Ref'),
 560         constraint           => sub { ref($_) eq 'ARRAY'  },
 561         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 562         constraint_generator => sub {
 563             my $type_parameter = shift;
 564             my $check = $type_parameter->_compiled_type_constraint;
 565             return sub {
 566                 foreach my $x (@$_) {
 567                     ($check->($x)) || return
 568                 } 1;
 569             }
 570         }
 571     )
 572 );
 573
 574 $REGISTRY->add_type_constraint(
 575     Moose::Meta::TypeConstraint::Parameterizable->new(
 576         name                 => 'HashRef',
 577         package_defined_in   => __PACKAGE__,
 578         parent               => find_type_constraint('Ref'),
 579         constraint           => sub { ref($_) eq 'HASH'  },
 580         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 581         constraint_generator => sub {
 582             my $type_parameter = shift;
 583             my $check = $type_parameter->_compiled_type_constraint;
 584             return sub {
 585                 foreach my $x (values %$_) {
 586                     ($check->($x)) || return
 587                 } 1;
 588             }
 589         }
 590     )
 591 );
 592
 593 $REGISTRY->add_type_constraint(
 594     Moose::Meta::TypeConstraint::Parameterizable->new(
 595         name                 => 'Maybe',
 596         package_defined_in   => __PACKAGE__,
 597         parent               => find_type_constraint('Item'),
 598         constraint           => sub { 1 },
 599         constraint_generator => sub {
 600             my $type_parameter = shift;
 601             my $check = $type_parameter->_compiled_type_constraint;
 602             return sub {
 603                 return 1 if not(defined($_)) || $check->($_);
 604                 return;
 605             }
 606         }
 607     )
 608 );
 609
 610 my @PARAMETERIZABLE_TYPES = map {
 611     $REGISTRY->get_type_constraint($_)
 612 } qw[ArrayRef HashRef Maybe];
 613
 614 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 615 sub add_parameterizable_type {
 616     my $type = shift;
 617     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 618         || Moose->throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 619     push @PARAMETERIZABLE_TYPES => $type;
 620 }
 621
 622 ## --------------------------------------------------------
 623 # end of built-in types ...
 624 ## --------------------------------------------------------
 625
 626 {
 627     my @BUILTINS = list_all_type_constraints();
 628     sub list_all_builtin_type_constraints { @BUILTINS }
 629 }
 630
 631 1;
 632
 633 __END__
 634
 635 =pod
 636
 637 =head1 NAME
 638
 639 Moose::Util::TypeConstraints - Type constraint system for Moose
 640
 641 =head1 SYNOPSIS
 642
 643   use Moose::Util::TypeConstraints;
 644
 645   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 646
 647   subtype 'Natural'
 648       => as 'Int'
 649       => where { $_ > 0 };
 650
 651   subtype 'NaturalLessThanTen'
 652       => as 'Natural'
 653       => where { $_ < 10 }
 654       => message { "This number ($_) is not less than ten!" };
 655
 656   coerce 'Num'
 657       => from 'Str'
 658         => via { 0+$_ };
 659
 660   enum 'RGBColors' => qw(red green blue);
 661
 662 =head1 DESCRIPTION
 663
 664 This module provides Moose with the ability to create custom type
 665 contraints to be used in attribute definition.
 666
 667 =head2 Important Caveat
 668
 669 This is B<NOT> a type system for Perl 5. These are type constraints,
 670 and they are not used by Moose unless you tell it to. No type
 671 inference is performed, expression are not typed, etc. etc. etc.
 672
 673 This is simply a means of creating small constraint functions which
 674 can be used to simplify your own type-checking code, with the added
 675 side benefit of making your intentions clearer through self-documentation.
 676
 677 =head2 Slightly Less Important Caveat
 678
 679 It is B<always> a good idea to quote your type and subtype names.
 680
 681 This is to prevent perl from trying to execute the call as an indirect
 682 object call. This issue only seems to come up when you have a subtype
 683 the same name as a valid class, but when the issue does arise it tends
 684 to be quite annoying to debug.
 685
 686 So for instance, this:
 687
 688   subtype DateTime => as Object => where { $_->isa('DateTime') };
 689
 690 will I<Just Work>, while this:
 691
 692   use DateTime;
 693   subtype DateTime => as Object => where { $_->isa('DateTime') };
 694
 695 will fail silently and cause many headaches. The simple way to solve
 696 this, as well as future proof your subtypes from classes which have
 697 yet to have been created yet, is to simply do this:
 698
 699   use DateTime;
 700   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 701
 702 =head2 Default Type Constraints
 703
 704 This module also provides a simple hierarchy for Perl 5 types, here is
 705 that hierarchy represented visually.
 706
 707   Any
 708   Item
 709       Bool
 710       Maybe[`a]
 711       Undef
 712       Defined
 713           Value
 714               Num
 715                 Int
 716               Str
 717                 ClassName
 718           Ref
 719               ScalarRef
 720               ArrayRef[`a]
 721               HashRef[`a]
 722               CodeRef
 723               RegexpRef
 724               GlobRef
 725                 FileHandle
 726               Object
 727                   Role
 728
 729 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 730 parameterized, this means you can say:
 731
 732   ArrayRef[Int]    # an array of integers
 733   HashRef[CodeRef] # a hash of str to CODE ref mappings
 734   Maybe[Str]       # value may be a string, may be undefined
 735
 736 B<NOTE:> Unless you parameterize a type, then it is invalid to
 737 include the square brackets. I.e. C<ArrayRef[]> will be
 738 literally interpreted as a type name.
 739
 740 B<NOTE:> The C<Undef> type constraint for the most part works
 741 correctly now, but edge cases may still exist, please use it
 742 sparringly.
 743
 744 B<NOTE:> The C<ClassName> type constraint does a complex package
 745 existence check. This means that your class B<must> be loaded for
 746 this type constraint to pass. I know this is not ideal for all,
 747 but it is a saner restriction than most others.
 748
 749 =head2 Type Constraint Naming
 750
 751 Since the types created by this module are global, it is suggested
 752 that you namespace your types just as you would namespace your
 753 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 754 module, you would call the type I<My::Graphics::Color> instead.
 755
 756 =head2 Use with Other Constraint Modules
 757
 758 This module should play fairly nicely with other constraint
 759 modules with only some slight tweaking. The C<where> clause
 760 in types is expected to be a C<CODE> reference which checks
 761 it's first argument and returns a boolean. Since most constraint
 762 modules work in a similar way, it should be simple to adapt
 763 them to work with Moose.
 764
 765 For instance, this is how you could use it with
 766 L<Declare::Constraints::Simple> to declare a completely new type.
 767
 768   type 'HashOfArrayOfObjects'
 769       => IsHashRef(
 770           -keys   => HasLength,
 771           -values => IsArrayRef( IsObject ));
 772
 773 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 774 test file.
 775
 776 Here is an example of using L<Test::Deep> and it's non-test
 777 related C<eq_deeply> function.
 778
 779   type 'ArrayOfHashOfBarsAndRandomNumbers'
 780       => where {
 781           eq_deeply($_,
 782               array_each(subhashof({
 783                   bar           => isa('Bar'),
 784                   random_number => ignore()
 785               })))
 786         };
 787
 788 For a complete example see the
 789 F<t/200_examples/205_example_w_TestDeep.t> test file.
 790
 791 =head1 FUNCTIONS
 792
 793 =head2 Type Constraint Constructors
 794
 795 The following functions are used to create type constraints.
 796 They will then register the type constraints in a global store
 797 where Moose can get to them if it needs to.
 798
 799 See the L<SYNOPSIS> for an example of how to use these.
 800
 801 =over 4
 802
 803 =item B<type ($name, $where_clause)>
 804
 805 This creates a base type, which has no parent.
 806
 807 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 808
 809 This creates a named subtype.
 810
 811 =item B<subtype ($parent, $where_clause, ?$message)>
 812
 813 This creates an unnamed subtype and will return the type
 814 constraint meta-object, which will be an instance of
 815 L<Moose::Meta::TypeConstraint>.
 816
 817 =item B<class_type ($class, ?$options)>
 818
 819 Creates a type constraint with the name C<$class> and the metaclass
 820 L<Moose::Meta::TypeConstraint::Class>.
 821
 822 =item B<role_type ($role, ?$options)>
 823
 824 Creates a type constraint with the name C<$role> and the metaclass
 825 L<Moose::Meta::TypeConstraint::Role>.
 826
 827 =item B<enum ($name, @values)>
 828
 829 This will create a basic subtype for a given set of strings.
 830 The resulting constraint will be a subtype of C<Str> and
 831 will match any of the items in C<@values>. It is case sensitive.
 832 See the L<SYNOPSIS> for a simple example.
 833
 834 B<NOTE:> This is not a true proper enum type, it is simple
 835 a convient constraint builder.
 836
 837 =item B<enum (\@values)>
 838
 839 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 840 this will create an unnamed enum. This can then be used in an attribute
 841 definition like so:
 842
 843   has 'sort_order' => (
 844       is  => 'ro',
 845       isa => enum([qw[ ascending descending ]]),
 846   );
 847
 848 =item B<as>
 849
 850 This is just sugar for the type constraint construction syntax.
 851
 852 =item B<where>
 853
 854 This is just sugar for the type constraint construction syntax.
 855
 856 Takes a block/code ref as an argument. When the type constraint is
 857 tested, the supplied code is run with the value to be tested in
 858 $_. This block should return true or false to indicate whether or not
 859 the constraint check passed.
 860
 861 =item B<message>
 862
 863 This is just sugar for the type constraint construction syntax.
 864
 865 Takes a block/code ref as an argument. When the type constraint fails,
 866 then the code block is run (with the value provided in $_). This code
 867 ref should return a string, which will be used in the text of the
 868 exception thrown.
 869
 870 =item B<optimize_as>
 871
 872 This can be used to define a "hand optimized" version of your
 873 type constraint which can be used to avoid traversing a subtype
 874 constraint heirarchy.
 875
 876 B<NOTE:> You should only use this if you know what you are doing,
 877 all the built in types use this, so your subtypes (assuming they
 878 are shallow) will not likely need to use this.
 879
 880 =back
 881
 882 =head2 Type Coercion Constructors
 883
 884 Type constraints can also contain type coercions as well. If you
 885 ask your accessor to coerce, then Moose will run the type-coercion
 886 code first, followed by the type constraint check. This feature
 887 should be used carefully as it is very powerful and could easily
 888 take off a limb if you are not careful.
 889
 890 See the L<SYNOPSIS> for an example of how to use these.
 891
 892 =over 4
 893
 894 =item B<coerce>
 895
 896 =item B<from>
 897
 898 This is just sugar for the type coercion construction syntax.
 899
 900 =item B<via>
 901
 902 This is just sugar for the type coercion construction syntax.
 903
 904 =back
 905
 906 =head2 Type Constraint Construction & Locating
 907
 908 =over 4
 909
 910 =item B<normalize_type_constraint_name ($type_constraint_name)>
 911
 912 Given a string that is expected to match a type constraint, will normalize the
 913 string so that extra whitespace and newlines are removed.
 914
 915 =item B<create_type_constraint_union ($pipe_seperated_types | @type_constraint_names)>
 916
 917 Given string with C<$pipe_seperated_types> or a list of C<@type_constraint_names>,
 918 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 919
 920 =item B<create_parameterized_type_constraint ($type_name)>
 921
 922 Given a C<$type_name> in the form of:
 923
 924   BaseType[ContainerType]
 925
 926 this will extract the base type and container type and build an instance of
 927 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 928
 929 =item B<create_class_type_constraint ($class, ?$options)>
 930
 931 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 932 object for that class name.
 933
 934 =item B<create_role_type_constraint ($role, ?$options)>
 935
 936 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
 937 object for that role name.
 938
 939 =item B<create_enum_type_constraint ($name, $values)>
 940
 941 =item B<find_or_parse_type_constraint ($type_name)>
 942
 943 This will attempt to find or create a type constraint given the a C<$type_name>.
 944 If it cannot find it in the registry, it will see if it should be a union or
 945 container type an create one if appropriate
 946
 947 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
 948
 949 This function will first call C<find_or_parse_type_constraint> with the type name.
 950
 951 If no type is found or created, but C<$options_for_anon_type> are provided, it
 952 will create the corresponding type.
 953
 954 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
 955 and are now superseded by C<find_or_create_isa_type_constraint> and
 956 C<find_or_create_does_type_constraint>.
 957
 958 =item B<find_or_create_isa_type_constraint ($type_name)>
 959
 960 =item B<find_or_create_does_type_constraint ($type_name)>
 961
 962 Attempts to parse the type name using C<find_or_parse_type_constraint> and if
 963 no appropriate constraint is found will create a new anonymous one.
 964
 965 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
 966 variant will use C<create_role_type_constraint>.
 967
 968 =item B<find_type_constraint ($type_name)>
 969
 970 This function can be used to locate a specific type constraint
 971 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
 972 derivative. What you do with it from there is up to you :)
 973
 974 =item B<register_type_constraint ($type_object)>
 975
 976 This function will register a named type constraint with the type registry.
 977
 978 =item B<get_type_constraint_registry>
 979
 980 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
 981 keeps track of all type constraints.
 982
 983 =item B<list_all_type_constraints>
 984
 985 This will return a list of type constraint names, you can then
 986 fetch them using C<find_type_constraint ($type_name)> if you
 987 want to.
 988
 989 =item B<list_all_builtin_type_constraints>
 990
 991 This will return a list of builtin type constraints, meaning,
 992 those which are defined in this module. See the section
 993 labeled L<Default Type Constraints> for a complete list.
 994
 995 =item B<export_type_constraints_as_functions>
 996
 997 This will export all the current type constraints as functions
 998 into the caller's namespace. Right now, this is mostly used for
 999 testing, but it might prove useful to others.
1000
1001 =item B<get_all_parameterizable_types>
1002
1003 This returns all the parameterizable types that have been registered.
1004
1005 =item B<add_parameterizable_type ($type)>
1006
1007 Adds C<$type> to the list of parameterizable types
1008
1009 =back
1010
1011 =head2 Namespace Management
1012
1013 =over 4
1014
1015 =item B<unimport>
1016
1017 This will remove all the type constraint keywords from the
1018 calling class namespace.
1019
1020 =back
1021
1022 =head1 BUGS
1023
1024 All complex software has bugs lurking in it, and this module is no
1025 exception. If you find a bug please either email me, or add the bug
1026 to cpan-RT.
1027
1028 =head1 AUTHOR
1029
1030 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1031
1032 =head1 COPYRIGHT AND LICENSE
1033
1034 Copyright 2006-2008 by Infinity Interactive, Inc.
1035
1036 L<http://www.iinteractive.com>
1037
1038 This library is free software; you can redistribute it and/or modify
1039 it under the same terms as Perl itself.
1040
1041 =cut