lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '0.02';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::TypeConstraint';
  14
  15 __PACKAGE__->meta->add_attribute('class' => (
  16     reader => 'class',
  17 ));
  18
  19 sub new {
  20     my ( $class, %args ) = @_;
  21
  22     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  23     my $self      = $class->meta->new_object(%args);
  24
  25     $self->_create_hand_optimized_type_constraint;
  26     $self->compile_type_constraint();
  27
  28     return $self;
  29 }
  30
  31 sub _create_hand_optimized_type_constraint {
  32     my $self = shift;
  33     my $class = $self->class;
  34     $self->hand_optimized_type_constraint(
  35         sub {
  36             blessed( $_[0] ) && $_[0]->isa($class)
  37         }
  38     );
  39 }
  40
  41 sub parents {
  42     my $self = shift;
  43     return (
  44         $self->parent,
  45         map {
  46             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  47             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  48             # if anybody thinks this problematic please discuss on IRC.
  49             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  50             # regardless of their name
  51             Moose::Util::TypeConstraints::find_type_constraint($_)
  52                 ||
  53             __PACKAGE__->new( class => $_, name => "__ANON__" )
  54         } $self->class->meta->superclasses,
  55     );
  56 }
  57
  58 sub equals {
  59     my ( $self, $type_or_name ) = @_;
  60
  61     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  62
  63     return unless $other->isa(__PACKAGE__);
  64
  65     return $self->class eq $other->class;
  66 }
  67
  68 sub is_a_type_of {
  69     my ($self, $type_or_name) = @_;
  70
  71     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  72
  73     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  74 }
  75
  76 sub is_subtype_of {
  77     my ($self, $type_or_name_or_class ) = @_;
  78
  79     if ( not ref $type_or_name_or_class ) {
  80         # it might be a class
  81         return 1 if $self->class->isa( $type_or_name_or_class );
  82     }
  83
  84     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  85
  86     if ( $type->isa(__PACKAGE__) ) {
  87         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  88         # or it could also just be a type object in this branch
  89         return $self->class->isa( $type->class );
  90     } else {
  91         # the only other thing we are a subtype of is Object
  92         $self->SUPER::is_subtype_of($type);
  93     }
  94 }
  95
  96 1;
  97
  98 __END__
  99
 100 =pod
 101
 102 =head1 NAME
 103
 104 Moose::Meta::TypeConstraint::Class - Class/TypeConstraint parallel hierarchy
 105
 106 =head1 METHODS
 107
 108 =over 4
 109
 110 =item B<new>
 111
 112 =item B<class>
 113
 114 =item B<hand_optimized_type_constraint>
 115
 116 =item B<has_hand_optimized_type_constraint>
 117
 118 =item B<equals>
 119
 120 =item B<is_a_type_of>
 121
 122 =item B<is_subtype_of>
 123
 124 =item B<parents>
 125
 126 Return all the parent types, corresponding to the parent classes.
 127
 128 =item B<meta>
 129
 130 =back
 131
 132 =head1 BUGS
 133
 134 All complex software has bugs lurking in it, and this module is no
 135 exception. If you find a bug please either email me, or add the bug
 136 to cpan-RT.
 137
 138 =head1 AUTHOR
 139
 140 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 141
 142 =head1 COPYRIGHT AND LICENSE
 143
 144 Copyright 2006-2008 by Infinity Interactive, Inc.
 145
 146 L<http://www.iinteractive.com>
 147
 148 This library is free software; you can redistribute it and/or modify
 149 it under the same terms as Perl itself.
 150
 151 =cut