lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 use Carp 'confess';
  11
  12 our $VERSION   = '0.10';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 sub new {
  16     my $class = shift;
  17     my %params;
  18     if (scalar @_ == 1) {
  19         if (defined $_[0]) {
  20             (ref($_[0]) eq 'HASH')
  21                 || confess "Single parameters to new() must be a HASH ref";
  22             %params = %{$_[0]};
  23         }
  24     }
  25     else {
  26         %params = @_;
  27     }
  28     my $self = $class->meta->new_object(%params);
  29     $self->BUILDALL(\%params);
  30     return $self;
  31 }
  32
  33 sub BUILDALL {
  34     # NOTE: we ask Perl if we even
  35     # need to do this first, to avoid
  36     # extra meta level calls
  37     return unless $_[0]->can('BUILD');
  38     my ($self, $params) = @_;
  39     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  40         $method->{code}->($self, $params);
  41     }
  42 }
  43
  44 sub DEMOLISHALL {
  45     # NOTE: we ask Perl if we even
  46     # need to do this first, to avoid
  47     # extra meta level calls
  48     return unless $_[0]->can('DEMOLISH');
  49     my $self = shift;
  50     foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  51         $method->{code}->($self);
  52     }
  53 }
  54
  55 sub DESTROY { goto &DEMOLISHALL }
  56
  57 # new does() methods will be created
  58 # as approiate see Moose::Meta::Role
  59 sub does {
  60     my ($self, $role_name) = @_;
  61     (defined $role_name)
  62         || confess "You much supply a role name to does()";
  63     my $meta = $self->meta;
  64     foreach my $class ($meta->class_precedence_list) {
  65         return 1
  66             if $meta->initialize($class)->does_role($role_name);
  67     }
  68     return 0;
  69 }
  70
  71 # RANT:
  72 # Cmon, how many times have you written
  73 # the following code while debugging:
  74 #
  75 #  use Data::Dumper;
  76 #  warn Dumper \%thing;
  77 #
  78 # It can get seriously annoying, so why
  79 # not just do this ...
  80 sub dump {
  81     my $self = shift;
  82     require Data::Dumper;
  83     $Data::Dumper::Maxdepth = shift if @_;
  84     Data::Dumper::Dumper $self;
  85 }
  86
  87 1;
  88
  89 __END__
  90
  91 =pod
  92
  93 =head1 NAME
  94
  95 Moose::Object - The base object for Moose
  96
  97 =head1 DESCRIPTION
  98
  99 This serves as the base object for all Moose classes. Every
 100 effort will be made to ensure that all classes which C<use Moose>
 101 will inherit from this class. It provides a default constructor
 102 and destructor, which run all the BUILD and DEMOLISH methods in
 103 the class tree.
 104
 105 You don't actually I<need> to inherit from this in order to
 106 use Moose though. It is just here to make life easier.
 107
 108 =head1 METHODS
 109
 110 =over 4
 111
 112 =item B<meta>
 113
 114 This will return the metaclass associated with the given class.
 115
 116 =item B<new>
 117
 118 This will create a new instance and call C<BUILDALL>.
 119
 120 =item B<BUILDALL>
 121
 122 This will call every C<BUILD> method in the inheritance hierarchy,
 123 and pass it a hash-ref of the the C<%params> passed to C<new>.
 124
 125 =item B<DEMOLISHALL>
 126
 127 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 128
 129 =item B<does ($role_name)>
 130
 131 This will check if the invocant's class C<does> a given C<$role_name>.
 132 This is similar to C<isa> for object, but it checks the roles instead.
 133
 134 =item B<dump ($maxdepth)>
 135
 136 Cmon, how many times have you written the following code while debugging:
 137
 138  use Data::Dumper;
 139  warn Dumper $obj;
 140
 141 It can get seriously annoying, so why not just use this.
 142
 143 =back
 144
 145 =head1 BUGS
 146
 147 All complex software has bugs lurking in it, and this module is no
 148 exception. If you find a bug please either email me, or add the bug
 149 to cpan-RT.
 150
 151 =head1 AUTHOR
 152
 153 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 154
 155 =head1 COPYRIGHT AND LICENSE
 156
 157 Copyright 2006-2008 by Infinity Interactive, Inc.
 158
 159 L<http://www.iinteractive.com>
 160
 161 This library is free software; you can redistribute it and/or modify
 162 it under the same terms as Perl itself.
 163
 164 =cut