lib/Moose/Meta/TypeConstraint/Role.pm

   1 package Moose::Meta::TypeConstraint::Role;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '0.53';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::TypeConstraint';
  14
  15 __PACKAGE__->meta->add_attribute('role' => (
  16     reader => 'role',
  17 ));
  18
  19 sub new {
  20     my ( $class, %args ) = @_;
  21
  22     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Role');
  23     my $self      = $class->meta->new_object(%args);
  24
  25     $self->_create_hand_optimized_type_constraint;
  26     $self->compile_type_constraint();
  27
  28     return $self;
  29 }
  30
  31 sub _create_hand_optimized_type_constraint {
  32     my $self = shift;
  33     my $role = $self->role;
  34     $self->hand_optimized_type_constraint(
  35         sub { Moose::Util::does_role($_[0], $role) }
  36     );
  37 }
  38
  39 sub parents {
  40     my $self = shift;
  41     return (
  42         $self->parent,
  43         map {
  44             # FIXME find_type_constraint might find a TC named after the role but that isn't really it
  45             # I did this anyway since it's a convention that preceded TypeConstraint::Role, and it should DWIM
  46             # if anybody thinks this problematic please discuss on IRC.
  47             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  48             # regardless of their name
  49             Moose::Util::TypeConstraints::find_type_constraint($_)
  50                 ||
  51             __PACKAGE__->new( role => $_, name => "__ANON__" )
  52         } @{ $self->role->meta->get_roles },
  53     );
  54 }
  55
  56 sub equals {
  57     my ( $self, $type_or_name ) = @_;
  58
  59     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  60
  61     return unless $other->isa(__PACKAGE__);
  62
  63     return $self->role eq $other->role;
  64 }
  65
  66 sub is_a_type_of {
  67     my ($self, $type_or_name) = @_;
  68
  69     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  70
  71     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  72 }
  73
  74 sub is_subtype_of {
  75     my ($self, $type_or_name_or_role ) = @_;
  76
  77     if ( not ref $type_or_name_or_role ) {
  78         # it might be a role
  79         return 1 if $self->role->meta->does_role( $type_or_name_or_role );
  80     }
  81
  82     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_role);
  83
  84     if ( $type->isa(__PACKAGE__) ) {
  85         # if $type_or_name_or_role isn't a role, it might be the TC name of another ::Role type
  86         # or it could also just be a type object in this branch
  87         return $self->role->meta->does_role( $type->role );
  88     } else {
  89         # the only other thing we are a subtype of is Object
  90         $self->SUPER::is_subtype_of($type);
  91     }
  92 }
  93
  94 1;
  95
  96 __END__
  97
  98 =pod
  99
 100 =head1 NAME
 101
 102 Moose::Meta::TypeConstraint::Role - Role/TypeConstraint parallel hierarchy
 103
 104 =head1 METHODS
 105
 106 =over 4
 107
 108 =item B<new>
 109
 110 =item B<role>
 111
 112 =item B<hand_optimized_type_constraint>
 113
 114 =item B<has_hand_optimized_type_constraint>
 115
 116 =item B<equals>
 117
 118 =item B<is_a_type_of>
 119
 120 =item B<is_subtype_of>
 121
 122 =item B<parents>
 123
 124 Return all the parent types, corresponding to the parent classes.
 125
 126 =item B<meta>
 127
 128 =back
 129
 130 =head1 BUGS
 131
 132 All complex software has bugs lurking in it, and this module is no
 133 exception. If you find a bug please either email me, or add the bug
 134 to cpan-RT.
 135
 136 =head1 AUTHOR
 137
 138 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 139
 140 =head1 COPYRIGHT AND LICENSE
 141
 142 Copyright 2006-2008 by Infinity Interactive, Inc.
 143
 144 L<http://www.iinteractive.com>
 145
 146 This library is free software; you can redistribute it and/or modify
 147 it under the same terms as Perl itself.
 148
 149 =cut