lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Moose::Meta::Class;
   8 use metaclass 'Moose::Meta::Class';
   9
  10 use Carp 'confess';
  11
  12 our $VERSION = '0.06';
  13
  14 sub new {
  15     my $class = shift;
  16     my %params;
  17     if (scalar @_ == 1) {
  18         (ref($_[0]) eq 'HASH')
  19             || confess "Single parameters to new() must be a HASH ref";
  20         %params = %{$_[0]};
  21     }
  22     else {
  23         %params = @_;
  24     }
  25         my $self = $class->meta->new_object(%params);
  26         $self->BUILDALL(\%params);
  27         return $self;
  28 }
  29
  30 sub BUILDALL {
  31         my ($self, $params) = @_;
  32         foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  33                 $method->{code}->($self, $params);
  34         }
  35 }
  36
  37 sub DEMOLISHALL {
  38         my $self = shift;
  39         foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  40                 $method->{code}->($self);
  41         }
  42 }
  43
  44 sub DESTROY { goto &DEMOLISHALL }
  45
  46 # new does() methods will be created
  47 # as approiate see Moose::Meta::Role
  48 sub does {
  49     my ($self, $role_name) = @_;
  50     (defined $role_name)
  51         || confess "You much supply a role name to does()";
  52     my $meta = $self->meta;
  53     foreach my $class ($meta->class_precedence_list) {
  54         return 1
  55             if $meta->initialize($class)->does_role($role_name);
  56     }
  57     return 0;
  58 }
  59
  60 # RANT:
  61 # Cmon, how many times have you written
  62 # the following code while debugging:
  63 #
  64 #  use Data::Dumper;
  65 #  warn Dumper \%thing;
  66 #
  67 # It can get seriously annoying, so why
  68 # not just do this ...
  69 sub dump {
  70     my $self = shift;
  71     require Data::Dumper;
  72     $Data::Dumper::Maxdepth = shift if @_;
  73     Data::Dumper::Dumper $self;
  74 }
  75
  76 1;
  77
  78 __END__
  79
  80 =pod
  81
  82 =head1 NAME
  83
  84 Moose::Object - The base object for Moose
  85
  86 =head1 DESCRIPTION
  87
  88 This serves as the base object for all Moose classes. Every
  89 effort will be made to ensure that all classes which C<use Moose>
  90 will inherit from this class. It provides a default constructor
  91 and destructor, which run all the BUILD and DEMOLISH methods in
  92 the class tree.
  93
  94 You don't actually I<need> to inherit from this in order to
  95 use Moose though. It is just here to make life easier.
  96
  97 =head1 METHODS
  98
  99 =over 4
 100
 101 =item B<meta>
 102
 103 This will return the metaclass associated with the given class.
 104
 105 =item B<new>
 106
 107 This will create a new instance and call C<BUILDALL>.
 108
 109 =item B<BUILDALL>
 110
 111 This will call every C<BUILD> method in the inheritance hierarchy,
 112 and pass it a hash-ref of the the C<%params> passed to C<new>.
 113
 114 =item B<DEMOLISHALL>
 115
 116 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 117
 118 =item B<does ($role_name)>
 119
 120 This will check if the invocant's class C<does> a given C<$role_name>.
 121 This is similar to C<isa> for object, but it checks the roles instead.
 122
 123 =item B<dump ($maxdepth)>
 124
 125 Cmon, how many times have you written the following code while debugging:
 126
 127  use Data::Dumper;
 128  warn Dumper $obj;
 129
 130 It can get seriously annoying, so why not just use this.
 131
 132 =back
 133
 134 =head1 BUGS
 135
 136 All complex software has bugs lurking in it, and this module is no
 137 exception. If you find a bug please either email me, or add the bug
 138 to cpan-RT.
 139
 140 =head1 AUTHOR
 141
 142 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 143
 144 =head1 COPYRIGHT AND LICENSE
 145
 146 Copyright 2006 by Infinity Interactive, Inc.
 147
 148 L<http://www.iinteractive.com>
 149
 150 This library is free software; you can redistribute it and/or modify
 151 it under the same terms as Perl itself.
 152
 153 =cut