lib/Moose/Meta/TypeConstraint/Parameterizable.pm

   1 package Moose::Meta::TypeConstraint::Parameterizable;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 our $VERSION   = '0.72';
   8 $VERSION = eval $VERSION;
   9 our $AUTHORITY = 'cpan:STEVAN';
  10
  11 use base 'Moose::Meta::TypeConstraint';
  12 use Moose::Meta::TypeConstraint::Parameterized;
  13 use Moose::Util::TypeConstraints ();
  14
  15 __PACKAGE__->meta->add_attribute('constraint_generator' => (
  16     accessor  => 'constraint_generator',
  17     predicate => 'has_constraint_generator',
  18 ));
  19
  20 sub generate_constraint_for {
  21     my ($self, $type) = @_;
  22
  23     return unless $self->has_constraint_generator;
  24
  25     return $self->constraint_generator->($type->type_parameter)
  26         if $type->is_subtype_of($self->name);
  27
  28     return $self->_can_coerce_constraint_from($type)
  29         if $self->has_coercion
  30         && $self->coercion->has_coercion_for_type($type->parent->name);
  31
  32     return;
  33 }
  34
  35 sub _can_coerce_constraint_from {
  36     my ($self, $type) = @_;
  37     my $coercion   = $self->coercion;
  38     my $constraint = $self->constraint_generator->($type->type_parameter);
  39     return sub {
  40         local $_ = $coercion->coerce($_);
  41         $constraint->(@_);
  42     };
  43 }
  44
  45 sub _parse_type_parameter {
  46     my ($self, $type_parameter) = @_;
  47     return Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($type_parameter);
  48 }
  49
  50 sub parameterize {
  51     my ($self, $type_parameter) = @_;
  52
  53     my $contained_tc = $self->_parse_type_parameter($type_parameter);
  54
  55     ## The type parameter should be a subtype of the parent's type parameter
  56     ## if there is one.
  57
  58     if(my $parent = $self->parent) {
  59         if($parent->can('type_parameter')) {
  60             unless ( $contained_tc->is_a_type_of($parent->type_parameter) ) {
  61                 require Moose;
  62                 Moose->throw_error("$type_parameter is not a subtype of ".$parent->type_parameter);
  63             }
  64         }
  65     }
  66
  67     if ( $contained_tc->isa('Moose::Meta::TypeConstraint') ) {
  68         my $tc_name = $self->name . '[' . $contained_tc->name . ']';
  69         return Moose::Meta::TypeConstraint::Parameterized->new(
  70             name           => $tc_name,
  71             parent         => $self,
  72             type_parameter => $contained_tc,
  73         );
  74     }
  75     else {
  76         require Moose;
  77         Moose->throw_error("The type parameter must be a Moose meta type");
  78     }
  79 }
  80
  81
  82 1;
  83
  84 __END__
  85
  86
  87 =pod
  88
  89 =head1 NAME
  90
  91 Moose::Meta::TypeConstraint::Parameterizable - Higher Order type constraints for Moose
  92
  93 =head1 METHODS
  94
  95 =over 4
  96
  97 =item B<constraint_generator>
  98
  99 =item B<has_constraint_generator>
 100
 101 =item B<generate_constraint_for>
 102
 103 =item B<parameterize>
 104
 105 Given a single type constraint or type constraint string, this method
 106 parameterizes the type based on the given argument.
 107
 108 =item B<meta>
 109
 110 =back
 111
 112 =head1 BUGS
 113
 114 All complex software has bugs lurking in it, and this module is no
 115 exception. If you find a bug please either email me, or add the bug
 116 to cpan-RT.
 117
 118 =head1 AUTHOR
 119
 120 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 121
 122 =head1 COPYRIGHT AND LICENSE
 123
 124 Copyright 2006-2009 by Infinity Interactive, Inc.
 125
 126 L<http://www.iinteractive.com>
 127
 128 This library is free software; you can redistribute it and/or modify
 129 it under the same terms as Perl itself.
 130
 131 =cut