lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 use Carp 'confess';
  11
  12 our $VERSION   = '0.53';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 sub new {
  16     my $class = shift;
  17     my $params = $class->BUILDARGS(@_);
  18     my $self = $class->meta->new_object(%$params);
  19     $self->BUILDALL($params);
  20     return $self;
  21 }
  22
  23 sub BUILDARGS {
  24     my $class = shift;
  25     if (scalar @_ == 1) {
  26         if (defined $_[0]) {
  27             (ref($_[0]) eq 'HASH')
  28                 || confess "Single parameters to new() must be a HASH ref";
  29             return {%{$_[0]}};
  30         }
  31         else {
  32             return {}; # FIXME this is compat behavior, but is it correct?
  33         }
  34     }
  35     else {
  36         return {@_};
  37     }
  38 }
  39
  40 sub BUILDALL {
  41     # NOTE: we ask Perl if we even
  42     # need to do this first, to avoid
  43     # extra meta level calls
  44     return unless $_[0]->can('BUILD');
  45     my ($self, $params) = @_;
  46     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  47         $method->{code}->body->($self, $params);
  48     }
  49 }
  50
  51 sub DEMOLISHALL {
  52     my $self = shift;
  53     foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  54         $method->{code}->body->($self);
  55     }
  56 }
  57
  58 sub DESTROY {
  59     # NOTE: we ask Perl if we even
  60     # need to do this first, to avoid
  61     # extra meta level calls
  62     return unless $_[0]->can('DEMOLISH');
  63     # if we have an exception here ...
  64     if ($@) {
  65         # localize the $@ ...
  66         local $@;
  67         # run DEMOLISHALL ourselves, ...
  68         $_[0]->DEMOLISHALL;
  69         # and return ...
  70         return;
  71     }
  72     # otherwise it is normal destruction
  73     $_[0]->DEMOLISHALL;
  74 }
  75
  76 # support for UNIVERSAL::DOES ...
  77 sub DOES {
  78     my ( $self, $class_or_role_name ) = @_;
  79     if (my $DOES = __PACKAGE__->meta->find_next_method_by_name('DOES')) {
  80         return $DOES->body->($self, $class_or_role_name)
  81             || $self->does($class_or_role_name);
  82     }
  83     return $self->isa($class_or_role_name)
  84         || $self->does($class_or_role_name);
  85 }
  86
  87 # new does() methods will be created
  88 # as approiate see Moose::Meta::Role
  89 sub does {
  90     my ($self, $role_name) = @_;
  91     (defined $role_name)
  92         || confess "You must supply a role name to does()";
  93     my $meta = $self->meta;
  94     foreach my $class ($meta->class_precedence_list) {
  95         my $m = $meta->initialize($class);
  96         return 1
  97             if $m->can('does_role') && $m->does_role($role_name);
  98     }
  99     return 0;
 100 }
 101
 102 # RANT:
 103 # Cmon, how many times have you written
 104 # the following code while debugging:
 105 #
 106 #  use Data::Dumper;
 107 #  warn Dumper \%thing;
 108 #
 109 # It can get seriously annoying, so why
 110 # not just do this ...
 111 sub dump {
 112     my $self = shift;
 113     require Data::Dumper;
 114     local $Data::Dumper::Maxdepth = shift if @_;
 115     Data::Dumper::Dumper $self;
 116 }
 117
 118 1;
 119
 120 __END__
 121
 122 =pod
 123
 124 =head1 NAME
 125
 126 Moose::Object - The base object for Moose
 127
 128 =head1 DESCRIPTION
 129
 130 This serves as the base object for all Moose classes. Every
 131 effort will be made to ensure that all classes which C<use Moose>
 132 will inherit from this class. It provides a default constructor
 133 and destructor, which run all the BUILD and DEMOLISH methods in
 134 the class tree.
 135
 136 You don't actually I<need> to inherit from this in order to
 137 use Moose though. It is just here to make life easier.
 138
 139 =head1 METHODS
 140
 141 =over 4
 142
 143 =item B<meta>
 144
 145 This will return the metaclass associated with the given class.
 146
 147 =item B<new>
 148
 149 This will call C<BUILDARGS>, create a new instance and call C<BUILDALL>.
 150
 151 =item B<BUILDARGS>
 152
 153 This method processes an argument list into a hash reference. It is used by
 154 C<new>.
 155
 156 =item B<BUILDALL>
 157
 158 This will call every C<BUILD> method in the inheritance hierarchy,
 159 and pass it a hash-ref of the the C<%params> passed to C<new>.
 160
 161 =item B<DEMOLISHALL>
 162
 163 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 164
 165 =item B<does ($role_name)>
 166
 167 This will check if the invocant's class C<does> a given C<$role_name>.
 168 This is similar to C<isa> for object, but it checks the roles instead.
 169
 170 =item B<DOES ($class_or_role_name)>
 171
 172 A Moose Role aware implementation of L<UNIVERSAL/DOES>.
 173
 174 C<DOES> is equivalent to C<isa> or C<does>.
 175
 176 =item B<dump ($maxdepth)>
 177
 178 Cmon, how many times have you written the following code while debugging:
 179
 180  use Data::Dumper;
 181  warn Dumper $obj;
 182
 183 It can get seriously annoying, so why not just use this.
 184
 185 =back
 186
 187 =head1 BUGS
 188
 189 All complex software has bugs lurking in it, and this module is no
 190 exception. If you find a bug please either email me, or add the bug
 191 to cpan-RT.
 192
 193 =head1 AUTHOR
 194
 195 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 196
 197 =head1 COPYRIGHT AND LICENSE
 198
 199 Copyright 2006-2008 by Infinity Interactive, Inc.
 200
 201 L<http://www.iinteractive.com>
 202
 203 This library is free software; you can redistribute it and/or modify
 204 it under the same terms as Perl itself.
 205
 206 =cut