lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use B;
   8 use Scalar::Util 'blessed';
   9 use Moose::Util::TypeConstraints ();
  10
  11 use base 'Moose::Meta::TypeConstraint';
  12
  13 __PACKAGE__->meta->add_attribute('class' => (
  14     reader => 'class',
  15 ));
  16
  17 my $inliner = sub {
  18     my $self = shift;
  19     my $val  = shift;
  20
  21     return
  22         "Scalar::Util::blessed($val) && $val->isa("
  23         . B::perlstring( $self->class ) . ')';
  24 };
  25
  26 sub new {
  27     my ( $class, %args ) = @_;
  28
  29     $args{parent}
  30         = Moose::Util::TypeConstraints::find_type_constraint('Object');
  31
  32     my $class_name = $args{class};
  33     $args{constraint} = sub { $_[0]->isa($class_name) };
  34
  35     $args{inlined} = $inliner;
  36
  37     my $self = $class->_new( \%args );
  38
  39     $self->_create_hand_optimized_type_constraint;
  40     $self->compile_type_constraint();
  41
  42     return $self;
  43 }
  44
  45 sub _create_hand_optimized_type_constraint {
  46     my $self = shift;
  47     my $class = $self->class;
  48     $self->hand_optimized_type_constraint(
  49         sub {
  50             blessed( $_[0] ) && $_[0]->isa($class)
  51         }
  52     );
  53 }
  54
  55 sub parents {
  56     my $self = shift;
  57     return (
  58         $self->parent,
  59         map {
  60             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  61             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  62             # if anybody thinks this problematic please discuss on IRC.
  63             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  64             # regardless of their name
  65             Moose::Util::TypeConstraints::find_type_constraint($_)
  66                 ||
  67             __PACKAGE__->new( class => $_, name => "__ANON__" )
  68         } Class::MOP::class_of($self->class)->superclasses,
  69     );
  70 }
  71
  72 sub equals {
  73     my ( $self, $type_or_name ) = @_;
  74
  75     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  76
  77     return unless defined $other;
  78     return unless $other->isa(__PACKAGE__);
  79
  80     return $self->class eq $other->class;
  81 }
  82
  83 sub is_a_type_of {
  84     my ($self, $type_or_name) = @_;
  85
  86     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  87
  88     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  89 }
  90
  91 sub is_subtype_of {
  92     my ($self, $type_or_name_or_class ) = @_;
  93
  94     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  95
  96     if ( not defined $type ) {
  97         if ( not ref $type_or_name_or_class ) {
  98             # it might be a class
  99             return 1 if $self->class->isa( $type_or_name_or_class );
 100         }
 101         return;
 102     }
 103
 104     if ( $type->isa(__PACKAGE__) && $type->class ne $self->class) {
 105         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
 106         # or it could also just be a type object in this branch
 107         return $self->class->isa( $type->class );
 108     } else {
 109         # the only other thing we are a subtype of is Object
 110         $self->SUPER::is_subtype_of($type);
 111     }
 112 }
 113
 114 # This is a bit counter-intuitive, but a child type of a Class type
 115 # constraint is not itself a Class type constraint (it has no class
 116 # attribute). This whole create_child_type thing needs some changing
 117 # though, probably making MMC->new a factory or something.
 118 sub create_child_type {
 119     my ($self, @args) = @_;
 120     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 121 }
 122
 123 sub get_message {
 124     my $self = shift;
 125     my ($value) = @_;
 126
 127     if ($self->has_message) {
 128         return $self->SUPER::get_message(@_);
 129     }
 130
 131     $value = (defined $value ? overload::StrVal($value) : 'undef');
 132     return "Validation failed for '" . $self->name . "' with value $value (not isa " . $self->class . ")";
 133 }
 134
 135 1;
 136
 137 # ABSTRACT: Class/TypeConstraint parallel hierarchy
 138
 139 __END__
 140
 141 =pod
 142
 143 =head1 DESCRIPTION
 144
 145 This class represents type constraints for a class.
 146
 147 =head1 INHERITANCE
 148
 149 C<Moose::Meta::TypeConstraint::Class> is a subclass of
 150 L<Moose::Meta::TypeConstraint>.
 151
 152 =head1 METHODS
 153
 154 =over 4
 155
 156 =item B<< Moose::Meta::TypeConstraint::Class->new(%options) >>
 157
 158 This creates a new class type constraint based on the given
 159 C<%options>.
 160
 161 It takes the same options as its parent, with two exceptions. First,
 162 it requires an additional option, C<class>, which is name of the
 163 constraint's class.  Second, it automatically sets the parent to the
 164 C<Object> type.
 165
 166 The constructor also overrides the hand optimized type constraint with
 167 one it creates internally.
 168
 169 =item B<< $constraint->class >>
 170
 171 Returns the class name associated with the constraint.
 172
 173 =item B<< $constraint->parents >>
 174
 175 Returns all the type's parent types, corresponding to its parent
 176 classes.
 177
 178 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 179
 180 If the given type is also a class type, then this checks that the
 181 type's class is a subclass of the other type's class.
 182
 183 Otherwise it falls back to the implementation in
 184 L<Moose::Meta::TypeConstraint>.
 185
 186 =item B<< $constraint->create_child_type(%options) >>
 187
 188 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 189 as its parent.
 190
 191 Note that it does I<not> return a
 192 C<Moose::Meta::TypeConstraint::Class> object!
 193
 194 =item B<< $constraint->get_message($value) >>
 195
 196 This is the same as L<Moose::Meta::TypeConstraint/get_message> except
 197 that it explicitly says C<isa> was checked. This is to help users deal
 198 with accidentally autovivified type constraints.
 199
 200 =back
 201
 202 =head1 BUGS
 203
 204 See L<Moose/BUGS> for details on reporting bugs.
 205
 206 =cut