lib/Moose/Util/MetaRole.pm

   1 package Moose::Util::MetaRole;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.78';
   7 $VERSION = eval $VERSION;
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use List::MoreUtils qw( all );
  11
  12 my @Classes = qw( constructor_class destructor_class error_class );
  13
  14 sub apply_metaclass_roles {
  15     my %options = @_;
  16
  17     my $for = $options{for_class};
  18
  19     my %old_classes = map { $_ => Class::MOP::class_of($for)->$_ }
  20                       grep { Class::MOP::class_of($for)->can($_) }
  21                       @Classes;
  22
  23     my $meta = _make_new_metaclass( $for, \%options );
  24
  25     for my $c ( grep { $meta->can($_) } @Classes ) {
  26         if ( $options{ $c . '_roles' } ) {
  27             my $class = _make_new_class(
  28                 $meta->$c(),
  29                 $options{ $c . '_roles' }
  30             );
  31
  32             $meta->$c($class);
  33         }
  34         else {
  35             $meta->$c( $old_classes{$c} );
  36         }
  37     }
  38
  39     return $meta;
  40 }
  41
  42 sub _make_new_metaclass {
  43     my $for     = shift;
  44     my $options = shift;
  45
  46     return Class::MOP::class_of($for)
  47         unless grep { exists $options->{ $_ . '_roles' } }
  48             qw(
  49             metaclass
  50             attribute_metaclass
  51             method_metaclass
  52             wrapped_method_metaclass
  53             instance_metaclass
  54     );
  55
  56     my $old_meta = Class::MOP::class_of($for);
  57     my $new_metaclass
  58         = _make_new_class( ref $old_meta, $options->{metaclass_roles} );
  59
  60     # This could get called for a Moose::Meta::Role as well as a Moose::Meta::Class
  61     my %classes = map {
  62         $_ => _make_new_class( $old_meta->$_(), $options->{ $_ . '_roles' } )
  63         }
  64         grep { $old_meta->can($_) }
  65         qw(
  66         attribute_metaclass
  67         method_metaclass
  68         wrapped_method_metaclass
  69         instance_metaclass
  70     );
  71
  72     return $new_metaclass->reinitialize( $for, %classes );
  73 }
  74
  75 sub apply_base_class_roles {
  76     my %options = @_;
  77
  78     my $for = $options{for_class};
  79
  80     my $meta = Class::MOP::class_of($for);
  81
  82     my $new_base = _make_new_class(
  83         $for,
  84         $options{roles},
  85         [ $meta->superclasses() ],
  86     );
  87
  88     $meta->superclasses($new_base)
  89         if $new_base ne $meta->name();
  90 }
  91
  92 sub _make_new_class {
  93     my $existing_class = shift;
  94     my $roles          = shift;
  95     my $superclasses   = shift || [$existing_class];
  96
  97     return $existing_class unless $roles;
  98
  99     my $meta = Class::MOP::Class->initialize($existing_class);
 100
 101     return $existing_class
 102         if $meta->can('does_role') && all { $meta->does_role($_) } @{$roles};
 103
 104     return Moose::Meta::Class->create_anon_class(
 105         superclasses => $superclasses,
 106         roles        => $roles,
 107         cache        => 1,
 108     )->name();
 109 }
 110
 111 1;
 112
 113 __END__
 114
 115 =head1 NAME
 116
 117 Moose::Util::MetaRole - Apply roles to any metaclass, as well as the object base class
 118
 119 =head1 SYNOPSIS
 120
 121   package MyApp::Moose;
 122
 123   use Moose ();
 124   use Moose::Exporter;
 125   use Moose::Util::MetaRole;
 126
 127   use MyApp::Role::Meta::Class;
 128   use MyApp::Role::Meta::Method::Constructor;
 129   use MyApp::Role::Object;
 130
 131   Moose::Exporter->setup_import_methods( also => 'Moose' );
 132
 133   sub init_meta {
 134       shift;
 135       my %options = @_;
 136
 137       Moose->init_meta(%options);
 138
 139       Moose::Util::MetaRole::apply_metaclass_roles(
 140           for_class               => $options{for_class},
 141           metaclass_roles         => ['MyApp::Role::Meta::Class'],
 142           constructor_class_roles => ['MyApp::Role::Meta::Method::Constructor'],
 143       );
 144
 145       Moose::Util::MetaRole::apply_base_class_roles(
 146           for_class => $options{for_class},
 147           roles     => ['MyApp::Role::Object'],
 148       );
 149
 150       return $options{for_class}->meta();
 151   }
 152
 153 =head1 DESCRIPTION
 154
 155 B<The whole concept behind this module is still considered
 156 experimental, and it could go away in the future!>
 157
 158 This utility module is designed to help authors of Moose extensions
 159 write extensions that are able to cooperate with other Moose
 160 extensions. To do this, you must write your extensions as roles, which
 161 can then be dynamically applied to the caller's metaclasses.
 162
 163 This module makes sure to preserve any existing superclasses and roles
 164 already set for the meta objects, which means that any number of
 165 extensions can apply roles in any order.
 166
 167 =head1 USAGE
 168
 169 B<It is very important that you only call this module's functions when
 170 your module is imported by the caller>. The process of applying roles
 171 to the metaclass reinitializes the metaclass object, which wipes out
 172 any existing attributes already defined. However, as long as you do
 173 this when your module is imported, the caller should not have any
 174 attributes defined yet.
 175
 176 The easiest way to ensure that this happens is to use
 177 L<Moose::Exporter> and provide an C<init_meta> method that will be
 178 called when imported.
 179
 180 =head1 FUNCTIONS
 181
 182 This module provides two functions.
 183
 184 =head2 apply_metaclass_roles( ... )
 185
 186 This function will apply roles to one or more metaclasses for the
 187 specified class. It accepts the following parameters:
 188
 189 =over 4
 190
 191 =item * for_class => $name
 192
 193 This specifies the class for which to alter the meta classes.
 194
 195 =item * metaclass_roles => \@roles
 196
 197 =item * attribute_metaclass_roles => \@roles
 198
 199 =item * method_metaclass_roles => \@roles
 200
 201 =item * wrapped_method_metaclass_roles => \@roles
 202
 203 =item * instance_metaclass_roles => \@roles
 204
 205 =item * constructor_class_roles => \@roles
 206
 207 =item * destructor_class_roles => \@roles
 208
 209 These parameter all specify one or more roles to be applied to the
 210 specified metaclass. You can pass any or all of these parameters at
 211 once.
 212
 213 =back
 214
 215 =head2 apply_base_class_roles( for_class => $class, roles => \@roles )
 216
 217 This function will apply the specified roles to the object's base class.
 218
 219 =head1 AUTHOR
 220
 221 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 222
 223 =head1 COPYRIGHT AND LICENSE
 224
 225 Copyright 2009 by Infinity Interactive, Inc.
 226
 227 L<http://www.iinteractive.com>
 228
 229 This library is free software; you can redistribute it and/or modify
 230 it under the same terms as Perl itself.
 231
 232 =cut