lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Carp         'confess';
   9 use Scalar::Util 'blessed';
  10
  11 our $VERSION   = '0.55_03';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Class;
  16 use Moose::Meta::Role::Method;
  17 use Moose::Meta::Role::Method::Required;
  18
  19 use base 'Class::MOP::Module';
  20
  21 ## ------------------------------------------------------------------
  22 ## NOTE:
  23 ## I normally don't do this, but I am doing
  24 ## a whole bunch of meta-programmin in this
  25 ## module, so it just makes sense. For a clearer
  26 ## picture of what is going on in the next
  27 ## several lines of code, look at the really
  28 ## big comment at the end of this file (right
  29 ## before the POD).
  30 ## - SL
  31 ## ------------------------------------------------------------------
  32
  33 my $META = __PACKAGE__->meta;
  34
  35 ## ------------------------------------------------------------------
  36 ## attributes ...
  37
  38 # NOTE:
  39 # since roles are lazy, we hold all the attributes
  40 # of the individual role in 'statis' until which
  41 # time when it is applied to a class. This means
  42 # keeping a lot of things in hash maps, so we are
  43 # using a little of that meta-programmin' magic
  44 # here an saving lots of extra typin. And since
  45 # many of these attributes above require similar
  46 # functionality to support them, so we again use
  47 # the wonders of meta-programmin' to deliver a
  48 # very compact solution to this normally verbose
  49 # problem.
  50 # - SL
  51
  52 foreach my $action (
  53     {
  54         name        => 'excluded_roles_map',
  55         attr_reader => 'get_excluded_roles_map' ,
  56         methods     => {
  57             add       => 'add_excluded_roles',
  58             get_list  => 'get_excluded_roles_list',
  59             existence => 'excludes_role',
  60         }
  61     },
  62     {
  63         name        => 'required_methods',
  64         attr_reader => 'get_required_methods_map',
  65         methods     => {
  66             add       => 'add_required_methods',
  67             remove    => 'remove_required_methods',
  68             get_list  => 'get_required_method_list',
  69             existence => 'requires_method',
  70         }
  71     },
  72     {
  73         name        => 'attribute_map',
  74         attr_reader => 'get_attribute_map',
  75         methods     => {
  76             get       => 'get_attribute',
  77             get_list  => 'get_attribute_list',
  78             existence => 'has_attribute',
  79             remove    => 'remove_attribute',
  80         }
  81     }
  82 ) {
  83
  84     my $attr_reader = $action->{attr_reader};
  85     my $methods     = $action->{methods};
  86
  87     # create the attribute
  88     $META->add_attribute($action->{name} => (
  89         reader  => $attr_reader,
  90         default => sub { {} }
  91     ));
  92
  93     # create some helper methods
  94     $META->add_method($methods->{add} => sub {
  95         my ($self, @values) = @_;
  96         $self->$attr_reader->{$_} = undef foreach @values;
  97     }) if exists $methods->{add};
  98
  99     $META->add_method($methods->{get_list} => sub {
 100         my ($self) = @_;
 101         keys %{$self->$attr_reader};
 102     }) if exists $methods->{get_list};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 ## some things don't always fit, so they go here ...
 121
 122 sub add_attribute {
 123     my $self = shift;
 124     my $name = shift;
 125     my $attr_desc;
 126     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 127         $attr_desc = $_[0];
 128     }
 129     else {
 130         $attr_desc = { @_ };
 131     }
 132     $self->get_attribute_map->{$name} = $attr_desc;
 133 }
 134
 135 # DEPRECATED
 136 # sub _clean_up_required_methods {
 137 #     my $self = shift;
 138 #     foreach my $method ($self->get_required_method_list) {
 139 #         $self->remove_required_methods($method)
 140 #             if $self->has_method($method);
 141 #     }
 142 # }
 143
 144 ## ------------------------------------------------------------------
 145 ## method modifiers
 146
 147 # NOTE:
 148 # the before/around/after method modifiers are
 149 # stored by name, but there can be many methods
 150 # then associated with that name. So again we have
 151 # lots of similar functionality, so we can do some
 152 # meta-programmin' and save some time.
 153 # - SL
 154
 155 foreach my $modifier_type (qw[ before around after ]) {
 156
 157     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 158
 159     # create the attribute ...
 160     $META->add_attribute("${modifier_type}_method_modifiers" => (
 161         reader  => $attr_reader,
 162         default => sub { {} }
 163     ));
 164
 165     # and some helper methods ...
 166     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 167         my ($self, $method_name) = @_;
 168         #return () unless exists $self->$attr_reader->{$method_name};
 169         @{$self->$attr_reader->{$method_name}};
 170     });
 171
 172     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 173         my ($self, $method_name) = @_;
 174         # NOTE:
 175         # for now we assume that if it exists,..
 176         # it has at least one modifier in it
 177         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 178     });
 179
 180     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 181         my ($self, $method_name, $method) = @_;
 182
 183         $self->$attr_reader->{$method_name} = []
 184             unless exists $self->$attr_reader->{$method_name};
 185
 186         my $modifiers = $self->$attr_reader->{$method_name};
 187
 188         # NOTE:
 189         # check to see that we aren't adding the
 190         # same code twice. We err in favor of the
 191         # first on here, this may not be as expected
 192         foreach my $modifier (@{$modifiers}) {
 193             return if $modifier == $method;
 194         }
 195
 196         push @{$modifiers} => $method;
 197     });
 198
 199 }
 200
 201 ## ------------------------------------------------------------------
 202 ## override method mofidiers
 203
 204 $META->add_attribute('override_method_modifiers' => (
 205     reader  => 'get_override_method_modifiers_map',
 206     default => sub { {} }
 207 ));
 208
 209 # NOTE:
 210 # these are a little different because there
 211 # can only be one per name, whereas the other
 212 # method modifiers can have multiples.
 213 # - SL
 214
 215 sub add_override_method_modifier {
 216     my ($self, $method_name, $method) = @_;
 217     (!$self->has_method($method_name))
 218         || confess "Cannot add an override of method '$method_name' " .
 219                    "because there is a local version of '$method_name'";
 220     $self->get_override_method_modifiers_map->{$method_name} = $method;
 221 }
 222
 223 sub has_override_method_modifier {
 224     my ($self, $method_name) = @_;
 225     # NOTE:
 226     # for now we assume that if it exists,..
 227     # it has at least one modifier in it
 228     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 229 }
 230
 231 sub get_override_method_modifier {
 232     my ($self, $method_name) = @_;
 233     $self->get_override_method_modifiers_map->{$method_name};
 234 }
 235
 236 ## general list accessor ...
 237
 238 sub get_method_modifier_list {
 239     my ($self, $modifier_type) = @_;
 240     my $accessor = "get_${modifier_type}_method_modifiers_map";
 241     keys %{$self->$accessor};
 242 }
 243
 244 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 245 sub update_package_cache_flag {
 246     my $self = shift;
 247     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 248 }
 249
 250
 251
 252 ## ------------------------------------------------------------------
 253 ## subroles
 254
 255 __PACKAGE__->meta->add_attribute('roles' => (
 256     reader  => 'get_roles',
 257     default => sub { [] }
 258 ));
 259
 260 sub add_role {
 261     my ($self, $role) = @_;
 262     (blessed($role) && $role->isa('Moose::Meta::Role'))
 263         || confess "Roles must be instances of Moose::Meta::Role";
 264     push @{$self->get_roles} => $role;
 265     $self->reset_package_cache_flag;
 266 }
 267
 268 sub calculate_all_roles {
 269     my $self = shift;
 270     my %seen;
 271     grep {
 272         !$seen{$_->name}++
 273     } ($self, map {
 274                   $_->calculate_all_roles
 275               } @{ $self->get_roles });
 276 }
 277
 278 sub does_role {
 279     my ($self, $role_name) = @_;
 280     (defined $role_name)
 281         || confess "You must supply a role name to look for";
 282     # if we are it,.. then return true
 283     return 1 if $role_name eq $self->name;
 284     # otherwise.. check our children
 285     foreach my $role (@{$self->get_roles}) {
 286         return 1 if $role->does_role($role_name);
 287     }
 288     return 0;
 289 }
 290
 291 ## ------------------------------------------------------------------
 292 ## methods
 293
 294 sub method_metaclass { 'Moose::Meta::Role::Method' }
 295
 296 sub get_method_map {
 297     my $self = shift;
 298
 299     my $current = Class::MOP::check_package_cache_flag($self->name);
 300
 301     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 302         return $self->{'methods'} ||= {};
 303     }
 304
 305     $self->{_package_cache_flag} = $current;
 306
 307     my $map  = $self->{'methods'} ||= {};
 308
 309     my $role_name        = $self->name;
 310     my $method_metaclass = $self->method_metaclass;
 311
 312     my %all_code = $self->get_all_package_symbols('CODE');
 313
 314     foreach my $symbol (keys %all_code) {
 315         my $code = $all_code{$symbol};
 316
 317         next if exists  $map->{$symbol} &&
 318                 defined $map->{$symbol} &&
 319                         $map->{$symbol}->body == $code;
 320
 321         my ($pkg, $name) = Class::MOP::get_code_info($code);
 322
 323         if ($pkg->can('meta')
 324             # NOTE:
 325             # we don't know what ->meta we are calling
 326             # here, so we need to be careful cause it
 327             # just might blow up at us, or just complain
 328             # loudly (in the case of Curses.pm) so we
 329             # just be a little overly cautious here.
 330             # - SL
 331             && eval { no warnings; blessed($pkg->meta) } # FIXME calls meta
 332             && $pkg->meta->isa('Moose::Meta::Role')) {
 333             my $role = $pkg->meta->name;
 334             next unless $self->does_role($role);
 335         }
 336         else {
 337             # NOTE:
 338             # in 5.10 constant.pm the constants show up
 339             # as being in the right package, but in pre-5.10
 340             # they show up as constant::__ANON__ so we
 341             # make an exception here to be sure that things
 342             # work as expected in both.
 343             # - SL
 344             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 345                 next if ($pkg  || '') ne $role_name ||
 346                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 347             }
 348         }
 349
 350         $map->{$symbol} = $method_metaclass->wrap(
 351             $code,
 352             package_name => $role_name,
 353             name         => $name
 354         );
 355     }
 356
 357     return $map;
 358 }
 359
 360 sub get_method {
 361     my ($self, $name) = @_;
 362     $self->get_method_map->{$name};
 363 }
 364
 365 sub has_method {
 366     my ($self, $name) = @_;
 367     exists $self->get_method_map->{$name} ? 1 : 0
 368 }
 369
 370 # FIXME this is copypasated from Class::MOP::Class
 371 # refactor to inherit from some common base
 372 sub wrap_method_body {
 373     my ( $self, %args ) = @_;
 374
 375     my $body = delete $args{body}; # delete is for compat
 376
 377     ('CODE' eq ref($body))
 378         || confess "Your code block must be a CODE reference";
 379
 380     $self->method_metaclass->wrap( $body => (
 381         package_name => $self->name,
 382         %args,
 383     ));
 384 }
 385
 386 sub add_method {
 387     my ($self, $method_name, $method) = @_;
 388     (defined $method_name && $method_name)
 389     || confess "You must define a method name";
 390
 391     my $body;
 392     if (blessed($method)) {
 393         $body = $method->body;
 394         if ($method->package_name ne $self->name &&
 395             $method->name         ne $method_name) {
 396             warn "Hello there, got something for you."
 397             . " Method says " . $method->package_name . " " . $method->name
 398             . " Class says " . $self->name . " " . $method_name;
 399             $method = $method->clone(
 400                 package_name => $self->name,
 401                 name         => $method_name
 402             ) if $method->can('clone');
 403         }
 404     }
 405     else {
 406         $body = $method;
 407         $method = $self->wrap_method_body( body => $body, name => $method_name );
 408     }
 409
 410     $method->attach_to_class($self);
 411
 412     $self->get_method_map->{$method_name} = $method;
 413
 414     my $full_method_name = ($self->name . '::' . $method_name);
 415     $self->add_package_symbol(
 416         { sigil => '&', type => 'CODE', name => $method_name },
 417         Class::MOP::subname($full_method_name => $body)
 418     );
 419
 420     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 421 }
 422
 423 sub find_method_by_name { (shift)->get_method(@_) }
 424
 425 sub get_method_list {
 426     my $self = shift;
 427     grep { !/^meta$/ } keys %{$self->get_method_map};
 428 }
 429
 430 sub alias_method {
 431     my ($self, $method_name, $method) = @_;
 432     (defined $method_name && $method_name)
 433         || confess "You must define a method name";
 434
 435     my $body = (blessed($method) ? $method->body : $method);
 436     ('CODE' eq ref($body))
 437         || confess "Your code block must be a CODE reference";
 438
 439     $self->add_package_symbol(
 440         { sigil => '&', type => 'CODE', name => $method_name },
 441         $body
 442     );
 443 }
 444
 445 ## ------------------------------------------------------------------
 446 ## role construction
 447 ## ------------------------------------------------------------------
 448
 449 sub apply {
 450     my ($self, $other, @args) = @_;
 451
 452     (blessed($other))
 453         || confess "You must pass in an blessed instance";
 454
 455     if ($other->isa('Moose::Meta::Role')) {
 456         require Moose::Meta::Role::Application::ToRole;
 457         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 458     }
 459     elsif ($other->isa('Moose::Meta::Class')) {
 460         require Moose::Meta::Role::Application::ToClass;
 461         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 462     }
 463     else {
 464         require Moose::Meta::Role::Application::ToInstance;
 465         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 466     }
 467 }
 468
 469 sub apply_to_metaclass_instance {
 470     my ($self, $meta, @args) = @_;
 471
 472     $meta->isa('Moose::Meta::Class') || $meta->isa('Moose::Meta::Role')
 473         || confess "You must pass in a Moose::Meta::Class or Moose::Meta::Role instance";
 474
 475     require Moose::Meta::Role::Application::ToMetaclassInstance;
 476     return Moose::Meta::Role::Application::ToMetaclassInstance->new(@args)->apply($self, $meta);
 477 }
 478
 479 sub combine {
 480     my ($class, @role_specs) = @_;
 481
 482     require Moose::Meta::Role::Application::RoleSummation;
 483     require Moose::Meta::Role::Composite;
 484
 485     my (@roles, %role_params);
 486     while (@role_specs) {
 487         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 488         push @roles => $role->meta;
 489         next unless defined $params;
 490         $role_params{$role} = $params;
 491     }
 492
 493     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 494     Moose::Meta::Role::Application::RoleSummation->new(
 495         role_params => \%role_params
 496     )->apply($c);
 497
 498     return $c;
 499 }
 500
 501 #####################################################################
 502 ## NOTE:
 503 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 504 ## MooseX::AttributeHelpers module). It is here as a reference to
 505 ## make it easier to see what is happening above with all the meta
 506 ## programming. - SL
 507 #####################################################################
 508 #
 509 # has 'roles' => (
 510 #     metaclass => 'Collection::Array',
 511 #     reader    => 'get_roles',
 512 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 513 #     default   => sub { [] },
 514 #     provides  => {
 515 #         'push' => 'add_role',
 516 #     }
 517 # );
 518 #
 519 # has 'excluded_roles_map' => (
 520 #     metaclass => 'Collection::Hash',
 521 #     reader    => 'get_excluded_roles_map',
 522 #     isa       => 'HashRef[Str]',
 523 #     provides  => {
 524 #         # Not exactly set, cause it sets multiple
 525 #         'set'    => 'add_excluded_roles',
 526 #         'keys'   => 'get_excluded_roles_list',
 527 #         'exists' => 'excludes_role',
 528 #     }
 529 # );
 530 #
 531 # has 'attribute_map' => (
 532 #     metaclass => 'Collection::Hash',
 533 #     reader    => 'get_attribute_map',
 534 #     isa       => 'HashRef[Str]',
 535 #     provides => {
 536 #         # 'set'  => 'add_attribute' # has some special crap in it
 537 #         'get'    => 'get_attribute',
 538 #         'keys'   => 'get_attribute_list',
 539 #         'exists' => 'has_attribute',
 540 #         # Not exactly delete, cause it sets multiple
 541 #         'delete' => 'remove_attribute',
 542 #     }
 543 # );
 544 #
 545 # has 'required_methods' => (
 546 #     metaclass => 'Collection::Hash',
 547 #     reader    => 'get_required_methods_map',
 548 #     isa       => 'HashRef[Str]',
 549 #     provides  => {
 550 #         # not exactly set, or delete since it works for multiple
 551 #         'set'    => 'add_required_methods',
 552 #         'delete' => 'remove_required_methods',
 553 #         'keys'   => 'get_required_method_list',
 554 #         'exists' => 'requires_method',
 555 #     }
 556 # );
 557 #
 558 # # the before, around and after modifiers are
 559 # # HASH keyed by method-name, with ARRAY of
 560 # # CODE refs to apply in that order
 561 #
 562 # has 'before_method_modifiers' => (
 563 #     metaclass => 'Collection::Hash',
 564 #     reader    => 'get_before_method_modifiers_map',
 565 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 566 #     provides  => {
 567 #         'keys'   => 'get_before_method_modifiers',
 568 #         'exists' => 'has_before_method_modifiers',
 569 #         # This actually makes sure there is an
 570 #         # ARRAY at the given key, and pushed onto
 571 #         # it. It also checks for duplicates as well
 572 #         # 'add'  => 'add_before_method_modifier'
 573 #     }
 574 # );
 575 #
 576 # has 'after_method_modifiers' => (
 577 #     metaclass => 'Collection::Hash',
 578 #     reader    =>'get_after_method_modifiers_map',
 579 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 580 #     provides  => {
 581 #         'keys'   => 'get_after_method_modifiers',
 582 #         'exists' => 'has_after_method_modifiers',
 583 #         # This actually makes sure there is an
 584 #         # ARRAY at the given key, and pushed onto
 585 #         # it. It also checks for duplicates as well
 586 #         # 'add'  => 'add_after_method_modifier'
 587 #     }
 588 # );
 589 #
 590 # has 'around_method_modifiers' => (
 591 #     metaclass => 'Collection::Hash',
 592 #     reader    =>'get_around_method_modifiers_map',
 593 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 594 #     provides  => {
 595 #         'keys'   => 'get_around_method_modifiers',
 596 #         'exists' => 'has_around_method_modifiers',
 597 #         # This actually makes sure there is an
 598 #         # ARRAY at the given key, and pushed onto
 599 #         # it. It also checks for duplicates as well
 600 #         # 'add'  => 'add_around_method_modifier'
 601 #     }
 602 # );
 603 #
 604 # # override is similar to the other modifiers
 605 # # except that it is not an ARRAY of code refs
 606 # # but instead just a single name->code mapping
 607 #
 608 # has 'override_method_modifiers' => (
 609 #     metaclass => 'Collection::Hash',
 610 #     reader    =>'get_override_method_modifiers_map',
 611 #     isa       => 'HashRef[CodeRef]',
 612 #     provides  => {
 613 #         'keys'   => 'get_override_method_modifier',
 614 #         'exists' => 'has_override_method_modifier',
 615 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 616 #     }
 617 # );
 618 #
 619 #####################################################################
 620
 621
 622 1;
 623
 624 __END__
 625
 626 =pod
 627
 628 =head1 NAME
 629
 630 Moose::Meta::Role - The Moose Role metaclass
 631
 632 =head1 DESCRIPTION
 633
 634 Please see L<Moose::Role> for more information about roles.
 635 For the most part, this has no user-serviceable parts inside
 636 this module. It's API is still subject to some change (although
 637 probably not that much really).
 638
 639 =head1 METHODS
 640
 641 =over 4
 642
 643 =item B<meta>
 644
 645 =item B<new>
 646
 647 =item B<apply>
 648
 649 =item B<apply_to_metaclass_instance>
 650
 651 =item B<combine>
 652
 653 =back
 654
 655 =over 4
 656
 657 =item B<name>
 658
 659 =item B<version>
 660
 661 =item B<role_meta>
 662
 663 =back
 664
 665 =over 4
 666
 667 =item B<get_roles>
 668
 669 =item B<add_role>
 670
 671 =item B<does_role>
 672
 673 =back
 674
 675 =over 4
 676
 677 =item B<add_excluded_roles>
 678
 679 =item B<excludes_role>
 680
 681 =item B<get_excluded_roles_list>
 682
 683 =item B<get_excluded_roles_map>
 684
 685 =item B<calculate_all_roles>
 686
 687 =back
 688
 689 =over 4
 690
 691 =item B<method_metaclass>
 692
 693 =item B<find_method_by_name>
 694
 695 =item B<get_method>
 696
 697 =item B<has_method>
 698
 699 =item B<add_method>
 700
 701 =item B<wrap_method_body>
 702
 703 =item B<alias_method>
 704
 705 =item B<get_method_list>
 706
 707 =item B<get_method_map>
 708
 709 =item B<update_package_cache_flag>
 710
 711 =item B<reset_package_cache_flag>
 712
 713 =back
 714
 715 =over 4
 716
 717 =item B<add_attribute>
 718
 719 =item B<has_attribute>
 720
 721 =item B<get_attribute>
 722
 723 =item B<get_attribute_list>
 724
 725 =item B<get_attribute_map>
 726
 727 =item B<remove_attribute>
 728
 729 =back
 730
 731 =over 4
 732
 733 =item B<add_required_methods>
 734
 735 =item B<remove_required_methods>
 736
 737 =item B<get_required_method_list>
 738
 739 =item B<get_required_methods_map>
 740
 741 =item B<requires_method>
 742
 743 =back
 744
 745 =over 4
 746
 747 =item B<add_after_method_modifier>
 748
 749 =item B<add_around_method_modifier>
 750
 751 =item B<add_before_method_modifier>
 752
 753 =item B<add_override_method_modifier>
 754
 755 =over 4
 756
 757 =back
 758
 759 =item B<has_after_method_modifiers>
 760
 761 =item B<has_around_method_modifiers>
 762
 763 =item B<has_before_method_modifiers>
 764
 765 =item B<has_override_method_modifier>
 766
 767 =over 4
 768
 769 =back
 770
 771 =item B<get_after_method_modifiers>
 772
 773 =item B<get_around_method_modifiers>
 774
 775 =item B<get_before_method_modifiers>
 776
 777 =item B<get_method_modifier_list>
 778
 779 =over 4
 780
 781 =back
 782
 783 =item B<get_override_method_modifier>
 784
 785 =item B<get_after_method_modifiers_map>
 786
 787 =item B<get_around_method_modifiers_map>
 788
 789 =item B<get_before_method_modifiers_map>
 790
 791 =item B<get_override_method_modifiers_map>
 792
 793 =back
 794
 795 =head1 BUGS
 796
 797 All complex software has bugs lurking in it, and this module is no
 798 exception. If you find a bug please either email me, or add the bug
 799 to cpan-RT.
 800
 801 =head1 AUTHOR
 802
 803 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 804
 805 =head1 COPYRIGHT AND LICENSE
 806
 807 Copyright 2006-2008 by Infinity Interactive, Inc.
 808
 809 L<http://www.iinteractive.com>
 810
 811 This library is free software; you can redistribute it and/or modify
 812 it under the same terms as Perl itself.
 813
 814 =cut