lib/Moose/Meta/TypeConstraint/Parameterizable.pm

   1 package Moose::Meta::TypeConstraint::Parameterizable;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use base 'Moose::Meta::TypeConstraint';
   8 use Moose::Meta::TypeConstraint::Parameterized;
   9 use Moose::Util::TypeConstraints ();
  10
  11 __PACKAGE__->meta->add_attribute('constraint_generator' => (
  12     accessor  => 'constraint_generator',
  13     predicate => 'has_constraint_generator',
  14 ));
  15
  16 __PACKAGE__->meta->add_attribute('inline_generator' => (
  17     accessor  => 'inline_generator',
  18     predicate => 'has_inline_generator',
  19 ));
  20
  21 sub generate_constraint_for {
  22     my ($self, $type) = @_;
  23
  24     return unless $self->has_constraint_generator;
  25
  26     return $self->constraint_generator->($type->type_parameter)
  27         if $type->is_subtype_of($self->name);
  28
  29     return $self->_can_coerce_constraint_from($type)
  30         if $self->has_coercion
  31         && $self->coercion->has_coercion_for_type($type->parent->name);
  32
  33     return;
  34 }
  35
  36 sub _can_coerce_constraint_from {
  37     my ($self, $type) = @_;
  38     my $coercion   = $self->coercion;
  39     my $constraint = $self->constraint_generator->($type->type_parameter);
  40     return sub {
  41         local $_ = $coercion->coerce($_);
  42         $constraint->(@_);
  43     };
  44 }
  45
  46 sub generate_inline_for {
  47     my ($self, $type, $val) = @_;
  48
  49     return unless $self->has_inline_generator;
  50
  51     return $self->inline_generator->( $self, $type, $val );
  52 }
  53
  54 sub _parse_type_parameter {
  55     my ($self, $type_parameter) = @_;
  56     return Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($type_parameter);
  57 }
  58
  59 sub parameterize {
  60     my ($self, $type_parameter) = @_;
  61
  62     my $contained_tc = $self->_parse_type_parameter($type_parameter);
  63
  64     ## The type parameter should be a subtype of the parent's type parameter
  65     ## if there is one.
  66
  67     if(my $parent = $self->parent) {
  68         if($parent->can('type_parameter')) {
  69             unless ( $contained_tc->is_a_type_of($parent->type_parameter) ) {
  70                 require Moose;
  71                 Moose->throw_error("$type_parameter is not a subtype of ".$parent->type_parameter);
  72             }
  73         }
  74     }
  75
  76     if ( $contained_tc->isa('Moose::Meta::TypeConstraint') ) {
  77         my $tc_name = $self->name . '[' . $contained_tc->name . ']';
  78         return Moose::Meta::TypeConstraint::Parameterized->new(
  79             name               => $tc_name,
  80             parent             => $self,
  81             type_parameter     => $contained_tc,
  82             parameterized_from => $self,
  83         );
  84     }
  85     else {
  86         require Moose;
  87         Moose->throw_error("The type parameter must be a Moose meta type");
  88     }
  89 }
  90
  91
  92 1;
  93
  94 # ABSTRACT: Type constraints which can take a parameter (ArrayRef)
  95
  96 __END__
  97
  98
  99 =pod
 100
 101 =head1 DESCRIPTION
 102
 103 This class represents a parameterizable type constraint. This is a
 104 type constraint like C<ArrayRef> or C<HashRef>, that can be
 105 parameterized and made more specific by specifying a contained
 106 type. For example, instead of just an C<ArrayRef> of anything, you can
 107 specify that is an C<ArrayRef[Int]>.
 108
 109 A parameterizable constraint should not be used as an attribute type
 110 constraint. Instead, when parameterized it creates a
 111 L<Moose::Meta::TypeConstraint::Parameterized> which should be used.
 112
 113 =head1 INHERITANCE
 114
 115 C<Moose::Meta::TypeConstraint::Parameterizable> is a subclass of
 116 L<Moose::Meta::TypeConstraint>.
 117
 118 =head1 METHODS
 119
 120 This class is intentionally not documented because the API is
 121 confusing and needs some work.
 122
 123 =head1 BUGS
 124
 125 See L<Moose/BUGS> for details on reporting bugs.
 126
 127 =cut