lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '0.01';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::TypeConstraint';
  14
  15 __PACKAGE__->meta->add_attribute('class' => (
  16     reader  => 'class',
  17 ));
  18
  19 sub new {
  20     my ( $class, %args ) = @_;
  21
  22     $args{class} = $args{name} unless exists $args{class};
  23
  24     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  25
  26     my $self  = $class->meta->new_object(%args);
  27
  28     $self->_create_hand_optimized_type_constraint;
  29
  30     $self->compile_type_constraint();
  31
  32     return $self;
  33 }
  34
  35 sub _create_hand_optimized_type_constraint {
  36     my $self = shift;
  37     my $class = $self->class;
  38     $self->hand_optimized_type_constraint(sub { blessed( $_[0] ) && $_[0]->isa($class) });
  39 }
  40
  41 sub parents {
  42     my $self = shift;
  43     return (
  44         $self->parent,
  45         map {
  46             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  47             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  48             # if anybody thinks this problematic please discuss on IRC.
  49             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  50             # regardless of their name
  51             Moose::Util::TypeConstraints::find_type_constraint($_) || __PACKAGE__->new( name => $_ )
  52         } $self->class->meta->superclasses,
  53     );
  54 }
  55
  56 sub equals {
  57     my ( $self, $type_or_name ) = @_;
  58
  59     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  60
  61     return unless $other->isa(__PACKAGE__);
  62
  63     return $self->class eq $other->class;
  64 }
  65
  66 sub is_a_type_of {
  67     my ($self, $type_or_name) = @_;
  68
  69     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  70
  71     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  72 }
  73
  74 sub is_subtype_of {
  75     my ($self, $type_or_name_or_class ) = @_;
  76
  77     if ( not ref $type_or_name_or_class ) {
  78         # it might be a class
  79         return 1 if $self->class->isa( $type_or_name_or_class );
  80     }
  81
  82     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  83
  84     if ( $type->isa(__PACKAGE__) ) {
  85         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  86         # or it could also just be a type object in this branch
  87         return $self->class->isa( $type->class );
  88     } else {
  89         # the only other thing we are a subtype of is Object
  90         $self->SUPER::is_subtype_of($type);
  91     }
  92 }
  93
  94 1;
  95
  96 __END__
  97
  98 =pod
  99
 100 =head1 NAME
 101
 102 Moose::Meta::TypeConstraint::Class - Class/TypeConstraint parallel hierarchy
 103
 104 =head1 METHODS
 105
 106 =over 4
 107
 108 =item B<new>
 109
 110 =item B<hand_optimized_type_constraint>
 111
 112 =item B<has_hand_optimized_type_constraint>
 113
 114 =item B<equals>
 115
 116 =item B<is_a_type_of>
 117
 118 =item B<is_subtype_of>
 119
 120 =item B<parents>
 121
 122 Return all the parent types, corresponding to the parent classes.
 123
 124 =item B<meta>
 125
 126 =back
 127
 128 =head1 BUGS
 129
 130 All complex software has bugs lurking in it, and this module is no
 131 exception. If you find a bug please either email me, or add the bug
 132 to cpan-RT.
 133
 134 =head1 AUTHOR
 135
 136 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 137
 138 =head1 COPYRIGHT AND LICENSE
 139
 140 Copyright 2006-2008 by Infinity Interactive, Inc.
 141
 142 L<http://www.iinteractive.com>
 143
 144 This library is free software; you can redistribute it and/or modify
 145 it under the same terms as Perl itself.
 146
 147 =cut