lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 use Carp 'confess';
  11
  12 our $VERSION   = '0.52';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 sub new {
  16     my $class = shift;
  17     my $params = $class->BUILDARGS(@_);
  18     my $self = $class->meta->new_object(%$params);
  19     $self->BUILDALL($params);
  20     return $self;
  21 }
  22
  23 sub BUILDARGS {
  24     my $class = shift;
  25
  26     if (scalar @_ == 1) {
  27         if (defined $_[0]) {
  28             no warnings 'uninitialized';
  29             (ref($_[0]) eq 'HASH')
  30                 || confess "Single parameters to new() must be a HASH ref";
  31             return {%{$_[0]}};
  32         } else {
  33             return {}; # FIXME this is compat behavior, but is it correct?
  34         }
  35     } else {
  36         return {@_};
  37     }
  38 }
  39
  40 sub BUILDALL {
  41     # NOTE: we ask Perl if we even
  42     # need to do this first, to avoid
  43     # extra meta level calls
  44     return unless $_[0]->can('BUILD');
  45     my ($self, $params) = @_;
  46     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  47         $method->{code}->body->($self, $params);
  48     }
  49 }
  50
  51 sub DEMOLISHALL {
  52     my $self = shift;
  53     foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  54         $method->{code}->body->($self);
  55     }
  56 }
  57
  58 sub DESTROY {
  59     # NOTE: we ask Perl if we even
  60     # need to do this first, to avoid
  61     # extra meta level calls
  62     return unless $_[0]->can('DEMOLISH');
  63     # if we have an exception here ...
  64     if ($@) {
  65         # localize the $@ ...
  66         local $@;
  67         # run DEMOLISHALL ourselves, ...
  68         $_[0]->DEMOLISHALL;
  69         # and return ...
  70         return;
  71     }
  72     # otherwise it is normal destruction
  73     $_[0]->DEMOLISHALL;
  74 }
  75
  76 # new does() methods will be created
  77 # as approiate see Moose::Meta::Role
  78 sub does {
  79     my ($self, $role_name) = @_;
  80     (defined $role_name)
  81         || confess "You must supply a role name to does()";
  82     my $meta = $self->meta;
  83     foreach my $class ($meta->class_precedence_list) {
  84         my $m = $meta->initialize($class);
  85         return 1
  86             if $m->can('does_role') && $m->does_role($role_name);
  87     }
  88     return 0;
  89 }
  90
  91 # RANT:
  92 # Cmon, how many times have you written
  93 # the following code while debugging:
  94 #
  95 #  use Data::Dumper;
  96 #  warn Dumper \%thing;
  97 #
  98 # It can get seriously annoying, so why
  99 # not just do this ...
 100 sub dump {
 101     my $self = shift;
 102     require Data::Dumper;
 103     local $Data::Dumper::Maxdepth = shift if @_;
 104     Data::Dumper::Dumper $self;
 105 }
 106
 107 1;
 108
 109 __END__
 110
 111 =pod
 112
 113 =head1 NAME
 114
 115 Moose::Object - The base object for Moose
 116
 117 =head1 DESCRIPTION
 118
 119 This serves as the base object for all Moose classes. Every
 120 effort will be made to ensure that all classes which C<use Moose>
 121 will inherit from this class. It provides a default constructor
 122 and destructor, which run all the BUILD and DEMOLISH methods in
 123 the class tree.
 124
 125 You don't actually I<need> to inherit from this in order to
 126 use Moose though. It is just here to make life easier.
 127
 128 =head1 METHODS
 129
 130 =over 4
 131
 132 =item B<meta>
 133
 134 This will return the metaclass associated with the given class.
 135
 136 =item B<new>
 137
 138 This will call C<BUILDARGS>, create a new instance and call C<BUILDALL>.
 139
 140 =item B<BUILDARGS>
 141
 142 This method processes an argument list into a hash reference. It is used by
 143 C<new>.
 144
 145 =item B<BUILDALL>
 146
 147 This will call every C<BUILD> method in the inheritance hierarchy,
 148 and pass it a hash-ref of the the C<%params> passed to C<new>.
 149
 150 =item B<DEMOLISHALL>
 151
 152 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 153
 154 =item B<does ($role_name)>
 155
 156 This will check if the invocant's class C<does> a given C<$role_name>.
 157 This is similar to C<isa> for object, but it checks the roles instead.
 158
 159 =item B<dump ($maxdepth)>
 160
 161 Cmon, how many times have you written the following code while debugging:
 162
 163  use Data::Dumper;
 164  warn Dumper $obj;
 165
 166 It can get seriously annoying, so why not just use this.
 167
 168 =back
 169
 170 =head1 BUGS
 171
 172 All complex software has bugs lurking in it, and this module is no
 173 exception. If you find a bug please either email me, or add the bug
 174 to cpan-RT.
 175
 176 =head1 AUTHOR
 177
 178 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 179
 180 =head1 COPYRIGHT AND LICENSE
 181
 182 Copyright 2006-2008 by Infinity Interactive, Inc.
 183
 184 L<http://www.iinteractive.com>
 185
 186 This library is free software; you can redistribute it and/or modify
 187 it under the same terms as Perl itself.
 188
 189 =cut