lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 use Carp 'confess';
  11
  12 our $VERSION   = '0.50';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 sub new {
  16     my $class = shift;
  17     my $params = $class->BUILDARGS(@_);
  18     my $self = $class->meta->new_object(%$params);
  19     $self->BUILDALL($params);
  20     return $self;
  21 }
  22
  23 sub BUILDARGS {
  24     my $class = shift;
  25
  26     if (scalar @_ == 1) {
  27         if (defined $_[0]) {
  28             (ref($_[0]) eq 'HASH')
  29                 || confess "Single parameters to new() must be a HASH ref";
  30             return {%{$_[0]}};
  31         }
  32
  33         return {}; # FIXME this is compat behavior, but is it correct?
  34     } else {
  35         return {@_};
  36     }
  37 }
  38
  39 sub BUILDALL {
  40     # NOTE: we ask Perl if we even
  41     # need to do this first, to avoid
  42     # extra meta level calls
  43     return unless $_[0]->can('BUILD');
  44     my ($self, $params) = @_;
  45     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  46         $method->{code}->body->($self, $params);
  47     }
  48 }
  49
  50 sub DEMOLISHALL {
  51     my $self = shift;
  52     foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  53         $method->{code}->body->($self);
  54     }
  55 }
  56
  57 sub DESTROY {
  58     # NOTE: we ask Perl if we even
  59     # need to do this first, to avoid
  60     # extra meta level calls
  61     return unless $_[0]->can('DEMOLISH');
  62     # if we have an exception here ...
  63     if ($@) {
  64         # localize the $@ ...
  65         local $@;
  66         # run DEMOLISHALL ourselves, ...
  67         $_[0]->DEMOLISHALL;
  68         # and return ...
  69         return;
  70     }
  71     # otherwise it is normal destruction
  72     $_[0]->DEMOLISHALL;
  73 }
  74
  75 # new does() methods will be created
  76 # as approiate see Moose::Meta::Role
  77 sub does {
  78     my ($self, $role_name) = @_;
  79     (defined $role_name)
  80         || confess "You must supply a role name to does()";
  81     my $meta = $self->meta;
  82     foreach my $class ($meta->class_precedence_list) {
  83         my $m = $meta->initialize($class);
  84         return 1
  85             if $m->can('does_role') && $m->does_role($role_name);
  86     }
  87     return 0;
  88 }
  89
  90 # RANT:
  91 # Cmon, how many times have you written
  92 # the following code while debugging:
  93 #
  94 #  use Data::Dumper;
  95 #  warn Dumper \%thing;
  96 #
  97 # It can get seriously annoying, so why
  98 # not just do this ...
  99 sub dump {
 100     my $self = shift;
 101     require Data::Dumper;
 102     local $Data::Dumper::Maxdepth = shift if @_;
 103     Data::Dumper::Dumper $self;
 104 }
 105
 106 1;
 107
 108 __END__
 109
 110 =pod
 111
 112 =head1 NAME
 113
 114 Moose::Object - The base object for Moose
 115
 116 =head1 DESCRIPTION
 117
 118 This serves as the base object for all Moose classes. Every
 119 effort will be made to ensure that all classes which C<use Moose>
 120 will inherit from this class. It provides a default constructor
 121 and destructor, which run all the BUILD and DEMOLISH methods in
 122 the class tree.
 123
 124 You don't actually I<need> to inherit from this in order to
 125 use Moose though. It is just here to make life easier.
 126
 127 =head1 METHODS
 128
 129 =over 4
 130
 131 =item B<meta>
 132
 133 This will return the metaclass associated with the given class.
 134
 135 =item B<new>
 136
 137 This will call C<BUILDARGS>, create a new instance and call C<BUILDALL>.
 138
 139 =item B<BUILDARGS>
 140
 141 This method processes an argument list into a hash reference. It is used by
 142 C<new>.
 143
 144 =item B<BUILDALL>
 145
 146 This will call every C<BUILD> method in the inheritance hierarchy,
 147 and pass it a hash-ref of the the C<%params> passed to C<new>.
 148
 149 =item B<DEMOLISHALL>
 150
 151 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 152
 153 =item B<does ($role_name)>
 154
 155 This will check if the invocant's class C<does> a given C<$role_name>.
 156 This is similar to C<isa> for object, but it checks the roles instead.
 157
 158 =item B<dump ($maxdepth)>
 159
 160 Cmon, how many times have you written the following code while debugging:
 161
 162  use Data::Dumper;
 163  warn Dumper $obj;
 164
 165 It can get seriously annoying, so why not just use this.
 166
 167 =back
 168
 169 =head1 BUGS
 170
 171 All complex software has bugs lurking in it, and this module is no
 172 exception. If you find a bug please either email me, or add the bug
 173 to cpan-RT.
 174
 175 =head1 AUTHOR
 176
 177 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 178
 179 =head1 COPYRIGHT AND LICENSE
 180
 181 Copyright 2006-2008 by Infinity Interactive, Inc.
 182
 183 L<http://www.iinteractive.com>
 184
 185 This library is free software; you can redistribute it and/or modify
 186 it under the same terms as Perl itself.
 187
 188 =cut