lib/Moose/Meta/TypeConstraint/Enum.pm

   1 package Moose::Meta::TypeConstraint::Enum;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use B;
   8 use Moose::Util::TypeConstraints ();
   9
  10 use base 'Moose::Meta::TypeConstraint';
  11
  12 __PACKAGE__->meta->add_attribute('values' => (
  13     accessor => 'values',
  14 ));
  15
  16 our %ENUMS;
  17
  18 my $inliner = sub {
  19     my $self = shift;
  20     my $val  = shift;
  21
  22     my $name = $self->name();
  23     $ENUMS{$name} ||= { map { $_ => 1 } @{ $self->values() } };
  24
  25     return
  26           "defined $val && " . '$'
  27         . __PACKAGE__
  28         . '::ENUMS{'
  29         . B::perlstring($name)
  30         . "}{ $val }";
  31 };
  32
  33 sub new {
  34     my ( $class, %args ) = @_;
  35
  36     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Str');
  37     $args{inlined} = $inliner;
  38
  39     if ( scalar @{ $args{values} } < 2 ) {
  40         require Moose;
  41         Moose->throw_error("You must have at least two values to enumerate through");
  42     }
  43
  44     for (@{ $args{values} }) {
  45         if (!defined($_)) {
  46             require Moose;
  47             Moose->throw_error("Enum values must be strings, not undef");
  48         }
  49         elsif (ref($_)) {
  50             require Moose;
  51             Moose->throw_error("Enum values must be strings, not '$_'");
  52         }
  53     }
  54
  55     my %values = map { $_ => 1 } @{ $args{values} };
  56     $args{constraint} = sub { $values{ $_[0] } };
  57
  58     my $self = $class->_new(\%args);
  59
  60     $self->compile_type_constraint()
  61         unless $self->_has_compiled_type_constraint;
  62
  63     return $self;
  64 }
  65
  66 sub equals {
  67     my ( $self, $type_or_name ) = @_;
  68
  69     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  70
  71     return unless $other->isa(__PACKAGE__);
  72
  73     my @self_values  = sort @{ $self->values };
  74     my @other_values = sort @{ $other->values };
  75
  76     return unless @self_values == @other_values;
  77
  78     while ( @self_values ) {
  79         my $value = shift @self_values;
  80         my $other_value = shift @other_values;
  81
  82         return unless $value eq $other_value;
  83     }
  84
  85     return 1;
  86 }
  87
  88 sub constraint {
  89     my $self = shift;
  90
  91     my %values = map { $_ => undef } @{ $self->values };
  92
  93     return sub { exists $values{$_[0]} };
  94 }
  95
  96 sub _compile_hand_optimized_type_constraint {
  97     my $self  = shift;
  98
  99     my %values = map { $_ => undef } @{ $self->values };
 100
 101     sub { defined($_[0]) && !ref($_[0]) && exists $values{$_[0]} };
 102 }
 103
 104 sub create_child_type {
 105     my ($self, @args) = @_;
 106     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 107 }
 108
 109 1;
 110
 111 # ABSTRACT: Type constraint for enumerated values.
 112
 113 __END__
 114
 115 =pod
 116
 117 =head1 DESCRIPTION
 118
 119 This class represents type constraints based on an enumerated list of
 120 acceptable values.
 121
 122 =head1 INHERITANCE
 123
 124 C<Moose::Meta::TypeConstraint::Enum> is a subclass of
 125 L<Moose::Meta::TypeConstraint>.
 126
 127 =head1 METHODS
 128
 129 =over 4
 130
 131 =item B<< Moose::Meta::TypeConstraint::Enum->new(%options) >>
 132
 133 This creates a new enum type constraint based on the given
 134 C<%options>.
 135
 136 It takes the same options as its parent, with several
 137 exceptions. First, it requires an additional option, C<values>. This
 138 should be an array reference containing a list of valid string
 139 values. Second, it automatically sets the parent to the C<Str> type.
 140
 141 Finally, it ignores any provided C<constraint> option. The constraint
 142 is generated automatically based on the provided C<values>.
 143
 144 =item B<< $constraint->values >>
 145
 146 Returns the array reference of acceptable values provided to the
 147 constructor.
 148
 149 =item B<< $constraint->create_child_type >>
 150
 151 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 152 as its parent.
 153
 154 Note that it does I<not> return a C<Moose::Meta::TypeConstraint::Enum>
 155 object!
 156
 157 =back
 158
 159 =head1 BUGS
 160
 161 See L<Moose/BUGS> for details on reporting bugs.
 162
 163 =cut
 164
 165