lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use B;
   8 use Scalar::Util 'blessed';
   9 use Moose::Util::TypeConstraints ();
  10
  11 use base 'Moose::Meta::TypeConstraint';
  12
  13 __PACKAGE__->meta->add_attribute('class' => (
  14     reader => 'class',
  15     Class::MOP::_definition_context(),
  16 ));
  17
  18 my $inliner = sub {
  19     my $self = shift;
  20     my $val  = shift;
  21
  22     return 'Scalar::Util::blessed(' . $val . ')'
  23              . ' && ' . $val . '->isa(' . B::perlstring($self->class) . ')';
  24 };
  25
  26 sub new {
  27     my ( $class, %args ) = @_;
  28
  29     $args{parent}
  30         = Moose::Util::TypeConstraints::find_type_constraint('Object');
  31
  32     my $class_name = $args{class};
  33     $args{constraint} = sub { $_[0]->isa($class_name) };
  34
  35     $args{inlined} = $inliner;
  36
  37     my $self = $class->SUPER::new( \%args );
  38
  39     $self->compile_type_constraint();
  40
  41     return $self;
  42 }
  43
  44 sub parents {
  45     my $self = shift;
  46     return (
  47         $self->parent,
  48         map {
  49             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  50             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  51             # if anybody thinks this problematic please discuss on IRC.
  52             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  53             # regardless of their name
  54             Moose::Util::TypeConstraints::find_type_constraint($_)
  55                 ||
  56             __PACKAGE__->new( class => $_, name => "__ANON__" )
  57         } Class::MOP::class_of($self->class)->superclasses,
  58     );
  59 }
  60
  61 sub equals {
  62     my ( $self, $type_or_name ) = @_;
  63
  64     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  65
  66     return unless defined $other;
  67     return unless $other->isa(__PACKAGE__);
  68
  69     return $self->class eq $other->class;
  70 }
  71
  72 sub is_a_type_of {
  73     my ($self, $type_or_name) = @_;
  74
  75     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  76
  77     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  78 }
  79
  80 sub is_subtype_of {
  81     my ($self, $type_or_name_or_class ) = @_;
  82
  83     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  84
  85     if ( not defined $type ) {
  86         if ( not ref $type_or_name_or_class ) {
  87             # it might be a class
  88             return 1 if $self->class->isa( $type_or_name_or_class );
  89         }
  90         return;
  91     }
  92
  93     if ( $type->isa(__PACKAGE__) && $type->class ne $self->class) {
  94         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  95         # or it could also just be a type object in this branch
  96         return $self->class->isa( $type->class );
  97     } else {
  98         # the only other thing we are a subtype of is Object
  99         $self->SUPER::is_subtype_of($type);
 100     }
 101 }
 102
 103 # This is a bit counter-intuitive, but a child type of a Class type
 104 # constraint is not itself a Class type constraint (it has no class
 105 # attribute). This whole create_child_type thing needs some changing
 106 # though, probably making MMC->new a factory or something.
 107 sub create_child_type {
 108     my ($self, @args) = @_;
 109     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 110 }
 111
 112 sub get_message {
 113     my $self = shift;
 114     my ($value) = @_;
 115
 116     if ($self->has_message) {
 117         return $self->SUPER::get_message(@_);
 118     }
 119
 120     $value = (defined $value ? overload::StrVal($value) : 'undef');
 121     return "Validation failed for '" . $self->name . "' with value $value (not isa " . $self->class . ")";
 122 }
 123
 124 1;
 125
 126 # ABSTRACT: Class/TypeConstraint parallel hierarchy
 127
 128 __END__
 129
 130 =pod
 131
 132 =head1 DESCRIPTION
 133
 134 This class represents type constraints for a class.
 135
 136 =head1 INHERITANCE
 137
 138 C<Moose::Meta::TypeConstraint::Class> is a subclass of
 139 L<Moose::Meta::TypeConstraint>.
 140
 141 =head1 METHODS
 142
 143 =over 4
 144
 145 =item B<< Moose::Meta::TypeConstraint::Class->new(%options) >>
 146
 147 This creates a new class type constraint based on the given
 148 C<%options>.
 149
 150 It takes the same options as its parent, with two exceptions. First,
 151 it requires an additional option, C<class>, which is name of the
 152 constraint's class.  Second, it automatically sets the parent to the
 153 C<Object> type.
 154
 155 The constructor also overrides the hand optimized type constraint with
 156 one it creates internally.
 157
 158 =item B<< $constraint->class >>
 159
 160 Returns the class name associated with the constraint.
 161
 162 =item B<< $constraint->parents >>
 163
 164 Returns all the type's parent types, corresponding to its parent
 165 classes.
 166
 167 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 168
 169 If the given type is also a class type, then this checks that the
 170 type's class is a subclass of the other type's class.
 171
 172 Otherwise it falls back to the implementation in
 173 L<Moose::Meta::TypeConstraint>.
 174
 175 =item B<< $constraint->create_child_type(%options) >>
 176
 177 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 178 as its parent.
 179
 180 Note that it does I<not> return a
 181 C<Moose::Meta::TypeConstraint::Class> object!
 182
 183 =item B<< $constraint->get_message($value) >>
 184
 185 This is the same as L<Moose::Meta::TypeConstraint/get_message> except
 186 that it explicitly says C<isa> was checked. This is to help users deal
 187 with accidentally autovivified type constraints.
 188
 189 =back
 190
 191 =head1 BUGS
 192
 193 See L<Moose/BUGS> for details on reporting bugs.
 194
 195 =cut