lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Carp         'confess';
   9 use Scalar::Util 'blessed';
  10 use B            'svref_2object';
  11
  12 use Moose::Meta::Class;
  13
  14 our $VERSION = '0.04';
  15
  16 ## Attributes
  17
  18 ## the meta for the role package
  19
  20 __PACKAGE__->meta->add_attribute('_role_meta' => (
  21     reader   => '_role_meta',
  22     init_arg => ':role_meta'
  23 ));
  24
  25 ## roles
  26
  27 __PACKAGE__->meta->add_attribute('roles' => (
  28     reader  => 'get_roles',
  29     default => sub { [] }
  30 ));
  31
  32 ## excluded roles
  33
  34 __PACKAGE__->meta->add_attribute('excluded_roles_map' => (
  35     reader  => 'get_excluded_roles_map',
  36     default => sub { {} }
  37 ));
  38
  39 ## attributes
  40
  41 __PACKAGE__->meta->add_attribute('attribute_map' => (
  42     reader   => 'get_attribute_map',
  43     default  => sub { {} }
  44 ));
  45
  46 ## required methods
  47
  48 __PACKAGE__->meta->add_attribute('required_methods' => (
  49     reader  => 'get_required_methods_map',
  50     default => sub { {} }
  51 ));
  52
  53 ## method modifiers
  54
  55 __PACKAGE__->meta->add_attribute('before_method_modifiers' => (
  56     reader  => 'get_before_method_modifiers_map',
  57     default => sub { {} } # (<name> => [ (CODE) ])
  58 ));
  59
  60 __PACKAGE__->meta->add_attribute('after_method_modifiers' => (
  61     reader  => 'get_after_method_modifiers_map',
  62     default => sub { {} } # (<name> => [ (CODE) ])
  63 ));
  64
  65 __PACKAGE__->meta->add_attribute('around_method_modifiers' => (
  66     reader  => 'get_around_method_modifiers_map',
  67     default => sub { {} } # (<name> => [ (CODE) ])
  68 ));
  69
  70 __PACKAGE__->meta->add_attribute('override_method_modifiers' => (
  71     reader  => 'get_override_method_modifiers_map',
  72     default => sub { {} } # (<name> => CODE)
  73 ));
  74
  75 ## Methods
  76
  77 sub new {
  78     my $class   = shift;
  79     my %options = @_;
  80     $options{':role_meta'} = Moose::Meta::Class->initialize(
  81         $options{role_name},
  82         ':method_metaclass' => 'Moose::Meta::Role::Method'
  83     ) unless defined $options{':role_meta'} &&
  84              $options{':role_meta'}->isa('Moose::Meta::Class');
  85     my $self = $class->meta->new_object(%options);
  86     return $self;
  87 }
  88
  89 ## subroles
  90
  91 sub add_role {
  92     my ($self, $role) = @_;
  93     (blessed($role) && $role->isa('Moose::Meta::Role'))
  94         || confess "Roles must be instances of Moose::Meta::Role";
  95     push @{$self->get_roles} => $role;
  96 }
  97
  98 sub calculate_all_roles {
  99     my $self = shift;
 100     my %seen;
 101     grep { !$seen{$_->name}++ } $self, map { $_->calculate_all_roles } @{ $self->get_roles };
 102 }
 103
 104 sub does_role {
 105     my ($self, $role_name) = @_;
 106     (defined $role_name)
 107         || confess "You must supply a role name to look for";
 108     # if we are it,.. then return true
 109     return 1 if $role_name eq $self->name;
 110     # otherwise.. check our children
 111     foreach my $role (@{$self->get_roles}) {
 112         return 1 if $role->does_role($role_name);
 113     }
 114     return 0;
 115 }
 116
 117 ## excluded roles
 118
 119 sub add_excluded_roles {
 120     my ($self, @excluded_role_names) = @_;
 121     $self->get_excluded_roles_map->{$_} = undef foreach @excluded_role_names;
 122 }
 123
 124 sub get_excluded_roles_list {
 125     my ($self) = @_;
 126     keys %{$self->get_excluded_roles_map};
 127 }
 128
 129 sub excludes_role {
 130     my ($self, $role_name) = @_;
 131     exists $self->get_excluded_roles_map->{$role_name} ? 1 : 0;
 132 }
 133
 134 ## required methods
 135
 136 sub add_required_methods {
 137     my ($self, @methods) = @_;
 138     $self->get_required_methods_map->{$_} = undef foreach @methods;
 139 }
 140
 141 sub remove_required_methods {
 142     my ($self, @methods) = @_;
 143     delete $self->get_required_methods_map->{$_} foreach @methods;
 144 }
 145
 146 sub get_required_method_list {
 147     my ($self) = @_;
 148     keys %{$self->get_required_methods_map};
 149 }
 150
 151 sub requires_method {
 152     my ($self, $method_name) = @_;
 153     exists $self->get_required_methods_map->{$method_name} ? 1 : 0;
 154 }
 155
 156 sub _clean_up_required_methods {
 157     my $self = shift;
 158     foreach my $method ($self->get_required_method_list) {
 159         $self->remove_required_methods($method)
 160             if $self->has_method($method);
 161     }
 162 }
 163
 164 ## methods
 165
 166 # NOTE:
 167 # we delegate to some role_meta methods for convience here
 168 # the Moose::Meta::Role is meant to be a read-only interface
 169 # to the underlying role package, if you want to manipulate
 170 # that, just use ->role_meta
 171
 172 sub name    { (shift)->_role_meta->name    }
 173 sub version { (shift)->_role_meta->version }
 174
 175 sub get_method      { (shift)->_role_meta->get_method(@_)   }
 176 sub has_method      { (shift)->_role_meta->has_method(@_)   }
 177 sub alias_method    { (shift)->_role_meta->alias_method(@_) }
 178 sub get_method_list {
 179     my ($self) = @_;
 180     grep {
 181         # NOTE:
 182         # this is a kludge for now,... these functions
 183         # should not be showing up in the list at all,
 184         # but they do, so we need to switch Moose::Role
 185         # and Moose to use Sub::Exporter to prevent this
 186         !/^(meta|has|extends|blessed|confess|augment|inner|override|super|before|after|around|with|requires)$/
 187     } $self->_role_meta->get_method_list;
 188 }
 189
 190 # ... however the items in statis (attributes & method modifiers)
 191 # can be removed and added to through this API
 192
 193 # attributes
 194
 195 sub add_attribute {
 196     my $self = shift;
 197     my $name = shift;
 198     my $attr_desc;
 199     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 200         $attr_desc = $_[0];
 201     }
 202     else {
 203         $attr_desc = { @_ };
 204     }
 205     $self->get_attribute_map->{$name} = $attr_desc;
 206 }
 207
 208 sub has_attribute {
 209     my ($self, $name) = @_;
 210     exists $self->get_attribute_map->{$name} ? 1 : 0;
 211 }
 212
 213 sub get_attribute {
 214     my ($self, $name) = @_;
 215     $self->get_attribute_map->{$name}
 216 }
 217
 218 sub remove_attribute {
 219     my ($self, $name) = @_;
 220     delete $self->get_attribute_map->{$name}
 221 }
 222
 223 sub get_attribute_list {
 224     my ($self) = @_;
 225     keys %{$self->get_attribute_map};
 226 }
 227
 228
 229 ## applying a role to a class ...
 230
 231 sub _check_excluded_roles {
 232     my ($self, $other) = @_;
 233     if ($other->excludes_role($self->name)) {
 234         confess "Conflict detected: " . $other->name . " excludes role '" . $self->name . "'";
 235     }
 236     foreach my $excluded_role_name ($self->get_excluded_roles_list) {
 237         if ($other->does_role($excluded_role_name)) {
 238             confess "The class " . $other->name . " does the excluded role '$excluded_role_name'";
 239         }
 240         else {
 241             if ($other->isa('Moose::Meta::Role')) {
 242                 $other->add_excluded_roles($excluded_role_name);
 243             }
 244             # else -> ignore it :)
 245         }
 246     }
 247 }
 248
 249 sub _check_required_methods {
 250     my ($self, $other) = @_;
 251     # NOTE:
 252     # we might need to move this down below the
 253     # the attributes so that we can require any
 254     # attribute accessors. However I am thinking
 255     # that maybe those are somehow exempt from
 256     # the require methods stuff.
 257     foreach my $required_method_name ($self->get_required_method_list) {
 258
 259         # FIXME:
 260         # This should not call has_method, instead it should
 261         # call find_method_by_name (to be added to Class::MOP)
 262         unless ($other->has_method($required_method_name)) {
 263             if ($other->isa('Moose::Meta::Role')) {
 264                 $other->add_required_methods($required_method_name);
 265             }
 266             else {
 267                 confess "'" . $self->name . "' requires the method '$required_method_name' " .
 268                         "to be implemented by '" . $other->name . "'";
 269             }
 270         }
 271         else {
 272             # NOTE:
 273             # we need to make sure that the method is
 274             # not a method modifier, because those do
 275             # not satisfy the requirements ...
 276
 277             # FIXME:
 278             # This should also call find_method_by_name
 279             my $method = $other->get_method($required_method_name);
 280             # check if it is an override or a generated accessor ..
 281             (!$method->isa('Moose::Meta::Method::Overriden') &&
 282              !$method->isa('Class::MOP::Attribute::Accessor'))
 283                 || confess "'" . $self->name . "' requires the method '$required_method_name' " .
 284                            "to be implemented by '" . $other->name . "', the method is only a method modifier";
 285             # before/after/around methods are a little trickier
 286             # since we wrap the original local method (if applicable)
 287             # so we need to check if the original wrapped method is
 288             # from the same package, and not a wrap of the super method
 289             if ($method->isa('Class::MOP::Method::Wrapped')) {
 290                 ($method->get_original_method->package_name eq $other->name)
 291                     || confess "'" . $self->name . "' requires the method '$required_method_name' " .
 292                                "to be implemented by '" . $other->name . "', the method is only a method modifier";
 293             }
 294         }
 295     }
 296 }
 297
 298 sub _apply_attributes {
 299     my ($self, $other) = @_;
 300     foreach my $attribute_name ($self->get_attribute_list) {
 301         # it if it has one already
 302         if ($other->has_attribute($attribute_name) &&
 303             # make sure we haven't seen this one already too
 304             $other->get_attribute($attribute_name) != $self->get_attribute($attribute_name)) {
 305             # see if we are being composed
 306             # into a role or not
 307             if ($other->isa('Moose::Meta::Role')) {
 308                 # all attribute conflicts between roles
 309                 # result in an immediate fatal error
 310                 confess "Role '" . $self->name . "' has encountered an attribute conflict " .
 311                         "during composition. This is fatal error and cannot be disambiguated.";
 312             }
 313             else {
 314                 # but if this is a class, we
 315                 # can safely skip adding the
 316                 # attribute to the class
 317                 next;
 318             }
 319         }
 320         else {
 321             $other->add_attribute(
 322                 $attribute_name,
 323                 $self->get_attribute($attribute_name)
 324             );
 325         }
 326     }
 327 }
 328
 329 sub _apply_methods {
 330     my ($self, $other) = @_;
 331     foreach my $method_name ($self->get_method_list) {
 332         # it if it has one already
 333         if ($other->has_method($method_name) &&
 334             # and if they are not the same thing ...
 335             $other->get_method($method_name) != $self->get_method($method_name)) {
 336             # see if we are composing into a role
 337             if ($other->isa('Moose::Meta::Role')) {
 338                 # method conflicts between roles result
 339                 # in the method becoming a requirement
 340                 $other->add_required_methods($method_name);
 341                 # NOTE:
 342                 # we have to remove the method from our
 343                 # role, if this is being called from combine()
 344                 # which means the meta is an anon class
 345                 # this *may* cause problems later, but it
 346                 # is probably fairly safe to assume that
 347                 # anon classes will only be used internally
 348                 # or by people who know what they are doing
 349                 $other->_role_meta->remove_method($method_name)
 350                     if $other->_role_meta->name =~ /__ANON__/;
 351             }
 352             else {
 353                 next;
 354             }
 355         }
 356         else {
 357             # add it, although it could be overriden
 358             $other->alias_method(
 359                 $method_name,
 360                 $self->get_method($method_name)
 361             );
 362         }
 363     }
 364 }
 365
 366 sub apply {
 367     my ($self, $other) = @_;
 368
 369     $self->_check_excluded_roles($other);
 370     $self->_check_required_methods($other);
 371
 372     $self->_apply_attributes($other);
 373     $self->_apply_methods($other);
 374
 375     $other->add_role($self);
 376 }
 377
 378 sub combine {
 379     my ($class, @roles) = @_;
 380
 381     my $combined = $class->new(
 382         ':role_meta' => Moose::Meta::Class->create_anon_class()
 383     );
 384
 385     foreach my $role (@roles) {
 386         $role->apply($combined);
 387     }
 388
 389     $combined->_clean_up_required_methods;
 390
 391     return $combined;
 392 }
 393
 394 package Moose::Meta::Role::Method;
 395
 396 use strict;
 397 use warnings;
 398
 399 our $VERSION = '0.01';
 400
 401 use base 'Class::MOP::Method';
 402
 403 1;
 404
 405 __END__
 406
 407 =pod
 408
 409 =head1 NAME
 410
 411 Moose::Meta::Role - The Moose Role metaclass
 412
 413 =head1 DESCRIPTION
 414
 415 Moose's Roles are being actively developed, please see L<Moose::Role>
 416 for more information. For the most part, this has no user-serviceable
 417 parts inside. It's API is still subject to some change (although
 418 probably not that much really).
 419
 420 =head1 METHODS
 421
 422 =over 4
 423
 424 =item B<meta>
 425
 426 =item B<new>
 427
 428 =item B<apply>
 429
 430 =item B<combine>
 431
 432 =back
 433
 434 =over 4
 435
 436 =item B<name>
 437
 438 =item B<version>
 439
 440 =item B<role_meta>
 441
 442 =back
 443
 444 =over 4
 445
 446 =item B<get_roles>
 447
 448 =item B<add_role>
 449
 450 =item B<does_role>
 451
 452 =back
 453
 454 =over 4
 455
 456 =item B<add_excluded_roles>
 457
 458 =item B<excludes_role>
 459
 460 =item B<get_excluded_roles_list>
 461
 462 =item B<get_excluded_roles_map>
 463
 464 =item B<calculate_all_roles>
 465
 466 =back
 467
 468 =over 4
 469
 470 =item B<get_method>
 471
 472 =item B<has_method>
 473
 474 =item B<alias_method>
 475
 476 =item B<get_method_list>
 477
 478 =back
 479
 480 =over 4
 481
 482 =item B<add_attribute>
 483
 484 =item B<has_attribute>
 485
 486 =item B<get_attribute>
 487
 488 =item B<get_attribute_list>
 489
 490 =item B<get_attribute_map>
 491
 492 =item B<remove_attribute>
 493
 494 =back
 495
 496 =over 4
 497
 498 =item B<add_required_methods>
 499
 500 =item B<remove_required_methods>
 501
 502 =item B<get_required_method_list>
 503
 504 =item B<get_required_methods_map>
 505
 506 =item B<requires_method>
 507
 508 =back
 509
 510 =over 4
 511
 512 =item B<add_after_method_modifier>
 513
 514 =item B<add_around_method_modifier>
 515
 516 =item B<add_before_method_modifier>
 517
 518 =item B<add_override_method_modifier>
 519
 520 =over 4
 521
 522 =back
 523
 524 =item B<has_after_method_modifiers>
 525
 526 =item B<has_around_method_modifiers>
 527
 528 =item B<has_before_method_modifiers>
 529
 530 =item B<has_override_method_modifier>
 531
 532 =over 4
 533
 534 =back
 535
 536 =item B<get_after_method_modifiers>
 537
 538 =item B<get_around_method_modifiers>
 539
 540 =item B<get_before_method_modifiers>
 541
 542 =item B<get_method_modifier_list>
 543
 544 =over 4
 545
 546 =back
 547
 548 =item B<get_override_method_modifier>
 549
 550 =item B<get_after_method_modifiers_map>
 551
 552 =item B<get_around_method_modifiers_map>
 553
 554 =item B<get_before_method_modifiers_map>
 555
 556 =item B<get_override_method_modifiers_map>
 557
 558 =back
 559
 560 =head1 BUGS
 561
 562 All complex software has bugs lurking in it, and this module is no
 563 exception. If you find a bug please either email me, or add the bug
 564 to cpan-RT.
 565
 566 =head1 AUTHOR
 567
 568 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 569
 570 =head1 COPYRIGHT AND LICENSE
 571
 572 Copyright 2006 by Infinity Interactive, Inc.
 573
 574 L<http://www.iinteractive.com>
 575
 576 This library is free software; you can redistribute it and/or modify
 577 it under the same terms as Perl itself.
 578
 579 =cut