lib/Moose/Meta/TypeConstraint/Parameterizable.pm

   1 package Moose::Meta::TypeConstraint::Parameterizable;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 our $VERSION   = '0.57';
   8 $VERSION = eval $VERSION;
   9 our $AUTHORITY = 'cpan:STEVAN';
  10
  11 use base 'Moose::Meta::TypeConstraint';
  12 use Moose::Meta::TypeConstraint::Parameterized;
  13 use Moose::Util::TypeConstraints ();
  14
  15 __PACKAGE__->meta->add_attribute('constraint_generator' => (
  16     accessor  => 'constraint_generator',
  17     predicate => 'has_constraint_generator',
  18 ));
  19
  20 sub generate_constraint_for {
  21     my ($self, $type) = @_;
  22
  23     return unless $self->has_constraint_generator;
  24
  25     return $self->constraint_generator->($type->type_parameter)
  26         if $type->is_subtype_of($self->name);
  27
  28     return $self->_can_coerce_constraint_from($type)
  29         if $self->has_coercion
  30         && $self->coercion->has_coercion_for_type($type->parent->name);
  31
  32     return;
  33 }
  34
  35 sub _can_coerce_constraint_from {
  36     my ($self, $type) = @_;
  37     my $coercion   = $self->coercion;
  38     my $constraint = $self->constraint_generator->($type->type_parameter);
  39     return sub {
  40         local $_ = $coercion->coerce($_);
  41         $constraint->(@_);
  42     };
  43 }
  44
  45 sub parse_parameter_str {
  46     my ($self, $type_str) = @_;
  47     return Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($type_str);
  48 }
  49
  50 sub parameterize {
  51         my ($self, $contained_tc) = @_;
  52
  53         if($contained_tc->isa('Moose::Meta::TypeConstraint')) {
  54         my $tc_name = $self->name .'['. $contained_tc->name .']';
  55         return Moose::Meta::TypeConstraint::Parameterized->new(
  56             name           => $tc_name,
  57             parent         => $self,
  58             type_parameter => $contained_tc,
  59         );
  60         } else {
  61         Moose->throw_error("The type parameter must be a Moose meta type");
  62     }
  63 }
  64
  65
  66 1;
  67
  68 __END__
  69
  70
  71 =pod
  72
  73 =head1 NAME
  74
  75 Moose::Meta::TypeConstraint::Parameterizable - Higher Order type constraints for Moose
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item B<constraint_generator>
  82
  83 =item B<has_constraint_generator>
  84
  85 =item B<generate_constraint_for>
  86
  87 =item B<parse_parameter_str>
  88
  89 Given a string, convert it to a Perl structure.
  90
  91 =item B<parameterize>
  92
  93 Given an array of type constraints, parameterize the current type constraint.
  94
  95 =item B<meta>
  96
  97 =back
  98
  99 =head1 BUGS
 100
 101 All complex software has bugs lurking in it, and this module is no
 102 exception. If you find a bug please either email me, or add the bug
 103 to cpan-RT.
 104
 105 =head1 AUTHOR
 106
 107 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 108
 109 =head1 COPYRIGHT AND LICENSE
 110
 111 Copyright 2006-2008 by Infinity Interactive, Inc.
 112
 113 L<http://www.iinteractive.com>
 114
 115 This library is free software; you can redistribute it and/or modify
 116 it under the same terms as Perl itself.
 117
 118 =cut