lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 use base 'Moose::Meta::TypeConstraint';
  11
  12 __PACKAGE__->meta->add_attribute('class' => (
  13     reader => 'class',
  14 ));
  15
  16 sub new {
  17     my ( $class, %args ) = @_;
  18
  19     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  20     my $self      = $class->_new(\%args);
  21
  22     $self->_create_hand_optimized_type_constraint;
  23     $self->compile_type_constraint();
  24
  25     return $self;
  26 }
  27
  28 sub _create_hand_optimized_type_constraint {
  29     my $self = shift;
  30     my $class = $self->class;
  31     $self->hand_optimized_type_constraint(
  32         sub {
  33             blessed( $_[0] ) && blessed( $_[0] ) ne 'Regexp' && $_[0]->isa($class)
  34         }
  35     );
  36 }
  37
  38 sub parents {
  39     my $self = shift;
  40     return (
  41         $self->parent,
  42         map {
  43             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  44             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  45             # if anybody thinks this problematic please discuss on IRC.
  46             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  47             # regardless of their name
  48             Moose::Util::TypeConstraints::find_type_constraint($_)
  49                 ||
  50             __PACKAGE__->new( class => $_, name => "__ANON__" )
  51         } Class::MOP::class_of($self->class)->superclasses,
  52     );
  53 }
  54
  55 sub equals {
  56     my ( $self, $type_or_name ) = @_;
  57
  58     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  59
  60     return unless defined $other;
  61     return unless $other->isa(__PACKAGE__);
  62
  63     return $self->class eq $other->class;
  64 }
  65
  66 sub is_a_type_of {
  67     my ($self, $type_or_name) = @_;
  68
  69     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  70
  71     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  72 }
  73
  74 sub is_subtype_of {
  75     my ($self, $type_or_name_or_class ) = @_;
  76
  77     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  78
  79     if ( not defined $type ) {
  80         if ( not ref $type_or_name_or_class ) {
  81             # it might be a class
  82             return 1 if $self->class->isa( $type_or_name_or_class );
  83         }
  84         return;
  85     }
  86
  87     if ( $type->isa(__PACKAGE__) && $type->class ne $self->class) {
  88         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  89         # or it could also just be a type object in this branch
  90         return $self->class->isa( $type->class );
  91     } else {
  92         # the only other thing we are a subtype of is Object
  93         $self->SUPER::is_subtype_of($type);
  94     }
  95 }
  96
  97 # This is a bit counter-intuitive, but a child type of a Class type
  98 # constraint is not itself a Class type constraint (it has no class
  99 # attribute). This whole create_child_type thing needs some changing
 100 # though, probably making MMC->new a factory or something.
 101 sub create_child_type {
 102     my ($self, @args) = @_;
 103     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 104 }
 105
 106 sub get_message {
 107     my $self = shift;
 108     my ($value) = @_;
 109
 110     if ($self->has_message) {
 111         return $self->SUPER::get_message(@_);
 112     }
 113
 114     $value = (defined $value ? overload::StrVal($value) : 'undef');
 115     return "Validation failed for '" . $self->name . "' with value $value (not isa " . $self->class . ")";
 116 }
 117
 118 1;
 119
 120 # ABSTRACT: Class/TypeConstraint parallel hierarchy
 121
 122 __END__
 123
 124 =pod
 125
 126 =head1 DESCRIPTION
 127
 128 This class represents type constraints for a class.
 129
 130 =head1 INHERITANCE
 131
 132 C<Moose::Meta::TypeConstraint::Class> is a subclass of
 133 L<Moose::Meta::TypeConstraint>.
 134
 135 =head1 METHODS
 136
 137 =over 4
 138
 139 =item B<< Moose::Meta::TypeConstraint::Class->new(%options) >>
 140
 141 This creates a new class type constraint based on the given
 142 C<%options>.
 143
 144 It takes the same options as its parent, with two exceptions. First,
 145 it requires an additional option, C<class>, which is name of the
 146 constraint's class.  Second, it automatically sets the parent to the
 147 C<Object> type.
 148
 149 The constructor also overrides the hand optimized type constraint with
 150 one it creates internally.
 151
 152 =item B<< $constraint->class >>
 153
 154 Returns the class name associated with the constraint.
 155
 156 =item B<< $constraint->parents >>
 157
 158 Returns all the type's parent types, corresponding to its parent
 159 classes.
 160
 161 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 162
 163 If the given type is also a class type, then this checks that the
 164 type's class is a subclass of the other type's class.
 165
 166 Otherwise it falls back to the implementation in
 167 L<Moose::Meta::TypeConstraint>.
 168
 169 =item B<< $constraint->create_child_type(%options) >>
 170
 171 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 172 as its parent.
 173
 174 Note that it does I<not> return a
 175 C<Moose::Meta::TypeConstraint::Class> object!
 176
 177 =item B<< $constraint->get_message($value) >>
 178
 179 This is the same as L<Moose::Meta::TypeConstraint/get_message> except
 180 that it explicitly says C<isa> was checked. This is to help users deal
 181 with accidentally autovivified type constraints.
 182
 183 =back
 184
 185 =head1 BUGS
 186
 187 See L<Moose/BUGS> for details on reporting bugs.
 188
 189 =cut