lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::TypeConstraint';
  13
  14 __PACKAGE__->meta->add_attribute('class' => (
  15     reader => 'class',
  16 ));
  17
  18 sub new {
  19     my ( $class, %args ) = @_;
  20
  21     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  22     my $self      = $class->_new(\%args);
  23
  24     $self->_create_hand_optimized_type_constraint;
  25     $self->compile_type_constraint();
  26
  27     return $self;
  28 }
  29
  30 sub _create_hand_optimized_type_constraint {
  31     my $self = shift;
  32     my $class = $self->class;
  33     $self->hand_optimized_type_constraint(
  34         sub {
  35             blessed( $_[0] ) && blessed( $_[0] ) ne 'Regexp' && $_[0]->isa($class)
  36         }
  37     );
  38 }
  39
  40 sub parents {
  41     my $self = shift;
  42     return (
  43         $self->parent,
  44         map {
  45             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  46             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  47             # if anybody thinks this problematic please discuss on IRC.
  48             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  49             # regardless of their name
  50             Moose::Util::TypeConstraints::find_type_constraint($_)
  51                 ||
  52             __PACKAGE__->new( class => $_, name => "__ANON__" )
  53         } Class::MOP::class_of($self->class)->superclasses,
  54     );
  55 }
  56
  57 sub equals {
  58     my ( $self, $type_or_name ) = @_;
  59
  60     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  61
  62     return unless defined $other;
  63     return unless $other->isa(__PACKAGE__);
  64
  65     return $self->class eq $other->class;
  66 }
  67
  68 sub is_a_type_of {
  69     my ($self, $type_or_name) = @_;
  70
  71     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  72
  73     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  74 }
  75
  76 sub is_subtype_of {
  77     my ($self, $type_or_name_or_class ) = @_;
  78
  79     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  80
  81     if ( not defined $type ) {
  82         if ( not ref $type_or_name_or_class ) {
  83             # it might be a class
  84             return 1 if $self->class->isa( $type_or_name_or_class );
  85         }
  86         return;
  87     }
  88
  89     if ( $type->isa(__PACKAGE__) && $type->class ne $self->class) {
  90         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  91         # or it could also just be a type object in this branch
  92         return $self->class->isa( $type->class );
  93     } else {
  94         # the only other thing we are a subtype of is Object
  95         $self->SUPER::is_subtype_of($type);
  96     }
  97 }
  98
  99 # This is a bit counter-intuitive, but a child type of a Class type
 100 # constraint is not itself a Class type constraint (it has no class
 101 # attribute). This whole create_child_type thing needs some changing
 102 # though, probably making MMC->new a factory or something.
 103 sub create_child_type {
 104     my ($self, @args) = @_;
 105     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 106 }
 107
 108 sub get_message {
 109     my $self = shift;
 110     my ($value) = @_;
 111
 112     if ($self->has_message) {
 113         return $self->SUPER::get_message(@_);
 114     }
 115
 116     $value = (defined $value ? overload::StrVal($value) : 'undef');
 117     return "Validation failed for '" . $self->name . "' with value $value (not isa " . $self->class . ")";
 118 }
 119
 120 1;
 121
 122 # ABSTRACT: Class/TypeConstraint parallel hierarchy
 123
 124 __END__
 125
 126 =pod
 127
 128 =head1 DESCRIPTION
 129
 130 This class represents type constraints for a class.
 131
 132 =head1 INHERITANCE
 133
 134 C<Moose::Meta::TypeConstraint::Class> is a subclass of
 135 L<Moose::Meta::TypeConstraint>.
 136
 137 =head1 METHODS
 138
 139 =over 4
 140
 141 =item B<< Moose::Meta::TypeConstraint::Class->new(%options) >>
 142
 143 This creates a new class type constraint based on the given
 144 C<%options>.
 145
 146 It takes the same options as its parent, with two exceptions. First,
 147 it requires an additional option, C<class>, which is name of the
 148 constraint's class.  Second, it automatically sets the parent to the
 149 C<Object> type.
 150
 151 The constructor also overrides the hand optimized type constraint with
 152 one it creates internally.
 153
 154 =item B<< $constraint->class >>
 155
 156 Returns the class name associated with the constraint.
 157
 158 =item B<< $constraint->parents >>
 159
 160 Returns all the type's parent types, corresponding to its parent
 161 classes.
 162
 163 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 164
 165 If the given type is also a class type, then this checks that the
 166 type's class is a subclass of the other type's class.
 167
 168 Otherwise it falls back to the implementation in
 169 L<Moose::Meta::TypeConstraint>.
 170
 171 =item B<< $constraint->create_child_type(%options) >>
 172
 173 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 174 as its parent.
 175
 176 Note that it does I<not> return a
 177 C<Moose::Meta::TypeConstraint::Class> object!
 178
 179 =item B<< $constraint->get_message($value) >>
 180
 181 This is the same as L<Moose::Meta::TypeConstraint/get_message> except
 182 that it explicitly says C<isa> was checked. This is to help users deal
 183 with accidentally autovivified type constraints.
 184
 185 =back
 186
 187 =head1 BUGS
 188
 189 See L<Moose/BUGS> for details on reporting bugs.
 190
 191 =cut