lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 our $VERSION   = '0.67';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 sub new {
  15     my $class = shift;
  16     my $params = $class->BUILDARGS(@_);
  17     my $self = $class->meta->new_object($params);
  18     $self->BUILDALL($params);
  19     return $self;
  20 }
  21
  22 sub BUILDARGS {
  23     my $class = shift;
  24     if (scalar @_ == 1) {
  25         if (defined $_[0]) {
  26             (ref($_[0]) eq 'HASH')
  27                 || $class->meta->throw_error("Single parameters to new() must be a HASH ref", data => $_[0]);
  28             return {%{$_[0]}};
  29         }
  30         else {
  31             return {}; # FIXME this is compat behavior, but is it correct?
  32         }
  33     }
  34     else {
  35         return {@_};
  36     }
  37 }
  38
  39 sub BUILDALL {
  40     # NOTE: we ask Perl if we even
  41     # need to do this first, to avoid
  42     # extra meta level calls
  43     return unless $_[0]->can('BUILD');
  44     my ($self, $params) = @_;
  45     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  46         $method->{code}->execute($self, $params);
  47     }
  48 }
  49
  50 sub DEMOLISHALL {
  51     my $self = shift;
  52     foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  53         $method->{code}->execute($self);
  54     }
  55 }
  56
  57 sub DESTROY {
  58     # NOTE: we ask Perl if we even
  59     # need to do this first, to avoid
  60     # extra meta level calls
  61     return unless $_[0]->can('DEMOLISH');
  62     # if we have an exception here ...
  63     if ($@) {
  64         # localize the $@ ...
  65         local $@;
  66         # run DEMOLISHALL ourselves, ...
  67         $_[0]->DEMOLISHALL;
  68         # and return ...
  69         return;
  70     }
  71     # otherwise it is normal destruction
  72     $_[0]->DEMOLISHALL;
  73 }
  74
  75 # support for UNIVERSAL::DOES ...
  76 BEGIN {
  77     my $does = UNIVERSAL->can("DOES") ? "SUPER::DOES" : "isa";
  78     eval 'sub DOES {
  79         my ( $self, $class_or_role_name ) = @_;
  80         return $self->'.$does.'($class_or_role_name)
  81             || $self->does($class_or_role_name);
  82     }';
  83 }
  84
  85 # new does() methods will be created
  86 # as appropiate see Moose::Meta::Role
  87 sub does {
  88     my ($self, $role_name) = @_;
  89     my $meta = $self->meta;
  90     (defined $role_name)
  91         || $meta->throw_error("You much supply a role name to does()");
  92     foreach my $class ($meta->class_precedence_list) {
  93         my $m = $meta->initialize($class);
  94         return 1
  95             if $m->can('does_role') && $m->does_role($role_name);
  96     }
  97     return 0;
  98 }
  99
 100 sub dump {
 101     my $self = shift;
 102     require Data::Dumper;
 103     local $Data::Dumper::Maxdepth = shift if @_;
 104     Data::Dumper::Dumper $self;
 105 }
 106
 107 1;
 108
 109 __END__
 110
 111 =pod
 112
 113 =head1 NAME
 114
 115 Moose::Object - The base object for Moose
 116
 117 =head1 DESCRIPTION
 118
 119 This serves as the base object for all Moose classes. Every
 120 effort will be made to ensure that all classes which C<use Moose>
 121 will inherit from this class. It provides a default constructor
 122 and destructor, which run all the BUILD and DEMOLISH methods in
 123 the class tree.
 124
 125 You don't actually I<need> to inherit from this in order to
 126 use Moose though. It is just here to make life easier.
 127
 128 =head1 METHODS
 129
 130 =over 4
 131
 132 =item B<meta>
 133
 134 This will return the metaclass associated with the given class.
 135
 136 =item B<new>
 137
 138 This will call C<BUILDARGS>, create a new instance and call C<BUILDALL>.
 139
 140 =item B<BUILDARGS>
 141
 142 This method processes an argument list into a hash reference. It is used by
 143 C<new>.
 144
 145 =item B<BUILDALL>
 146
 147 This will call every C<BUILD> method in the inheritance hierarchy,
 148 and pass it a hash-ref of the the C<%params> passed to C<new>.
 149
 150 =item B<DEMOLISHALL>
 151
 152 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 153
 154 =item B<does ($role_name)>
 155
 156 This will check if the invocant's class C<does> a given C<$role_name>.
 157 This is similar to C<isa> for object, but it checks the roles instead.
 158
 159 =item B<DOES ($class_or_role_name)>
 160
 161 A Moose Role aware implementation of L<UNIVERSAL/DOES>.
 162
 163 C<DOES> is equivalent to C<isa> or C<does>.
 164
 165 =item B<dump ($maxdepth)>
 166
 167 C'mon, how many times have you written the following code while debugging:
 168
 169  use Data::Dumper;
 170  warn Dumper $obj;
 171
 172 It can get seriously annoying, so why not just use this.
 173
 174 =back
 175
 176 =head1 BUGS
 177
 178 All complex software has bugs lurking in it, and this module is no
 179 exception. If you find a bug please either email me, or add the bug
 180 to cpan-RT.
 181
 182 =head1 AUTHOR
 183
 184 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 185
 186 =head1 COPYRIGHT AND LICENSE
 187
 188 Copyright 2006-2009 by Infinity Interactive, Inc.
 189
 190 L<http://www.iinteractive.com>
 191
 192 This library is free software; you can redistribute it and/or modify
 193 it under the same terms as Perl itself.
 194
 195 =cut